poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 include <funcs.scad>
   4
   5 coarse = false;
   6
   7 main_dia = 71.2 + 0.50 - 2.26;
   8 top_thick_middle = 4;
   9 top_thick_by_oring = 3.0;
  10 top_middle_dr = 11;
  11
  12 main_cnr = 6.0;
  13
  14 min_wall = 3;
  15
  16 rivet_posn = 6.0 + 0.30;
  17 rivet_thick = 1.67;
  18 rivet_width = 4.15 + 1.0;
  19 rivet_tall = 5.51 + 1.49;
  20
  21 over_rivet_wall = 1.0;
  22 side_rivet_gap = 1.5;
  23 inside_rivet_gap = 1.5;
  24
  25 bayo_interf = 0.30;
  26 bayo_behind = 3.5;
  27 bayo_interf_width = 2.0;
  28 bayo_interf_slope = 0.5;
  29
  30 oring_thick = 5.0;
  31 oring_bore = 62.0;
  32
  33 oring_upper_embed_angle = 80;
  34 oring_compress = 0.1; // proportion
  35 oring_compress_more = 0.2;
  36
  37 oring_rm_beside = 8;
  38 oring_rm_scale = 2.0;
  39 oring_rm_angle = 20;
  40
  41 side_taper = 1.0;
  42
  43 bayo_gap = 6.0;
  44
  45 bayo_entry = bayo_behind/3;
  46
  47 bayo_slice_size = coarse ? 5 : 1;
  48
  49 brace_hole_width = 1.0;
  50 brace_above_below = 1.2;
  51 brace_end_shorter = 0.3;
  52
  53 jig_thick = 1.4;
  54 jig_hole_dia = 3.0;
  55 jig_rim = 5;
  56 jig_mark = 5;
  57
  58 strap_hoop_thick = 6;
  59 strap_hoop_inside = 10;
  60 strap_hoop_strlen = 10;
  61 strap_hoop_elevation = 45;
  62
  63 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  64 sm_main_thick = 2.0;
  65 sm_main_width = 20;
  66
  67 sm_bolt_dia = 3.5 + 0.1;
  68 sm_bolt_shaft = 21.9;
  69 sm_bolt_head_dia = 6.94 + 1.0;
  70 sm_bolt_head_thick = 2.14;
  71 sm_bolt_nut_width = 5.89 + 0.25;
  72 sm_bolt_nut_thick = 3.68;
  73 sm_bolt_tighten_allow = 2.0;
  74
  75 sm_bolt_y_clear = 0.75;
  76 sm_bolt_y_over = 0.5;
  77
  78 sm_closure_cnr = 3.0;
  79
  80 catch_stem_h = 3;
  81 catch_stem_len = 50;
  82 catch_stem_th = 3;
  83
  84 catch_pin_slop = 0.25; // each side, and above
  85 catch_pin_slop_x_extra = 0.25; // only on one side
  86 catch_stalk_above_gap = 1.5;
  87 catch_stalk_eff_bend_rad = catch_stem_len * 0.75;
  88
  89 catch_stalk_base_width = 15;
  90
  91 catch_knob_dia = 6;
  92 catch_knob_above_gap = 8;
  93 catch_knob_height = 6;
  94
  95 catch_stem_below_gap = 1.0;
  96 catch_stem_beside_gap = 2.0;
  97 catch_pin_gap = 0.5;
  98 catch_hook_slope = 0.15;
  99
 100 // calculated
 101
 102 TAU = PI*2;
 103
 104 bayo_entry_x = bayo_entry;
 105 bayo_entry_z = bayo_entry;
 106 bayo_inramp_x = bayo_entry;
 107 bayo_inramp_z = bayo_entry;
 108
 109 oring_mid_dia = oring_bore + oring_thick;
 110 oring_outer_dia = oring_mid_dia + oring_thick;
 111
 112 oring_oblate = (1 - oring_compress);
 113
 114 oring_y_rad = oring_thick/2 * oring_oblate;
 115 oring_x_rad = oring_thick/2 / oring_oblate;
 116
 117 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 118
 119 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 120 side_thick = rivet_tall + over_rivet_wall;
 121
 122 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 123
 124 middle_bot_z = top_z - top_thick_middle;
 125
 126 bayo_entry = bayo_behind / 3.0;
 127 bayo_top_z = bayo_behind + bayo_gap;
 128
 129 bayo_nom_rad = main_dia/2 + side_thick;
 130 bayo_real_rad = main_dia/2 + rivet_tall;
 131
 132 rivet_entry_width = rivet_width + side_rivet_gap;
 133
 134 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 135
 136 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 137 handling_angle = 45;
 138
 139 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 140 sm_outer_rad = sm_inner_rad + sm_main_thick;
 141
 142 smc_pos = [ 0, sm_inner_rad, 0 ];
 143
 144 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 145 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 146
 147 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 148 smc_max_y = smc_bolt_y + sm_bolt_y_over
 149   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 150 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 151   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 152
 153 catch_cr = catch_knob_dia/2 + catch_stem_beside_gap;
 154 catch_strap_width = sm_main_width;
 155 catch_strap_thick = sm_main_thick;
 156 catch_stem_end_h = catch_stem_h;
 157 catch_pin_width = (rivet_entry_width * sm_inner_rad / bayo_nom_rad)
 158                    - catch_pin_gap;
 159
 160 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 161
 162 $fs= coarse ? 2.5 : 0.5;
 163 $fa= coarse ? 5 : 1;
 164
 165 include <poster-tube-lid-parametric.scad>
 166
 167 // bayonet definition
 168
 169 bayo_a = [ bayo_entry_x, 0 ];
 170 bayo_p = [ 0, bayo_entry_z ];
 171 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 172 bayo_m = [ bayo_inramp_x, bayo_behind ];
 173 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 174 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 175 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 176 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 177 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 178 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 179
 180 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 181 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 182 bayo_c = bayo_d + [0,-5];
 183 bayo_b = bayo_a + [0,-5];
 184
 185 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 186
 187 bayo_polygon = [ bayo_a,
 188                  bayo_b,
 189                  bayo_c,
 190                  bayo_d,
 191                  bayo_e,
 192                  bayo_f,
 193                  bayo_g,
 194                  bayo_h,
 195                  bayo_i,
 196                  bayo_j,
 197                  bayo_k,
 198                  bayo_l,
 199                  bayo_m,
 200                  bayo_n,
 201                  bayo_p ];
 202
 203 echo(bayo_polygon);
 204
 205 // CATCH
 206
 207 //cppy6 = -catch_strap_width * 2/3;
 208
 209 cppxC = 0.41 * sm_inner_rad * TAU;
 210
 211 // catch pin
 212
 213 cppa = bayo_f + [1,-1] * catch_pin_slop;
 214 cppb = bayo_g + [1,-1] * catch_pin_slop;
 215 cppd = [ bayo_n[0] - catch_pin_slop - catch_pin_slop_x_extra,
 216          -catch_stalk_above_gap ];
 217 cppc = [ cppd[0], cppb[1] ];
 218 cpph = cppd + [0,-1] * catch_stem_h;
 219 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 220 cppf = [ cppa[0], cppe[1] ];
 221 cppg = [ cppa[0], cpph[1] ];
 222 cppB = 0.5 * (cppf + cppe);
 223
 224 // catch assembly depression below pin
 225
 226 cppy6 = cppB[1] - (catch_knob_dia/2
 227                    + (cppc[1] - cppd[1])
 228                    + catch_stem_below_gap);
 229 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 230 cpp11 = cpp7 + [1,0] * catch_cr;
 231 cppy9 = cppy6 + catch_strap_width * 1/3;
 232 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 233 cpp8 = cpp9 + [0,-1] * catch_cr;
 234 cpp10 = cpp8 + [-1,0] * catch_cr;
 235 cppC = [ cppxC, cpp9[1] ];
 236 cppD = cppC + [0,-1] * catch_strap_width;
 237
 238 // catch assembly stalk and so on
 239
 240 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 241 cpp4 = [ cppg[0] - catch_stem_len, cpph[1] ] + [1,-1] * catch_cr;
 242 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 243 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 244 cpp2r = cpp2 + [1,0] * catch_cr;
 245 cpp2d = cpp2 + [0,-1] * catch_cr;
 246 cpp3 = [ cpp2[0] + catch_cr * 2, cppd[1] - catch_cr ];
 247 cppA = [ -cppxC, cpp9[1] ];
 248 cppE = [ cppA[0], cppD[1] ];
 249
 250 catch_assembly_dy = -cppy9 + catch_strap_width;
 251
 252
 253 module MainProfile(){
 254   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 255   difference(){
 256     union(){
 257       translate(main_cnr_pos){
 258         intersection(){
 259           difference(){
 260             circle(r = main_cnr);
 261             circle(r = main_cnr * 0.5);
 262           }
 263           square([10,10]);
 264         }
 265       }
 266       polygon([[ -top_middle_dr,        middle_bot_z      ],
 267                [ -top_middle_dr,        top_z             ],
 268                [ main_cnr_pos[0],       top_z             ],
 269                [ side_thick,            main_cnr_pos[1]   ],
 270                [ side_thick,            -side_height      ],
 271                [ side_taper,            -side_height      ],
 272                [ 0,                     -rivet_posn       ],
 273                [ 0,                     by_oring_z        ],
 274                [ -oring_x_rad,          by_oring_z        ],
 275                ],
 276               convexity=10);
 277     }
 278     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 279       hull(){
 280       translate([ 0, oring_y_rad ])
 281         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 282         circle(oring_thick/2);
 283       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 284         circle(oring_thick/2);
 285     }
 286   }
 287 }
 288
 289 module StrapHoopProfile(){
 290   circle(r = strap_hoop_thick/2);
 291 }
 292
 293 module StrapHoop(){ ////toplevel
 294   bigrad = strap_hoop_inside/2 + strap_hoop_thick/2;
 295   extralen = strap_hoop_thick * 5;
 296
 297   intersection(){
 298     rotate([strap_hoop_elevation, 0,0]){
 299       for (x= [ -1, +1 ] * bigrad) {
 300         translate([x, -extralen, 0])
 301           rotate([-90,0,0])
 302           linear_extrude(height= extralen + strap_hoop_strlen + 0.1,
 303                          convexity=10)
 304           StrapHoopProfile();
 305       }
 306       translate([0, strap_hoop_strlen, 0]){
 307         intersection(){
 308           rotate_extrude(convexity=10)
 309             translate([bigrad, 0,0])
 310             StrapHoopProfile();
 311           translate([0,50,0])
 312             cube([100,100,100], center=true);
 313         }
 314       }
 315     }
 316     translate([0, 50, 0])
 317       cube(100, center=true);
 318   }
 319 }
 320
 321 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 322   // nom_rad > real_rad
 323   rotate([0,0, atan2(offset, nom_rad) ]){
 324     intersection(){
 325       translate([-offset, -10, 0])
 326         rotate([90,0,0])
 327         linear_extrude(height= nom_rad*2)
 328         children(0);
 329       translate([0,0, -25])
 330         cylinder(h=50, r= real_rad);
 331       translate([0,0, -25])
 332         linear_extrude(height= 50)
 333         polygon([ [ 0,0 ],
 334                   [ -slice_size, -real_rad*2 ],
 335                   [ +slice_size, -real_rad*2 ] ]);
 336     }
 337   }
 338 }
 339
 340 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 341   offs = [ for (i=[ x_min :
 342                     slice_size :
 343                     x_max + slice_size ]) i ];
 344   echo (offs);
 345   for (off=offs)
 346     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 347     children(0);
 348 }
 349
 350 module BayonetCutout(){
 351   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 352                 bayo_nom_rad,
 353                 bayo_real_rad)
 354     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 355     polygon(bayo_polygon, convexity=10);
 356 }
 357
 358 module ProfilesDemo(){ ////toplevel
 359   translate([-10,0]) MainProfile();
 360   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 361 }
 362
 363 module LimitForHandling(){ ////toplevel
 364   hull() for (r=[0,180])
 365     rotate([0,0,r]) {
 366       for (rs=[-1,+1]) {
 367         for (xd=[0,1]) {
 368           rotate([0,0, rs * handling_angle/2]) {
 369             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 370                        main_dia/2 + side_thick - main_cnr,
 371                        top_z - main_cnr]) {
 372               mirror([0,0,1])
 373                 cylinder(r= main_cnr, h=50);
 374               sphere(main_cnr);
 375             }
 376           }
 377         }
 378       }
 379     }
 380   hull() rotate_extrude(){
 381     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 382       circle(r = main_cnr);
 383       mirror([0,1]) square([ main_cnr, 50 ]);
 384     }
 385   }
 386   //cylinder(r= handling_dia/2, h=20);
 387 }
 388
 389 module Cover(){ ////toplevel
 390   render() difference(){
 391     intersection(){
 392       union(){
 393         rotate_extrude(convexity=10)
 394           translate([main_dia/2, 0])
 395           MainProfile();
 396         translate([0,0, middle_bot_z])
 397           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 398       }
 399       LimitForHandling();
 400     }
 401     for (r=[0,180]){
 402       rotate([0,0, r])
 403         translate([0,0, -side_height])
 404         BayonetCutout();
 405       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 406         translate([0,
 407                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 408                    oring_y_rad * 1.5])
 409         rotate([-oring_rm_angle, 0, 0])
 410         mirror([0,0,1])
 411         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 412     }
 413     for (r=[0 : 60 : 179]) {
 414       rotate([0,0, r]) {
 415         height = top_thick_middle - brace_above_below*2;
 416         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 417         cube(center=true, [ oring_bore - brace_end_shorter,
 418                             brace_hole_width, height ]);
 419       }
 420     }
 421   }
 422   for (r=[0,180])
 423     rotate([0,0,r])
 424       translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 425                  -implheadcup_large_dia * .0,
 426                  middle_bot_z + 0.1])
 427       ImplHeadCup();
 428 //  translate(strap_hoop_thick * [-0.5, 0, +1])
 429 //    translate([handling_dia/2, 0, -side_height])
 430 //    rotate([0,180,0]) rotate([0,0,90])
 431 //    StrapHoop();
 432 }
 433
 434 module SavingHole(){
 435   translate([0,0, -10])
 436     cylinder(r= main_dia/2 - jig_rim, h=20);
 437 }
 438
 439 module Jig(){ ////toplevel
 440   difference(){
 441     union(){
 442       translate([0,0, -side_height]){
 443         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 444       }
 445       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 446         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 447     }
 448     translate([0,0, -side_height-1])
 449       cylinder(r= main_dia/2, h= side_height + 1);
 450     SavingHole();
 451     translate([0,0, -rivet_posn])
 452       rotate([90, 0,0])
 453       translate([0,0, -100])
 454       cylinder(r= jig_hole_dia/2, h = 200);
 455   }
 456 }
 457
 458 module CoverTest2(){ ////toplevel
 459   difference(){
 460     Cover();
 461     SavingHole();
 462   }
 463 }
 464
 465 module CoverTest1(){ ////toplevel
 466   difference(){
 467     CoverTest2();
 468     difference(){
 469       for (r= [ 40, 147 ]){
 470         rotate([0,0, r]){
 471           translate([0,0, -10]) {
 472             cube([ main_dia*3, main_dia * .53, 18], center=true);
 473           }
 474         }
 475       }
 476 //      translate([ 50, 0, 0 ])
 477 //      cube([ 100,
 478 //             strap_hoop_inside + strap_hoop_thick*2 + 1,
 479 //             100 ],
 480 //           center=true);
 481     }
 482   }
 483 }
 484
 485 module ImplHeadCupTest(){ ////toplevel
 486   for (r=[0,180])
 487     rotate([0,0,r])
 488       translate([-17,0,0])
 489       ImplHeadCup();
 490 }
 491
 492 module SomeStrap(){
 493   // children(0) is to add, (1) subtract
 494   difference(){
 495     union(){
 496       cylinder(r=sm_outer_rad, h=sm_main_width);
 497       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 498                            smc_max_y,
 499                            sm_closure_cnr);
 500       children(0);
 501     }
 502     translate([0,0,-1])
 503       cylinder(r=sm_inner_rad, h=sm_main_width+2);
 504     translate(smc_pos)
 505       StrapMountBolt(10);
 506     translate(smc_pos)
 507       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 508     children(1);
 509   }
 510 }
 511
 512 module StrapMountBolt(l_delta){ ///toplevel
 513   // positioned relative to smc_pos
 514   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 515              smc_bolt_y,
 516              sm_main_width/2]){
 517     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 518       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 519     }
 520     translate([ -sm_bolt_shaft/2, 0,0 ])
 521       rotate([0,-90,0])
 522       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 523                h=smc_bolt_nut_eff_thick + l_delta);
 524     translate([ sm_bolt_shaft/2, 0,0 ])
 525       rotate([0,90,0])
 526       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 527   }
 528 }
 529
 530 module StrapMountProtrusion(half_x, max_y, cnr){
 531   translate(smc_pos){
 532     linear_extrude(height=sm_main_width, convexity=10){
 533       hull(){
 534         for (m = [0,1]) mirror([m,0,0]) {
 535           translate([-(half_x - cnr), max_y - cnr])
 536             circle(r=cnr);
 537           translate([-half_x, -sm_inner_rad])
 538             square([1,1]);
 539         }
 540       }
 541     }
 542   }
 543 }
 544
 545 module StrapMount(){ ////toplevel
 546   SomeStrap(){
 547     rotate([0,0,180]){
 548       StrapMountProtrusion(strap_hoop_inside/2 + strap_hoop_thick,
 549                            strap_hoop_thick,
 550                            sm_closure_cnr);
 551       translate(smc_pos +
 552                 [0,0, sm_main_width] +
 553                 strap_hoop_thick * [ 0, 0.5, -1.0 ])
 554         StrapHoop();
 555     }
 556     union(){ };
 557   }
 558 }
 559
 560 module CatchAssemblyCoreProfile(){
 561   difference(){
 562     union(){
 563       hull(){
 564         translate(cpp3) circle(r= catch_cr);
 565         polygon([ cpp3,
 566                   cpp2r,
 567                   cpp5,
 568                   cpph,
 569                   cppd
 570                   ]);
 571       }
 572       polygon([cppD,
 573                cppC,
 574                cpp9,
 575                cpp10,
 576                cpp11,
 577                cpp4,
 578                cpp2r,
 579                cpp2d,
 580                cppA,
 581                cppE
 582                ]);
 583       translate(cpp8) circle(r= catch_cr);
 584     }
 585     hull(){
 586       translate(cpp4) circle(r= catch_cr);
 587       translate(cpp5) circle(r= catch_cr);
 588       translate(cpp7) circle(r= catch_cr);
 589       polygon([cpp4,
 590                cppg,
 591                cpph,
 592                cpp10,
 593                cpp11,
 594                ]);
 595     }
 596     translate(cpp2) circle(r= catch_cr);
 597   }
 598 }
 599
 600 module CatchHeadProfile(){
 601   intersection(){
 602     translate(cppF){
 603       difference(){
 604         circle(r = dist2d(cppF, cppd));
 605         circle(r = dist2d(cppF, cppa));
 606       }
 607     }
 608     polygon([ cppa,
 609               cppg,
 610               cpph,
 611               cppd,
 612               cppc,
 613               cppb ]);
 614   }
 615   polygon([ cppd,
 616             cppg,
 617             cppf,
 618             cppe,
 619             cpph ]);
 620 }
 621
 622
 623 module CatchCore(){ /////toplevel
 624   linear_extrude(height=catch_strap_thick, convexity=10)
 625     CatchAssemblyCoreProfile();
 626
 627   linear_extrude(height=catch_strap_thick, convexity=10)
 628     CatchHeadProfile();
 629
 630   translate(concat(cppB,[0])) hull(){
 631     translate([0,0, catch_knob_height - catch_knob_dia/2])
 632       sphere(r = catch_knob_dia/2);
 633     cylinder(r = catch_knob_dia/2, h = 0.1);
 634   }
 635 }
 636
 637 module CatchPreDistort(){ /////toplevel
 638   scale(100 / sm_inner_rad)
 639     rotate([90,0,0])
 640     CatchCore();
 641 }
 642
 643 module CatchAssembly(){ /////toplevel
 644   rotate([0,0, -(cppe[0] + cppB[0]) / sm_inner_rad * 360/TAU])
 645     translate([0,0, catch_assembly_dy])
 646     scale(sm_inner_rad / 100)
 647     import(str("poster-tube-lid,CatchPostDistort-fa",
 648                (coarse ? 20 : 3),
 649                ".stl"),
 650            convexity=20);
 651
 652   SomeStrap(){
 653     union(){ }
 654     union(){
 655       translate([-200, -200, -200])
 656         cube([400, 200, 400]);
 657     }
 658   }
 659 }
 660
 661 module CatchDemo(){ /////toplevel
 662   color("blue") translate([0,0,
 663                            -catch_assembly_dy
 664              ])
 665     CatchAssembly();
 666   translate([0,0,+side_height
 667              ])
 668     Cover();
 669 }
 670
 671 module CatchDemoS(){ /////toplevel
 672   color("blue") translate([0,0,
 673              -catch_assembly_dy
 674              ])
 675     CatchAssembly();
 676   intersection(){
 677     translate([0,0,+side_height
 678                ])
 679       Cover();
 680     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 681   }
 682   color("black")
 683     translate([0,-33,0])
 684     cube([6.15, 2,2], center=true);
 685 }
 686
 687 module CatchPinProfileDemo(){ /////toplevel
 688   echo("G ",
 689        cpp2[0] - cpp1[0],
 690        bayo_n[0] - bayo_e[0]);
 691   color("blue") translate([0,0,
 692                            +1,
 693              ]) {
 694     CatchAssemblyCoreProfile();
 695     CatchHeadProfile();
 696   }
 697   polygon(bayo_polygon, convexity=10);
 698 }
 699
 700 //ProfilesDemo();
 701 //BayonetCutout();
 702 //MainProfile();
 703 //Cover();
 704 //Jig();
 705 //CoverTest();