poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 main_dia = 71.2 + 0.50 - 2.26;
   4 top_minthick_middle = 4;
   5 top_minthick_by_oring = 2.5;
   6
   7 main_cnr = 4.0;
   8
   9 rivet_posn = 6.0;
  10 rivet_thick = 1.67;
  11 rivet_width = 4.15 + 1.0;
  12 rivet_tall = 5.51 + 0.49;
  13
  14 over_rivet_wall = 0.5;
  15 side_rivet_gap = 1.5;
  16
  17 bayo_interf = 1.25;
  18 bayo_behind = 3.5;
  19 bayo_interf_width = 2.0;
  20 bayo_interf_slope = 0.75;
  21
  22 oring_thick = 5.0;
  23 oring_bore = 62.0;
  24
  25 oring_upper_embed_angle = 80;
  26 oring_compress = 0.1; // proportion
  27
  28 side_taper = 1.0;
  29
  30 bayo_above_gap = 1.0;
  31
  32 bayo_entry = bayo_behind/3;
  33
  34 bayo_slice_size = 1;
  35
  36 brace_hole_width = 1.0;
  37 brace_above_below = 1.2;
  38 brace_end_shorter = 0.3;
  39
  40 jig_thick = 1.4;
  41 jig_hole_dia = 3.0;
  42 jig_rim = 5;
  43 jig_mark = 5;
  44
  45 // calculated
  46
  47 bayo_entry_x = bayo_entry;
  48 bayo_entry_z = bayo_entry;
  49 bayo_inramp_x = bayo_entry;
  50 bayo_inramp_z = bayo_entry;
  51
  52 oring_mid_dia = oring_bore + oring_thick;
  53 oring_outer_dia = oring_mid_dia + oring_thick;
  54
  55 oring_oblate = (1 - oring_compress);
  56
  57 oring_y_rad = oring_thick/2 * oring_oblate;
  58 oring_x_rad = oring_thick/2 / oring_oblate;
  59
  60 seal_thick = oring_y_rad * (1 + cos(oring_upper_embed_angle));
  61
  62 side_height = rivet_posn + bayo_behind + rivet_thick/2;
  63 side_thick = rivet_tall + over_rivet_wall;
  64
  65 top_thick = max(top_minthick_middle,
  66                 top_minthick_by_oring + oring_y_rad);
  67
  68 top_z = top_thick + seal_thick;
  69
  70 bayo_entry = bayo_behind / 3.0;
  71 bayo_top_z = bayo_behind + rivet_thick + bayo_above_gap;
  72 bayo_entry_ramp = bayo_entry + bayo_interf;
  73
  74 rivet_entry_width = rivet_width + side_rivet_gap;
  75
  76 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
  77
  78 $fs=0.5;
  79 $fa=1;
  80
  81 // bayonet definition
  82
  83 bayo_a = [ bayo_entry_x, 0 ];
  84 bayo_p = [ 0, bayo_entry_z ];
  85 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
  86 bayo_m = [ bayo_inramp_x, bayo_behind ];
  87 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
  88 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
  89 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
  90 bayo_i = bayo_j + [ rivet_width, 0 ];
  91 bayo_h = [ bayo_i[0], bayo_behind + rivet_thick
  92                       + bayo_above_gap + bayo_interf ];
  93 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
  94
  95 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
  96 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
  97 bayo_c = bayo_d + [0,-5];
  98 bayo_b = bayo_a + [0,-5];
  99
 100 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 101
 102 bayo_polygon = [ bayo_a,
 103                  bayo_b,
 104                  bayo_c,
 105                  bayo_d,
 106                  bayo_e,
 107                  bayo_f,
 108                  bayo_g,
 109                  bayo_h,
 110                  bayo_i,
 111                  bayo_j,
 112                  bayo_k,
 113                  bayo_l,
 114                  bayo_m,
 115                  bayo_n,
 116                  bayo_p ];
 117
 118 echo(bayo_polygon);
 119
 120 module MainProfile(){
 121   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 122   difference(){
 123     union(){
 124       translate(main_cnr_pos){
 125         intersection(){
 126           difference(){
 127             circle(r = main_cnr);
 128             circle(r = main_cnr * 0.5);
 129           }
 130           square([10,10]);
 131         }
 132       }
 133       polygon([[ -11,                   seal_thick        ],
 134                [ -11,                   top_z             ],
 135                [ main_cnr_pos[0],       top_z             ],
 136                [ side_thick,            main_cnr_pos[1]   ],
 137                [ side_thick,            -side_height      ],
 138                [ side_taper,            -side_height      ],
 139                [ 0,                     -rivet_posn       ],
 140                [ 0,                     seal_thick        ],
 141                ],
 142               convexity=10);
 143     }
 144     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 145       hull(){
 146       translate([ 0, oring_y_rad ])
 147         scale([ 1/oring_oblate, oring_oblate ])
 148         circle(oring_thick/2);
 149       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 150         circle(oring_thick/2);
 151     }
 152   }
 153 }
 154
 155 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 156   // nom_rad > real_rad
 157   rotate([0,0, atan2(offset, nom_rad) ]){
 158     intersection(){
 159       translate([-offset, -10, 0])
 160         rotate([90,0,0])
 161         linear_extrude(height= nom_rad*2)
 162         children(0);
 163       translate([0,0, -25])
 164         cylinder(h=50, r= real_rad);
 165       translate([0,0, -25])
 166         linear_extrude(height= 50)
 167         polygon([ [ 0,0 ],
 168                   [ -slice_size, -real_rad*2 ],
 169                   [ +slice_size, -real_rad*2 ] ]);
 170     }
 171   }
 172 }
 173
 174 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 175   offs = [ for (i=[ x_min :
 176                     slice_size :
 177                     x_max + slice_size ]) i ];
 178   echo (offs);
 179   for (off=offs)
 180     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 181     children(0);
 182 }
 183
 184 module BayonetCutout(){
 185   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 186                 main_dia/2 + side_thick,
 187                 main_dia/2 + rivet_tall)
 188     polygon(bayo_polygon, convexity=10);
 189 }
 190
 191 module ProfilesDemo(){ ////toplevel
 192   translate([-20,0]) MainProfile();
 193   polygon(bayo_polygon, convexity=10);
 194 }
 195
 196 module Cover(){ ////toplevel
 197   render() difference(){
 198     union(){
 199       rotate_extrude(convexity=10)
 200         translate([main_dia/2, 0])
 201         MainProfile();
 202       translate([0,0, seal_thick])
 203         cylinder(h= top_thick, r = main_dia/2 - 10);
 204     }
 205     for (r=[0,180])
 206       rotate([0,0, r])
 207         translate([0,0, -side_height])
 208         BayonetCutout();
 209     for (r=[0 : 60 : 179]) {
 210       rotate([0,0, r]) {
 211         height = top_thick - brace_above_below*2;
 212         translate([0,0, seal_thick + brace_above_below + height/2 ])
 213         cube(center=true, [ oring_bore - brace_end_shorter,
 214                             brace_hole_width, height ]);
 215       }
 216     }
 217   }
 218 }
 219
 220 module SavingHole(){
 221   translate([0,0, -10])
 222     cylinder(r= main_dia/2 - jig_rim, h=20);
 223 }
 224
 225 module Jig(){ ////toplevel
 226   difference(){
 227     union(){
 228       translate([0,0, -side_height]){
 229         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 230       }
 231       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 232         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 233     }
 234     translate([0,0, -side_height-1])
 235       cylinder(r= main_dia/2, h= side_height + 1);
 236     SavingHole();
 237     translate([0,0, -rivet_posn])
 238       rotate([90, 0,0])
 239       translate([0,0, -100])
 240       cylinder(r= jig_hole_dia/2, h = 200);
 241   }
 242 }
 243
 244 module CoverTest2(){ ////toplevel
 245   difference(){
 246     Cover();
 247     SavingHole();
 248   }
 249 }
 250
 251 module CoverTest1(){ ////toplevel
 252   difference(){
 253     CoverTest2();
 254     translate([0,0, -10])
 255       cube([ main_dia*3, main_dia * .85, 20], center=true);
 256   }
 257 }
 258
 259 //ProfilesDemo();
 260 //BayonetCutout();
 261 //MainProfile();
 262 //Cover();
 263 //Jig();
 264 //CoverTest();