poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 main_dia = 71.2 + 0.50 - 2.26;
   4 top_minthick_middle = 4;
   5 top_minthick_by_oring = 2.5;
   6
   7 main_cnr = 4.0;
   8
   9 rivet_posn = 6.0;
  10 rivet_thick = 1.67;
  11 rivet_width = 4.15 + 1.0;
  12 rivet_tall = 5.51 + 0.49;
  13
  14 over_rivet_wall = 0.5;
  15 side_rivet_gap = 1.5;
  16
  17 bayo_interf = 1.25;
  18 bayo_behind = 3.5;
  19 bayo_interf_width = 2.0;
  20 bayo_interf_slope = 0.75;
  21
  22 oring_thick = 5.0;
  23 oring_bore = 62.0;
  24
  25 oring_upper_embed_angle = 80;
  26 oring_compress = 0.1; // proportion
  27
  28 side_taper = 1.0;
  29
  30 bayo_above_gap = 1.0;
  31
  32 bayo_entry = bayo_behind/3;
  33
  34 bayo_slice_size = 1;
  35
  36 brace_hole_width = 1.0;
  37 brace_above_below = 1.2;
  38 brace_end_shorter = 0.3;
  39
  40 jig_thick = 1.4;
  41 jig_hole_dia = 3.0;
  42 jig_rim = 5;
  43 jig_mark = 5;
  44
  45 // calculated
  46
  47 bayo_entry_x = bayo_entry;
  48 bayo_entry_z = bayo_entry;
  49 bayo_inramp_x = bayo_entry;
  50 bayo_inramp_z = bayo_entry;
  51
  52 oring_mid_dia = oring_bore + oring_thick;
  53 oring_outer_dia = oring_mid_dia + oring_thick;
  54
  55 oring_oblate = (1 - oring_compress);
  56
  57 oring_y_rad = oring_thick/2 * oring_oblate;
  58 oring_x_rad = oring_thick/2 / oring_oblate;
  59
  60 seal_thick = oring_y_rad * (1 + cos(oring_upper_embed_angle));
  61
  62 side_height = rivet_posn + bayo_behind + rivet_thick/2;
  63 side_thick = rivet_tall + over_rivet_wall;
  64
  65 top_thick = max(top_minthick_middle,
  66                 top_minthick_by_oring + oring_y_rad);
  67
  68 top_z = top_thick + seal_thick;
  69
  70 middle_bot_z = top_z - top_minthick_middle;
  71
  72 bayo_entry = bayo_behind / 3.0;
  73 bayo_top_z = bayo_behind + rivet_thick + bayo_above_gap;
  74 bayo_entry_ramp = bayo_entry + bayo_interf;
  75
  76 rivet_entry_width = rivet_width + side_rivet_gap;
  77
  78 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
  79
  80 $fs=0.5;
  81 $fa=1;
  82
  83 // bayonet definition
  84
  85 bayo_a = [ bayo_entry_x, 0 ];
  86 bayo_p = [ 0, bayo_entry_z ];
  87 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
  88 bayo_m = [ bayo_inramp_x, bayo_behind ];
  89 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
  90 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
  91 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
  92 bayo_i = bayo_j + [ rivet_width, 0 ];
  93 bayo_h = [ bayo_i[0], bayo_behind + rivet_thick
  94                       + bayo_above_gap + bayo_interf ];
  95 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
  96
  97 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
  98 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
  99 bayo_c = bayo_d + [0,-5];
 100 bayo_b = bayo_a + [0,-5];
 101
 102 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 103
 104 bayo_polygon = [ bayo_a,
 105                  bayo_b,
 106                  bayo_c,
 107                  bayo_d,
 108                  bayo_e,
 109                  bayo_f,
 110                  bayo_g,
 111                  bayo_h,
 112                  bayo_i,
 113                  bayo_j,
 114                  bayo_k,
 115                  bayo_l,
 116                  bayo_m,
 117                  bayo_n,
 118                  bayo_p ];
 119
 120 echo(bayo_polygon);
 121
 122 module MainProfile(){
 123   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 124   difference(){
 125     union(){
 126       translate(main_cnr_pos){
 127         intersection(){
 128           difference(){
 129             circle(r = main_cnr);
 130             circle(r = main_cnr * 0.5);
 131           }
 132           square([10,10]);
 133         }
 134       }
 135       polygon([[ -11,                   middle_bot_z      ],
 136                [ -11,                   top_z             ],
 137                [ main_cnr_pos[0],       top_z             ],
 138                [ side_thick,            main_cnr_pos[1]   ],
 139                [ side_thick,            -side_height      ],
 140                [ side_taper,            -side_height      ],
 141                [ 0,                     -rivet_posn       ],
 142                [ 0,                     seal_thick        ],
 143                [ -oring_x_rad,          seal_thick        ],
 144                ],
 145               convexity=10);
 146     }
 147     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 148       hull(){
 149       translate([ 0, oring_y_rad ])
 150         scale([ 1/oring_oblate, oring_oblate ])
 151         circle(oring_thick/2);
 152       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 153         circle(oring_thick/2);
 154     }
 155   }
 156 }
 157
 158 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 159   // nom_rad > real_rad
 160   rotate([0,0, atan2(offset, nom_rad) ]){
 161     intersection(){
 162       translate([-offset, -10, 0])
 163         rotate([90,0,0])
 164         linear_extrude(height= nom_rad*2)
 165         children(0);
 166       translate([0,0, -25])
 167         cylinder(h=50, r= real_rad);
 168       translate([0,0, -25])
 169         linear_extrude(height= 50)
 170         polygon([ [ 0,0 ],
 171                   [ -slice_size, -real_rad*2 ],
 172                   [ +slice_size, -real_rad*2 ] ]);
 173     }
 174   }
 175 }
 176
 177 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 178   offs = [ for (i=[ x_min :
 179                     slice_size :
 180                     x_max + slice_size ]) i ];
 181   echo (offs);
 182   for (off=offs)
 183     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 184     children(0);
 185 }
 186
 187 module BayonetCutout(){
 188   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 189                 main_dia/2 + side_thick,
 190                 main_dia/2 + rivet_tall)
 191     polygon(bayo_polygon, convexity=10);
 192 }
 193
 194 module ProfilesDemo(){ ////toplevel
 195   translate([-10,0]) MainProfile();
 196   translate([+10,0]) polygon(bayo_polygon, convexity=10);
 197 }
 198
 199 module Cover(){ ////toplevel
 200   render() difference(){
 201     union(){
 202       rotate_extrude(convexity=10)
 203         translate([main_dia/2, 0])
 204         MainProfile();
 205       translate([0,0, middle_bot_z])
 206         cylinder(h= top_minthick_middle, r = main_dia/2 - 10);
 207     }
 208     for (r=[0,180])
 209       rotate([0,0, r])
 210         translate([0,0, -side_height])
 211         BayonetCutout();
 212     for (r=[0 : 60 : 179]) {
 213       rotate([0,0, r]) {
 214         height = top_thick - brace_above_below*2;
 215         translate([0,0, seal_thick + brace_above_below + height/2 ])
 216         cube(center=true, [ oring_bore - brace_end_shorter,
 217                             brace_hole_width, height ]);
 218       }
 219     }
 220   }
 221 }
 222
 223 module SavingHole(){
 224   translate([0,0, -10])
 225     cylinder(r= main_dia/2 - jig_rim, h=20);
 226 }
 227
 228 module Jig(){ ////toplevel
 229   difference(){
 230     union(){
 231       translate([0,0, -side_height]){
 232         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 233       }
 234       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 235         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 236     }
 237     translate([0,0, -side_height-1])
 238       cylinder(r= main_dia/2, h= side_height + 1);
 239     SavingHole();
 240     translate([0,0, -rivet_posn])
 241       rotate([90, 0,0])
 242       translate([0,0, -100])
 243       cylinder(r= jig_hole_dia/2, h = 200);
 244   }
 245 }
 246
 247 module CoverTest2(){ ////toplevel
 248   difference(){
 249     Cover();
 250     SavingHole();
 251   }
 252 }
 253
 254 module CoverTest1(){ ////toplevel
 255   difference(){
 256     CoverTest2();
 257     translate([0,0, -10])
 258       cube([ main_dia*3, main_dia * .85, 20], center=true);
 259   }
 260 }
 261
 262 //ProfilesDemo();
 263 //BayonetCutout();
 264 //MainProfile();
 265 //Cover();
 266 //Jig();
 267 //CoverTest();