pattress-boxes-3-cover.scad

   1 // -*- C -*-
   2
   3 patbox_side = 87;
   4 patbox_centres = 60.3;
   5
   6 lid_thinboxbase_overlap = 5;
   7 lid_fatbox_overlap = 12;
   8
   9 lid_thinbox_h = 9;
  10 lid_fatbox_h = 24;
  11 lid_fatbox_switches_h = 6+2;
  12
  13 lid_max_switches_w = 70;
  14 lid_switches_y_slop = 3;
  15
  16 total_len = 260;
  17 thinbox_len = 87;
  18
  19 lid_top_wall = 1.5;
  20 lid_front_wall = 1.5;
  21 lid_side_wall = 1.5;
  22
  23 peg_engage_depth = 1;
  24 peg_engage_dia = 6.5;
  25 peg_main_dia = 9;
  26 peg_max_dia = 15;
  27 peg_inner_dia = 3.5;
  28 peg_top_thick = 1;
  29 peg_straight_len = 3;
  30
  31 peg_inner_slop = 0.2;
  32 peg_outer_slop = 0.1;
  33
  34 peg_slope = 1;
  35
  36 lid_side_slop = 0.5;
  37 lid_rail_behindslop = 0.5;
  38
  39 // computed
  40
  41 lid_inner_max_h =
  42   lid_thinboxbase_overlap + lid_fatbox_h + lid_fatbox_switches_h;
  43 lid_inner_min_h = lid_fatbox_overlap + lid_fatbox_switches_h;
  44
  45 lid_inner_kink = [thinbox_len, thinbox_len*2];
  46
  47 lid_inner_w_nom = patbox_side;
  48 lid_inner_w = lid_inner_w_nom + lid_side_slop * 2;
  49
  50 lid_seatline_w = (lid_inner_w - lid_max_switches_w)/2 - lid_switches_y_slop;
  51
  52 lid_seatline_h = lid_fatbox_switches_h;
  53
  54 echo(lid_seatline_w);
  55
  56 peg_main_height = peg_straight_len + (peg_max_dia - peg_main_dia)/2/peg_slope;
  57
  58 echo(peg_main_height);
  59
  60 thinbox_front_z = lid_fatbox_switches_h + lid_fatbox_h - lid_thinbox_h;
  61
  62 module LidSideProfile(){
  63   polygon([[-lid_top_wall,     lid_inner_max_h],
  64            [lid_inner_kink[0], lid_inner_max_h],
  65            [lid_inner_kink[1], lid_inner_min_h],
  66            [total_len,         lid_inner_min_h],
  67            [total_len,         -lid_front_wall],
  68            [-lid_top_wall,     -lid_front_wall]]);
  69 }
  70
  71 module RailProfile(){
  72   yt_base = thinbox_front_z;
  73   yt = yt_base - lid_rail_behindslop;
  74   pegx = (lid_inner_w_nom - patbox_centres)/2;
  75
  76   polygon([[-0.1,                  yt],
  77            [pegx - peg_main_dia/2, yt],
  78            [pegx - peg_main_dia/2, yt_base - peg_straight_len],
  79            [-0.1,
  80             yt_base - peg_straight_len - (pegx - peg_main_dia/2)/peg_slope
  81            -0.1]]);
  82 }
  83
  84 module LidSide(){
  85   overlap = [0.1, 0.1, 0.1];
  86
  87   // main side profile
  88   rotate([90,0,0])
  89     linear_extrude(height= lid_side_wall)
  90     LidSideProfile();
  91
  92   // seatline
  93   translate(-overlap)
  94     cube(overlap + [total_len, lid_seatline_w, lid_seatline_h]);
  95
  96   // lid front
  97   translate([-0.1, -0.1, -lid_front_wall])
  98     cube([total_len+0.1, lid_inner_w/2 + 0.2, lid_front_wall]);
  99
 100   // lid top
 101   translate([-lid_top_wall, -lid_side_wall, -lid_front_wall])
 102     cube([lid_top_wall, lid_inner_w/2 + 10, lid_front_wall + lid_inner_max_h]);
 103
 104   // rail
 105   rotate([90,0,90])
 106     translate([0,0,-0.1])
 107     linear_extrude(height=100.1) //todo
 108     RailProfile();
 109 }
 110
 111 module PegProfile(){
 112   polygon([[-peg_engage_depth, (peg_engage_dia - peg_outer_slop)/2],
 113            [0,                 (peg_engage_dia - peg_outer_slop)/2],
 114            [0,                 (peg_main_dia - peg_outer_slop)/2],
 115            [peg_straight_len,  (peg_main_dia - peg_outer_slop)/2],
 116            [peg_main_height,   (peg_max_dia - peg_outer_slop)/2],
 117            [peg_main_height+peg_top_thick, (peg_max_dia - peg_outer_slop)/2],
 118            [peg_main_height+peg_top_thick, (peg_inner_dia + peg_inner_slop)/2],
 119            [-peg_engage_depth,  (peg_inner_dia + peg_inner_slop)/2]]);
 120 }
 121
 122 module Peg(){
 123   rotate_extrude($fn=50)
 124     rotate([0,0,-90])
 125     PegProfile();
 126 }
 127
 128 module AtFixingCentres(){
 129   for (fc=[-1,+1]) {
 130     translate([patbox_side/2 + fc*patbox_centres/2,
 131                patbox_side/2,
 132                0])
 133       children();
 134   }
 135 }
 136
 137 module TopPattressBox(){
 138   difference(){
 139     translate([0,0, -lid_thinbox_h])
 140       cube([patbox_side, patbox_side, lid_thinbox_h]);
 141     AtFixingCentres(){
 142       translate([0,0,-10]) cylinder(r=peg_engage_dia/2, h=20);
 143     }
 144   }
 145 }
 146
 147 module Demo(){
 148   translate([0, -lid_inner_w/2, 0]) LidSide();
 149   translate([0,0, thinbox_front_z])
 150     rotate([0,180,0]) translate([0, -patbox_side/2, 0])
 151     rotate([0,0,90]) union(){
 152       %TopPattressBox();
 153       color("blue") AtFixingCentres(){
 154         rotate([180,0,0]) Peg();
 155       }
 156   }
 157 }
 158
 159 //LidSide();
 160 //PegProfile();
 161 //Peg();
 162 //TopPattressBox();
 163 //RailProfile();
 164 Demo();