flyscreen-handle.scad

   1 // -*- C -*-
   2
   3 opening_height = 7.84;
   4 opening_depth = 7.88;
   5 openingedge_dia = 1.34;
   6 opening_protrh = 1.8;
   7
   8 pivot_x = 6;
   9 inside_len = 4;
  10
  11 pivoting_gap = 0.1;
  12
  13 outside_gap = 3;
  14 outside_len = 16;
  15 outend_height = 3;
  16
  17 outside_pushh = 4;
  18 outside_pushslope = 1.4;
  19 outside_push_inadj = 0.82;
  20
  21 ourcirc_r = 0.5 / 2;
  22
  23 opening_protr_slop = 0.1;
  24
  25 intooth_top_slop = 0.1;
  26 inside_h_xgap = 1;
  27
  28 pivot_r = 2;
  29 pivot_slop = 0.25;
  30
  31 width = 5;
  32
  33 // calculated
  34
  35 inside_h = opening_height/2 - opening_protrh - inside_h_xgap/2;
  36
  37 edge_or = openingedge_dia/2 + opening_protr_slop;
  38
  39 Q0 = [ openingedge_dia/2,
  40        openingedge_dia/2 + opening_height/2 ];
  41
  42 p4p5d = [edge_or + ourcirc_r, 0];
  43
  44 P0 = [ pivot_x, pivoting_gap ];
  45 P4 = Q0 - p4p5d;
  46 P3t = [ P4[0], Q0[1] - openingedge_dia/2 + opening_protrh
  47         - intooth_top_slop - ourcirc_r ];
  48 P2 = P4 + [ -(inside_len - ourcirc_r*2), 0 ];
  49 P1 = [ P2[0], P3t[1] - (inside_h + ourcirc_r*2) ];
  50 P9 = [ outside_len - ourcirc_r, outside_gap/2 + ourcirc_r ];
  51 P8 = P9 + [ 0, outend_height - ourcirc_r*2 ];
  52 P5 = Q0 + p4p5d;
  53
  54 P6t = P5 + [ 0, outside_pushh - ourcirc_r*2 ];
  55 P7t = [ P6t[0] + (P6t[1] - P1[1]) / outside_pushslope,
  56         P1[1] ];
  57
  58 outside_push_inadj_slope = (P3t[1]-P4[1]) / (P6a[1]-P5[1]);
  59
  60 P3a = P3t + [ -outside_push_inadj, 0 ];
  61 P6a = P6t + [ -outside_push_inadj, 0 ];
  62 P7a = [ P6a[0] + (P6a[1] - P1[1]) / outside_pushslope,
  63         P1[1] ];
  64
  65 module ExtrusionSect(){
  66   cr = openingedge_dia/2;
  67   toph = opening_height/2 + opening_protrh;
  68
  69   for (my=[0,1]) {
  70     mirror([0,my]) {
  71       translate(Q0) {
  72         hull(){
  73           circle(r=cr, $fn=20);
  74           translate([-cr,10]) square([cr*2, 1]);
  75         }
  76       }
  77     }
  78   }
  79   translate([-opening_depth, -toph]) {
  80     difference(){
  81       translate([-5,-5])
  82         square([opening_depth+6, toph*2+10]);
  83       square([opening_depth+2, toph*2]);
  84     }
  85   }
  86 }
  87
  88 module PsHull(ps) {
  89   hull(){
  90     for (p = ps) {
  91       translate(p)
  92         circle(r = ourcirc_r, $fn=10);
  93     }
  94   }
  95 }
  96
  97 module LeverSect(inadj=false){
  98   P3 = inadj ? P3a : P3t;
  99   diag = inadj ? 0 : atan(outside_push_inadj_slope);
 100   PsHull([P2,P3,P4]);
 101   difference(){
 102     PsHull([P0,P1,P2,P5,P8,P9]);
 103     translate(Q0) {
 104       rotate(diag){
 105         hull(){
 106           circle(r=edge_or, $fn=20);
 107           translate([0,10]) circle(r=edge_or, $fn=20);
 108         }
 109       }
 110     }
 111   }
 112 }
 113
 114 module LeverSectTop(){
 115   difference(){
 116     LeverSect(false);
 117     translate([pivot_x,0]) circle(r= pivot_r + pivot_slop, $fn=20);
 118   }
 119 }
 120
 121 module LeverSectBot(inadj=false){
 122   P6 = inadj ? P6a : P6t;
 123   P7 = inadj ? P7a : P7t;
 124   mirror([0,1]) {
 125     LeverSect(inadj);
 126     PsHull([P5,P6,P7]);
 127     translate([pivot_x,0]) circle(r=pivot_r, $fn=20);
 128   }
 129 }
 130
 131 module Demo(){
 132   translate([0,0,-5]) color("white") ExtrusionSect();
 133   LeverSectTop();
 134   LeverSectBot();
 135 }
 136
 137 module LeverTop(){
 138   linear_extrude(height=width, convexity=100) LeverSectTop();
 139 }
 140
 141 module LeverBot(inadj=false){
 142   linear_extrude(height=width, convexity=100) LeverSectBot(inadj);
 143 }
 144
 145 module Test(){
 146   translate([0,2,0]) LeverTop();
 147   LeverBot();
 148   translate([0,-opening_height - 2,0]) LeverBot(true);
 149 }
 150
 151 //Demo();
 152 Test();