filamentspool.scad

   1 // -*- C -*-
   2
   3 fdia=2.85;
   4
   5 slop=0.5;
   6 bigslop=slop*2;
   7
   8 function selsz(sm,lg) = fdia < 2 ? sm : lg;
   9 function usedove() = selsz(true,false);
  10
  11 exteffrad = 70;
  12 hubeffrad = selsz(30, 60);
  13 hubbigrad = selsz(20, 50);
  14 hublwidth = selsz(3, 5);
  15 hubstemwidth = 2;
  16 hublthick = 10;
  17 hubaxlerad = selsz(5, 17/2);
  18 totalheightfromtower = 240;
  19 axletowerfudgebend = 0;
  20 axleaxlefudgebend = 3;
  21 axlepadlen = 1.0;
  22
  23 prongthick=selsz(5,7);
  24 prongwidth=selsz(5,7);
  25 ratchetstep=15;
  26 ratchettooth=3;
  27 ratchettoothheight=5;
  28 ratchettoothsmoothr=1;
  29 ratchettoothslope=0.75;
  30 overlap=0.5;
  31 cupwidth=selsz(40,60);
  32 cupheight=selsz(55,75);
  33
  34 propxshift = 0;
  35
  36 doveclipheight = 10;
  37
  38 teethh=3;
  39 teethgapx=4+fdia;
  40
  41 prongstalkxwidth=3;
  42
  43 stalklength=selsz(35,55);
  44 overclipcupgap=5;
  45 overclipdepth=15;
  46 overcliproundr=2.0;
  47 overclipthick=1.0;
  48 overclipcupnextgap=20;
  49
  50 hubaxlelen = selsz(25, cupwidth);
  51
  52 overclipsmaller=-2.5;
  53 overclipbigger=0.0;
  54
  55 wingspoke=3;
  56 wingsize=6;
  57 wingthick=3;
  58
  59 armendwallthick=2.5;
  60 armendbasethick=1.2;
  61
  62 axlehorizoffset = 12.5;
  63 axlevertheight = 100;
  64 towercliph = 16;
  65 towerclipcount = 3;
  66 towerpillarw = 5;
  67
  68 axlepinrad = 2;
  69 axlepintabrad = 5;
  70
  71 washerthick = 1.2;
  72 washerthinthick = 0.8;
  73 washerverythinthick = 0.4;
  74 washerrad = hubaxlerad + 7.5;
  75 frictionwasherarmwidth = 3;
  76 frictionwasherextrapush = 1.0;
  77
  78 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
  79
  80 nondove_armbase = 100;
  81 nondove_armhole_x = 60;
  82 nondove_armhole_hole = 4;
  83
  84 include <doveclip.scad>
  85 include <cliphook.scad>
  86 include <filamentteeth.scad>
  87 include <axlepin.scad>
  88
  89 channelwidth = prongthick + slop;
  90 channeldepth = prongwidth + ratchettoothheight;
  91 totalwidth = armendwallthick*2 + channelwidth;
  92 totalheight = channeldepth + armendbasethick;
  93 stalkwidth = prongwidth + prongstalkxwidth;
  94
  95 module ArmEnd(length=120){ ////toplevel
  96   if (usedove()) {
  97     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
  98       rotate([0,0,-90])
  99         DoveClipPairBase(h=doveclipheight);
 100     }
 101   } else {
 102     difference(){
 103       translate([1, -armendwallthick, -armendbasethick])
 104         mirror([1,0,0])
 105         cube([nondove_armbase+1, totalwidth, totalheight]);
 106       translate([-nondove_armbase + nondove_armhole_x,
 107                  -armendwallthick + totalwidth/2,
 108                  -armendbasethick -1])
 109         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 110     }
 111   }
 112
 113   difference(){
 114     translate([0, -armendwallthick, -armendbasethick])
 115       cube([length, totalwidth, totalheight]);
 116     translate([-1, 0, 0])
 117       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 118     translate([-1, 0, ratchettoothheight])
 119       cube([length+2, channelwidth, channeldepth+1]);
 120   }
 121   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 122     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 123       rotate([90,0,0])
 124         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 125       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 126                         [       0,      1,      0,      0       ],
 127                         [       0,      0,      1,      0       ],
 128                         [       0,      0,      0,      1       ]])
 129         cube([ratchettooth - ratchettoothsmoothr*2,
 130               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 131     }
 132   }
 133 }
 134
 135 module FilamentCupHandle(){
 136   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 137   mirror([0,1,0]) {
 138     cube([stalklength, stalkwidth, prongthick]);
 139     translate([stalklength, stalkwidth/2, 0])
 140       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 141     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 142       minkowski(){
 143         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 144         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 145                         [       0,      1,      0,      0       ],
 146                         [       0,      0,      1,      0       ],
 147                         [       0,      0,      0,      1       ]])
 148           cube([pawlusewidth,
 149                 ratchettoothheight - ratchettoothsmoothr,
 150                 prongthick - 1]);
 151       }
 152     }
 153   }
 154 }
 155
 156 module FilamentCupCup(){
 157   for (my=[0,1]) mirror([0,my,0]) {
 158     translate([0,cupwidth/2,0])
 159       cube([cupheight + prongwidth, prongwidth, prongthick]);
 160   }
 161 }
 162
 163 module FilamentCup() { ////toplevel
 164   FilamentCupHandle();
 165
 166   gapy = prongwidth;
 167   dy = cupwidth/2 + gapy + overclipcupgap;
 168
 169   translate([0, dy, 0])
 170     FilamentCupCup();
 171   translate([0, -1, 0]);
 172   cube([prongwidth, dy+1+cupwidth/2, prongthick]);
 173
 174   midrad = cupwidth/2 + prongwidth/2;
 175
 176   propshift = stalklength - overclipdepth - prongthick + propxshift;
 177   proptaken = propshift;
 178   echo(midrad, propshift, proptaken);
 179
 180   translate([propshift, -1, 0]) {
 181     // something is wrong with the y calculation
 182     cube([prongwidth,
 183           gapy+2,
 184           prongthick]);
 185   }
 186   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 187     translate([0, y, 0])
 188       rotate([0,0, 102 + fdia])
 189       FilamentTeeth(fdia=fdia, h=teethh);
 190   }
 191   for (x = [-0.3, -1.3]) {
 192     translate([cupheight + overclipcupnextgap*x, dy+cupwidth/2 + prongthick, 0])
 193       rotate([0,0, 12 + fdia])
 194       FilamentTeeth(fdia=fdia, h=teethh);
 195   }
 196 }
 197
 198 module CupSecuringClipSolid(w,d,h1,h2){
 199   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 200     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 201   }
 202 }
 203
 204 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 205   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 206   minkowski(){
 207     CupSecuringClipSolid(w=totalwidth,
 208                          d=overclipdepth + xdepth,
 209                          h1=hbase - overclipsmaller,
 210                          h2=hbase + overclipbigger);
 211     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 212   }
 213 }
 214
 215 module CupSecuringClip(){ ////toplevel
 216   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 217   difference(){
 218     union(){
 219       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 220       translate([-wingswidth/2, -wingsize/2, 0])
 221         cube([wingswidth, wingsize, wingthick]);
 222       translate([-wingsize/2, -wingswidth/2, 0])
 223         cube([wingsize, wingswidth, wingthick]);
 224     }
 225     translate([0,0,-0.1])
 226       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 227   }
 228 }
 229
 230 module ArmDoveClipPin(){ ////toplevel
 231   DoveClipPin(h=doveclipheight);
 232 }
 233
 234 module TowerDoveClipPin(){ ////toplevel
 235   DoveClipPin(h=towercliph/2);
 236 }
 237
 238 module Hub(){ ////toplevel
 239   difference(){
 240     cylinder($fn=60, h=hublthick, r=hubbigrad);
 241     translate([0,0,-1])
 242       cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 243   }
 244   axlerad = hubaxlerad + slop;
 245   difference(){
 246     cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 247     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 248   }
 249   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 250   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 251   for (ang=[0,120,240])
 252     rotate([0,0,ang]) {
 253       difference() {
 254         translate([hubeffrad,0,0])
 255           DoveClipPairSane(h=doveclipheight,
 256                            baseextend = (hubeffrad - DoveClip_depth()
 257                                          - hubbigrad + hublwidth));
 258         if (hole>hublwidth && holewidth > 2) {
 259           translate([hubbigrad + hublwidth, -holewidth/2, -1])
 260             cube([hole, holewidth, hublthick+2]);
 261         }
 262       }
 263     }
 264   xmin = axlerad+hublwidth/2;
 265   xmax = hubbigrad-hublwidth/2;
 266   for (ang = [0 : 60 : 359])
 267     rotate([0,0,ang]) rotate([90,0,0]) {
 268       translate([0,0,-hublwidth/2])
 269         linear_extrude(height=hublwidth)
 270         polygon([[xmin,0.05], [xmax,0.05],
 271                  [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 272     }
 273 }
 274
 275 module ArmExtender(){ ////toplevel
 276   DoveClipExtender(length=exteffrad-hubeffrad,
 277                    ha=doveclipheight,
 278                    hb=doveclipheight);
 279 }
 280
 281 module FsAxlePin(){ ////toplevel
 282   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 283 }
 284
 285 module Axle(){ ////toplevel
 286   pillarswidth = DoveClipPairSane_width(towerclipcount);
 287
 288   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 289   translate([-axlehorizoffset, -axlevertheight, 0]) {
 290     rotate([0,0,-axletowerfudgebend])
 291     rotate([0,0,-90])
 292       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 293     translate([0, DoveClip_depth(), 0])
 294     rotate([0,0,90])
 295       ExtenderPillars(axlevertheight - DoveClip_depth(),
 296                       pillarswidth, towercliph,
 297                       pillarw=towerpillarw);
 298   }
 299
 300   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 301   axlerad = hubaxlerad-slop;
 302   bump = axlerad * 0.2;
 303   shift = axlerad-bump;
 304   joinbelowallow = 3;
 305
 306   intersection(){
 307     translate([0, 0, shift]) {
 308       difference() {
 309         union(){
 310           translate([-1, 0, 0])
 311             rotate([0,90,0])
 312             cylinder($fn=60,
 313                      r = axlerad,
 314                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 315           mirror([1,0,0]) rotate([0,90,0])
 316             cylinder(r = axlerad*1.75, h = 3);
 317           intersection(){
 318             mirror([1,0,0])
 319               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 320               rotate([0,90,0])
 321               cylinder($fn=60,
 322                        r = towercliph - shift,
 323                        h = pillarswidth);
 324             translate([-50, -joinbelowallow, -50])
 325               cube([100, joinbelowallow+50, 100]);
 326           }
 327         }
 328         rotate([90,0,0])
 329         translate([axleclearlen + axlepinrad/2, 0, -25])
 330           cylinder(r = axlepinrad + slop, h=50);
 331       }
 332     }
 333     translate([-50,-50,0]) cube([100,100,100]);
 334   }
 335 }
 336
 337 module washer(thick){
 338   Washer(hubaxlerad, washerrad, thick, slop);
 339 }
 340
 341 module AxleWasher(){ ////toplevel
 342   washer(thick=washerthick);
 343 }
 344
 345 module AxleThinWasher(){ ////toplevel
 346   washer(thick=washerthinthick);
 347 }
 348
 349 module AxleVeryThinWasher(){ ////toplevel
 350   washer(thick=washerverythinthick);
 351 }
 352
 353 module AxleFrictionWasher(){ ////toplevel
 354   difference(){
 355     cylinder(h=washerthick, r=washerrad);
 356     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 357   }
 358   frarmr = hubbigrad;
 359   frarmw = frictionwasherarmwidth;
 360   frarmpawlr = hublwidth;
 361   frarmpawlpush = slop*4 + frictionwasherextrapush;
 362   for (ang=[0,180]) rotate([0,0,ang]) {
 363     translate([washerrad-1, -frarmw/2, 0])
 364       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 365     intersection(){
 366       translate([frarmr - frarmpawlr, -50, 0])
 367         cube([frarmpawlr, 100, 50]);
 368       rotate([0,90,0])
 369         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 370     }
 371   }
 372 }
 373
 374 module TowerExtender(){ ////toplevel
 375   l = totalheightfromtower - axlevertheight;
 376   echo("TowerExtender",l);
 377   DoveClipExtender(length = l,
 378                    ha = towercliph, hb = towercliph,
 379                    counta = towerclipcount, countb = towerclipcount,
 380                    pillarw = towerpillarw);
 381 }
 382
 383 module FilamentCupPair(){ ////toplevel
 384   FilamentCup();
 385   translate([cupheight + prongthick*3,
 386              cupwidth/2*1.7,
 387              0])
 388     rotate([0,0,180]) FilamentCup();
 389 }
 390
 391 //ArmEnd();
 392 //FilamentCup();
 393 //FilamentCupPair();
 394 //CupSecuringClip();
 395 Hub();
 396 //ArmExtender();
 397 //Axle();
 398 //AxleWasher();
 399 //AxlePin();
 400 //AxleFrictionWasher();