filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 //     This is the default.
  50 //
  51 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  52 //
  53 // A light duty 3-armed spool suitable for up to around 30m
  54 // of Faberdashery 2.85mm PLA.
  55 //
  56 //     Set
  57 //           fdia=2.85
  58 //           lightduty=true
  59 //     (or look in filamentspool-lt.scad).
  60 //
  61 //     And print following parts
  62 //           Hub
  63 //           ArmEnd x 3
  64 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  65 //           CupSecuringClip x 3
  66 //           TowerDoveClipPin x 6
  67 //
  68 //     When assembling, insert one TowerDoveClipPin from each side,
  69 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  70 //     Modest force with pliers is good to seat them properly.
  71 //
  72 //     (note that the light duty and heavy duty CupSecuringClips
  73 //      are slightly different)
  74 //
  75 // ===== Notes regarding both the above spools =====
  76 //
  77 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  78 // end of the hub towards the printer - ie, put put the spool on
  79 // `backwards'.  This ensures that the spool's arms will clear the
  80 // printer framework.
  81 //
  82 // For the above, I generally used the Cura `Standard' PLA profile.
  83 //
  84 // ===== TAZ-5 feed tube adjustment kit =====
  85 //
  86 // With a TAZ-5 I recommend using this kit to improve the feed
  87 // reliability:
  88 //
  89 //       Set
  90 //           fdia=2.85
  91 //     And print following parts
  92 //           FilamentGuideSpacer (ideally, at `high detail')
  93 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  94 //
  95 //     And possibly also
  96 //           t-nut_jig_0.2.stl
  97 //     from Aleph Objects - look here:
  98 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  99 //
 100 // The spacer clips onto the filament guide tube holder arm, on the
 101 // inside, with the pointy flanged end towards the filament guide
 102 // tube.  It stops the filament guide tube angle (and so the
 103 // filament's natural pickup location) changing as the print head moves.
 104 //
 105 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 106 // with your TAZ-5.  It's longer, so that the filament pickup point is
 107 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 108 // T-nuts in the aluminium channel from annoyingly sliding down to the
 109 // bottom while you swap out the arm.
 110 //
 111 // (Faberdashery coils, and therefore both the above spools, have a
 112 // larger diameter than the flat-walled spools often supplied by other
 113 // vendors.  And the spools above have individual arms rather than a
 114 // continuous disc.  If the filament `unhooks' from the arm, it can
 115 // pull taught around the hub and stop feeding properly.)
 116 //
 117 // ===== Spool storage arm, for mounting on walls =====
 118 //
 119 // A storage arm suitable for screwing to walls, bookshelves,
 120 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 121 // spools each with a 100m coil.
 122 //
 123 //     Set
 124 //           fdia=2.85
 125 //           lightduty=false
 126 //     (or look in filamentspool-sm.scad).
 127 //
 128 //     And print one of these, according to taste
 129 //            StorageArmLeft
 130 //            StorageArmRight
 131 //
 132 //     NB that the `light duty' version of this is shorter and
 133 //     will only take two `light duty' spools.
 134 //
 135 // For the above, I used the Cura `High detail' PLA profile because
 136 // I wanted it pretty, but the `Standard' profile should do fine.
 137 //
 138 // ===== Spools for 1.75mm filament =====
 139 //
 140 // Spool (in many parts) for handing 1.75mm filament, printable
 141 // on, and with parts for mounting on, a Reprappro Huxley.
 142
 143
 144 fdia=2.85; // or 1.75
 145 lightduty=false; // or true
 146
 147
 148 slop=0.5;
 149 bigslop=slop*2;
 150
 151 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 152 function usedove() = selsz(true,true,false);
 153
 154 num_arms = selsz(3,3,4);
 155
 156 channelslop=selsz(slop,0.75,slop);
 157
 158 exteffrad = 70;
 159 hubeffrad = selsz(30, 82, 40);
 160 hubbigrad = selsz(20, 38, 38);
 161 hublwidth = selsz(3, 2.5, 3.0);
 162 hubstemwidth = 2;
 163 hublthick = 10;
 164 hubaxlerad = selsz(5, 28/2, 28/2);
 165 totalheightfromtower = 240;
 166 axletowerfudgebend = 0;
 167 axleaxlefudgebend = 3;
 168 axlepadlen = 1.0;
 169
 170 armend_length = 120;
 171
 172 prongthick=selsz(5,4,5);
 173 prongwidth=selsz(5,4,5);
 174 prongribwidth=3;
 175 prongribheight=selsz(0,0,4);
 176 ratchetstep=15;
 177 ratchettooth=3;
 178 ratchettoothheight=5;
 179 ratchettoothsmoothr=1;
 180 ratchettoothslope=0.75;
 181 overlap=0.5;
 182 cupwidth=selsz(40,25,50);
 183 cupheight=selsz(55,25,55);
 184
 185 cupstrong_dx=selsz(0,0,-10);
 186
 187 propxshift = -6;
 188
 189 doveclipheight = 10;
 190
 191 teethh=3;
 192 teethgapx=4+fdia;
 193
 194 prongstalkxwidth=3;
 195
 196 stalklength=selsz(35,25,55);
 197 overclipcupgap=5;
 198 overclipdepth=15;
 199 overcliproundr=2.0;
 200 overclipthick=1.0;
 201 overclipcupnextgap=selsz(20,15,20);
 202
 203 hubaxlelen = selsz(25, 62.5, 77.5);
 204 echo(hubaxlelen);
 205
 206 overclipsmaller=-2.5;
 207 overclipbigger=0.0;
 208
 209 wingspoke=2.5;
 210 wingsize=6;
 211 wingthick=3;
 212
 213 armendwallthick=selsz(2.5, 1.8, 2.5);
 214 armendbasethick=selsz(1.2, 1.2, 1.2);
 215
 216 numbers_relief = 0.7;
 217 numbers_tick_len = 8;
 218 numbers_tick_width = 0.75;
 219 numbers_tick_linespc = 1.0;
 220 numbers_height_allow = 8;
 221
 222 axlehorizoffset = 12.5;
 223 axlevertheight = 100;
 224 towercliph = 16;
 225 towerclipcount = 3;
 226 towerpillarw = 5;
 227
 228 axlepinrad = 2;
 229 axlepintabrad = 5;
 230
 231 washerthick = 1.2;
 232 washerthinthick = 0.8;
 233 washerverythinthick = 0.4;
 234 washerrad = hubaxlerad + 7.5;
 235 frictionwasherarmwidth = 3;
 236 frictionwasherextrapush = 1.0;
 237
 238 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 239
 240 nondove_armhole_x = 32;
 241 nondove_armhole_hole = 4 + 0.8;
 242 nondove_armhole_support = 7;
 243 nondove_armhole_wall = 3.2;
 244 nondove_armhole_slop = 0.5;
 245 nondove_armhole_slop_x = 0.5;
 246
 247 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 248   nondove_armhole_support;
 249 echo(nondove_armbase);
 250
 251 include <doveclip.scad>
 252 include <cliphook.scad>
 253 include <filamentteeth.scad>
 254 include <axlepin.scad>
 255 include <commitid.scad>
 256
 257 hub_clip_baseextend = (hubeffrad - DoveClip_depth()
 258                        - hubbigrad + hublwidth);
 259
 260 real_exteffrad = selsz(exteffrad + hub_clip_baseextend,
 261                        hubeffrad + DoveClip_depth(),
 262                        hubeffrad + nondove_armbase);
 263
 264 channelwidth = prongthick + channelslop;
 265 channeldepth = prongwidth + ratchettoothheight;
 266 totalwidth = armendwallthick*2 + channelwidth;
 267 totalheight = channeldepth + armendbasethick;
 268 stalkwidth = prongwidth + prongstalkxwidth;
 269
 270 tau = PI*2;
 271
 272 module ArmEnd(length=armend_length){ ////toplevel
 273   if (usedove()) {
 274     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 275       rotate([0,0,-90])
 276         DoveClipPairBase(h=doveclipheight);
 277     }
 278   } else {
 279     difference(){
 280       translate([1, -armendwallthick, -armendbasethick])
 281         mirror([1,0,0])
 282         cube([nondove_armbase+1, totalwidth, totalheight]);
 283       translate([-nondove_armbase + nondove_armhole_x,
 284                  -armendwallthick + totalwidth/2,
 285                  -armendbasethick -1])
 286         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 287       translate([-nondove_armbase, -armendwallthick, -armendbasethick])
 288         rotate([90,0,0])
 289         Commitid_BestCount([nondove_armbase, totalwidth]);
 290     }
 291   }
 292
 293   difference(){
 294     union(){
 295       difference(){
 296         translate([0, -armendwallthick, -armendbasethick])
 297           cube([length, totalwidth, totalheight]);
 298         translate([-1, 0, 0])
 299           cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 300         translate([-1, 0, ratchettoothheight])
 301           cube([length+2, channelwidth, channeldepth+1]);
 302       }
 303       for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 304         translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 305           rotate([90,0,0])
 306             cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 307           multmatrix([  [       1, 0, ratchettoothslope, 0      ],
 308                             [   0,      1,      0,      0       ],
 309                             [   0,      0,      1,      0       ],
 310                             [   0,      0,      0,      1       ]])
 311             cube([ratchettooth - ratchettoothsmoothr*2,
 312                   channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 313         }
 314       }
 315     }
 316
 317     for (otherside=[0,1]) {
 318       for (circum = [300:100:1500]) {
 319         assign(rad = circum / tau)
 320           assign(fn = str("filamentspool-number-n",circum,".dxf"))
 321           assign(rotateoffset = [0, totalwidth/2, 0])
 322           assign(xlen = rad - real_exteffrad) {
 323           if (xlen >= numbers_tick_width/2
 324               + (otherside ? numbers_height_allow : 0) &&
 325               xlen <= length - (otherside ? 0 : numbers_height_allow))
 326             translate([xlen, -armendwallthick,
 327                        -armendbasethick + (totalheight - numbers_tick_len)/2])
 328             translate(rotateoffset)
 329             rotate([0,0, otherside*180])
 330             translate(-rotateoffset){
 331               translate([-numbers_tick_width/2, -1, 0])
 332                 cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 333               translate([numbers_tick_width/2 + numbers_tick_linespc,
 334                          1,
 335                          numbers_tick_len])
 336                 rotate([90,0,0])
 337                 rotate([0,0,-90])
 338                 linear_extrude(height= numbers_relief+1)
 339                 //    scale(templatescale)
 340                 import(file=fn, convexity=100);
 341             }
 342         }
 343       }
 344     }
 345
 346     if (usedove()){
 347       translate([0, -armendwallthick, -armendbasethick])
 348         Commitid_BestCount_M([length/3, totalwidth]);
 349     }
 350   }
 351 }
 352
 353 module FilamentCupHandle(){
 354   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 355   mirror([0,1,0]) {
 356     cube([stalklength, stalkwidth, prongthick]);
 357     translate([stalklength, stalkwidth/2, 0])
 358       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 359     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 360       minkowski(){
 361         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 362         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 363                         [       0,      1,      0,      0       ],
 364                         [       0,      0,      1,      0       ],
 365                         [       0,      0,      0,      1       ]])
 366           cube([pawlusewidth,
 367                 ratchettoothheight - ratchettoothsmoothr,
 368                 prongthick - 1]);
 369       }
 370     }
 371   }
 372 }
 373
 374 module FilamentCupCup(){
 375   for (my=[0,1]) mirror([0,my,0]) {
 376     translate([0, cupwidth/2, 0])
 377       cube([cupheight + prongwidth, prongwidth, prongthick]);
 378   }
 379 }
 380
 381 module FilamentCupPositive() {
 382   FilamentCupHandle();
 383
 384   gapy = prongwidth;
 385   dy = cupwidth/2 + gapy + overclipcupgap;
 386   baselen = dy+cupwidth/2;
 387
 388   translate([0, dy, 0])
 389     FilamentCupCup();
 390   cube([prongwidth, baselen+1, prongthick]);
 391
 392   translate([cupstrong_dx, prongwidth, 0]) {
 393     cube([prongwidth, baselen-prongwidth, prongthick]);
 394     for (y = [0, .33, .67, 1])
 395       translate([0, (baselen - prongwidth) * y, 0])
 396         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 397   }
 398   if (cupstrong_dx != 0) {
 399     rotate([0,0,45])
 400       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 401       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 402   }
 403
 404   translate([0, -0.2, 0])
 405     cube([prongribwidth, baselen, prongthick + prongribheight]);
 406
 407   if (prongribheight > 0) {
 408     translate([-prongwidth, baselen, 0])
 409       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 410   }
 411
 412   midrad = cupwidth/2 + prongwidth/2;
 413
 414   propshift = stalklength - overclipdepth - prongthick + propxshift;
 415   proptaken = propshift;
 416   echo(midrad, propshift, proptaken);
 417
 418   translate([propshift, -1, 0]) {
 419     // something is wrong with the y calculation
 420     cube([prongwidth,
 421           gapy+2,
 422           prongthick]);
 423   }
 424   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 425     translate([cupstrong_dx, y + prongwidth, 0])
 426       rotate([0,0, 102 + fdia])
 427       FilamentTeeth(fdia=fdia, h=teethh);
 428   }
 429   for (x = [-0.3, -1.3]) {
 430     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 431       rotate([0,0, 12 + fdia])
 432       FilamentTeeth(fdia=fdia, h=teethh);
 433   }
 434 }
 435
 436 module FilamentCup() { ////toplevel
 437   difference(){
 438     FilamentCupPositive();
 439     translate([0, -stalkwidth, 0])
 440       Commitid_BestCount_M([stalklength - stalkwidth, stalkwidth]);
 441   }
 442 }
 443
 444 module CupSecuringClipSolid(w,d,h1,h2){
 445   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 446     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 447   }
 448 }
 449
 450 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 451   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 452   minkowski(){
 453     CupSecuringClipSolid(w=totalwidth,
 454                          d=overclipdepth + xdepth,
 455                          h1=hbase - overclipsmaller,
 456                          h2=hbase + overclipbigger);
 457     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 458   }
 459 }
 460
 461 module CupSecuringClip(){ ////toplevel
 462   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 463   difference(){
 464     union(){
 465       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 466       translate([-wingswidth/2, -wingsize/2, 0])
 467         cube([wingswidth, wingsize, wingthick]);
 468       translate([-wingsize/2, -wingswidth/2, 0])
 469         cube([wingsize, wingswidth, wingthick]);
 470     }
 471     translate([0,0,-0.1])
 472       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 473   }
 474 }
 475
 476 module ArmDoveClipPin(){ ////toplevel
 477   DoveClipPin(h=doveclipheight);
 478 }
 479
 480 module TowerDoveClipPin(){ ////toplevel
 481   DoveClipPin(h=towercliph/2);
 482 }
 483
 484 module Hub(){ ////toplevel
 485   axlerad = hubaxlerad + slop;
 486   xmin = axlerad+hublwidth/2;
 487   xmax = hubbigrad-hublwidth/2;
 488   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 489   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 490   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 491   difference(){
 492     union(){
 493       difference(){
 494         cylinder($fn=60, h=hublthick, r=hubbigrad);
 495         translate([0,0,-1])
 496           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 497       }
 498       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 499       for (ang=[0 : 360/num_arms : 359])
 500         rotate([0,0,ang]) {
 501           if (usedove()){
 502             difference() {
 503               translate([hubeffrad,0,0])
 504                 DoveClipPairSane(h=doveclipheight,
 505                                  baseextend = hub_clip_baseextend);
 506               if (hole>hublwidth && holewidth > 2) {
 507                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 508                   cube([hole, holewidth, hublthick+2]);
 509               }
 510             }
 511           } else {
 512             difference(){
 513               translate([0,
 514                          -nondove_allwidth/2,
 515                          0])
 516                 cube([hubeffrad + nondove_armhole_x
 517                       + nondove_armhole_hole/2 + nondove_armhole_support,
 518                       nondove_allwidth,
 519                       nondove_armhole_wall + totalheight]);
 520               translate([hubeffrad - nondove_armhole_slop_x,
 521                          -nondove_allwidth/2
 522                          + nondove_armhole_wall - nondove_armhole_slop,
 523                          nondove_armhole_wall])
 524                 cube([nondove_armhole_x + 50,
 525                       totalwidth + nondove_armhole_slop*2,
 526                       totalheight + 1]);
 527               translate([hubeffrad + nondove_armhole_x, 0, -20])
 528                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 529             }
 530           }
 531         }
 532       for (ang = [0 : 180/num_arms : 359])
 533         rotate([0,0,ang]) rotate([90,0,0]) {
 534           translate([0,0,-hublwidth/2])
 535             linear_extrude(height=hublwidth)
 536             polygon([[xmin,0.05], [xmax,0.05],
 537                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 538         }
 539     }
 540     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 541
 542     rotate([0,0, selsz(0,0,45)])
 543       translate([axlerad+hublwidth,
 544                  -hublwidth/2,
 545                  0])
 546       rotate([90,0,0])
 547       Commitid_BestCount([(hubbigrad-hublwidth) - (axlerad+hublwidth),
 548                           hublthick +
 549                           hublwidth/2 * hubaxlelen/(hubbigrad-axlerad),
 550                           ]);
 551   }
 552 }
 553
 554 module ArmExtender(){ ////toplevel
 555   DoveClipExtender(length=exteffrad-hubeffrad,
 556                    ha=doveclipheight,
 557                    hb=doveclipheight);
 558 }
 559
 560 module FsAxlePin(){ ////toplevel
 561   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 562 }
 563
 564 module Axle(){ ////toplevel
 565   pillarswidth = DoveClipPairSane_width(towerclipcount);
 566
 567   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 568   translate([-axlehorizoffset, -axlevertheight, 0]) {
 569     rotate([0,0,-axletowerfudgebend])
 570     rotate([0,0,-90])
 571       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 572     translate([0, DoveClip_depth(), 0])
 573     rotate([0,0,90])
 574       ExtenderPillars(axlevertheight - DoveClip_depth(),
 575                       pillarswidth, towercliph,
 576                       pillarw=towerpillarw);
 577   }
 578
 579   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 580   axlerad = hubaxlerad-slop;
 581   bump = axlerad * 0.2;
 582   shift = axlerad-bump;
 583   joinbelowallow = 3;
 584
 585   intersection(){
 586     translate([0, 0, shift]) {
 587       difference() {
 588         union(){
 589           translate([-1, 0, 0])
 590             rotate([0,90,0])
 591             cylinder($fn=60,
 592                      r = axlerad,
 593                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 594           mirror([1,0,0]) rotate([0,90,0])
 595             cylinder(r = axlerad*1.75, h = 3);
 596           intersection(){
 597             mirror([1,0,0])
 598               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 599               rotate([0,90,0])
 600               cylinder($fn=60,
 601                        r = towercliph - shift,
 602                        h = pillarswidth);
 603             translate([-50, -joinbelowallow, -50])
 604               cube([100, joinbelowallow+50, 100]);
 605           }
 606         }
 607         rotate([90,0,0])
 608         translate([axleclearlen + axlepinrad/2, 0, -25])
 609           cylinder(r = axlepinrad + slop, h=50);
 610       }
 611     }
 612     translate([-50,-50,0]) cube([100,100,100]);
 613   }
 614 }
 615
 616 module washer(thick){
 617   Washer(hubaxlerad, washerrad, thick, slop);
 618 }
 619
 620 module AxleWasher(){ ////toplevel
 621   washer(thick=washerthick);
 622 }
 623
 624 module AxleThinWasher(){ ////toplevel
 625   washer(thick=washerthinthick);
 626 }
 627
 628 module AxleVeryThinWasher(){ ////toplevel
 629   washer(thick=washerverythinthick);
 630 }
 631
 632 module AxleFrictionWasher(){ ////toplevel
 633   difference(){
 634     cylinder(h=washerthick, r=washerrad);
 635     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 636   }
 637   frarmr = hubbigrad;
 638   frarmw = frictionwasherarmwidth;
 639   frarmpawlr = hublwidth;
 640   frarmpawlpush = slop*4 + frictionwasherextrapush;
 641   for (ang=[0,180]) rotate([0,0,ang]) {
 642     translate([washerrad-1, -frarmw/2, 0])
 643       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 644     intersection(){
 645       translate([frarmr - frarmpawlr, -50, 0])
 646         cube([frarmpawlr, 100, 50]);
 647       rotate([0,90,0])
 648         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 649     }
 650   }
 651 }
 652
 653 module TowerExtender(){ ////toplevel
 654   l = totalheightfromtower - axlevertheight;
 655   echo("TowerExtender",l);
 656   DoveClipExtender(length = l,
 657                    ha = towercliph, hb = towercliph,
 658                    counta = towerclipcount, countb = towerclipcount,
 659                    pillarw = towerpillarw);
 660 }
 661
 662 module FilamentCupPair(){ ////toplevel
 663   FilamentCup();
 664   translate([cupheight + prongthick*3,
 665              cupwidth/2*1.7,
 666              0])
 667     rotate([0,0,180]) FilamentCup();
 668 }
 669
 670 //----- storarm -----
 671
 672 storarm_hooklen = 8;
 673 storarm_hookheight = 5;
 674 storarm_thick = 10;
 675 storarm_axleslop = 4;
 676
 677 storarm_base_w = 30;
 678 storarm_base_h = 100;
 679 storarm_base_d = 15;
 680 storarm_base_mind = 2;
 681
 682 storarm_cope_hubaxle_mk1 = true;
 683
 684 storarm_screw_hole = 4;
 685 storarm_screw_hole_slop = 0.5;
 686 storarm_besides_hole = 4;
 687
 688 storarm_under_hole = 5;
 689 storarm_screw_hole_head = 8.8;
 690 storarm_screw_hole_head_slop = 1.5;
 691
 692 // calculated
 693
 694 storarm_spools = 2;
 695
 696 storarm_axlerad = hubaxlerad - storarm_axleslop;
 697 storarm_mainlen = hubaxlelen*storarm_spools
 698   + storarm_axleslop*(storarm_spools-1)
 699   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 700 storarm_totlen = storarm_mainlen + storarm_hooklen;
 701
 702 storarm_mid_off_y = storarm_axlerad;
 703
 704 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 705
 706 module StorageArmDiagPartSide(xmin, xmax){
 707   xsz = xmax-xmin;
 708   yuse = storarm_thick/2;
 709
 710   intersection(){
 711     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 712       rotate([0,90,0])
 713       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 714     translate([xmin, -yuse, 0])
 715       cube([xsz, yuse, storarm_thick]);
 716   }
 717 }
 718
 719 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 720   hull(){
 721     StorageArmDiagPartSide(xmin,xmax);
 722
 723     multmatrix([[1,0,0,0],
 724                 [shear,1,0,0],
 725                 [0,0,1,0],
 726                 [0,0,0,1]])
 727       translate([0, -storarm_axlerad*2 + adjbot, 0])
 728       mirror([0,1,0])
 729       StorageArmDiagPartSide(xmin,xmax);
 730   }
 731 }
 732
 733 module StorageArmBaseTemplate(){
 734   square([storarm_base_w, storarm_base_h]);
 735 }
 736
 737 module StorageArmAtMountingHoles(){
 738   bes = storarm_besides_hole + storarm_screw_hole;
 739
 740   x0 = bes;
 741   x1 = storarm_base_w-bes;
 742   y1 = storarm_base_h - bes;
 743   y0 = bes;
 744
 745   for (pos=[ [x0, y1],
 746              [x1, y1],
 747              [x1, y0] ]) {
 748     rotate([0,90,0])
 749       translate([pos[0] - storarm_base_w,
 750                  pos[1] - storarm_base_off_y, -storarm_base_d])
 751       children();
 752   }
 753 }
 754
 755 module StorageArmRight(){ ////toplevel
 756   shear = storarm_hookheight / (storarm_mainlen/2);
 757
 758   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 759   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 760                      storarm_hookheight/2);
 761
 762   translate([0, storarm_hookheight, 0])
 763     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 764                        shear/2, -storarm_hookheight/2);
 765
 766   difference(){
 767     union(){
 768       hull(){
 769         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 770           rotate([0,90,0])
 771           linear_extrude(height=storarm_base_mind)
 772           StorageArmBaseTemplate();
 773         StorageArmDiagPart(-1, 0, shear, 0);
 774       }
 775       StorageArmAtMountingHoles(){
 776         cylinder(r= storarm_screw_hole_head/2,
 777                  h=10);
 778       }
 779     }
 780     StorageArmAtMountingHoles(){
 781       translate([0,0,-1])
 782         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 783                  h=20);
 784       translate([0,0,storarm_under_hole])
 785         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 786                  h=20);
 787     }
 788   }
 789 }
 790
 791 module StorageArmLeft(){ ////toplevel
 792   mirror([1,0,0]) StorageArmRight();
 793 }
 794
 795 module StorArmHoleTest(){ ////toplevel
 796   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 797   intersection(){
 798     StorageArmRight();
 799     translate([-50, -storarm_base_off_y, -1])
 800       cube([100, sz, sz+1]);
 801   }
 802 }
 803
 804
 805 //----- filament guide spacer -----
 806
 807 guide_armdia = 15.0;
 808 guide_armwidth = 10.2;
 809 guide_armcorelen = 25.0;
 810 guide_clipcirclethick = 10.0;
 811
 812 guidefilclip_outerdia = 22.8;
 813
 814 guidespacer_armslop = 0.75;
 815 guidespacer_armlenslop = 1.05;
 816
 817 guidespacer_prongprotrude = 4;
 818 guidespacer_thick = 1.6;
 819
 820 // calculated
 821
 822 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 823 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 824 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 825   + guidespacer_armlenslop;
 826
 827 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 828
 829 module FilamentGuideArmTemplate(extra=0){
 830   intersection(){
 831     circle(r= (guidespacer_armdia/2) + extra);
 832     square(center=true, [guidespacer_armwidth+extra*2,
 833                          guidespacer_armdia + extra*2 + 10]);
 834   }
 835 }
 836
 837 module FilamentGuideSpacerInnerTemplate(){
 838   FilamentGuideArmTemplate();
 839   translate([0, -guidespacer_armdia/2])
 840     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 841                          guidespacer_armdia]);
 842 }
 843
 844 module FilamentGuideSpacer(){ ////toplevel
 845   difference(){
 846     union(){
 847       linear_extrude(height= guidespacer_len)
 848         FilamentGuideArmTemplate(extra= guidespacer_thick);
 849       for (angle=[26, 60]) {
 850         for (m=[0,1]) {
 851           mirror([m,0,0]) {
 852             rotate([0,0,angle]) {
 853               hull(){
 854                 for (t=[[0, guidespacer_wingheight],
 855                         [guidespacer_len-1, -guidespacer_wingheight]])
 856                   translate([0,0, t[0] + 0.5])
 857                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 858                       1],
 859                          center=true);
 860               }
 861             }
 862           }
 863         }
 864       }
 865     }
 866     translate([0,0,-1])
 867       linear_extrude(height= guidespacer_len+5)
 868       FilamentGuideSpacerInnerTemplate();
 869   }
 870 }
 871
 872
 873 //----- replacement filament guide arm for TAZ-5 -----
 874
 875 guidearm_armslop = 0.25;
 876 guidearm_armlenslop = 0.25;
 877
 878 guidearm_hookprotr = 3;
 879 guidearm_hookprotrflat = 1;
 880 guidearm_hookslope = 0.3;
 881
 882 guidearm_totallen = 60;
 883
 884 guidearm_screwplatesz = 12;
 885 guidearm_screwplateth = 4;
 886 guidearm_screwplatewd = 15;
 887 guidearm_screwhole = 5 + 0.5;
 888
 889 guidearm_bendlen = 40;
 890 guidearm_bendslot = 4.5;
 891
 892 guidearm_stopthick = 4;
 893 guidearm_protrslop = 1.0;
 894
 895 // calculated
 896
 897 guidearm_armdia = guide_armdia - guidearm_armslop;
 898 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 899 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 900
 901 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 902
 903 guidearm_realbendlen = min(guidearm_bendlen,
 904                            guidearm_totallen - guidearm_screwplateth - 0.1);
 905 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 906
 907 module FilamentGuideArmStop(h){
 908   for (ts=[-1,+1]) {
 909     translate([ts * guidearm_hookprotr, 0,0])
 910       cylinder(r=guidearm_armdia/2, h, $fn=80);
 911   }
 912 }
 913
 914 module FilamentGuideArmShaftPositive(){
 915   r = guidearm_armdia/2;
 916
 917   translate([0,0, guidearm_base_z0+1])
 918     cylinder(r=r, h= guidearm_totallen, $fn=80);
 919   translate([0,0, guidearm_armcorelen]){
 920     hull(){
 921       FilamentGuideArmStop(guidearm_hookprotrflat);
 922       translate([0,0, guidearm_slopelen])
 923         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 924     }
 925   }
 926   mirror([0,0,1])
 927     FilamentGuideArmStop(guidearm_stopthick);
 928 }
 929
 930 module FilamentGuideArmBase(){
 931   translate([0,
 932              (guidearm_screwplatewd - guidearm_armwidth)/2,
 933              guidearm_base_z0]){
 934     difference(){
 935       translate([0,0, guidearm_screwplateth/2])
 936         cube(center=true,
 937              [guidearm_armdia + guidearm_screwplatesz*2,
 938               guidearm_screwplatewd,
 939               guidearm_screwplateth]);
 940       for (ts=[-1,+1]) {
 941         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 942                    0,
 943                    -20])
 944           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 945       }
 946     }
 947   }
 948 }
 949
 950 module FilamentGuideArm(){ ///toplevel
 951   intersection(){
 952     difference(){
 953       FilamentGuideArmShaftPositive();
 954       translate([-guidearm_bendslot/2,
 955                  -50,
 956                  -guidearm_realbendlen + guidearm_armcorelen])
 957         cube([guidearm_bendslot,
 958               100,
 959               guidearm_realbendlen + 100]);
 960       hull(){
 961         for (zx=[ [ 0, guidearm_bendslot ],
 962                   [ guidearm_armcorelen + guidearm_slopelen,
 963                     guidearm_hookprotr*2 + guidearm_protrslop ]
 964                   ]) {
 965           translate([-zx[1]/2, -50, zx[0]])
 966           cube([zx[1], 100, 1]);
 967         }
 968       }
 969     }
 970     cube(center=true,
 971          [guidearm_armdia*2,
 972           guidearm_armwidth,
 973           guidearm_totallen*3]);
 974   }
 975   FilamentGuideArmBase();
 976 }
 977
 978 module FilamentGuideArmPrint(){ ////toplevel
 979   rotate([90,0,0])
 980     FilamentGuideArm();
 981 }
 982
 983 module Demo(){ ////toplevel
 984   translate([-real_exteffrad,-20,0]) Hub();
 985   ArmEnd();
 986   translate([ratchettooth*2, 30, 0]) FilamentCup();
 987   if (selsz(true,false,false)) {
 988     translate([-exteffrad + hubeffrad - hub_clip_baseextend, -10, 0])
 989       ArmExtender();
 990   }
 991 }
 992
 993 //ArmEnd();
 994 //FilamentCup();
 995 //FilamentCupPair();
 996 //CupSecuringClip();
 997 //Hub();
 998 //ArmExtender();
 999 //Axle();
1000 //AxleWasher();
1001 //AxlePin();
1002 //AxleFrictionWasher();
1003 //StorageArmLeft();
1004 //StorArmHoleTest();
1005 //FilamentGuideSpacer();
1006 //FilamentGuideArm();
1007 //FilamentGuideArmPrint();
1008 //Demo();