filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  50 //
  51 // A light duty 3-armed spool suitable for up to around 30m
  52 // of Faberdashery 2.85mm PLA.
  53 //
  54 //     Set
  55 //           fdia=2.85
  56 //           lightduty=true
  57 //     And print following parts
  58 //           Hub
  59 //           ArmEnd x 3
  60 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  61 //           CupSecuringClip x 3
  62 //           TowerDoveClipPin x 6
  63 //
  64 //     When assembling, insert one TowerDoveClipPin from each side,
  65 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  66 //     Modest force with pliers is good to seat them properly.
  67 //
  68 //     (note that the light duty and heavy duty CupSecuringClips
  69 //      are slightly different)
  70 //
  71 // ===== Notes regarding both the above spools =====
  72 //
  73 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  74 // end of the hub towards the printer - ie, put put the spool on
  75 // `backwards'.  This ensures that the spool's arms will clear the
  76 // printer framework.
  77 //
  78 // For the above, I generally used the Cura `Standard' PLA profile.
  79 //
  80 // ===== TAZ-5 feed tube adjustment kit =====
  81 //
  82 // With a TAZ-5 I recommend using this kit to improve the feed
  83 // reliability:
  84 //
  85 //       Set
  86 //           fdia=2.85
  87 //     And print following parts
  88 //           FilamentGuideSpacer (ideally, at `high detail')
  89 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  90 //
  91 //     And possibly also
  92 //           t-nut_jig_0.2.stl
  93 //     from Aleph Objects - look here:
  94 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  95 //
  96 // The spacer clips onto the filament guide tube holder arm, on the
  97 // inside, with the pointy flanged end towards the filament guide
  98 // tube.  It stops the filament guide tube angle (and so the
  99 // filament's natural pickup location) changing as the print head moves.
 100 //
 101 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 102 // with your TAZ-5.  It's longer, so that the filament pickup point is
 103 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 104 // T-nuts in the aluminium channel from annoyingly sliding down to the
 105 // bottom while you swap out the arm.
 106 //
 107 // (Faberdashery coils, and therefore both the above spools, have a
 108 // larger diameter than the flat-walled spools often supplied by other
 109 // vendors.  And the spools above have individual arms rather than a
 110 // continuous disc.  If the filament `unhooks' from the arm, it can
 111 // pull taught around the hub and stop feeding properly.)
 112 //
 113 // ===== Spool storage arm, for mounting on walls =====
 114 //
 115 // A storage arm suitable for screwing to walls, bookshelves,
 116 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 117 // spools each with a 100m coil.
 118 //
 119 //     Set
 120 //           fdia=2.85
 121 //           lightduty=false
 122 //     And print one of these, according to taste
 123 //            StorageArmLeft
 124 //            StorageArmRight
 125 //
 126 //     NB that the `light duty' version of this is shorter and
 127 //     will only take two `light duty' spools.
 128 //
 129 // For the above, I used the Cura `High detail' PLA profile because
 130 // I wanted it pretty, but the `Standard' profile should do fine.
 131 //
 132 // ===== Spools for 1.75mm filament =====
 133 //
 134 // Spool (in many parts) for handing 1.75mm filament, printable
 135 // on, and with parts for mounting on, a Reprappro Huxley.
 136
 137
 138 fdia=2.85; // or 1.75
 139 lightduty=false; // or true
 140
 141
 142 slop=0.5;
 143 bigslop=slop*2;
 144
 145 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 146 function usedove() = selsz(true,true,false);
 147
 148 num_arms = selsz(3,3,4);
 149
 150 channelslop=selsz(slop,0.75,slop);
 151
 152 exteffrad = 70;
 153 hubeffrad = selsz(30, 82, 40);
 154 hubbigrad = selsz(20, 38, 38);
 155 hublwidth = selsz(3, 2.5, 4);
 156 hubstemwidth = 2;
 157 hublthick = 10;
 158 hubaxlerad = selsz(5, 28/2, 28/2);
 159 totalheightfromtower = 240;
 160 axletowerfudgebend = 0;
 161 axleaxlefudgebend = 3;
 162 axlepadlen = 1.0;
 163
 164 armend_length = 120;
 165
 166 prongthick=selsz(5,4,5);
 167 prongwidth=selsz(5,4,5);
 168 prongribwidth=3;
 169 prongribheight=selsz(0,0,4);
 170 ratchetstep=15;
 171 ratchettooth=3;
 172 ratchettoothheight=5;
 173 ratchettoothsmoothr=1;
 174 ratchettoothslope=0.75;
 175 overlap=0.5;
 176 cupwidth=selsz(40,25,50);
 177 cupheight=selsz(55,25,55);
 178
 179 cupstrong_dx=selsz(0,0,-10);
 180
 181 propxshift = -6;
 182
 183 doveclipheight = 10;
 184
 185 teethh=3;
 186 teethgapx=4+fdia;
 187
 188 prongstalkxwidth=3;
 189
 190 stalklength=selsz(35,25,55);
 191 overclipcupgap=5;
 192 overclipdepth=15;
 193 overcliproundr=2.0;
 194 overclipthick=1.0;
 195 overclipcupnextgap=selsz(20,15,20);
 196
 197 hubaxlelen = selsz(25, 62.5, 77.5);
 198 echo(hubaxlelen);
 199
 200 overclipsmaller=-2.5;
 201 overclipbigger=0.0;
 202
 203 wingspoke=2.5;
 204 wingsize=6;
 205 wingthick=3;
 206
 207 armendwallthick=selsz(2.5, 1.8, 2.5);
 208 armendbasethick=selsz(1.2, 1.2, 1.2);
 209
 210 numbers_relief = 0.7;
 211 numbers_tick_len = 8;
 212 numbers_tick_width = 0.75;
 213 numbers_tick_linespc = 1.0;
 214 numbers_height_allow = 8;
 215
 216 axlehorizoffset = 12.5;
 217 axlevertheight = 100;
 218 towercliph = 16;
 219 towerclipcount = 3;
 220 towerpillarw = 5;
 221
 222 axlepinrad = 2;
 223 axlepintabrad = 5;
 224
 225 washerthick = 1.2;
 226 washerthinthick = 0.8;
 227 washerverythinthick = 0.4;
 228 washerrad = hubaxlerad + 7.5;
 229 frictionwasherarmwidth = 3;
 230 frictionwasherextrapush = 1.0;
 231
 232 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 233
 234 nondove_armhole_x = 32;
 235 nondove_armhole_hole = 4 + 0.8;
 236 nondove_armhole_support = 7;
 237 nondove_armhole_wall = 3.2;
 238 nondove_armhole_slop = 0.5;
 239 nondove_armhole_slop_x = 0.5;
 240
 241 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 242   nondove_armhole_support;
 243 echo(nondove_armbase);
 244
 245 real_exteffrad = selsz(exteffrad,
 246                        hubeffrad + nondove_armbase,
 247                        hubeffrad + nondove_armbase);
 248
 249 include <doveclip.scad>
 250 include <cliphook.scad>
 251 include <filamentteeth.scad>
 252 include <axlepin.scad>
 253
 254 channelwidth = prongthick + channelslop;
 255 channeldepth = prongwidth + ratchettoothheight;
 256 totalwidth = armendwallthick*2 + channelwidth;
 257 totalheight = channeldepth + armendbasethick;
 258 stalkwidth = prongwidth + prongstalkxwidth;
 259
 260 tau = PI*2;
 261
 262 module ArmEnd(length=armend_length){ ////toplevel
 263   if (usedove()) {
 264     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 265       rotate([0,0,-90])
 266         DoveClipPairBase(h=doveclipheight);
 267     }
 268   } else {
 269     difference(){
 270       translate([1, -armendwallthick, -armendbasethick])
 271         mirror([1,0,0])
 272         cube([nondove_armbase+1, totalwidth, totalheight]);
 273       translate([-nondove_armbase + nondove_armhole_x,
 274                  -armendwallthick + totalwidth/2,
 275                  -armendbasethick -1])
 276         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 277     }
 278   }
 279
 280   for (otherside=[0]) { // [0,1]
 281     for (circum = [300:100:1500]) {
 282       assign(rad = circum / tau)
 283         assign(fn = str("filamentspool-number-n",circum,".dxf"))
 284         assign(xlen = rad - real_exteffrad) {
 285         echo(circum, rad, xlen);
 286         if (xlen >= numbers_tick_width/2 &&
 287             xlen <= length - numbers_height_allow)
 288           translate([xlen, -armendwallthick,
 289                      -armendbasethick + (totalheight - numbers_tick_len)/2])
 290             color("blue"){
 291             translate([-numbers_tick_width/2, -1, 0])
 292               cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 293             //  echo(fn);
 294             translate([numbers_tick_width/2 + numbers_tick_linespc,
 295                        1,
 296                        numbers_tick_len])
 297               rotate([90,0,0])
 298               rotate([0,0,-90])
 299               linear_extrude(height= numbers_relief+1)
 300               //    scale(templatescale)
 301               import(file=fn, convexity=100);
 302           }
 303       }
 304     }
 305   }
 306
 307   difference(){
 308     translate([0, -armendwallthick, -armendbasethick])
 309       cube([length, totalwidth, totalheight]);
 310     translate([-1, 0, 0])
 311       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 312     translate([-1, 0, ratchettoothheight])
 313       cube([length+2, channelwidth, channeldepth+1]);
 314   }
 315   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 316     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 317       rotate([90,0,0])
 318         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 319       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 320                         [       0,      1,      0,      0       ],
 321                         [       0,      0,      1,      0       ],
 322                         [       0,      0,      0,      1       ]])
 323         cube([ratchettooth - ratchettoothsmoothr*2,
 324               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 325     }
 326   }
 327 }
 328
 329 module FilamentCupHandle(){
 330   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 331   mirror([0,1,0]) {
 332     cube([stalklength, stalkwidth, prongthick]);
 333     translate([stalklength, stalkwidth/2, 0])
 334       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 335     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 336       minkowski(){
 337         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 338         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 339                         [       0,      1,      0,      0       ],
 340                         [       0,      0,      1,      0       ],
 341                         [       0,      0,      0,      1       ]])
 342           cube([pawlusewidth,
 343                 ratchettoothheight - ratchettoothsmoothr,
 344                 prongthick - 1]);
 345       }
 346     }
 347   }
 348 }
 349
 350 module FilamentCupCup(){
 351   for (my=[0,1]) mirror([0,my,0]) {
 352     translate([0, cupwidth/2, 0])
 353       cube([cupheight + prongwidth, prongwidth, prongthick]);
 354   }
 355 }
 356
 357 module FilamentCup() { ////toplevel
 358   FilamentCupHandle();
 359
 360   gapy = prongwidth;
 361   dy = cupwidth/2 + gapy + overclipcupgap;
 362   baselen = dy+cupwidth/2;
 363
 364   translate([0, dy, 0])
 365     FilamentCupCup();
 366   cube([prongwidth, baselen+1, prongthick]);
 367
 368   translate([cupstrong_dx, prongwidth, 0]) {
 369     cube([prongwidth, baselen-prongwidth, prongthick]);
 370     for (y = [0, .33, .67, 1])
 371       translate([0, (baselen - prongwidth) * y, 0])
 372         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 373   }
 374   if (cupstrong_dx != 0) {
 375     rotate([0,0,45])
 376       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 377       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 378   }
 379
 380   translate([0, -0.2, 0])
 381     cube([prongribwidth, baselen, prongthick + prongribheight]);
 382
 383   if (prongribheight > 0) {
 384     translate([-prongwidth, baselen, 0])
 385       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 386   }
 387
 388   midrad = cupwidth/2 + prongwidth/2;
 389
 390   propshift = stalklength - overclipdepth - prongthick + propxshift;
 391   proptaken = propshift;
 392   echo(midrad, propshift, proptaken);
 393
 394   translate([propshift, -1, 0]) {
 395     // something is wrong with the y calculation
 396     cube([prongwidth,
 397           gapy+2,
 398           prongthick]);
 399   }
 400   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 401     translate([cupstrong_dx, y + prongwidth, 0])
 402       rotate([0,0, 102 + fdia])
 403       FilamentTeeth(fdia=fdia, h=teethh);
 404   }
 405   for (x = [-0.3, -1.3]) {
 406     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 407       rotate([0,0, 12 + fdia])
 408       FilamentTeeth(fdia=fdia, h=teethh);
 409   }
 410 }
 411
 412 module CupSecuringClipSolid(w,d,h1,h2){
 413   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 414     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 415   }
 416 }
 417
 418 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 419   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 420   minkowski(){
 421     CupSecuringClipSolid(w=totalwidth,
 422                          d=overclipdepth + xdepth,
 423                          h1=hbase - overclipsmaller,
 424                          h2=hbase + overclipbigger);
 425     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 426   }
 427 }
 428
 429 module CupSecuringClip(){ ////toplevel
 430   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 431   difference(){
 432     union(){
 433       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 434       translate([-wingswidth/2, -wingsize/2, 0])
 435         cube([wingswidth, wingsize, wingthick]);
 436       translate([-wingsize/2, -wingswidth/2, 0])
 437         cube([wingsize, wingswidth, wingthick]);
 438     }
 439     translate([0,0,-0.1])
 440       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 441   }
 442 }
 443
 444 module ArmDoveClipPin(){ ////toplevel
 445   DoveClipPin(h=doveclipheight);
 446 }
 447
 448 module TowerDoveClipPin(){ ////toplevel
 449   DoveClipPin(h=towercliph/2);
 450 }
 451
 452 module Hub(){ ////toplevel
 453   axlerad = hubaxlerad + slop;
 454   xmin = axlerad+hublwidth/2;
 455   xmax = hubbigrad-hublwidth/2;
 456   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 457   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 458   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 459   difference(){
 460     union(){
 461       difference(){
 462         cylinder($fn=60, h=hublthick, r=hubbigrad);
 463         translate([0,0,-1])
 464           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 465       }
 466       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 467       for (ang=[0 : 360/num_arms : 359])
 468         rotate([0,0,ang]) {
 469           if (usedove()){
 470             difference() {
 471               translate([hubeffrad,0,0])
 472                 DoveClipPairSane(h=doveclipheight,
 473                                  baseextend = (hubeffrad - DoveClip_depth()
 474                                                - hubbigrad + hublwidth));
 475               if (hole>hublwidth && holewidth > 2) {
 476                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 477                   cube([hole, holewidth, hublthick+2]);
 478               }
 479             }
 480           } else {
 481             difference(){
 482               translate([0,
 483                          -nondove_allwidth/2,
 484                          0])
 485                 cube([hubeffrad + nondove_armhole_x
 486                       + nondove_armhole_hole/2 + nondove_armhole_support,
 487                       nondove_allwidth,
 488                       nondove_armhole_wall + totalheight]);
 489               translate([hubeffrad - nondove_armhole_slop_x,
 490                          -nondove_allwidth/2
 491                          + nondove_armhole_wall - nondove_armhole_slop,
 492                          nondove_armhole_wall])
 493                 cube([nondove_armhole_x + 50,
 494                       totalwidth + nondove_armhole_slop*2,
 495                       totalheight + 1]);
 496               translate([hubeffrad + nondove_armhole_x, 0, -20])
 497                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 498             }
 499           }
 500         }
 501       for (ang = [0 : 180/num_arms : 359])
 502         rotate([0,0,ang]) rotate([90,0,0]) {
 503           translate([0,0,-hublwidth/2])
 504             linear_extrude(height=hublwidth)
 505             polygon([[xmin,0.05], [xmax,0.05],
 506                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 507         }
 508     }
 509     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 510   }
 511 }
 512
 513 module ArmExtender(){ ////toplevel
 514   DoveClipExtender(length=exteffrad-hubeffrad,
 515                    ha=doveclipheight,
 516                    hb=doveclipheight);
 517 }
 518
 519 module FsAxlePin(){ ////toplevel
 520   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 521 }
 522
 523 module Axle(){ ////toplevel
 524   pillarswidth = DoveClipPairSane_width(towerclipcount);
 525
 526   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 527   translate([-axlehorizoffset, -axlevertheight, 0]) {
 528     rotate([0,0,-axletowerfudgebend])
 529     rotate([0,0,-90])
 530       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 531     translate([0, DoveClip_depth(), 0])
 532     rotate([0,0,90])
 533       ExtenderPillars(axlevertheight - DoveClip_depth(),
 534                       pillarswidth, towercliph,
 535                       pillarw=towerpillarw);
 536   }
 537
 538   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 539   axlerad = hubaxlerad-slop;
 540   bump = axlerad * 0.2;
 541   shift = axlerad-bump;
 542   joinbelowallow = 3;
 543
 544   intersection(){
 545     translate([0, 0, shift]) {
 546       difference() {
 547         union(){
 548           translate([-1, 0, 0])
 549             rotate([0,90,0])
 550             cylinder($fn=60,
 551                      r = axlerad,
 552                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 553           mirror([1,0,0]) rotate([0,90,0])
 554             cylinder(r = axlerad*1.75, h = 3);
 555           intersection(){
 556             mirror([1,0,0])
 557               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 558               rotate([0,90,0])
 559               cylinder($fn=60,
 560                        r = towercliph - shift,
 561                        h = pillarswidth);
 562             translate([-50, -joinbelowallow, -50])
 563               cube([100, joinbelowallow+50, 100]);
 564           }
 565         }
 566         rotate([90,0,0])
 567         translate([axleclearlen + axlepinrad/2, 0, -25])
 568           cylinder(r = axlepinrad + slop, h=50);
 569       }
 570     }
 571     translate([-50,-50,0]) cube([100,100,100]);
 572   }
 573 }
 574
 575 module washer(thick){
 576   Washer(hubaxlerad, washerrad, thick, slop);
 577 }
 578
 579 module AxleWasher(){ ////toplevel
 580   washer(thick=washerthick);
 581 }
 582
 583 module AxleThinWasher(){ ////toplevel
 584   washer(thick=washerthinthick);
 585 }
 586
 587 module AxleVeryThinWasher(){ ////toplevel
 588   washer(thick=washerverythinthick);
 589 }
 590
 591 module AxleFrictionWasher(){ ////toplevel
 592   difference(){
 593     cylinder(h=washerthick, r=washerrad);
 594     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 595   }
 596   frarmr = hubbigrad;
 597   frarmw = frictionwasherarmwidth;
 598   frarmpawlr = hublwidth;
 599   frarmpawlpush = slop*4 + frictionwasherextrapush;
 600   for (ang=[0,180]) rotate([0,0,ang]) {
 601     translate([washerrad-1, -frarmw/2, 0])
 602       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 603     intersection(){
 604       translate([frarmr - frarmpawlr, -50, 0])
 605         cube([frarmpawlr, 100, 50]);
 606       rotate([0,90,0])
 607         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 608     }
 609   }
 610 }
 611
 612 module TowerExtender(){ ////toplevel
 613   l = totalheightfromtower - axlevertheight;
 614   echo("TowerExtender",l);
 615   DoveClipExtender(length = l,
 616                    ha = towercliph, hb = towercliph,
 617                    counta = towerclipcount, countb = towerclipcount,
 618                    pillarw = towerpillarw);
 619 }
 620
 621 module FilamentCupPair(){ ////toplevel
 622   FilamentCup();
 623   translate([cupheight + prongthick*3,
 624              cupwidth/2*1.7,
 625              0])
 626     rotate([0,0,180]) FilamentCup();
 627 }
 628
 629 //----- storarm -----
 630
 631 storarm_hooklen = 8;
 632 storarm_hookheight = 5;
 633 storarm_thick = 10;
 634 storarm_axleslop = 4;
 635
 636 storarm_base_w = 30;
 637 storarm_base_h = 100;
 638 storarm_base_d = 15;
 639 storarm_base_mind = 2;
 640
 641 storarm_cope_hubaxle_mk1 = true;
 642
 643 storarm_screw_hole = 4;
 644 storarm_screw_hole_slop = 0.5;
 645 storarm_besides_hole = 4;
 646
 647 storarm_under_hole = 5;
 648 storarm_screw_hole_head = 8.8;
 649 storarm_screw_hole_head_slop = 1.5;
 650
 651 // calculated
 652
 653 storarm_axlerad = hubaxlerad - storarm_axleslop;
 654 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 655   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 656 storarm_totlen = storarm_mainlen + storarm_hooklen;
 657
 658 storarm_mid_off_y = storarm_axlerad;
 659
 660 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 661
 662 module StorageArmDiagPartSide(xmin, xmax){
 663   xsz = xmax-xmin;
 664   yuse = storarm_thick/2;
 665
 666   intersection(){
 667     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 668       rotate([0,90,0])
 669       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 670     translate([xmin, -yuse, 0])
 671       cube([xsz, yuse, storarm_thick]);
 672   }
 673 }
 674
 675 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 676   hull(){
 677     StorageArmDiagPartSide(xmin,xmax);
 678
 679     multmatrix([[1,0,0,0],
 680                 [shear,1,0,0],
 681                 [0,0,1,0],
 682                 [0,0,0,1]])
 683       translate([0, -storarm_axlerad*2 + adjbot, 0])
 684       mirror([0,1,0])
 685       StorageArmDiagPartSide(xmin,xmax);
 686   }
 687 }
 688
 689 module StorageArmBaseTemplate(){
 690   square([storarm_base_w, storarm_base_h]);
 691 }
 692
 693 module StorageArmAtMountingHoles(){
 694   bes = storarm_besides_hole + storarm_screw_hole;
 695
 696   x0 = bes;
 697   x1 = storarm_base_w-bes;
 698   y1 = storarm_base_h - bes;
 699   y0 = bes;
 700
 701   for (pos=[ [x0, y1],
 702              [x1, y1],
 703              [x1, y0] ]) {
 704     rotate([0,90,0])
 705       translate([pos[0] - storarm_base_w,
 706                  pos[1] - storarm_base_off_y, -storarm_base_d])
 707       children();
 708   }
 709 }
 710
 711 module StorageArmRight(){ ////toplevel
 712   shear = storarm_hookheight / (storarm_mainlen/2);
 713
 714   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 715   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 716                      storarm_hookheight/2);
 717
 718   translate([0, storarm_hookheight, 0])
 719     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 720                        shear/2, -storarm_hookheight/2);
 721
 722   difference(){
 723     union(){
 724       hull(){
 725         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 726           rotate([0,90,0])
 727           linear_extrude(height=storarm_base_mind)
 728           StorageArmBaseTemplate();
 729         StorageArmDiagPart(-1, 0, shear, 0);
 730       }
 731       StorageArmAtMountingHoles(){
 732         cylinder(r= storarm_screw_hole_head/2,
 733                  h=10);
 734       }
 735     }
 736     StorageArmAtMountingHoles(){
 737       translate([0,0,-1])
 738         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 739                  h=20);
 740       translate([0,0,storarm_under_hole])
 741         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 742                  h=20);
 743     }
 744   }
 745 }
 746
 747 module StorageArmLeft(){ ////toplevel
 748   mirror([1,0,0]) StorageArmRight();
 749 }
 750
 751 module StorArmHoleTest(){ ////toplevel
 752   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 753   intersection(){
 754     StorageArmRight();
 755     translate([-50, -storarm_base_off_y, -1])
 756       cube([100, sz, sz+1]);
 757   }
 758 }
 759
 760
 761 //----- filament guide spacer -----
 762
 763 guide_armdia = 15.0;
 764 guide_armwidth = 10.2;
 765 guide_armcorelen = 25.0;
 766 guide_clipcirclethick = 10.0;
 767
 768 guidefilclip_outerdia = 22.8;
 769
 770 guidespacer_armslop = 0.75;
 771 guidespacer_armlenslop = 1.05;
 772
 773 guidespacer_prongprotrude = 4;
 774 guidespacer_thick = 1.6;
 775
 776 // calculated
 777
 778 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 779 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 780 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 781   + guidespacer_armlenslop;
 782
 783 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 784
 785 module FilamentGuideArmTemplate(extra=0){
 786   intersection(){
 787     circle(r= (guidespacer_armdia/2) + extra);
 788     square(center=true, [guidespacer_armwidth+extra*2,
 789                          guidespacer_armdia + extra*2 + 10]);
 790   }
 791 }
 792
 793 module FilamentGuideSpacerInnerTemplate(){
 794   FilamentGuideArmTemplate();
 795   translate([0, -guidespacer_armdia/2])
 796     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 797                          guidespacer_armdia]);
 798 }
 799
 800 module FilamentGuideSpacer(){ ////toplevel
 801   difference(){
 802     union(){
 803       linear_extrude(height= guidespacer_len)
 804         FilamentGuideArmTemplate(extra= guidespacer_thick);
 805       for (angle=[26, 60]) {
 806         for (m=[0,1]) {
 807           mirror([m,0,0]) {
 808             rotate([0,0,angle]) {
 809               hull(){
 810                 for (t=[[0, guidespacer_wingheight],
 811                         [guidespacer_len-1, -guidespacer_wingheight]])
 812                   translate([0,0, t[0] + 0.5])
 813                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 814                       1],
 815                          center=true);
 816               }
 817             }
 818           }
 819         }
 820       }
 821     }
 822     translate([0,0,-1])
 823       linear_extrude(height= guidespacer_len+5)
 824       FilamentGuideSpacerInnerTemplate();
 825   }
 826 }
 827
 828
 829 //----- replacement filament guide arm for TAZ-5 -----
 830
 831 guidearm_armslop = 0.25;
 832 guidearm_armlenslop = 0.25;
 833
 834 guidearm_hookprotr = 3;
 835 guidearm_hookprotrflat = 1;
 836 guidearm_hookslope = 0.3;
 837
 838 guidearm_totallen = 60;
 839
 840 guidearm_screwplatesz = 12;
 841 guidearm_screwplateth = 4;
 842 guidearm_screwplatewd = 15;
 843 guidearm_screwhole = 5 + 0.5;
 844
 845 guidearm_bendlen = 40;
 846 guidearm_bendslot = 4.5;
 847
 848 guidearm_stopthick = 4;
 849 guidearm_protrslop = 1.0;
 850
 851 // calculated
 852
 853 guidearm_armdia = guide_armdia - guidearm_armslop;
 854 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 855 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 856
 857 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 858
 859 guidearm_realbendlen = min(guidearm_bendlen,
 860                            guidearm_totallen - guidearm_screwplateth - 0.1);
 861 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 862
 863 module FilamentGuideArmStop(h){
 864   for (ts=[-1,+1]) {
 865     translate([ts * guidearm_hookprotr, 0,0])
 866       cylinder(r=guidearm_armdia/2, h, $fn=80);
 867   }
 868 }
 869
 870 module FilamentGuideArmShaftPositive(){
 871   r = guidearm_armdia/2;
 872
 873   translate([0,0, guidearm_base_z0+1])
 874     cylinder(r=r, h= guidearm_totallen, $fn=80);
 875   translate([0,0, guidearm_armcorelen]){
 876     hull(){
 877       FilamentGuideArmStop(guidearm_hookprotrflat);
 878       translate([0,0, guidearm_slopelen])
 879         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 880     }
 881   }
 882   mirror([0,0,1])
 883     FilamentGuideArmStop(guidearm_stopthick);
 884 }
 885
 886 module FilamentGuideArmBase(){
 887   translate([0,
 888              (guidearm_screwplatewd - guidearm_armwidth)/2,
 889              guidearm_base_z0]){
 890     difference(){
 891       translate([0,0, guidearm_screwplateth/2])
 892         cube(center=true,
 893              [guidearm_armdia + guidearm_screwplatesz*2,
 894               guidearm_screwplatewd,
 895               guidearm_screwplateth]);
 896       for (ts=[-1,+1]) {
 897         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 898                    0,
 899                    -20])
 900           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 901       }
 902     }
 903   }
 904 }
 905
 906 module FilamentGuideArm(){ ///toplevel
 907   intersection(){
 908     difference(){
 909       FilamentGuideArmShaftPositive();
 910       translate([-guidearm_bendslot/2,
 911                  -50,
 912                  -guidearm_realbendlen + guidearm_armcorelen])
 913         cube([guidearm_bendslot,
 914               100,
 915               guidearm_realbendlen + 100]);
 916       hull(){
 917         for (zx=[ [ 0, guidearm_bendslot ],
 918                   [ guidearm_armcorelen + guidearm_slopelen,
 919                     guidearm_hookprotr*2 + guidearm_protrslop ]
 920                   ]) {
 921           translate([-zx[1]/2, -50, zx[0]])
 922           cube([zx[1], 100, 1]);
 923         }
 924       }
 925     }
 926     cube(center=true,
 927          [guidearm_armdia*2,
 928           guidearm_armwidth,
 929           guidearm_totallen*3]);
 930   }
 931   FilamentGuideArmBase();
 932 }
 933
 934 module FilamentGuideArmPrint(){ ////toplevel
 935   rotate([90,0,0])
 936     FilamentGuideArm();
 937 }
 938
 939 module Demo(){ ////toplevel
 940   translate([-real_exteffrad,-20,0]) Hub();
 941   ArmEnd();
 942   translate([ratchettooth*2, 30, 0]) FilamentCup();
 943 }
 944
 945 //ArmEnd();
 946 //FilamentCup();
 947 //FilamentCupPair();
 948 //CupSecuringClip();
 949 //Hub();
 950 //ArmExtender();
 951 //Axle();
 952 //AxleWasher();
 953 //AxlePin();
 954 //AxleFrictionWasher();
 955 //StorageArmLeft();
 956 //StorArmHoleTest();
 957 //FilamentGuideSpacer();
 958 //FilamentGuideArm();
 959 //FilamentGuideArmPrint();
 960 //Demo();