filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  50 //
  51 // A light duty 3-armed spool suitable for up to around 30m
  52 // of Faberdashery 2.85mm PLA.
  53 //
  54 //     Set
  55 //           fdia=2.85
  56 //           lightduty=true
  57 //     And print following parts
  58 //           Hub
  59 //           ArmEnd x 3
  60 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  61 //           CupSecuringClip x 3
  62 //           TowerDoveClipPin x 6
  63 //
  64 //     When assembling, insert one TowerDoveClipPin from each side,
  65 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  66 //     Modest force with pliers is good to seat them properly.
  67 //
  68 //     (note that the light duty and heavy duty CupSecuringClips
  69 //      are slightly different)
  70 //
  71 // ===== Notes regarding both the above spools =====
  72 //
  73 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  74 // end of the hub towards the printer - ie, put put the spool on
  75 // `backwards'.  This ensures that the spool's arms will clear the
  76 // printer framework.
  77 //
  78 // For the above, I generally used the Cura `Standard' PLA profile.
  79 //
  80 // ===== TAZ-5 feed tube adjustment kit =====
  81 //
  82 // With a TAZ-5 I recommend using this kit to improve the feed
  83 // reliability:
  84 //
  85 //       Set
  86 //           fdia=2.85
  87 //     And print following parts
  88 //           FilamentGuideSpacer (ideally, at `high detail')
  89 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  90 //
  91 //     And possibly also
  92 //           t-nut_jig_0.2.stl
  93 //     from Aleph Objects - look here:
  94 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  95 //
  96 // The spacer clips onto the filament guide tube holder arm, on the
  97 // inside, with the pointy flanged end towards the filament guide
  98 // tube.  It stops the filament guide tube angle (and so the
  99 // filament's natural pickup location) changing as the print head moves.
 100 //
 101 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 102 // with your TAZ-5.  It's longer, so that the filament pickup point is
 103 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 104 // T-nuts in the aluminium channel from annoyingly sliding down to the
 105 // bottom while you swap out the arm.
 106 //
 107 // (Faberdashery coils, and therefore both the above spools, have a
 108 // larger diameter than the flat-walled spools often supplied by other
 109 // vendors.  And the spools above have individual arms rather than a
 110 // continuous disc.  If the filament `unhooks' from the arm, it can
 111 // pull taught around the hub and stop feeding properly.)
 112 //
 113 // ===== Spool storage arm, for mounting on walls =====
 114 //
 115 // A storage arm suitable for screwing to walls, bookshelves,
 116 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 117 // spools each with a 100m coil.
 118 //
 119 //     Set
 120 //           fdia=2.85
 121 //           lightduty=false
 122 //     And print one of these, according to taste
 123 //            StorageArmLeft
 124 //            StorageArmRight
 125 //
 126 //     NB that the `light duty' version of this is shorter and
 127 //     will only take two `light duty' spools.
 128 //
 129 // For the above, I used the Cura `High detail' PLA profile because
 130 // I wanted it pretty, but the `Standard' profile should do fine.
 131 //
 132 // ===== Spools for 1.75mm filament =====
 133 //
 134 // Spool (in many parts) for handing 1.75mm filament, printable
 135 // on, and with parts for mounting on, a Reprappro Huxley.
 136
 137
 138 fdia=2.85; // or 1.75
 139 lightduty=false; // or true
 140
 141
 142 slop=0.5;
 143 bigslop=slop*2;
 144
 145 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 146 function usedove() = selsz(true,true,false);
 147
 148 num_arms = selsz(3,3,4);
 149
 150 channelslop=selsz(slop,0.75,slop);
 151
 152 exteffrad = 70;
 153 hubeffrad = selsz(30, 82, 40);
 154 hubbigrad = selsz(20, 38, 38);
 155 hublwidth = selsz(3, 2.5, 4);
 156 hubstemwidth = 2;
 157 hublthick = 10;
 158 hubaxlerad = selsz(5, 28/2, 28/2);
 159 totalheightfromtower = 240;
 160 axletowerfudgebend = 0;
 161 axleaxlefudgebend = 3;
 162 axlepadlen = 1.0;
 163
 164 armend_length = 120;
 165
 166 prongthick=selsz(5,4,5);
 167 prongwidth=selsz(5,4,5);
 168 prongribwidth=3;
 169 prongribheight=selsz(0,0,4);
 170 ratchetstep=15;
 171 ratchettooth=3;
 172 ratchettoothheight=5;
 173 ratchettoothsmoothr=1;
 174 ratchettoothslope=0.75;
 175 overlap=0.5;
 176 cupwidth=selsz(40,25,50);
 177 cupheight=selsz(55,25,55);
 178
 179 cupstrong_dx=selsz(0,0,-10);
 180
 181 propxshift = -6;
 182
 183 doveclipheight = 10;
 184
 185 teethh=3;
 186 teethgapx=4+fdia;
 187
 188 prongstalkxwidth=3;
 189
 190 stalklength=selsz(35,25,55);
 191 overclipcupgap=5;
 192 overclipdepth=15;
 193 overcliproundr=2.0;
 194 overclipthick=1.0;
 195 overclipcupnextgap=selsz(20,15,20);
 196
 197 hubaxlelen = selsz(25, 62.5, 77.5);
 198 echo(hubaxlelen);
 199
 200 overclipsmaller=-2.5;
 201 overclipbigger=0.0;
 202
 203 wingspoke=2.5;
 204 wingsize=6;
 205 wingthick=3;
 206
 207 armendwallthick=selsz(2.5, 1.8, 2.5);
 208 armendbasethick=selsz(1.2, 1.2, 1.2);
 209
 210 axlehorizoffset = 12.5;
 211 axlevertheight = 100;
 212 towercliph = 16;
 213 towerclipcount = 3;
 214 towerpillarw = 5;
 215
 216 axlepinrad = 2;
 217 axlepintabrad = 5;
 218
 219 washerthick = 1.2;
 220 washerthinthick = 0.8;
 221 washerverythinthick = 0.4;
 222 washerrad = hubaxlerad + 7.5;
 223 frictionwasherarmwidth = 3;
 224 frictionwasherextrapush = 1.0;
 225
 226 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 227
 228 nondove_armhole_x = 32;
 229 nondove_armhole_hole = 4 + 0.8;
 230 nondove_armhole_support = 7;
 231 nondove_armhole_wall = 3.2;
 232 nondove_armhole_slop = 0.5;
 233 nondove_armhole_slop_x = 0.5;
 234
 235 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 236   nondove_armhole_support;
 237 echo(nondove_armbase);
 238
 239 real_exteffrad = selsz(exteffrad,
 240                        hubeffrad + nondove_armbase,
 241                        hubeffrad + nondove_armbase);
 242
 243 include <doveclip.scad>
 244 include <cliphook.scad>
 245 include <filamentteeth.scad>
 246 include <axlepin.scad>
 247
 248 channelwidth = prongthick + channelslop;
 249 channeldepth = prongwidth + ratchettoothheight;
 250 totalwidth = armendwallthick*2 + channelwidth;
 251 totalheight = channeldepth + armendbasethick;
 252 stalkwidth = prongwidth + prongstalkxwidth;
 253
 254 tau = PI*2;
 255
 256 module ArmEnd(length=armend_length){ ////toplevel
 257   if (usedove()) {
 258     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 259       rotate([0,0,-90])
 260         DoveClipPairBase(h=doveclipheight);
 261     }
 262   } else {
 263     difference(){
 264       translate([1, -armendwallthick, -armendbasethick])
 265         mirror([1,0,0])
 266         cube([nondove_armbase+1, totalwidth, totalheight]);
 267       translate([-nondove_armbase + nondove_armhole_x,
 268                  -armendwallthick + totalwidth/2,
 269                  -armendbasethick -1])
 270         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 271     }
 272   }
 273
 274 if (0)
 275   for (circum = [300:100:1500]) {
 276     assign(rad = circum / tau)
 277       assign(fn = str("filamentspool-number-n",circum,".dxf"))
 278       assign(xlen = rad - real_exteffrad) {
 279       echo(circum, rad, xlen);
 280       translate([xlen, -armendwallthick, -armendbasethick])
 281         color("blue"){
 282         translate([-.5,-1,0]) cube([1,2,15]);
 283         //  echo(fn);
 284         translate([0,0, totalheight - 1])
 285           rotate([90,0,0])
 286           rotate([0,0,-90])
 287           linear_extrude(height=10)
 288           //    scale(templatescale)
 289           import(file=fn, convexity=100);
 290       }
 291     }
 292   }
 293
 294   difference(){
 295     translate([0, -armendwallthick, -armendbasethick])
 296       cube([length, totalwidth, totalheight]);
 297     translate([-1, 0, 0])
 298       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 299     translate([-1, 0, ratchettoothheight])
 300       cube([length+2, channelwidth, channeldepth+1]);
 301   }
 302   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 303     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 304       rotate([90,0,0])
 305         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 306       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 307                         [       0,      1,      0,      0       ],
 308                         [       0,      0,      1,      0       ],
 309                         [       0,      0,      0,      1       ]])
 310         cube([ratchettooth - ratchettoothsmoothr*2,
 311               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 312     }
 313   }
 314 }
 315
 316 module FilamentCupHandle(){
 317   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 318   mirror([0,1,0]) {
 319     cube([stalklength, stalkwidth, prongthick]);
 320     translate([stalklength, stalkwidth/2, 0])
 321       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 322     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 323       minkowski(){
 324         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 325         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 326                         [       0,      1,      0,      0       ],
 327                         [       0,      0,      1,      0       ],
 328                         [       0,      0,      0,      1       ]])
 329           cube([pawlusewidth,
 330                 ratchettoothheight - ratchettoothsmoothr,
 331                 prongthick - 1]);
 332       }
 333     }
 334   }
 335 }
 336
 337 module FilamentCupCup(){
 338   for (my=[0,1]) mirror([0,my,0]) {
 339     translate([0, cupwidth/2, 0])
 340       cube([cupheight + prongwidth, prongwidth, prongthick]);
 341   }
 342 }
 343
 344 module FilamentCup() { ////toplevel
 345   FilamentCupHandle();
 346
 347   gapy = prongwidth;
 348   dy = cupwidth/2 + gapy + overclipcupgap;
 349   baselen = dy+cupwidth/2;
 350
 351   translate([0, dy, 0])
 352     FilamentCupCup();
 353   cube([prongwidth, baselen+1, prongthick]);
 354
 355   translate([cupstrong_dx, prongwidth, 0]) {
 356     cube([prongwidth, baselen-prongwidth, prongthick]);
 357     for (y = [0, .33, .67, 1])
 358       translate([0, (baselen - prongwidth) * y, 0])
 359         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 360   }
 361   if (cupstrong_dx != 0) {
 362     rotate([0,0,45])
 363       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 364       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 365   }
 366
 367   translate([0, -0.2, 0])
 368     cube([prongribwidth, baselen, prongthick + prongribheight]);
 369
 370   if (prongribheight > 0) {
 371     translate([-prongwidth, baselen, 0])
 372       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 373   }
 374
 375   midrad = cupwidth/2 + prongwidth/2;
 376
 377   propshift = stalklength - overclipdepth - prongthick + propxshift;
 378   proptaken = propshift;
 379   echo(midrad, propshift, proptaken);
 380
 381   translate([propshift, -1, 0]) {
 382     // something is wrong with the y calculation
 383     cube([prongwidth,
 384           gapy+2,
 385           prongthick]);
 386   }
 387   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 388     translate([cupstrong_dx, y + prongwidth, 0])
 389       rotate([0,0, 102 + fdia])
 390       FilamentTeeth(fdia=fdia, h=teethh);
 391   }
 392   for (x = [-0.3, -1.3]) {
 393     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 394       rotate([0,0, 12 + fdia])
 395       FilamentTeeth(fdia=fdia, h=teethh);
 396   }
 397 }
 398
 399 module CupSecuringClipSolid(w,d,h1,h2){
 400   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 401     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 402   }
 403 }
 404
 405 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 406   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 407   minkowski(){
 408     CupSecuringClipSolid(w=totalwidth,
 409                          d=overclipdepth + xdepth,
 410                          h1=hbase - overclipsmaller,
 411                          h2=hbase + overclipbigger);
 412     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 413   }
 414 }
 415
 416 module CupSecuringClip(){ ////toplevel
 417   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 418   difference(){
 419     union(){
 420       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 421       translate([-wingswidth/2, -wingsize/2, 0])
 422         cube([wingswidth, wingsize, wingthick]);
 423       translate([-wingsize/2, -wingswidth/2, 0])
 424         cube([wingsize, wingswidth, wingthick]);
 425     }
 426     translate([0,0,-0.1])
 427       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 428   }
 429 }
 430
 431 module ArmDoveClipPin(){ ////toplevel
 432   DoveClipPin(h=doveclipheight);
 433 }
 434
 435 module TowerDoveClipPin(){ ////toplevel
 436   DoveClipPin(h=towercliph/2);
 437 }
 438
 439 module Hub(){ ////toplevel
 440   axlerad = hubaxlerad + slop;
 441   xmin = axlerad+hublwidth/2;
 442   xmax = hubbigrad-hublwidth/2;
 443   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 444   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 445   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 446   difference(){
 447     union(){
 448       difference(){
 449         cylinder($fn=60, h=hublthick, r=hubbigrad);
 450         translate([0,0,-1])
 451           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 452       }
 453       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 454       for (ang=[0 : 360/num_arms : 359])
 455         rotate([0,0,ang]) {
 456           if (usedove()){
 457             difference() {
 458               translate([hubeffrad,0,0])
 459                 DoveClipPairSane(h=doveclipheight,
 460                                  baseextend = (hubeffrad - DoveClip_depth()
 461                                                - hubbigrad + hublwidth));
 462               if (hole>hublwidth && holewidth > 2) {
 463                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 464                   cube([hole, holewidth, hublthick+2]);
 465               }
 466             }
 467           } else {
 468             difference(){
 469               translate([0,
 470                          -nondove_allwidth/2,
 471                          0])
 472                 cube([hubeffrad + nondove_armhole_x
 473                       + nondove_armhole_hole/2 + nondove_armhole_support,
 474                       nondove_allwidth,
 475                       nondove_armhole_wall + totalheight]);
 476               translate([hubeffrad - nondove_armhole_slop_x,
 477                          -nondove_allwidth/2
 478                          + nondove_armhole_wall - nondove_armhole_slop,
 479                          nondove_armhole_wall])
 480                 cube([nondove_armhole_x + 50,
 481                       totalwidth + nondove_armhole_slop*2,
 482                       totalheight + 1]);
 483               translate([hubeffrad + nondove_armhole_x, 0, -20])
 484                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 485             }
 486           }
 487         }
 488       for (ang = [0 : 180/num_arms : 359])
 489         rotate([0,0,ang]) rotate([90,0,0]) {
 490           translate([0,0,-hublwidth/2])
 491             linear_extrude(height=hublwidth)
 492             polygon([[xmin,0.05], [xmax,0.05],
 493                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 494         }
 495     }
 496     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 497   }
 498 }
 499
 500 module ArmExtender(){ ////toplevel
 501   DoveClipExtender(length=exteffrad-hubeffrad,
 502                    ha=doveclipheight,
 503                    hb=doveclipheight);
 504 }
 505
 506 module FsAxlePin(){ ////toplevel
 507   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 508 }
 509
 510 module Axle(){ ////toplevel
 511   pillarswidth = DoveClipPairSane_width(towerclipcount);
 512
 513   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 514   translate([-axlehorizoffset, -axlevertheight, 0]) {
 515     rotate([0,0,-axletowerfudgebend])
 516     rotate([0,0,-90])
 517       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 518     translate([0, DoveClip_depth(), 0])
 519     rotate([0,0,90])
 520       ExtenderPillars(axlevertheight - DoveClip_depth(),
 521                       pillarswidth, towercliph,
 522                       pillarw=towerpillarw);
 523   }
 524
 525   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 526   axlerad = hubaxlerad-slop;
 527   bump = axlerad * 0.2;
 528   shift = axlerad-bump;
 529   joinbelowallow = 3;
 530
 531   intersection(){
 532     translate([0, 0, shift]) {
 533       difference() {
 534         union(){
 535           translate([-1, 0, 0])
 536             rotate([0,90,0])
 537             cylinder($fn=60,
 538                      r = axlerad,
 539                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 540           mirror([1,0,0]) rotate([0,90,0])
 541             cylinder(r = axlerad*1.75, h = 3);
 542           intersection(){
 543             mirror([1,0,0])
 544               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 545               rotate([0,90,0])
 546               cylinder($fn=60,
 547                        r = towercliph - shift,
 548                        h = pillarswidth);
 549             translate([-50, -joinbelowallow, -50])
 550               cube([100, joinbelowallow+50, 100]);
 551           }
 552         }
 553         rotate([90,0,0])
 554         translate([axleclearlen + axlepinrad/2, 0, -25])
 555           cylinder(r = axlepinrad + slop, h=50);
 556       }
 557     }
 558     translate([-50,-50,0]) cube([100,100,100]);
 559   }
 560 }
 561
 562 module washer(thick){
 563   Washer(hubaxlerad, washerrad, thick, slop);
 564 }
 565
 566 module AxleWasher(){ ////toplevel
 567   washer(thick=washerthick);
 568 }
 569
 570 module AxleThinWasher(){ ////toplevel
 571   washer(thick=washerthinthick);
 572 }
 573
 574 module AxleVeryThinWasher(){ ////toplevel
 575   washer(thick=washerverythinthick);
 576 }
 577
 578 module AxleFrictionWasher(){ ////toplevel
 579   difference(){
 580     cylinder(h=washerthick, r=washerrad);
 581     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 582   }
 583   frarmr = hubbigrad;
 584   frarmw = frictionwasherarmwidth;
 585   frarmpawlr = hublwidth;
 586   frarmpawlpush = slop*4 + frictionwasherextrapush;
 587   for (ang=[0,180]) rotate([0,0,ang]) {
 588     translate([washerrad-1, -frarmw/2, 0])
 589       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 590     intersection(){
 591       translate([frarmr - frarmpawlr, -50, 0])
 592         cube([frarmpawlr, 100, 50]);
 593       rotate([0,90,0])
 594         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 595     }
 596   }
 597 }
 598
 599 module TowerExtender(){ ////toplevel
 600   l = totalheightfromtower - axlevertheight;
 601   echo("TowerExtender",l);
 602   DoveClipExtender(length = l,
 603                    ha = towercliph, hb = towercliph,
 604                    counta = towerclipcount, countb = towerclipcount,
 605                    pillarw = towerpillarw);
 606 }
 607
 608 module FilamentCupPair(){ ////toplevel
 609   FilamentCup();
 610   translate([cupheight + prongthick*3,
 611              cupwidth/2*1.7,
 612              0])
 613     rotate([0,0,180]) FilamentCup();
 614 }
 615
 616 //----- storarm -----
 617
 618 storarm_hooklen = 8;
 619 storarm_hookheight = 5;
 620 storarm_thick = 10;
 621 storarm_axleslop = 4;
 622
 623 storarm_base_w = 30;
 624 storarm_base_h = 100;
 625 storarm_base_d = 15;
 626 storarm_base_mind = 2;
 627
 628 storarm_cope_hubaxle_mk1 = true;
 629
 630 storarm_screw_hole = 4;
 631 storarm_screw_hole_slop = 0.5;
 632 storarm_besides_hole = 4;
 633
 634 storarm_under_hole = 5;
 635 storarm_screw_hole_head = 8.8;
 636 storarm_screw_hole_head_slop = 1.5;
 637
 638 // calculated
 639
 640 storarm_axlerad = hubaxlerad - storarm_axleslop;
 641 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 642   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 643 storarm_totlen = storarm_mainlen + storarm_hooklen;
 644
 645 storarm_mid_off_y = storarm_axlerad;
 646
 647 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 648
 649 module StorageArmDiagPartSide(xmin, xmax){
 650   xsz = xmax-xmin;
 651   yuse = storarm_thick/2;
 652
 653   intersection(){
 654     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 655       rotate([0,90,0])
 656       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 657     translate([xmin, -yuse, 0])
 658       cube([xsz, yuse, storarm_thick]);
 659   }
 660 }
 661
 662 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 663   hull(){
 664     StorageArmDiagPartSide(xmin,xmax);
 665
 666     multmatrix([[1,0,0,0],
 667                 [shear,1,0,0],
 668                 [0,0,1,0],
 669                 [0,0,0,1]])
 670       translate([0, -storarm_axlerad*2 + adjbot, 0])
 671       mirror([0,1,0])
 672       StorageArmDiagPartSide(xmin,xmax);
 673   }
 674 }
 675
 676 module StorageArmBaseTemplate(){
 677   square([storarm_base_w, storarm_base_h]);
 678 }
 679
 680 module StorageArmAtMountingHoles(){
 681   bes = storarm_besides_hole + storarm_screw_hole;
 682
 683   x0 = bes;
 684   x1 = storarm_base_w-bes;
 685   y1 = storarm_base_h - bes;
 686   y0 = bes;
 687
 688   for (pos=[ [x0, y1],
 689              [x1, y1],
 690              [x1, y0] ]) {
 691     rotate([0,90,0])
 692       translate([pos[0] - storarm_base_w,
 693                  pos[1] - storarm_base_off_y, -storarm_base_d])
 694       children();
 695   }
 696 }
 697
 698 module StorageArmRight(){ ////toplevel
 699   shear = storarm_hookheight / (storarm_mainlen/2);
 700
 701   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 702   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 703                      storarm_hookheight/2);
 704
 705   translate([0, storarm_hookheight, 0])
 706     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 707                        shear/2, -storarm_hookheight/2);
 708
 709   difference(){
 710     union(){
 711       hull(){
 712         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 713           rotate([0,90,0])
 714           linear_extrude(height=storarm_base_mind)
 715           StorageArmBaseTemplate();
 716         StorageArmDiagPart(-1, 0, shear, 0);
 717       }
 718       StorageArmAtMountingHoles(){
 719         cylinder(r= storarm_screw_hole_head/2,
 720                  h=10);
 721       }
 722     }
 723     StorageArmAtMountingHoles(){
 724       translate([0,0,-1])
 725         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 726                  h=20);
 727       translate([0,0,storarm_under_hole])
 728         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 729                  h=20);
 730     }
 731   }
 732 }
 733
 734 module StorageArmLeft(){ ////toplevel
 735   mirror([1,0,0]) StorageArmRight();
 736 }
 737
 738 module StorArmHoleTest(){ ////toplevel
 739   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 740   intersection(){
 741     StorageArmRight();
 742     translate([-50, -storarm_base_off_y, -1])
 743       cube([100, sz, sz+1]);
 744   }
 745 }
 746
 747
 748 //----- filament guide spacer -----
 749
 750 guide_armdia = 15.0;
 751 guide_armwidth = 10.2;
 752 guide_armcorelen = 25.0;
 753 guide_clipcirclethick = 10.0;
 754
 755 guidefilclip_outerdia = 22.8;
 756
 757 guidespacer_armslop = 0.75;
 758 guidespacer_armlenslop = 1.05;
 759
 760 guidespacer_prongprotrude = 4;
 761 guidespacer_thick = 1.6;
 762
 763 // calculated
 764
 765 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 766 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 767 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 768   + guidespacer_armlenslop;
 769
 770 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 771
 772 module FilamentGuideArmTemplate(extra=0){
 773   intersection(){
 774     circle(r= (guidespacer_armdia/2) + extra);
 775     square(center=true, [guidespacer_armwidth+extra*2,
 776                          guidespacer_armdia + extra*2 + 10]);
 777   }
 778 }
 779
 780 module FilamentGuideSpacerInnerTemplate(){
 781   FilamentGuideArmTemplate();
 782   translate([0, -guidespacer_armdia/2])
 783     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 784                          guidespacer_armdia]);
 785 }
 786
 787 module FilamentGuideSpacer(){ ////toplevel
 788   difference(){
 789     union(){
 790       linear_extrude(height= guidespacer_len)
 791         FilamentGuideArmTemplate(extra= guidespacer_thick);
 792       for (angle=[26, 60]) {
 793         for (m=[0,1]) {
 794           mirror([m,0,0]) {
 795             rotate([0,0,angle]) {
 796               hull(){
 797                 for (t=[[0, guidespacer_wingheight],
 798                         [guidespacer_len-1, -guidespacer_wingheight]])
 799                   translate([0,0, t[0] + 0.5])
 800                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 801                       1],
 802                          center=true);
 803               }
 804             }
 805           }
 806         }
 807       }
 808     }
 809     translate([0,0,-1])
 810       linear_extrude(height= guidespacer_len+5)
 811       FilamentGuideSpacerInnerTemplate();
 812   }
 813 }
 814
 815
 816 //----- replacement filament guide arm for TAZ-5 -----
 817
 818 guidearm_armslop = 0.25;
 819 guidearm_armlenslop = 0.25;
 820
 821 guidearm_hookprotr = 3;
 822 guidearm_hookprotrflat = 1;
 823 guidearm_hookslope = 0.3;
 824
 825 guidearm_totallen = 60;
 826
 827 guidearm_screwplatesz = 12;
 828 guidearm_screwplateth = 4;
 829 guidearm_screwplatewd = 15;
 830 guidearm_screwhole = 5 + 0.5;
 831
 832 guidearm_bendlen = 40;
 833 guidearm_bendslot = 4.5;
 834
 835 guidearm_stopthick = 4;
 836 guidearm_protrslop = 1.0;
 837
 838 // calculated
 839
 840 guidearm_armdia = guide_armdia - guidearm_armslop;
 841 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 842 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 843
 844 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 845
 846 guidearm_realbendlen = min(guidearm_bendlen,
 847                            guidearm_totallen - guidearm_screwplateth - 0.1);
 848 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 849
 850 module FilamentGuideArmStop(h){
 851   for (ts=[-1,+1]) {
 852     translate([ts * guidearm_hookprotr, 0,0])
 853       cylinder(r=guidearm_armdia/2, h, $fn=80);
 854   }
 855 }
 856
 857 module FilamentGuideArmShaftPositive(){
 858   r = guidearm_armdia/2;
 859
 860   translate([0,0, guidearm_base_z0+1])
 861     cylinder(r=r, h= guidearm_totallen, $fn=80);
 862   translate([0,0, guidearm_armcorelen]){
 863     hull(){
 864       FilamentGuideArmStop(guidearm_hookprotrflat);
 865       translate([0,0, guidearm_slopelen])
 866         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 867     }
 868   }
 869   mirror([0,0,1])
 870     FilamentGuideArmStop(guidearm_stopthick);
 871 }
 872
 873 module FilamentGuideArmBase(){
 874   translate([0,
 875              (guidearm_screwplatewd - guidearm_armwidth)/2,
 876              guidearm_base_z0]){
 877     difference(){
 878       translate([0,0, guidearm_screwplateth/2])
 879         cube(center=true,
 880              [guidearm_armdia + guidearm_screwplatesz*2,
 881               guidearm_screwplatewd,
 882               guidearm_screwplateth]);
 883       for (ts=[-1,+1]) {
 884         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 885                    0,
 886                    -20])
 887           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 888       }
 889     }
 890   }
 891 }
 892
 893 module FilamentGuideArm(){ ///toplevel
 894   intersection(){
 895     difference(){
 896       FilamentGuideArmShaftPositive();
 897       translate([-guidearm_bendslot/2,
 898                  -50,
 899                  -guidearm_realbendlen + guidearm_armcorelen])
 900         cube([guidearm_bendslot,
 901               100,
 902               guidearm_realbendlen + 100]);
 903       hull(){
 904         for (zx=[ [ 0, guidearm_bendslot ],
 905                   [ guidearm_armcorelen + guidearm_slopelen,
 906                     guidearm_hookprotr*2 + guidearm_protrslop ]
 907                   ]) {
 908           translate([-zx[1]/2, -50, zx[0]])
 909           cube([zx[1], 100, 1]);
 910         }
 911       }
 912     }
 913     cube(center=true,
 914          [guidearm_armdia*2,
 915           guidearm_armwidth,
 916           guidearm_totallen*3]);
 917   }
 918   FilamentGuideArmBase();
 919 }
 920
 921 module FilamentGuideArmPrint(){ ////toplevel
 922   rotate([90,0,0])
 923     FilamentGuideArm();
 924 }
 925
 926 module Demo(){ ////toplevel
 927   translate([-real_exteffrad,-20,0]) Hub();
 928   ArmEnd();
 929   translate([ratchettooth*2, 30, 0]) FilamentCup();
 930 }
 931
 932 //ArmEnd();
 933 //FilamentCup();
 934 //FilamentCupPair();
 935 //CupSecuringClip();
 936 //Hub();
 937 //ArmExtender();
 938 //Axle();
 939 //AxleWasher();
 940 //AxlePin();
 941 //AxleFrictionWasher();
 942 //StorageArmLeft();
 943 //StorArmHoleTest();
 944 //FilamentGuideSpacer();
 945 //FilamentGuideArm();
 946 //FilamentGuideArmPrint();
 947 //Demo();