filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 //     This is the default.
  50 //
  51 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  52 //
  53 // A light duty 3-armed spool suitable for up to around 30m
  54 // of Faberdashery 2.85mm PLA.
  55 //
  56 //     Set
  57 //           fdia=2.85
  58 //           lightduty=true
  59 //     (or look in filamentspool-lt.scad).
  60 //
  61 //     And print following parts
  62 //           Hub
  63 //           ArmEnd x 3
  64 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  65 //           CupSecuringClip x 3
  66 //           TowerDoveClipPin x 6
  67 //
  68 //     When assembling, insert one TowerDoveClipPin from each side,
  69 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  70 //     Modest force with pliers is good to seat them properly.
  71 //
  72 //     (note that the light duty and heavy duty CupSecuringClips
  73 //      are slightly different)
  74 //
  75 // ===== Notes regarding both the above spools =====
  76 //
  77 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  78 // end of the hub towards the printer - ie, put put the spool on
  79 // `backwards'.  This ensures that the spool's arms will clear the
  80 // printer framework.
  81 //
  82 // For the above, I generally used the Cura `Standard' PLA profile.
  83 //
  84 // ===== TAZ-5 feed tube adjustment kit =====
  85 //
  86 // With a TAZ-5 I recommend using this kit to improve the feed
  87 // reliability:
  88 //
  89 //       Set
  90 //           fdia=2.85
  91 //     And print following parts
  92 //           FilamentGuideSpacer (ideally, at `high detail')
  93 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  94 //
  95 //     And possibly also
  96 //           t-nut_jig_0.2.stl
  97 //     from Aleph Objects - look here:
  98 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  99 //
 100 // The spacer clips onto the filament guide tube holder arm, on the
 101 // inside, with the pointy flanged end towards the filament guide
 102 // tube.  It stops the filament guide tube angle (and so the
 103 // filament's natural pickup location) changing as the print head moves.
 104 //
 105 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 106 // with your TAZ-5.  It's longer, so that the filament pickup point is
 107 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 108 // T-nuts in the aluminium channel from annoyingly sliding down to the
 109 // bottom while you swap out the arm.
 110 //
 111 // (Faberdashery coils, and therefore both the above spools, have a
 112 // larger diameter than the flat-walled spools often supplied by other
 113 // vendors.  And the spools above have individual arms rather than a
 114 // continuous disc.  If the filament `unhooks' from the arm, it can
 115 // pull taught around the hub and stop feeding properly.)
 116 //
 117 // ===== Spool storage arm, for mounting on walls =====
 118 //
 119 // A storage arm suitable for screwing to walls, bookshelves,
 120 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 121 // spools each with a 100m coil.
 122 //
 123 //     Set
 124 //           fdia=2.85
 125 //           lightduty=false
 126 //     (or look in filamentspool-sm.scad).
 127 //
 128 //     And print one of these, according to taste
 129 //            StorageArmLeft
 130 //            StorageArmRight
 131 //
 132 //     NB that the `light duty' version of this is shorter and
 133 //     will only take two `light duty' spools.
 134 //
 135 // For the above, I used the Cura `High detail' PLA profile because
 136 // I wanted it pretty, but the `Standard' profile should do fine.
 137 //
 138 // ===== Spools for 1.75mm filament =====
 139 //
 140 // Spool (in many parts) for handing 1.75mm filament, printable
 141 // on, and with parts for mounting on, a Reprappro Huxley.
 142
 143
 144 fdia=2.85; // or 1.75
 145 lightduty=false; // or true
 146
 147
 148 slop=0.5;
 149 bigslop=slop*2;
 150
 151 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 152 function usedove() = selsz(true,true,false);
 153
 154 num_arms = selsz(3,3,4);
 155
 156 channelslop=selsz(slop,0.75,slop);
 157
 158 exteffrad = 70;
 159 hubeffrad = selsz(30, 82, 40);
 160 hubbigrad = selsz(20, 38, 38);
 161 hublwidth = selsz(3, 2.5, 4);
 162 hubstemwidth = 2;
 163 hublthick = 10;
 164 hubaxlerad = selsz(5, 28/2, 28/2);
 165 totalheightfromtower = 240;
 166 axletowerfudgebend = 0;
 167 axleaxlefudgebend = 3;
 168 axlepadlen = 1.0;
 169
 170 armend_length = 120;
 171
 172 prongthick=selsz(5,4,5);
 173 prongwidth=selsz(5,4,5);
 174 prongribwidth=3;
 175 prongribheight=selsz(0,0,4);
 176 ratchetstep=15;
 177 ratchettooth=3;
 178 ratchettoothheight=5;
 179 ratchettoothsmoothr=1;
 180 ratchettoothslope=0.75;
 181 overlap=0.5;
 182 cupwidth=selsz(40,25,50);
 183 cupheight=selsz(55,25,55);
 184
 185 cupstrong_dx=selsz(0,0,-10);
 186
 187 propxshift = -6;
 188
 189 doveclipheight = 10;
 190
 191 teethh=3;
 192 teethgapx=4+fdia;
 193
 194 prongstalkxwidth=3;
 195
 196 stalklength=selsz(35,25,55);
 197 overclipcupgap=5;
 198 overclipdepth=15;
 199 overcliproundr=2.0;
 200 overclipthick=1.0;
 201 overclipcupnextgap=selsz(20,15,20);
 202
 203 hubaxlelen = selsz(25, 62.5, 77.5);
 204 echo(hubaxlelen);
 205
 206 overclipsmaller=-2.5;
 207 overclipbigger=0.0;
 208
 209 wingspoke=2.5;
 210 wingsize=6;
 211 wingthick=3;
 212
 213 armendwallthick=selsz(2.5, 1.8, 2.5);
 214 armendbasethick=selsz(1.2, 1.2, 1.2);
 215
 216 numbers_relief = 0.7;
 217 numbers_tick_len = 8;
 218 numbers_tick_width = 0.75;
 219 numbers_tick_linespc = 1.0;
 220 numbers_height_allow = 8;
 221
 222 axlehorizoffset = 12.5;
 223 axlevertheight = 100;
 224 towercliph = 16;
 225 towerclipcount = 3;
 226 towerpillarw = 5;
 227
 228 axlepinrad = 2;
 229 axlepintabrad = 5;
 230
 231 washerthick = 1.2;
 232 washerthinthick = 0.8;
 233 washerverythinthick = 0.4;
 234 washerrad = hubaxlerad + 7.5;
 235 frictionwasherarmwidth = 3;
 236 frictionwasherextrapush = 1.0;
 237
 238 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 239
 240 nondove_armhole_x = 32;
 241 nondove_armhole_hole = 4 + 0.8;
 242 nondove_armhole_support = 7;
 243 nondove_armhole_wall = 3.2;
 244 nondove_armhole_slop = 0.5;
 245 nondove_armhole_slop_x = 0.5;
 246
 247 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 248   nondove_armhole_support;
 249 echo(nondove_armbase);
 250
 251 include <doveclip.scad>
 252 include <cliphook.scad>
 253 include <filamentteeth.scad>
 254 include <axlepin.scad>
 255 include <commitid.scad>
 256
 257 hub_clip_baseextend = (hubeffrad - DoveClip_depth()
 258                        - hubbigrad + hublwidth);
 259
 260 real_exteffrad = selsz(exteffrad + hub_clip_baseextend,
 261                        hubeffrad + DoveClip_depth(),
 262                        hubeffrad + nondove_armbase);
 263
 264 channelwidth = prongthick + channelslop;
 265 channeldepth = prongwidth + ratchettoothheight;
 266 totalwidth = armendwallthick*2 + channelwidth;
 267 totalheight = channeldepth + armendbasethick;
 268 stalkwidth = prongwidth + prongstalkxwidth;
 269
 270 tau = PI*2;
 271
 272 module ArmEnd(length=armend_length){ ////toplevel
 273   if (usedove()) {
 274     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 275       rotate([0,0,-90])
 276         DoveClipPairBase(h=doveclipheight);
 277     }
 278   } else {
 279     difference(){
 280       translate([1, -armendwallthick, -armendbasethick])
 281         mirror([1,0,0])
 282         cube([nondove_armbase+1, totalwidth, totalheight]);
 283       translate([-nondove_armbase + nondove_armhole_x,
 284                  -armendwallthick + totalwidth/2,
 285                  -armendbasethick -1])
 286         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 287     }
 288   }
 289
 290   for (otherside=[0,1]) {
 291     for (circum = [300:100:1500]) {
 292       assign(rad = circum / tau)
 293         assign(fn = str("filamentspool-number-n",circum,".dxf"))
 294         assign(rotateoffset = [0, totalwidth/2, 0])
 295         assign(xlen = rad - real_exteffrad) {
 296         if (xlen >= numbers_tick_width/2
 297             + (otherside ? numbers_height_allow : 0) &&
 298             xlen <= length - (otherside ? 0 : numbers_height_allow))
 299           translate([xlen, -armendwallthick,
 300                      -armendbasethick + (totalheight - numbers_tick_len)/2])
 301           translate(rotateoffset)
 302           rotate([0,0, otherside*180])
 303           translate(-rotateoffset){
 304             translate([-numbers_tick_width/2, -1, 0])
 305               cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 306             translate([numbers_tick_width/2 + numbers_tick_linespc,
 307                        1,
 308                        numbers_tick_len])
 309               rotate([90,0,0])
 310               rotate([0,0,-90])
 311               linear_extrude(height= numbers_relief+1)
 312               //    scale(templatescale)
 313               import(file=fn, convexity=100);
 314           }
 315       }
 316     }
 317   }
 318
 319   difference(){
 320     translate([0, -armendwallthick, -armendbasethick])
 321       cube([length, totalwidth, totalheight]);
 322     translate([-1, 0, 0])
 323       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 324     translate([-1, 0, ratchettoothheight])
 325       cube([length+2, channelwidth, channeldepth+1]);
 326   }
 327   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 328     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 329       rotate([90,0,0])
 330         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 331       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 332                         [       0,      1,      0,      0       ],
 333                         [       0,      0,      1,      0       ],
 334                         [       0,      0,      0,      1       ]])
 335         cube([ratchettooth - ratchettoothsmoothr*2,
 336               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 337     }
 338   }
 339 }
 340
 341 module FilamentCupHandle(){
 342   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 343   mirror([0,1,0]) {
 344     cube([stalklength, stalkwidth, prongthick]);
 345     translate([stalklength, stalkwidth/2, 0])
 346       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 347     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 348       minkowski(){
 349         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 350         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 351                         [       0,      1,      0,      0       ],
 352                         [       0,      0,      1,      0       ],
 353                         [       0,      0,      0,      1       ]])
 354           cube([pawlusewidth,
 355                 ratchettoothheight - ratchettoothsmoothr,
 356                 prongthick - 1]);
 357       }
 358     }
 359   }
 360 }
 361
 362 module FilamentCupCup(){
 363   for (my=[0,1]) mirror([0,my,0]) {
 364     translate([0, cupwidth/2, 0])
 365       cube([cupheight + prongwidth, prongwidth, prongthick]);
 366   }
 367 }
 368
 369 module FilamentCup() { ////toplevel
 370   FilamentCupHandle();
 371
 372   gapy = prongwidth;
 373   dy = cupwidth/2 + gapy + overclipcupgap;
 374   baselen = dy+cupwidth/2;
 375
 376   translate([0, dy, 0])
 377     FilamentCupCup();
 378   cube([prongwidth, baselen+1, prongthick]);
 379
 380   translate([cupstrong_dx, prongwidth, 0]) {
 381     cube([prongwidth, baselen-prongwidth, prongthick]);
 382     for (y = [0, .33, .67, 1])
 383       translate([0, (baselen - prongwidth) * y, 0])
 384         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 385   }
 386   if (cupstrong_dx != 0) {
 387     rotate([0,0,45])
 388       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 389       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 390   }
 391
 392   translate([0, -0.2, 0])
 393     cube([prongribwidth, baselen, prongthick + prongribheight]);
 394
 395   if (prongribheight > 0) {
 396     translate([-prongwidth, baselen, 0])
 397       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 398   }
 399
 400   midrad = cupwidth/2 + prongwidth/2;
 401
 402   propshift = stalklength - overclipdepth - prongthick + propxshift;
 403   proptaken = propshift;
 404   echo(midrad, propshift, proptaken);
 405
 406   translate([propshift, -1, 0]) {
 407     // something is wrong with the y calculation
 408     cube([prongwidth,
 409           gapy+2,
 410           prongthick]);
 411   }
 412   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 413     translate([cupstrong_dx, y + prongwidth, 0])
 414       rotate([0,0, 102 + fdia])
 415       FilamentTeeth(fdia=fdia, h=teethh);
 416   }
 417   for (x = [-0.3, -1.3]) {
 418     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 419       rotate([0,0, 12 + fdia])
 420       FilamentTeeth(fdia=fdia, h=teethh);
 421   }
 422 }
 423
 424 module CupSecuringClipSolid(w,d,h1,h2){
 425   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 426     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 427   }
 428 }
 429
 430 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 431   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 432   minkowski(){
 433     CupSecuringClipSolid(w=totalwidth,
 434                          d=overclipdepth + xdepth,
 435                          h1=hbase - overclipsmaller,
 436                          h2=hbase + overclipbigger);
 437     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 438   }
 439 }
 440
 441 module CupSecuringClip(){ ////toplevel
 442   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 443   difference(){
 444     union(){
 445       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 446       translate([-wingswidth/2, -wingsize/2, 0])
 447         cube([wingswidth, wingsize, wingthick]);
 448       translate([-wingsize/2, -wingswidth/2, 0])
 449         cube([wingsize, wingswidth, wingthick]);
 450     }
 451     translate([0,0,-0.1])
 452       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 453   }
 454 }
 455
 456 module ArmDoveClipPin(){ ////toplevel
 457   DoveClipPin(h=doveclipheight);
 458 }
 459
 460 module TowerDoveClipPin(){ ////toplevel
 461   DoveClipPin(h=towercliph/2);
 462 }
 463
 464 module Hub(){ ////toplevel
 465   axlerad = hubaxlerad + slop;
 466   xmin = axlerad+hublwidth/2;
 467   xmax = hubbigrad-hublwidth/2;
 468   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 469   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 470   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 471   difference(){
 472     union(){
 473       difference(){
 474         cylinder($fn=60, h=hublthick, r=hubbigrad);
 475         translate([0,0,-1])
 476           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 477       }
 478       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 479       for (ang=[0 : 360/num_arms : 359])
 480         rotate([0,0,ang]) {
 481           if (usedove()){
 482             difference() {
 483               translate([hubeffrad,0,0])
 484                 DoveClipPairSane(h=doveclipheight,
 485                                  baseextend = hub_clip_baseextend);
 486               if (hole>hublwidth && holewidth > 2) {
 487                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 488                   cube([hole, holewidth, hublthick+2]);
 489               }
 490             }
 491           } else {
 492             difference(){
 493               translate([0,
 494                          -nondove_allwidth/2,
 495                          0])
 496                 cube([hubeffrad + nondove_armhole_x
 497                       + nondove_armhole_hole/2 + nondove_armhole_support,
 498                       nondove_allwidth,
 499                       nondove_armhole_wall + totalheight]);
 500               translate([hubeffrad - nondove_armhole_slop_x,
 501                          -nondove_allwidth/2
 502                          + nondove_armhole_wall - nondove_armhole_slop,
 503                          nondove_armhole_wall])
 504                 cube([nondove_armhole_x + 50,
 505                       totalwidth + nondove_armhole_slop*2,
 506                       totalheight + 1]);
 507               translate([hubeffrad + nondove_armhole_x, 0, -20])
 508                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 509             }
 510           }
 511         }
 512       for (ang = [0 : 180/num_arms : 359])
 513         rotate([0,0,ang]) rotate([90,0,0]) {
 514           translate([0,0,-hublwidth/2])
 515             linear_extrude(height=hublwidth)
 516             polygon([[xmin,0.05], [xmax,0.05],
 517                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 518         }
 519     }
 520     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 521
 522     rotate([0,0, selsz(0,0,45)])
 523       translate([axlerad+hublwidth,
 524                  -hublwidth/2,
 525                  0])
 526       rotate([90,0,0])
 527       Commitid_BestCount([(hubbigrad-hublwidth) - (axlerad+hublwidth),
 528                           hublthick +
 529                           hublwidth/2 * hubaxlelen/(hubbigrad-axlerad),
 530                           ]);
 531   }
 532 }
 533
 534 module ArmExtender(){ ////toplevel
 535   DoveClipExtender(length=exteffrad-hubeffrad,
 536                    ha=doveclipheight,
 537                    hb=doveclipheight);
 538 }
 539
 540 module FsAxlePin(){ ////toplevel
 541   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 542 }
 543
 544 module Axle(){ ////toplevel
 545   pillarswidth = DoveClipPairSane_width(towerclipcount);
 546
 547   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 548   translate([-axlehorizoffset, -axlevertheight, 0]) {
 549     rotate([0,0,-axletowerfudgebend])
 550     rotate([0,0,-90])
 551       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 552     translate([0, DoveClip_depth(), 0])
 553     rotate([0,0,90])
 554       ExtenderPillars(axlevertheight - DoveClip_depth(),
 555                       pillarswidth, towercliph,
 556                       pillarw=towerpillarw);
 557   }
 558
 559   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 560   axlerad = hubaxlerad-slop;
 561   bump = axlerad * 0.2;
 562   shift = axlerad-bump;
 563   joinbelowallow = 3;
 564
 565   intersection(){
 566     translate([0, 0, shift]) {
 567       difference() {
 568         union(){
 569           translate([-1, 0, 0])
 570             rotate([0,90,0])
 571             cylinder($fn=60,
 572                      r = axlerad,
 573                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 574           mirror([1,0,0]) rotate([0,90,0])
 575             cylinder(r = axlerad*1.75, h = 3);
 576           intersection(){
 577             mirror([1,0,0])
 578               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 579               rotate([0,90,0])
 580               cylinder($fn=60,
 581                        r = towercliph - shift,
 582                        h = pillarswidth);
 583             translate([-50, -joinbelowallow, -50])
 584               cube([100, joinbelowallow+50, 100]);
 585           }
 586         }
 587         rotate([90,0,0])
 588         translate([axleclearlen + axlepinrad/2, 0, -25])
 589           cylinder(r = axlepinrad + slop, h=50);
 590       }
 591     }
 592     translate([-50,-50,0]) cube([100,100,100]);
 593   }
 594 }
 595
 596 module washer(thick){
 597   Washer(hubaxlerad, washerrad, thick, slop);
 598 }
 599
 600 module AxleWasher(){ ////toplevel
 601   washer(thick=washerthick);
 602 }
 603
 604 module AxleThinWasher(){ ////toplevel
 605   washer(thick=washerthinthick);
 606 }
 607
 608 module AxleVeryThinWasher(){ ////toplevel
 609   washer(thick=washerverythinthick);
 610 }
 611
 612 module AxleFrictionWasher(){ ////toplevel
 613   difference(){
 614     cylinder(h=washerthick, r=washerrad);
 615     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 616   }
 617   frarmr = hubbigrad;
 618   frarmw = frictionwasherarmwidth;
 619   frarmpawlr = hublwidth;
 620   frarmpawlpush = slop*4 + frictionwasherextrapush;
 621   for (ang=[0,180]) rotate([0,0,ang]) {
 622     translate([washerrad-1, -frarmw/2, 0])
 623       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 624     intersection(){
 625       translate([frarmr - frarmpawlr, -50, 0])
 626         cube([frarmpawlr, 100, 50]);
 627       rotate([0,90,0])
 628         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 629     }
 630   }
 631 }
 632
 633 module TowerExtender(){ ////toplevel
 634   l = totalheightfromtower - axlevertheight;
 635   echo("TowerExtender",l);
 636   DoveClipExtender(length = l,
 637                    ha = towercliph, hb = towercliph,
 638                    counta = towerclipcount, countb = towerclipcount,
 639                    pillarw = towerpillarw);
 640 }
 641
 642 module FilamentCupPair(){ ////toplevel
 643   FilamentCup();
 644   translate([cupheight + prongthick*3,
 645              cupwidth/2*1.7,
 646              0])
 647     rotate([0,0,180]) FilamentCup();
 648 }
 649
 650 //----- storarm -----
 651
 652 storarm_hooklen = 8;
 653 storarm_hookheight = 5;
 654 storarm_thick = 10;
 655 storarm_axleslop = 4;
 656
 657 storarm_base_w = 30;
 658 storarm_base_h = 100;
 659 storarm_base_d = 15;
 660 storarm_base_mind = 2;
 661
 662 storarm_cope_hubaxle_mk1 = true;
 663
 664 storarm_screw_hole = 4;
 665 storarm_screw_hole_slop = 0.5;
 666 storarm_besides_hole = 4;
 667
 668 storarm_under_hole = 5;
 669 storarm_screw_hole_head = 8.8;
 670 storarm_screw_hole_head_slop = 1.5;
 671
 672 // calculated
 673
 674 storarm_axlerad = hubaxlerad - storarm_axleslop;
 675 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 676   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 677 storarm_totlen = storarm_mainlen + storarm_hooklen;
 678
 679 storarm_mid_off_y = storarm_axlerad;
 680
 681 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 682
 683 module StorageArmDiagPartSide(xmin, xmax){
 684   xsz = xmax-xmin;
 685   yuse = storarm_thick/2;
 686
 687   intersection(){
 688     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 689       rotate([0,90,0])
 690       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 691     translate([xmin, -yuse, 0])
 692       cube([xsz, yuse, storarm_thick]);
 693   }
 694 }
 695
 696 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 697   hull(){
 698     StorageArmDiagPartSide(xmin,xmax);
 699
 700     multmatrix([[1,0,0,0],
 701                 [shear,1,0,0],
 702                 [0,0,1,0],
 703                 [0,0,0,1]])
 704       translate([0, -storarm_axlerad*2 + adjbot, 0])
 705       mirror([0,1,0])
 706       StorageArmDiagPartSide(xmin,xmax);
 707   }
 708 }
 709
 710 module StorageArmBaseTemplate(){
 711   square([storarm_base_w, storarm_base_h]);
 712 }
 713
 714 module StorageArmAtMountingHoles(){
 715   bes = storarm_besides_hole + storarm_screw_hole;
 716
 717   x0 = bes;
 718   x1 = storarm_base_w-bes;
 719   y1 = storarm_base_h - bes;
 720   y0 = bes;
 721
 722   for (pos=[ [x0, y1],
 723              [x1, y1],
 724              [x1, y0] ]) {
 725     rotate([0,90,0])
 726       translate([pos[0] - storarm_base_w,
 727                  pos[1] - storarm_base_off_y, -storarm_base_d])
 728       children();
 729   }
 730 }
 731
 732 module StorageArmRight(){ ////toplevel
 733   shear = storarm_hookheight / (storarm_mainlen/2);
 734
 735   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 736   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 737                      storarm_hookheight/2);
 738
 739   translate([0, storarm_hookheight, 0])
 740     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 741                        shear/2, -storarm_hookheight/2);
 742
 743   difference(){
 744     union(){
 745       hull(){
 746         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 747           rotate([0,90,0])
 748           linear_extrude(height=storarm_base_mind)
 749           StorageArmBaseTemplate();
 750         StorageArmDiagPart(-1, 0, shear, 0);
 751       }
 752       StorageArmAtMountingHoles(){
 753         cylinder(r= storarm_screw_hole_head/2,
 754                  h=10);
 755       }
 756     }
 757     StorageArmAtMountingHoles(){
 758       translate([0,0,-1])
 759         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 760                  h=20);
 761       translate([0,0,storarm_under_hole])
 762         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 763                  h=20);
 764     }
 765   }
 766 }
 767
 768 module StorageArmLeft(){ ////toplevel
 769   mirror([1,0,0]) StorageArmRight();
 770 }
 771
 772 module StorArmHoleTest(){ ////toplevel
 773   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 774   intersection(){
 775     StorageArmRight();
 776     translate([-50, -storarm_base_off_y, -1])
 777       cube([100, sz, sz+1]);
 778   }
 779 }
 780
 781
 782 //----- filament guide spacer -----
 783
 784 guide_armdia = 15.0;
 785 guide_armwidth = 10.2;
 786 guide_armcorelen = 25.0;
 787 guide_clipcirclethick = 10.0;
 788
 789 guidefilclip_outerdia = 22.8;
 790
 791 guidespacer_armslop = 0.75;
 792 guidespacer_armlenslop = 1.05;
 793
 794 guidespacer_prongprotrude = 4;
 795 guidespacer_thick = 1.6;
 796
 797 // calculated
 798
 799 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 800 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 801 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 802   + guidespacer_armlenslop;
 803
 804 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 805
 806 module FilamentGuideArmTemplate(extra=0){
 807   intersection(){
 808     circle(r= (guidespacer_armdia/2) + extra);
 809     square(center=true, [guidespacer_armwidth+extra*2,
 810                          guidespacer_armdia + extra*2 + 10]);
 811   }
 812 }
 813
 814 module FilamentGuideSpacerInnerTemplate(){
 815   FilamentGuideArmTemplate();
 816   translate([0, -guidespacer_armdia/2])
 817     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 818                          guidespacer_armdia]);
 819 }
 820
 821 module FilamentGuideSpacer(){ ////toplevel
 822   difference(){
 823     union(){
 824       linear_extrude(height= guidespacer_len)
 825         FilamentGuideArmTemplate(extra= guidespacer_thick);
 826       for (angle=[26, 60]) {
 827         for (m=[0,1]) {
 828           mirror([m,0,0]) {
 829             rotate([0,0,angle]) {
 830               hull(){
 831                 for (t=[[0, guidespacer_wingheight],
 832                         [guidespacer_len-1, -guidespacer_wingheight]])
 833                   translate([0,0, t[0] + 0.5])
 834                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 835                       1],
 836                          center=true);
 837               }
 838             }
 839           }
 840         }
 841       }
 842     }
 843     translate([0,0,-1])
 844       linear_extrude(height= guidespacer_len+5)
 845       FilamentGuideSpacerInnerTemplate();
 846   }
 847 }
 848
 849
 850 //----- replacement filament guide arm for TAZ-5 -----
 851
 852 guidearm_armslop = 0.25;
 853 guidearm_armlenslop = 0.25;
 854
 855 guidearm_hookprotr = 3;
 856 guidearm_hookprotrflat = 1;
 857 guidearm_hookslope = 0.3;
 858
 859 guidearm_totallen = 60;
 860
 861 guidearm_screwplatesz = 12;
 862 guidearm_screwplateth = 4;
 863 guidearm_screwplatewd = 15;
 864 guidearm_screwhole = 5 + 0.5;
 865
 866 guidearm_bendlen = 40;
 867 guidearm_bendslot = 4.5;
 868
 869 guidearm_stopthick = 4;
 870 guidearm_protrslop = 1.0;
 871
 872 // calculated
 873
 874 guidearm_armdia = guide_armdia - guidearm_armslop;
 875 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 876 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 877
 878 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 879
 880 guidearm_realbendlen = min(guidearm_bendlen,
 881                            guidearm_totallen - guidearm_screwplateth - 0.1);
 882 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 883
 884 module FilamentGuideArmStop(h){
 885   for (ts=[-1,+1]) {
 886     translate([ts * guidearm_hookprotr, 0,0])
 887       cylinder(r=guidearm_armdia/2, h, $fn=80);
 888   }
 889 }
 890
 891 module FilamentGuideArmShaftPositive(){
 892   r = guidearm_armdia/2;
 893
 894   translate([0,0, guidearm_base_z0+1])
 895     cylinder(r=r, h= guidearm_totallen, $fn=80);
 896   translate([0,0, guidearm_armcorelen]){
 897     hull(){
 898       FilamentGuideArmStop(guidearm_hookprotrflat);
 899       translate([0,0, guidearm_slopelen])
 900         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 901     }
 902   }
 903   mirror([0,0,1])
 904     FilamentGuideArmStop(guidearm_stopthick);
 905 }
 906
 907 module FilamentGuideArmBase(){
 908   translate([0,
 909              (guidearm_screwplatewd - guidearm_armwidth)/2,
 910              guidearm_base_z0]){
 911     difference(){
 912       translate([0,0, guidearm_screwplateth/2])
 913         cube(center=true,
 914              [guidearm_armdia + guidearm_screwplatesz*2,
 915               guidearm_screwplatewd,
 916               guidearm_screwplateth]);
 917       for (ts=[-1,+1]) {
 918         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 919                    0,
 920                    -20])
 921           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 922       }
 923     }
 924   }
 925 }
 926
 927 module FilamentGuideArm(){ ///toplevel
 928   intersection(){
 929     difference(){
 930       FilamentGuideArmShaftPositive();
 931       translate([-guidearm_bendslot/2,
 932                  -50,
 933                  -guidearm_realbendlen + guidearm_armcorelen])
 934         cube([guidearm_bendslot,
 935               100,
 936               guidearm_realbendlen + 100]);
 937       hull(){
 938         for (zx=[ [ 0, guidearm_bendslot ],
 939                   [ guidearm_armcorelen + guidearm_slopelen,
 940                     guidearm_hookprotr*2 + guidearm_protrslop ]
 941                   ]) {
 942           translate([-zx[1]/2, -50, zx[0]])
 943           cube([zx[1], 100, 1]);
 944         }
 945       }
 946     }
 947     cube(center=true,
 948          [guidearm_armdia*2,
 949           guidearm_armwidth,
 950           guidearm_totallen*3]);
 951   }
 952   FilamentGuideArmBase();
 953 }
 954
 955 module FilamentGuideArmPrint(){ ////toplevel
 956   rotate([90,0,0])
 957     FilamentGuideArm();
 958 }
 959
 960 module Demo(){ ////toplevel
 961   translate([-real_exteffrad,-20,0]) Hub();
 962   ArmEnd();
 963   translate([ratchettooth*2, 30, 0]) FilamentCup();
 964   if (selsz(true,false,false)) {
 965     translate([-exteffrad + hubeffrad - hub_clip_baseextend, -10, 0])
 966       ArmExtender();
 967   }
 968 }
 969
 970 //ArmEnd();
 971 //FilamentCup();
 972 //FilamentCupPair();
 973 //CupSecuringClip();
 974 //Hub();
 975 //ArmExtender();
 976 //Axle();
 977 //AxleWasher();
 978 //AxlePin();
 979 //AxleFrictionWasher();
 980 //StorageArmLeft();
 981 //StorArmHoleTest();
 982 //FilamentGuideSpacer();
 983 //FilamentGuideArm();
 984 //FilamentGuideArmPrint();
 985 //Demo();