filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 //     This is the default.
  50 //
  51 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  52 //
  53 // A light duty 3-armed spool suitable for up to around 30m
  54 // of Faberdashery 2.85mm PLA.
  55 //
  56 //     Set
  57 //           fdia=2.85
  58 //           lightduty=true
  59 //     (or look in filamentspool-lt.scad).
  60 //
  61 //     And print following parts
  62 //           Hub
  63 //           ArmEnd x 3
  64 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  65 //           CupSecuringClip x 3
  66 //           TowerDoveClipPin x 6
  67 //
  68 //     When assembling, insert one TowerDoveClipPin from each side,
  69 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  70 //     Modest force with pliers is good to seat them properly.
  71 //
  72 //     (note that the light duty and heavy duty CupSecuringClips
  73 //      are slightly different)
  74 //
  75 // ===== Notes regarding both the above spools =====
  76 //
  77 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  78 // end of the hub towards the printer - ie, put put the spool on
  79 // `backwards'.  This ensures that the spool's arms will clear the
  80 // printer framework.
  81 //
  82 // For the above, I generally used the Cura `Standard' PLA profile.
  83 //
  84 // ===== TAZ-5 feed tube adjustment kit =====
  85 //
  86 // With a TAZ-5 I recommend using this kit to improve the feed
  87 // reliability:
  88 //
  89 //       Set
  90 //           fdia=2.85
  91 //     And print following parts
  92 //           FilamentGuideSpacer (ideally, at `high detail')
  93 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  94 //
  95 //     And possibly also
  96 //           t-nut_jig_0.2.stl
  97 //     from Aleph Objects - look here:
  98 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  99 //
 100 // The spacer clips onto the filament guide tube holder arm, on the
 101 // inside, with the pointy flanged end towards the filament guide
 102 // tube.  It stops the filament guide tube angle (and so the
 103 // filament's natural pickup location) changing as the print head moves.
 104 //
 105 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 106 // with your TAZ-5.  It's longer, so that the filament pickup point is
 107 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 108 // T-nuts in the aluminium channel from annoyingly sliding down to the
 109 // bottom while you swap out the arm.
 110 //
 111 // (Faberdashery coils, and therefore both the above spools, have a
 112 // larger diameter than the flat-walled spools often supplied by other
 113 // vendors.  And the spools above have individual arms rather than a
 114 // continuous disc.  If the filament `unhooks' from the arm, it can
 115 // pull taught around the hub and stop feeding properly.)
 116 //
 117 // ===== Spool storage arm, for mounting on walls =====
 118 //
 119 // A storage arm suitable for screwing to walls, bookshelves,
 120 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 121 // spools each with a 100m coil.
 122 //
 123 //     Set
 124 //           fdia=2.85
 125 //           lightduty=false
 126 //     (or look in filamentspool-sm.scad).
 127 //
 128 //     And print one of these, according to taste
 129 //            StorageArmLeft
 130 //            StorageArmRight
 131 //
 132 //     NB that the `light duty' version of this is shorter and
 133 //     will only take two `light duty' spools.
 134 //
 135 // For the above, I used the Cura `High detail' PLA profile because
 136 // I wanted it pretty, but the `Standard' profile should do fine.
 137 //
 138 // ===== Spools for 1.75mm filament =====
 139 //
 140 // Spool (in many parts) for handing 1.75mm filament, printable
 141 // on, and with parts for mounting on, a Reprappro Huxley.
 142
 143
 144 fdia=2.85; // or 1.75
 145 lightduty=false; // or true
 146
 147
 148 slop=0.5;
 149 bigslop=slop*2;
 150
 151 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 152 function usedove() = selsz(true,true,false);
 153
 154 num_arms = selsz(3,3,4);
 155
 156 channelslop=selsz(slop,0.75,slop);
 157
 158 exteffrad = 70;
 159 hubeffrad = selsz(30, 82, 40);
 160 hubbigrad = selsz(20, 38, 38);
 161 hublwidth = selsz(3, 2.5, 4);
 162 hubstemwidth = 2;
 163 hublthick = 10;
 164 hubaxlerad = selsz(5, 28/2, 28/2);
 165 totalheightfromtower = 240;
 166 axletowerfudgebend = 0;
 167 axleaxlefudgebend = 3;
 168 axlepadlen = 1.0;
 169
 170 armend_length = 120;
 171
 172 prongthick=selsz(5,4,5);
 173 prongwidth=selsz(5,4,5);
 174 prongribwidth=3;
 175 prongribheight=selsz(0,0,4);
 176 ratchetstep=15;
 177 ratchettooth=3;
 178 ratchettoothheight=5;
 179 ratchettoothsmoothr=1;
 180 ratchettoothslope=0.75;
 181 overlap=0.5;
 182 cupwidth=selsz(40,25,50);
 183 cupheight=selsz(55,25,55);
 184
 185 cupstrong_dx=selsz(0,0,-10);
 186
 187 propxshift = -6;
 188
 189 doveclipheight = 10;
 190
 191 teethh=3;
 192 teethgapx=4+fdia;
 193
 194 prongstalkxwidth=3;
 195
 196 stalklength=selsz(35,25,55);
 197 overclipcupgap=5;
 198 overclipdepth=15;
 199 overcliproundr=2.0;
 200 overclipthick=1.0;
 201 overclipcupnextgap=selsz(20,15,20);
 202
 203 hubaxlelen = selsz(25, 62.5, 77.5);
 204 echo(hubaxlelen);
 205
 206 overclipsmaller=-2.5;
 207 overclipbigger=0.0;
 208
 209 wingspoke=2.5;
 210 wingsize=6;
 211 wingthick=3;
 212
 213 armendwallthick=selsz(2.5, 1.8, 2.5);
 214 armendbasethick=selsz(1.2, 1.2, 1.2);
 215
 216 numbers_relief = 0.7;
 217 numbers_tick_len = 8;
 218 numbers_tick_width = 0.75;
 219 numbers_tick_linespc = 1.0;
 220 numbers_height_allow = 8;
 221
 222 axlehorizoffset = 12.5;
 223 axlevertheight = 100;
 224 towercliph = 16;
 225 towerclipcount = 3;
 226 towerpillarw = 5;
 227
 228 axlepinrad = 2;
 229 axlepintabrad = 5;
 230
 231 washerthick = 1.2;
 232 washerthinthick = 0.8;
 233 washerverythinthick = 0.4;
 234 washerrad = hubaxlerad + 7.5;
 235 frictionwasherarmwidth = 3;
 236 frictionwasherextrapush = 1.0;
 237
 238 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 239
 240 nondove_armhole_x = 32;
 241 nondove_armhole_hole = 4 + 0.8;
 242 nondove_armhole_support = 7;
 243 nondove_armhole_wall = 3.2;
 244 nondove_armhole_slop = 0.5;
 245 nondove_armhole_slop_x = 0.5;
 246
 247 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 248   nondove_armhole_support;
 249 echo(nondove_armbase);
 250
 251 include <doveclip.scad>
 252 include <cliphook.scad>
 253 include <filamentteeth.scad>
 254 include <axlepin.scad>
 255 include <commitid.scad>
 256
 257 hub_clip_baseextend = (hubeffrad - DoveClip_depth()
 258                        - hubbigrad + hublwidth);
 259
 260 real_exteffrad = selsz(exteffrad + hub_clip_baseextend,
 261                        hubeffrad + DoveClip_depth(),
 262                        hubeffrad + nondove_armbase);
 263
 264 channelwidth = prongthick + channelslop;
 265 channeldepth = prongwidth + ratchettoothheight;
 266 totalwidth = armendwallthick*2 + channelwidth;
 267 totalheight = channeldepth + armendbasethick;
 268 stalkwidth = prongwidth + prongstalkxwidth;
 269
 270 tau = PI*2;
 271
 272 module ArmEnd(length=armend_length){ ////toplevel
 273   if (usedove()) {
 274     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 275       rotate([0,0,-90])
 276         DoveClipPairBase(h=doveclipheight);
 277     }
 278   } else {
 279     difference(){
 280       translate([1, -armendwallthick, -armendbasethick])
 281         mirror([1,0,0])
 282         cube([nondove_armbase+1, totalwidth, totalheight]);
 283       translate([-nondove_armbase + nondove_armhole_x,
 284                  -armendwallthick + totalwidth/2,
 285                  -armendbasethick -1])
 286         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 287       translate([-nondove_armbase, -armendwallthick, -armendbasethick])
 288         rotate([90,0,0])
 289         Commitid_BestCount([nondove_armbase, totalwidth]);
 290     }
 291   }
 292
 293   for (otherside=[0,1]) {
 294     for (circum = [300:100:1500]) {
 295       assign(rad = circum / tau)
 296         assign(fn = str("filamentspool-number-n",circum,".dxf"))
 297         assign(rotateoffset = [0, totalwidth/2, 0])
 298         assign(xlen = rad - real_exteffrad) {
 299         if (xlen >= numbers_tick_width/2
 300             + (otherside ? numbers_height_allow : 0) &&
 301             xlen <= length - (otherside ? 0 : numbers_height_allow))
 302           translate([xlen, -armendwallthick,
 303                      -armendbasethick + (totalheight - numbers_tick_len)/2])
 304           translate(rotateoffset)
 305           rotate([0,0, otherside*180])
 306           translate(-rotateoffset){
 307             translate([-numbers_tick_width/2, -1, 0])
 308               cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 309             translate([numbers_tick_width/2 + numbers_tick_linespc,
 310                        1,
 311                        numbers_tick_len])
 312               rotate([90,0,0])
 313               rotate([0,0,-90])
 314               linear_extrude(height= numbers_relief+1)
 315               //    scale(templatescale)
 316               import(file=fn, convexity=100);
 317           }
 318       }
 319     }
 320   }
 321
 322   difference(){
 323     translate([0, -armendwallthick, -armendbasethick])
 324       cube([length, totalwidth, totalheight]);
 325     translate([-1, 0, 0])
 326       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 327     translate([-1, 0, ratchettoothheight])
 328       cube([length+2, channelwidth, channeldepth+1]);
 329
 330     if (usedove()){
 331       translate([0,0, -armendbasethick])
 332         Commitid_BestCount_M([length/3, totalwidth]);
 333     }
 334   }
 335   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 336     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 337       rotate([90,0,0])
 338         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 339       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 340                         [       0,      1,      0,      0       ],
 341                         [       0,      0,      1,      0       ],
 342                         [       0,      0,      0,      1       ]])
 343         cube([ratchettooth - ratchettoothsmoothr*2,
 344               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 345     }
 346   }
 347 }
 348
 349 module FilamentCupHandle(){
 350   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 351   mirror([0,1,0]) {
 352     cube([stalklength, stalkwidth, prongthick]);
 353     translate([stalklength, stalkwidth/2, 0])
 354       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 355     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 356       minkowski(){
 357         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 358         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 359                         [       0,      1,      0,      0       ],
 360                         [       0,      0,      1,      0       ],
 361                         [       0,      0,      0,      1       ]])
 362           cube([pawlusewidth,
 363                 ratchettoothheight - ratchettoothsmoothr,
 364                 prongthick - 1]);
 365       }
 366     }
 367   }
 368 }
 369
 370 module FilamentCupCup(){
 371   for (my=[0,1]) mirror([0,my,0]) {
 372     translate([0, cupwidth/2, 0])
 373       cube([cupheight + prongwidth, prongwidth, prongthick]);
 374   }
 375 }
 376
 377 module FilamentCupPositive() {
 378   FilamentCupHandle();
 379
 380   gapy = prongwidth;
 381   dy = cupwidth/2 + gapy + overclipcupgap;
 382   baselen = dy+cupwidth/2;
 383
 384   translate([0, dy, 0])
 385     FilamentCupCup();
 386   cube([prongwidth, baselen+1, prongthick]);
 387
 388   translate([cupstrong_dx, prongwidth, 0]) {
 389     cube([prongwidth, baselen-prongwidth, prongthick]);
 390     for (y = [0, .33, .67, 1])
 391       translate([0, (baselen - prongwidth) * y, 0])
 392         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 393   }
 394   if (cupstrong_dx != 0) {
 395     rotate([0,0,45])
 396       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 397       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 398   }
 399
 400   translate([0, -0.2, 0])
 401     cube([prongribwidth, baselen, prongthick + prongribheight]);
 402
 403   if (prongribheight > 0) {
 404     translate([-prongwidth, baselen, 0])
 405       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 406   }
 407
 408   midrad = cupwidth/2 + prongwidth/2;
 409
 410   propshift = stalklength - overclipdepth - prongthick + propxshift;
 411   proptaken = propshift;
 412   echo(midrad, propshift, proptaken);
 413
 414   translate([propshift, -1, 0]) {
 415     // something is wrong with the y calculation
 416     cube([prongwidth,
 417           gapy+2,
 418           prongthick]);
 419   }
 420   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 421     translate([cupstrong_dx, y + prongwidth, 0])
 422       rotate([0,0, 102 + fdia])
 423       FilamentTeeth(fdia=fdia, h=teethh);
 424   }
 425   for (x = [-0.3, -1.3]) {
 426     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 427       rotate([0,0, 12 + fdia])
 428       FilamentTeeth(fdia=fdia, h=teethh);
 429   }
 430 }
 431
 432 module FilamentCup() { ////toplevel
 433   difference(){
 434     FilamentCupPositive();
 435     translate([0, -stalkwidth, 0])
 436       Commitid_BestCount_M([stalklength - stalkwidth, stalkwidth]);
 437   }
 438 }
 439
 440 module CupSecuringClipSolid(w,d,h1,h2){
 441   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 442     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 443   }
 444 }
 445
 446 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 447   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 448   minkowski(){
 449     CupSecuringClipSolid(w=totalwidth,
 450                          d=overclipdepth + xdepth,
 451                          h1=hbase - overclipsmaller,
 452                          h2=hbase + overclipbigger);
 453     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 454   }
 455 }
 456
 457 module CupSecuringClip(){ ////toplevel
 458   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 459   difference(){
 460     union(){
 461       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 462       translate([-wingswidth/2, -wingsize/2, 0])
 463         cube([wingswidth, wingsize, wingthick]);
 464       translate([-wingsize/2, -wingswidth/2, 0])
 465         cube([wingsize, wingswidth, wingthick]);
 466     }
 467     translate([0,0,-0.1])
 468       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 469   }
 470 }
 471
 472 module ArmDoveClipPin(){ ////toplevel
 473   DoveClipPin(h=doveclipheight);
 474 }
 475
 476 module TowerDoveClipPin(){ ////toplevel
 477   DoveClipPin(h=towercliph/2);
 478 }
 479
 480 module Hub(){ ////toplevel
 481   axlerad = hubaxlerad + slop;
 482   xmin = axlerad+hublwidth/2;
 483   xmax = hubbigrad-hublwidth/2;
 484   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 485   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 486   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 487   difference(){
 488     union(){
 489       difference(){
 490         cylinder($fn=60, h=hublthick, r=hubbigrad);
 491         translate([0,0,-1])
 492           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 493       }
 494       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 495       for (ang=[0 : 360/num_arms : 359])
 496         rotate([0,0,ang]) {
 497           if (usedove()){
 498             difference() {
 499               translate([hubeffrad,0,0])
 500                 DoveClipPairSane(h=doveclipheight,
 501                                  baseextend = hub_clip_baseextend);
 502               if (hole>hublwidth && holewidth > 2) {
 503                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 504                   cube([hole, holewidth, hublthick+2]);
 505               }
 506             }
 507           } else {
 508             difference(){
 509               translate([0,
 510                          -nondove_allwidth/2,
 511                          0])
 512                 cube([hubeffrad + nondove_armhole_x
 513                       + nondove_armhole_hole/2 + nondove_armhole_support,
 514                       nondove_allwidth,
 515                       nondove_armhole_wall + totalheight]);
 516               translate([hubeffrad - nondove_armhole_slop_x,
 517                          -nondove_allwidth/2
 518                          + nondove_armhole_wall - nondove_armhole_slop,
 519                          nondove_armhole_wall])
 520                 cube([nondove_armhole_x + 50,
 521                       totalwidth + nondove_armhole_slop*2,
 522                       totalheight + 1]);
 523               translate([hubeffrad + nondove_armhole_x, 0, -20])
 524                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 525             }
 526           }
 527         }
 528       for (ang = [0 : 180/num_arms : 359])
 529         rotate([0,0,ang]) rotate([90,0,0]) {
 530           translate([0,0,-hublwidth/2])
 531             linear_extrude(height=hublwidth)
 532             polygon([[xmin,0.05], [xmax,0.05],
 533                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 534         }
 535     }
 536     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 537
 538     rotate([0,0, selsz(0,0,45)])
 539       translate([axlerad+hublwidth,
 540                  -hublwidth/2,
 541                  0])
 542       rotate([90,0,0])
 543       Commitid_BestCount([(hubbigrad-hublwidth) - (axlerad+hublwidth),
 544                           hublthick +
 545                           hublwidth/2 * hubaxlelen/(hubbigrad-axlerad),
 546                           ]);
 547   }
 548 }
 549
 550 module ArmExtender(){ ////toplevel
 551   DoveClipExtender(length=exteffrad-hubeffrad,
 552                    ha=doveclipheight,
 553                    hb=doveclipheight);
 554 }
 555
 556 module FsAxlePin(){ ////toplevel
 557   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 558 }
 559
 560 module Axle(){ ////toplevel
 561   pillarswidth = DoveClipPairSane_width(towerclipcount);
 562
 563   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 564   translate([-axlehorizoffset, -axlevertheight, 0]) {
 565     rotate([0,0,-axletowerfudgebend])
 566     rotate([0,0,-90])
 567       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 568     translate([0, DoveClip_depth(), 0])
 569     rotate([0,0,90])
 570       ExtenderPillars(axlevertheight - DoveClip_depth(),
 571                       pillarswidth, towercliph,
 572                       pillarw=towerpillarw);
 573   }
 574
 575   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 576   axlerad = hubaxlerad-slop;
 577   bump = axlerad * 0.2;
 578   shift = axlerad-bump;
 579   joinbelowallow = 3;
 580
 581   intersection(){
 582     translate([0, 0, shift]) {
 583       difference() {
 584         union(){
 585           translate([-1, 0, 0])
 586             rotate([0,90,0])
 587             cylinder($fn=60,
 588                      r = axlerad,
 589                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 590           mirror([1,0,0]) rotate([0,90,0])
 591             cylinder(r = axlerad*1.75, h = 3);
 592           intersection(){
 593             mirror([1,0,0])
 594               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 595               rotate([0,90,0])
 596               cylinder($fn=60,
 597                        r = towercliph - shift,
 598                        h = pillarswidth);
 599             translate([-50, -joinbelowallow, -50])
 600               cube([100, joinbelowallow+50, 100]);
 601           }
 602         }
 603         rotate([90,0,0])
 604         translate([axleclearlen + axlepinrad/2, 0, -25])
 605           cylinder(r = axlepinrad + slop, h=50);
 606       }
 607     }
 608     translate([-50,-50,0]) cube([100,100,100]);
 609   }
 610 }
 611
 612 module washer(thick){
 613   Washer(hubaxlerad, washerrad, thick, slop);
 614 }
 615
 616 module AxleWasher(){ ////toplevel
 617   washer(thick=washerthick);
 618 }
 619
 620 module AxleThinWasher(){ ////toplevel
 621   washer(thick=washerthinthick);
 622 }
 623
 624 module AxleVeryThinWasher(){ ////toplevel
 625   washer(thick=washerverythinthick);
 626 }
 627
 628 module AxleFrictionWasher(){ ////toplevel
 629   difference(){
 630     cylinder(h=washerthick, r=washerrad);
 631     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 632   }
 633   frarmr = hubbigrad;
 634   frarmw = frictionwasherarmwidth;
 635   frarmpawlr = hublwidth;
 636   frarmpawlpush = slop*4 + frictionwasherextrapush;
 637   for (ang=[0,180]) rotate([0,0,ang]) {
 638     translate([washerrad-1, -frarmw/2, 0])
 639       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 640     intersection(){
 641       translate([frarmr - frarmpawlr, -50, 0])
 642         cube([frarmpawlr, 100, 50]);
 643       rotate([0,90,0])
 644         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 645     }
 646   }
 647 }
 648
 649 module TowerExtender(){ ////toplevel
 650   l = totalheightfromtower - axlevertheight;
 651   echo("TowerExtender",l);
 652   DoveClipExtender(length = l,
 653                    ha = towercliph, hb = towercliph,
 654                    counta = towerclipcount, countb = towerclipcount,
 655                    pillarw = towerpillarw);
 656 }
 657
 658 module FilamentCupPair(){ ////toplevel
 659   FilamentCup();
 660   translate([cupheight + prongthick*3,
 661              cupwidth/2*1.7,
 662              0])
 663     rotate([0,0,180]) FilamentCup();
 664 }
 665
 666 //----- storarm -----
 667
 668 storarm_hooklen = 8;
 669 storarm_hookheight = 5;
 670 storarm_thick = 10;
 671 storarm_axleslop = 4;
 672
 673 storarm_base_w = 30;
 674 storarm_base_h = 100;
 675 storarm_base_d = 15;
 676 storarm_base_mind = 2;
 677
 678 storarm_cope_hubaxle_mk1 = true;
 679
 680 storarm_screw_hole = 4;
 681 storarm_screw_hole_slop = 0.5;
 682 storarm_besides_hole = 4;
 683
 684 storarm_under_hole = 5;
 685 storarm_screw_hole_head = 8.8;
 686 storarm_screw_hole_head_slop = 1.5;
 687
 688 // calculated
 689
 690 storarm_axlerad = hubaxlerad - storarm_axleslop;
 691 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 692   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 693 storarm_totlen = storarm_mainlen + storarm_hooklen;
 694
 695 storarm_mid_off_y = storarm_axlerad;
 696
 697 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 698
 699 module StorageArmDiagPartSide(xmin, xmax){
 700   xsz = xmax-xmin;
 701   yuse = storarm_thick/2;
 702
 703   intersection(){
 704     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 705       rotate([0,90,0])
 706       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 707     translate([xmin, -yuse, 0])
 708       cube([xsz, yuse, storarm_thick]);
 709   }
 710 }
 711
 712 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 713   hull(){
 714     StorageArmDiagPartSide(xmin,xmax);
 715
 716     multmatrix([[1,0,0,0],
 717                 [shear,1,0,0],
 718                 [0,0,1,0],
 719                 [0,0,0,1]])
 720       translate([0, -storarm_axlerad*2 + adjbot, 0])
 721       mirror([0,1,0])
 722       StorageArmDiagPartSide(xmin,xmax);
 723   }
 724 }
 725
 726 module StorageArmBaseTemplate(){
 727   square([storarm_base_w, storarm_base_h]);
 728 }
 729
 730 module StorageArmAtMountingHoles(){
 731   bes = storarm_besides_hole + storarm_screw_hole;
 732
 733   x0 = bes;
 734   x1 = storarm_base_w-bes;
 735   y1 = storarm_base_h - bes;
 736   y0 = bes;
 737
 738   for (pos=[ [x0, y1],
 739              [x1, y1],
 740              [x1, y0] ]) {
 741     rotate([0,90,0])
 742       translate([pos[0] - storarm_base_w,
 743                  pos[1] - storarm_base_off_y, -storarm_base_d])
 744       children();
 745   }
 746 }
 747
 748 module StorageArmRight(){ ////toplevel
 749   shear = storarm_hookheight / (storarm_mainlen/2);
 750
 751   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 752   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 753                      storarm_hookheight/2);
 754
 755   translate([0, storarm_hookheight, 0])
 756     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 757                        shear/2, -storarm_hookheight/2);
 758
 759   difference(){
 760     union(){
 761       hull(){
 762         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 763           rotate([0,90,0])
 764           linear_extrude(height=storarm_base_mind)
 765           StorageArmBaseTemplate();
 766         StorageArmDiagPart(-1, 0, shear, 0);
 767       }
 768       StorageArmAtMountingHoles(){
 769         cylinder(r= storarm_screw_hole_head/2,
 770                  h=10);
 771       }
 772     }
 773     StorageArmAtMountingHoles(){
 774       translate([0,0,-1])
 775         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 776                  h=20);
 777       translate([0,0,storarm_under_hole])
 778         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 779                  h=20);
 780     }
 781   }
 782 }
 783
 784 module StorageArmLeft(){ ////toplevel
 785   mirror([1,0,0]) StorageArmRight();
 786 }
 787
 788 module StorArmHoleTest(){ ////toplevel
 789   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 790   intersection(){
 791     StorageArmRight();
 792     translate([-50, -storarm_base_off_y, -1])
 793       cube([100, sz, sz+1]);
 794   }
 795 }
 796
 797
 798 //----- filament guide spacer -----
 799
 800 guide_armdia = 15.0;
 801 guide_armwidth = 10.2;
 802 guide_armcorelen = 25.0;
 803 guide_clipcirclethick = 10.0;
 804
 805 guidefilclip_outerdia = 22.8;
 806
 807 guidespacer_armslop = 0.75;
 808 guidespacer_armlenslop = 1.05;
 809
 810 guidespacer_prongprotrude = 4;
 811 guidespacer_thick = 1.6;
 812
 813 // calculated
 814
 815 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 816 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 817 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 818   + guidespacer_armlenslop;
 819
 820 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 821
 822 module FilamentGuideArmTemplate(extra=0){
 823   intersection(){
 824     circle(r= (guidespacer_armdia/2) + extra);
 825     square(center=true, [guidespacer_armwidth+extra*2,
 826                          guidespacer_armdia + extra*2 + 10]);
 827   }
 828 }
 829
 830 module FilamentGuideSpacerInnerTemplate(){
 831   FilamentGuideArmTemplate();
 832   translate([0, -guidespacer_armdia/2])
 833     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 834                          guidespacer_armdia]);
 835 }
 836
 837 module FilamentGuideSpacer(){ ////toplevel
 838   difference(){
 839     union(){
 840       linear_extrude(height= guidespacer_len)
 841         FilamentGuideArmTemplate(extra= guidespacer_thick);
 842       for (angle=[26, 60]) {
 843         for (m=[0,1]) {
 844           mirror([m,0,0]) {
 845             rotate([0,0,angle]) {
 846               hull(){
 847                 for (t=[[0, guidespacer_wingheight],
 848                         [guidespacer_len-1, -guidespacer_wingheight]])
 849                   translate([0,0, t[0] + 0.5])
 850                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 851                       1],
 852                          center=true);
 853               }
 854             }
 855           }
 856         }
 857       }
 858     }
 859     translate([0,0,-1])
 860       linear_extrude(height= guidespacer_len+5)
 861       FilamentGuideSpacerInnerTemplate();
 862   }
 863 }
 864
 865
 866 //----- replacement filament guide arm for TAZ-5 -----
 867
 868 guidearm_armslop = 0.25;
 869 guidearm_armlenslop = 0.25;
 870
 871 guidearm_hookprotr = 3;
 872 guidearm_hookprotrflat = 1;
 873 guidearm_hookslope = 0.3;
 874
 875 guidearm_totallen = 60;
 876
 877 guidearm_screwplatesz = 12;
 878 guidearm_screwplateth = 4;
 879 guidearm_screwplatewd = 15;
 880 guidearm_screwhole = 5 + 0.5;
 881
 882 guidearm_bendlen = 40;
 883 guidearm_bendslot = 4.5;
 884
 885 guidearm_stopthick = 4;
 886 guidearm_protrslop = 1.0;
 887
 888 // calculated
 889
 890 guidearm_armdia = guide_armdia - guidearm_armslop;
 891 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 892 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 893
 894 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 895
 896 guidearm_realbendlen = min(guidearm_bendlen,
 897                            guidearm_totallen - guidearm_screwplateth - 0.1);
 898 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 899
 900 module FilamentGuideArmStop(h){
 901   for (ts=[-1,+1]) {
 902     translate([ts * guidearm_hookprotr, 0,0])
 903       cylinder(r=guidearm_armdia/2, h, $fn=80);
 904   }
 905 }
 906
 907 module FilamentGuideArmShaftPositive(){
 908   r = guidearm_armdia/2;
 909
 910   translate([0,0, guidearm_base_z0+1])
 911     cylinder(r=r, h= guidearm_totallen, $fn=80);
 912   translate([0,0, guidearm_armcorelen]){
 913     hull(){
 914       FilamentGuideArmStop(guidearm_hookprotrflat);
 915       translate([0,0, guidearm_slopelen])
 916         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 917     }
 918   }
 919   mirror([0,0,1])
 920     FilamentGuideArmStop(guidearm_stopthick);
 921 }
 922
 923 module FilamentGuideArmBase(){
 924   translate([0,
 925              (guidearm_screwplatewd - guidearm_armwidth)/2,
 926              guidearm_base_z0]){
 927     difference(){
 928       translate([0,0, guidearm_screwplateth/2])
 929         cube(center=true,
 930              [guidearm_armdia + guidearm_screwplatesz*2,
 931               guidearm_screwplatewd,
 932               guidearm_screwplateth]);
 933       for (ts=[-1,+1]) {
 934         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 935                    0,
 936                    -20])
 937           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 938       }
 939     }
 940   }
 941 }
 942
 943 module FilamentGuideArm(){ ///toplevel
 944   intersection(){
 945     difference(){
 946       FilamentGuideArmShaftPositive();
 947       translate([-guidearm_bendslot/2,
 948                  -50,
 949                  -guidearm_realbendlen + guidearm_armcorelen])
 950         cube([guidearm_bendslot,
 951               100,
 952               guidearm_realbendlen + 100]);
 953       hull(){
 954         for (zx=[ [ 0, guidearm_bendslot ],
 955                   [ guidearm_armcorelen + guidearm_slopelen,
 956                     guidearm_hookprotr*2 + guidearm_protrslop ]
 957                   ]) {
 958           translate([-zx[1]/2, -50, zx[0]])
 959           cube([zx[1], 100, 1]);
 960         }
 961       }
 962     }
 963     cube(center=true,
 964          [guidearm_armdia*2,
 965           guidearm_armwidth,
 966           guidearm_totallen*3]);
 967   }
 968   FilamentGuideArmBase();
 969 }
 970
 971 module FilamentGuideArmPrint(){ ////toplevel
 972   rotate([90,0,0])
 973     FilamentGuideArm();
 974 }
 975
 976 module Demo(){ ////toplevel
 977   translate([-real_exteffrad,-20,0]) Hub();
 978   ArmEnd();
 979   translate([ratchettooth*2, 30, 0]) FilamentCup();
 980   if (selsz(true,false,false)) {
 981     translate([-exteffrad + hubeffrad - hub_clip_baseextend, -10, 0])
 982       ArmExtender();
 983   }
 984 }
 985
 986 //ArmEnd();
 987 //FilamentCup();
 988 //FilamentCupPair();
 989 //CupSecuringClip();
 990 //Hub();
 991 //ArmExtender();
 992 //Axle();
 993 //AxleWasher();
 994 //AxlePin();
 995 //AxleFrictionWasher();
 996 //StorageArmLeft();
 997 //StorArmHoleTest();
 998 //FilamentGuideSpacer();
 999 //FilamentGuideArm();
1000 //FilamentGuideArmPrint();
1001 //Demo();