filamentspool.scad

   1 // -*- C -*-
   2
   3 // filamentspool.scad
   4 // 3D design for filament spools to hold coils as supplied by Faberdashery
   5 //
   6
   7 //
   8 // Copyright 2012,2013,2016 Ian Jackson
   9 //
  10 // This work is free software: you can redistribute it and/or modify
  11 // it under the terms of the GNU General Public License as published by
  12 // the Free Software Foundation, either version 3 of the License, or
  13 // (at your option) any later version.
  14 //
  15 // This work is distributed in the hope that it will be useful,
  16 // but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 // MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 // GNU General Public License for more details.
  19 //
  20 // You should have received a copy of the GNU General Public License
  21 // along with this work.  If not, see <http://www.gnu.org/licenses/>
  22 //
  23
  24 //
  25 // Each spool is a hub with 3 or 4 arms.  Each arm has a cup for
  26 // holding the filament.  The effective diameter can be adjusted by
  27 // setting the cup into a different seat in the arm.  The cups are
  28 // held on with simple clips, so the filement coil can easily be
  29 // removed and replaced.
  30 //
  31 // This file (and its includes) can generate:
  32 //
  33 // ===== Heavy duty 4-armed spool for 3mm x 100m coil =====
  34 //
  35 // A heavy duty 4-armed spool suitable for holding a 100m
  36 // Faberdashery coil on the spool arm of a Lulzbot TAZ-5.
  37 //
  38 //     Set
  39 //           fdia=2.85
  40 //           lightduty=false
  41 //     And print following parts
  42 //            Hub
  43 //            ArmEnd x 4
  44 //            FilamentCup x 4  (or FilamentCupPair x 2)
  45 //            CupSecuringClip x 4
  46 //
  47 //     You will also need  4 x M4 machine screws and nuts.
  48 //
  49 // ===== Light duty 3-armed spool for 3mm x <=30m coil =====
  50 //
  51 // A light duty 3-armed spool suitable for up to around 30m
  52 // of Faberdashery 2.85mm PLA.
  53 //
  54 //     Set
  55 //           fdia=2.85
  56 //           lightduty=true
  57 //     And print following parts
  58 //           Hub
  59 //           ArmEnd x 3
  60 //           FilamentCup x 3  (or FilamentCup + FilamentCupPair)
  61 //           CupSecuringClip x 3
  62 //           TowerDoveClipPin x 6
  63 //
  64 //     When assembling, insert one TowerDoveClipPin from each side,
  65 //     joining each ArmEnd to the Hub with two TowerDoveClipPins.
  66 //     Modest force with pliers is good to seat them properly.
  67 //
  68 //     (note that the light duty and heavy duty CupSecuringClips
  69 //      are slightly different)
  70 //
  71 // ===== Notes regarding both the above spools =====
  72 //
  73 // When mounting either spool on the TAZ-5 spool arm, put the `pointy'
  74 // end of the hub towards the printer - ie, put put the spool on
  75 // `backwards'.  This ensures that the spool's arms will clear the
  76 // printer framework.
  77 //
  78 // For the above, I generally used the Cura `Standard' PLA profile.
  79 //
  80 // ===== TAZ-5 feed tube adjustment kit =====
  81 //
  82 // With a TAZ-5 I recommend using this kit to improve the feed
  83 // reliability:
  84 //
  85 //       Set
  86 //           fdia=2.85
  87 //     And print following parts
  88 //           FilamentGuideSpacer (ideally, at `high detail')
  89 //           FilamentGuideArmPrint (optional; `high detail' or `standard')
  90 //
  91 //     And possibly also
  92 //           t-nut_jig_0.2.stl
  93 //     from Aleph Objects - look here:
  94 //           http://download.lulzbot.com/TAZ/accessories/tool_heads/version_2/Dual_Extruder_v2/production_parts/stl/
  95 //
  96 // The spacer clips onto the filament guide tube holder arm, on the
  97 // inside, with the pointy flanged end towards the filament guide
  98 // tube.  It stops the filament guide tube angle (and so the
  99 // filament's natural pickup location) changing as the print head moves.
 100 //
 101 // The FilamentGuideArm[Print] is a replacement for the arm supplied
 102 // with your TAZ-5.  It's longer, so that the filament pickup point is
 103 // closer to the middle of the coil.  Use the t-nut_jig to stop the
 104 // T-nuts in the aluminium channel from annoyingly sliding down to the
 105 // bottom while you swap out the arm.
 106 //
 107 // (Faberdashery coils, and therefore both the above spools, have a
 108 // larger diameter than the flat-walled spools often supplied by other
 109 // vendors.  And the spools above have individual arms rather than a
 110 // continuous disc.  If the filament `unhooks' from the arm, it can
 111 // pull taught around the hub and stop feeding properly.)
 112 //
 113 // ===== Spool storage arm, for mounting on walls =====
 114 //
 115 // A storage arm suitable for screwing to walls, bookshelves,
 116 // etc. (requires non-countersunk M4 screws); will hold two heavy duty
 117 // spools each with a 100m coil.
 118 //
 119 //     Set
 120 //           fdia=2.85
 121 //           lightduty=false
 122 //     And print one of these, according to taste
 123 //            StorageArmLeft
 124 //            StorageArmRight
 125 //
 126 //     NB that the `light duty' version of this is shorter and
 127 //     will only take two `light duty' spools.
 128 //
 129 // For the above, I used the Cura `High detail' PLA profile because
 130 // I wanted it pretty, but the `Standard' profile should do fine.
 131 //
 132 // ===== Spools for 1.75mm filament =====
 133 //
 134 // Spool (in many parts) for handing 1.75mm filament, printable
 135 // on, and with parts for mounting on, a Reprappro Huxley.
 136
 137
 138 fdia=2.85; // or 1.75
 139 lightduty=false; // or true
 140
 141
 142 slop=0.5;
 143 bigslop=slop*2;
 144
 145 function selsz(sm,lt,lg) = fdia < 2 ? sm : lightduty ? lt : lg;
 146 function usedove() = selsz(true,true,false);
 147
 148 num_arms = selsz(3,3,4);
 149
 150 channelslop=selsz(slop,0.75,slop);
 151
 152 exteffrad = 70;
 153 hubeffrad = selsz(30, 82, 40);
 154 hubbigrad = selsz(20, 38, 38);
 155 hublwidth = selsz(3, 2.5, 4);
 156 hubstemwidth = 2;
 157 hublthick = 10;
 158 hubaxlerad = selsz(5, 28/2, 28/2);
 159 totalheightfromtower = 240;
 160 axletowerfudgebend = 0;
 161 axleaxlefudgebend = 3;
 162 axlepadlen = 1.0;
 163
 164 armend_length = 120;
 165
 166 prongthick=selsz(5,4,5);
 167 prongwidth=selsz(5,4,5);
 168 prongribwidth=3;
 169 prongribheight=selsz(0,0,4);
 170 ratchetstep=15;
 171 ratchettooth=3;
 172 ratchettoothheight=5;
 173 ratchettoothsmoothr=1;
 174 ratchettoothslope=0.75;
 175 overlap=0.5;
 176 cupwidth=selsz(40,25,50);
 177 cupheight=selsz(55,25,55);
 178
 179 cupstrong_dx=selsz(0,0,-10);
 180
 181 propxshift = -6;
 182
 183 doveclipheight = 10;
 184
 185 teethh=3;
 186 teethgapx=4+fdia;
 187
 188 prongstalkxwidth=3;
 189
 190 stalklength=selsz(35,25,55);
 191 overclipcupgap=5;
 192 overclipdepth=15;
 193 overcliproundr=2.0;
 194 overclipthick=1.0;
 195 overclipcupnextgap=selsz(20,15,20);
 196
 197 hubaxlelen = selsz(25, 62.5, 77.5);
 198 echo(hubaxlelen);
 199
 200 overclipsmaller=-2.5;
 201 overclipbigger=0.0;
 202
 203 wingspoke=2.5;
 204 wingsize=6;
 205 wingthick=3;
 206
 207 armendwallthick=selsz(2.5, 1.8, 2.5);
 208 armendbasethick=selsz(1.2, 1.2, 1.2);
 209
 210 numbers_relief = 0.7;
 211 numbers_tick_len = 8;
 212 numbers_tick_width = 0.75;
 213 numbers_tick_linespc = 1.0;
 214 numbers_height_allow = 8;
 215
 216 axlehorizoffset = 12.5;
 217 axlevertheight = 100;
 218 towercliph = 16;
 219 towerclipcount = 3;
 220 towerpillarw = 5;
 221
 222 axlepinrad = 2;
 223 axlepintabrad = 5;
 224
 225 washerthick = 1.2;
 226 washerthinthick = 0.8;
 227 washerverythinthick = 0.4;
 228 washerrad = hubaxlerad + 7.5;
 229 frictionwasherarmwidth = 3;
 230 frictionwasherextrapush = 1.0;
 231
 232 ratchetpawl=ratchetstep-ratchettooth-bigslop*2;
 233
 234 nondove_armhole_x = 32;
 235 nondove_armhole_hole = 4 + 0.8;
 236 nondove_armhole_support = 7;
 237 nondove_armhole_wall = 3.2;
 238 nondove_armhole_slop = 0.5;
 239 nondove_armhole_slop_x = 0.5;
 240
 241 nondove_armbase = nondove_armhole_x + nondove_armhole_hole/2 +
 242   nondove_armhole_support;
 243 echo(nondove_armbase);
 244
 245 real_exteffrad = selsz(exteffrad,
 246                        hubeffrad + nondove_armbase,
 247                        hubeffrad + nondove_armbase);
 248
 249 include <doveclip.scad>
 250 include <cliphook.scad>
 251 include <filamentteeth.scad>
 252 include <axlepin.scad>
 253
 254 channelwidth = prongthick + channelslop;
 255 channeldepth = prongwidth + ratchettoothheight;
 256 totalwidth = armendwallthick*2 + channelwidth;
 257 totalheight = channeldepth + armendbasethick;
 258 stalkwidth = prongwidth + prongstalkxwidth;
 259
 260 tau = PI*2;
 261
 262 module ArmEnd(length=armend_length){ ////toplevel
 263   if (usedove()) {
 264     translate([ratchettoothsmoothr, channelwidth/2, -armendbasethick]) {
 265       rotate([0,0,-90])
 266         DoveClipPairBase(h=doveclipheight);
 267     }
 268   } else {
 269     difference(){
 270       translate([1, -armendwallthick, -armendbasethick])
 271         mirror([1,0,0])
 272         cube([nondove_armbase+1, totalwidth, totalheight]);
 273       translate([-nondove_armbase + nondove_armhole_x,
 274                  -armendwallthick + totalwidth/2,
 275                  -armendbasethick -1])
 276         cylinder(r= nondove_armhole_hole/2, h=totalheight+2, $fn=10);
 277     }
 278   }
 279
 280   for (circum = [300:100:1500]) {
 281     assign(rad = circum / tau)
 282       assign(fn = str("filamentspool-number-n",circum,".dxf"))
 283       assign(xlen = rad - real_exteffrad) {
 284       echo(circum, rad, xlen);
 285       if (xlen >= numbers_tick_width/2 &&
 286           xlen <= length - numbers_height_allow)
 287       translate([xlen, -armendwallthick,
 288                  -armendbasethick + (totalheight - numbers_tick_len)/2])
 289         color("blue"){
 290         translate([-numbers_tick_width/2, -1, 0])
 291           cube([numbers_tick_width, numbers_relief+1, numbers_tick_len]);
 292         //  echo(fn);
 293         translate([numbers_tick_width/2 + numbers_tick_linespc,
 294                    1,
 295                    numbers_tick_len])
 296           rotate([90,0,0])
 297           rotate([0,0,-90])
 298           linear_extrude(height= numbers_relief+1)
 299           //    scale(templatescale)
 300           import(file=fn, convexity=100);
 301       }
 302     }
 303   }
 304
 305   difference(){
 306     translate([0, -armendwallthick, -armendbasethick])
 307       cube([length, totalwidth, totalheight]);
 308     translate([-1, 0, 0])
 309       cube([length+1 - ratchettooth, channelwidth, channeldepth+1]);
 310     translate([-1, 0, ratchettoothheight])
 311       cube([length+2, channelwidth, channeldepth+1]);
 312   }
 313   for (dx = [0 : ratchetstep : length - ratchetstep]) translate([dx,0,0]) {
 314     translate([ratchettoothsmoothr+0.5, armendwallthick/2, 0]) minkowski(){
 315       rotate([90,0,0])
 316         cylinder($fn=20, r=ratchettoothsmoothr, h=armendwallthick);
 317       multmatrix([      [       1, 0, ratchettoothslope, 0      ],
 318                         [       0,      1,      0,      0       ],
 319                         [       0,      0,      1,      0       ],
 320                         [       0,      0,      0,      1       ]])
 321         cube([ratchettooth - ratchettoothsmoothr*2,
 322               channelwidth, ratchettoothheight - ratchettoothsmoothr]);
 323     }
 324   }
 325 }
 326
 327 module FilamentCupHandle(){
 328   pawlusewidth = ratchetpawl-ratchettoothsmoothr*2;
 329   mirror([0,1,0]) {
 330     cube([stalklength, stalkwidth, prongthick]);
 331     translate([stalklength, stalkwidth/2, 0])
 332       cylinder(r=stalkwidth/2, h=prongthick, $fn=20);
 333     translate([ratchettoothsmoothr, stalkwidth, 0]) {
 334       minkowski(){
 335         cylinder($fn=20,r=ratchettoothsmoothr, h=1);
 336         multmatrix([    [       1, -ratchettoothslope, 0, 0     ],
 337                         [       0,      1,      0,      0       ],
 338                         [       0,      0,      1,      0       ],
 339                         [       0,      0,      0,      1       ]])
 340           cube([pawlusewidth,
 341                 ratchettoothheight - ratchettoothsmoothr,
 342                 prongthick - 1]);
 343       }
 344     }
 345   }
 346 }
 347
 348 module FilamentCupCup(){
 349   for (my=[0,1]) mirror([0,my,0]) {
 350     translate([0, cupwidth/2, 0])
 351       cube([cupheight + prongwidth, prongwidth, prongthick]);
 352   }
 353 }
 354
 355 module FilamentCup() { ////toplevel
 356   FilamentCupHandle();
 357
 358   gapy = prongwidth;
 359   dy = cupwidth/2 + gapy + overclipcupgap;
 360   baselen = dy+cupwidth/2;
 361
 362   translate([0, dy, 0])
 363     FilamentCupCup();
 364   cube([prongwidth, baselen+1, prongthick]);
 365
 366   translate([cupstrong_dx, prongwidth, 0]) {
 367     cube([prongwidth, baselen-prongwidth, prongthick]);
 368     for (y = [0, .33, .67, 1])
 369       translate([0, (baselen - prongwidth) * y, 0])
 370         cube([-cupstrong_dx + 1, prongwidth, prongthick]);
 371   }
 372   if (cupstrong_dx != 0) {
 373     rotate([0,0,45])
 374       translate([-prongwidth*.55, -prongwidth*2.1, 0])
 375       cube([prongwidth*(2.65), prongwidth*4.2, prongthick]);
 376   }
 377
 378   translate([0, -0.2, 0])
 379     cube([prongribwidth, baselen, prongthick + prongribheight]);
 380
 381   if (prongribheight > 0) {
 382     translate([-prongwidth, baselen, 0])
 383       cube([cupheight/2, prongwidth + prongribheight, prongribwidth]);
 384   }
 385
 386   midrad = cupwidth/2 + prongwidth/2;
 387
 388   propshift = stalklength - overclipdepth - prongthick + propxshift;
 389   proptaken = propshift;
 390   echo(midrad, propshift, proptaken);
 391
 392   translate([propshift, -1, 0]) {
 393     // something is wrong with the y calculation
 394     cube([prongwidth,
 395           gapy+2,
 396           prongthick]);
 397   }
 398   for (y = [overclipcupgap, overclipcupgap+overclipcupnextgap]) {
 399     translate([cupstrong_dx, y + prongwidth, 0])
 400       rotate([0,0, 102 + fdia])
 401       FilamentTeeth(fdia=fdia, h=teethh);
 402   }
 403   for (x = [-0.3, -1.3]) {
 404     translate([cupheight + overclipcupnextgap*x, baselen + prongwidth, 0])
 405       rotate([0,0, 12 + fdia])
 406       FilamentTeeth(fdia=fdia, h=teethh);
 407   }
 408 }
 409
 410 module CupSecuringClipSolid(w,d,h1,h2){
 411   rotate([0,-90,0]) translate([0,-h1/2,-w/2]) linear_extrude(height=w) {
 412     polygon(points=[[0,0], [d,0], [d,h2], [0,h1]]);
 413   }
 414 }
 415
 416 module CupSecuringClipSolidSmooth(xrad=0, xdepth=0){
 417   hbase = totalheight + prongstalkxwidth - overcliproundr*2;
 418   minkowski(){
 419     CupSecuringClipSolid(w=totalwidth,
 420                          d=overclipdepth + xdepth,
 421                          h1=hbase - overclipsmaller,
 422                          h2=hbase + overclipbigger);
 423     cylinder($fn=20, h=0.01, r=overcliproundr+xrad);
 424   }
 425 }
 426
 427 module CupSecuringClip(){ ////toplevel
 428   wingswidth = wingspoke*2 + overclipthick*2 + overcliproundr*2 + totalwidth;
 429   difference(){
 430     union(){
 431       CupSecuringClipSolidSmooth(xrad=overclipthick, xdepth=0);
 432       translate([-wingswidth/2, -wingsize/2, 0])
 433         cube([wingswidth, wingsize, wingthick]);
 434       translate([-wingsize/2, -wingswidth/2, 0])
 435         cube([wingsize, wingswidth, wingthick]);
 436     }
 437     translate([0,0,-0.1])
 438       CupSecuringClipSolidSmooth(xrad=0, xdepth=0.2);
 439   }
 440 }
 441
 442 module ArmDoveClipPin(){ ////toplevel
 443   DoveClipPin(h=doveclipheight);
 444 }
 445
 446 module TowerDoveClipPin(){ ////toplevel
 447   DoveClipPin(h=towercliph/2);
 448 }
 449
 450 module Hub(){ ////toplevel
 451   axlerad = hubaxlerad + slop;
 452   xmin = axlerad+hublwidth/2;
 453   xmax = hubbigrad-hublwidth/2;
 454   hole = hubeffrad - hubbigrad - DoveClip_depth() - hublwidth*2;
 455   holewidth = DoveClipPairSane_width() - hubstemwidth*2;
 456   nondove_allwidth = nondove_armhole_wall*2 + totalwidth;
 457   difference(){
 458     union(){
 459       difference(){
 460         cylinder($fn=60, h=hublthick, r=hubbigrad);
 461         translate([0,0,-1])
 462           cylinder($fn=30, h=hublthick+2, r=(hubbigrad-hublwidth));
 463       }
 464       cylinder(h=hubaxlelen, r=axlerad+hublwidth);
 465       for (ang=[0 : 360/num_arms : 359])
 466         rotate([0,0,ang]) {
 467           if (usedove()){
 468             difference() {
 469               translate([hubeffrad,0,0])
 470                 DoveClipPairSane(h=doveclipheight,
 471                                  baseextend = (hubeffrad - DoveClip_depth()
 472                                                - hubbigrad + hublwidth));
 473               if (hole>hublwidth && holewidth > 2) {
 474                 translate([hubbigrad + hublwidth, -holewidth/2, -1])
 475                   cube([hole, holewidth, hublthick+2]);
 476               }
 477             }
 478           } else {
 479             difference(){
 480               translate([0,
 481                          -nondove_allwidth/2,
 482                          0])
 483                 cube([hubeffrad + nondove_armhole_x
 484                       + nondove_armhole_hole/2 + nondove_armhole_support,
 485                       nondove_allwidth,
 486                       nondove_armhole_wall + totalheight]);
 487               translate([hubeffrad - nondove_armhole_slop_x,
 488                          -nondove_allwidth/2
 489                          + nondove_armhole_wall - nondove_armhole_slop,
 490                          nondove_armhole_wall])
 491                 cube([nondove_armhole_x + 50,
 492                       totalwidth + nondove_armhole_slop*2,
 493                       totalheight + 1]);
 494               translate([hubeffrad + nondove_armhole_x, 0, -20])
 495                 cylinder(r= nondove_armhole_hole/2, h=50, $fn=10);
 496             }
 497           }
 498         }
 499       for (ang = [0 : 180/num_arms : 359])
 500         rotate([0,0,ang]) rotate([90,0,0]) {
 501           translate([0,0,-hublwidth/2])
 502             linear_extrude(height=hublwidth)
 503             polygon([[xmin,0.05], [xmax,0.05],
 504                      [xmax,hublthick-0.2], [xmin, hubaxlelen-0.2]]);
 505         }
 506     }
 507     translate([0,0,-1]) cylinder($fn=60, h=hubaxlelen+2, r=axlerad);
 508   }
 509 }
 510
 511 module ArmExtender(){ ////toplevel
 512   DoveClipExtender(length=exteffrad-hubeffrad,
 513                    ha=doveclipheight,
 514                    hb=doveclipheight);
 515 }
 516
 517 module FsAxlePin(){ ////toplevel
 518   AxlePin(hubaxlerad, washerrad*2, axlepinrad, axlepintabrad, slop);
 519 }
 520
 521 module Axle(){ ////toplevel
 522   pillarswidth = DoveClipPairSane_width(towerclipcount);
 523
 524   rotate([0,0, -( axleaxlefudgebend + atan(slop/hubaxlelen) ) ])
 525   translate([-axlehorizoffset, -axlevertheight, 0]) {
 526     rotate([0,0,-axletowerfudgebend])
 527     rotate([0,0,-90])
 528       DoveClipPairSane(h=towercliph, count=towerclipcount, baseextend=3);
 529     translate([0, DoveClip_depth(), 0])
 530     rotate([0,0,90])
 531       ExtenderPillars(axlevertheight - DoveClip_depth(),
 532                       pillarswidth, towercliph,
 533                       pillarw=towerpillarw);
 534   }
 535
 536   axleclearlen = hubaxlelen + slop*4 + washerthick*2 + axlepadlen;
 537   axlerad = hubaxlerad-slop;
 538   bump = axlerad * 0.2;
 539   shift = axlerad-bump;
 540   joinbelowallow = 3;
 541
 542   intersection(){
 543     translate([0, 0, shift]) {
 544       difference() {
 545         union(){
 546           translate([-1, 0, 0])
 547             rotate([0,90,0])
 548             cylinder($fn=60,
 549                      r = axlerad,
 550                      h = 1 + axleclearlen + axlepinrad*2 + 2);
 551           mirror([1,0,0]) rotate([0,90,0])
 552             cylinder(r = axlerad*1.75, h = 3);
 553           intersection(){
 554             mirror([1,0,0])
 555               translate([axlehorizoffset - pillarswidth/2, 0, 0])
 556               rotate([0,90,0])
 557               cylinder($fn=60,
 558                        r = towercliph - shift,
 559                        h = pillarswidth);
 560             translate([-50, -joinbelowallow, -50])
 561               cube([100, joinbelowallow+50, 100]);
 562           }
 563         }
 564         rotate([90,0,0])
 565         translate([axleclearlen + axlepinrad/2, 0, -25])
 566           cylinder(r = axlepinrad + slop, h=50);
 567       }
 568     }
 569     translate([-50,-50,0]) cube([100,100,100]);
 570   }
 571 }
 572
 573 module washer(thick){
 574   Washer(hubaxlerad, washerrad, thick, slop);
 575 }
 576
 577 module AxleWasher(){ ////toplevel
 578   washer(thick=washerthick);
 579 }
 580
 581 module AxleThinWasher(){ ////toplevel
 582   washer(thick=washerthinthick);
 583 }
 584
 585 module AxleVeryThinWasher(){ ////toplevel
 586   washer(thick=washerverythinthick);
 587 }
 588
 589 module AxleFrictionWasher(){ ////toplevel
 590   difference(){
 591     cylinder(h=washerthick, r=washerrad);
 592     translate([0,0,-1]) cylinder(h=washerthick+2, r=hubaxlerad+slop);
 593   }
 594   frarmr = hubbigrad;
 595   frarmw = frictionwasherarmwidth;
 596   frarmpawlr = hublwidth;
 597   frarmpawlpush = slop*4 + frictionwasherextrapush;
 598   for (ang=[0,180]) rotate([0,0,ang]) {
 599     translate([washerrad-1, -frarmw/2, 0])
 600       cube([frarmr - washerrad + 1, frarmw, washerthick]);
 601     intersection(){
 602       translate([frarmr - frarmpawlr, -50, 0])
 603         cube([frarmpawlr, 100, 50]);
 604       rotate([0,90,0])
 605         cylinder(h = 50, r = frarmpawlpush, $fn=36);
 606     }
 607   }
 608 }
 609
 610 module TowerExtender(){ ////toplevel
 611   l = totalheightfromtower - axlevertheight;
 612   echo("TowerExtender",l);
 613   DoveClipExtender(length = l,
 614                    ha = towercliph, hb = towercliph,
 615                    counta = towerclipcount, countb = towerclipcount,
 616                    pillarw = towerpillarw);
 617 }
 618
 619 module FilamentCupPair(){ ////toplevel
 620   FilamentCup();
 621   translate([cupheight + prongthick*3,
 622              cupwidth/2*1.7,
 623              0])
 624     rotate([0,0,180]) FilamentCup();
 625 }
 626
 627 //----- storarm -----
 628
 629 storarm_hooklen = 8;
 630 storarm_hookheight = 5;
 631 storarm_thick = 10;
 632 storarm_axleslop = 4;
 633
 634 storarm_base_w = 30;
 635 storarm_base_h = 100;
 636 storarm_base_d = 15;
 637 storarm_base_mind = 2;
 638
 639 storarm_cope_hubaxle_mk1 = true;
 640
 641 storarm_screw_hole = 4;
 642 storarm_screw_hole_slop = 0.5;
 643 storarm_besides_hole = 4;
 644
 645 storarm_under_hole = 5;
 646 storarm_screw_hole_head = 8.8;
 647 storarm_screw_hole_head_slop = 1.5;
 648
 649 // calculated
 650
 651 storarm_axlerad = hubaxlerad - storarm_axleslop;
 652 storarm_mainlen = hubaxlelen*2 + storarm_axleslop
 653   + (storarm_cope_hubaxle_mk1 ? 10 : 0);
 654 storarm_totlen = storarm_mainlen + storarm_hooklen;
 655
 656 storarm_mid_off_y = storarm_axlerad;
 657
 658 storarm_base_off_y = storarm_mid_off_y + storarm_base_h/2;
 659
 660 module StorageArmDiagPartSide(xmin, xmax){
 661   xsz = xmax-xmin;
 662   yuse = storarm_thick/2;
 663
 664   intersection(){
 665     translate([xmin-1, -storarm_axlerad, storarm_thick/2])
 666       rotate([0,90,0])
 667       cylinder(r=storarm_axlerad, h=xsz+2, $fn=60);
 668     translate([xmin, -yuse, 0])
 669       cube([xsz, yuse, storarm_thick]);
 670   }
 671 }
 672
 673 module StorageArmDiagPart(xmin, xmax, shear, adjbot){
 674   hull(){
 675     StorageArmDiagPartSide(xmin,xmax);
 676
 677     multmatrix([[1,0,0,0],
 678                 [shear,1,0,0],
 679                 [0,0,1,0],
 680                 [0,0,0,1]])
 681       translate([0, -storarm_axlerad*2 + adjbot, 0])
 682       mirror([0,1,0])
 683       StorageArmDiagPartSide(xmin,xmax);
 684   }
 685 }
 686
 687 module StorageArmBaseTemplate(){
 688   square([storarm_base_w, storarm_base_h]);
 689 }
 690
 691 module StorageArmAtMountingHoles(){
 692   bes = storarm_besides_hole + storarm_screw_hole;
 693
 694   x0 = bes;
 695   x1 = storarm_base_w-bes;
 696   y1 = storarm_base_h - bes;
 697   y0 = bes;
 698
 699   for (pos=[ [x0, y1],
 700              [x1, y1],
 701              [x1, y0] ]) {
 702     rotate([0,90,0])
 703       translate([pos[0] - storarm_base_w,
 704                  pos[1] - storarm_base_off_y, -storarm_base_d])
 705       children();
 706   }
 707 }
 708
 709 module StorageArmRight(){ ////toplevel
 710   shear = storarm_hookheight / (storarm_mainlen/2);
 711
 712   StorageArmDiagPart(-1, storarm_mainlen/2+1, shear, 0);
 713   StorageArmDiagPart(storarm_mainlen/2-1, storarm_mainlen+1, shear/2,
 714                      storarm_hookheight/2);
 715
 716   translate([0, storarm_hookheight, 0])
 717     StorageArmDiagPart(storarm_mainlen, storarm_totlen,
 718                        shear/2, -storarm_hookheight/2);
 719
 720   difference(){
 721     union(){
 722       hull(){
 723         translate([-storarm_base_d, -storarm_base_off_y, storarm_base_w])
 724           rotate([0,90,0])
 725           linear_extrude(height=storarm_base_mind)
 726           StorageArmBaseTemplate();
 727         StorageArmDiagPart(-1, 0, shear, 0);
 728       }
 729       StorageArmAtMountingHoles(){
 730         cylinder(r= storarm_screw_hole_head/2,
 731                  h=10);
 732       }
 733     }
 734     StorageArmAtMountingHoles(){
 735       translate([0,0,-1])
 736         cylinder(r= (storarm_screw_hole + storarm_screw_hole_slop)/2 ,
 737                  h=20);
 738       translate([0,0,storarm_under_hole])
 739         cylinder(r= (storarm_screw_hole_head + storarm_screw_hole_head_slop)/2,
 740                  h=20);
 741     }
 742   }
 743 }
 744
 745 module StorageArmLeft(){ ////toplevel
 746   mirror([1,0,0]) StorageArmRight();
 747 }
 748
 749 module StorArmHoleTest(){ ////toplevel
 750   sz = storarm_screw_hole_head + storarm_besides_hole*2;
 751   intersection(){
 752     StorageArmRight();
 753     translate([-50, -storarm_base_off_y, -1])
 754       cube([100, sz, sz+1]);
 755   }
 756 }
 757
 758
 759 //----- filament guide spacer -----
 760
 761 guide_armdia = 15.0;
 762 guide_armwidth = 10.2;
 763 guide_armcorelen = 25.0;
 764 guide_clipcirclethick = 10.0;
 765
 766 guidefilclip_outerdia = 22.8;
 767
 768 guidespacer_armslop = 0.75;
 769 guidespacer_armlenslop = 1.05;
 770
 771 guidespacer_prongprotrude = 4;
 772 guidespacer_thick = 1.6;
 773
 774 // calculated
 775
 776 guidespacer_armdia = guide_armdia + guidespacer_armslop;
 777 guidespacer_armwidth = guide_armwidth + guidespacer_armslop;
 778 guidespacer_len = guide_armcorelen - guide_clipcirclethick
 779   + guidespacer_armlenslop;
 780
 781 guidespacer_wingheight = (guidefilclip_outerdia - guidespacer_armdia)/2;
 782
 783 module FilamentGuideArmTemplate(extra=0){
 784   intersection(){
 785     circle(r= (guidespacer_armdia/2) + extra);
 786     square(center=true, [guidespacer_armwidth+extra*2,
 787                          guidespacer_armdia + extra*2 + 10]);
 788   }
 789 }
 790
 791 module FilamentGuideSpacerInnerTemplate(){
 792   FilamentGuideArmTemplate();
 793   translate([0, -guidespacer_armdia/2])
 794     square(center=true, [guidespacer_armwidth - guidespacer_prongprotrude,
 795                          guidespacer_armdia]);
 796 }
 797
 798 module FilamentGuideSpacer(){ ////toplevel
 799   difference(){
 800     union(){
 801       linear_extrude(height= guidespacer_len)
 802         FilamentGuideArmTemplate(extra= guidespacer_thick);
 803       for (angle=[26, 60]) {
 804         for (m=[0,1]) {
 805           mirror([m,0,0]) {
 806             rotate([0,0,angle]) {
 807               hull(){
 808                 for (t=[[0, guidespacer_wingheight],
 809                         [guidespacer_len-1, -guidespacer_wingheight]])
 810                   translate([0,0, t[0] + 0.5])
 811                     cube([guidespacer_thick, guidespacer_armdia + t[1]*2,
 812                       1],
 813                          center=true);
 814               }
 815             }
 816           }
 817         }
 818       }
 819     }
 820     translate([0,0,-1])
 821       linear_extrude(height= guidespacer_len+5)
 822       FilamentGuideSpacerInnerTemplate();
 823   }
 824 }
 825
 826
 827 //----- replacement filament guide arm for TAZ-5 -----
 828
 829 guidearm_armslop = 0.25;
 830 guidearm_armlenslop = 0.25;
 831
 832 guidearm_hookprotr = 3;
 833 guidearm_hookprotrflat = 1;
 834 guidearm_hookslope = 0.3;
 835
 836 guidearm_totallen = 60;
 837
 838 guidearm_screwplatesz = 12;
 839 guidearm_screwplateth = 4;
 840 guidearm_screwplatewd = 15;
 841 guidearm_screwhole = 5 + 0.5;
 842
 843 guidearm_bendlen = 40;
 844 guidearm_bendslot = 4.5;
 845
 846 guidearm_stopthick = 4;
 847 guidearm_protrslop = 1.0;
 848
 849 // calculated
 850
 851 guidearm_armdia = guide_armdia - guidearm_armslop;
 852 guidearm_armwidth = guide_armwidth - guidearm_armslop;
 853 guidearm_armcorelen = guide_armcorelen + guidearm_armlenslop;
 854
 855 guidearm_base_z0 = -(guidearm_totallen - guidearm_armcorelen);
 856
 857 guidearm_realbendlen = min(guidearm_bendlen,
 858                            guidearm_totallen - guidearm_screwplateth - 0.1);
 859 guidearm_slopelen = guidearm_hookprotr/guidearm_hookslope;
 860
 861 module FilamentGuideArmStop(h){
 862   for (ts=[-1,+1]) {
 863     translate([ts * guidearm_hookprotr, 0,0])
 864       cylinder(r=guidearm_armdia/2, h, $fn=80);
 865   }
 866 }
 867
 868 module FilamentGuideArmShaftPositive(){
 869   r = guidearm_armdia/2;
 870
 871   translate([0,0, guidearm_base_z0+1])
 872     cylinder(r=r, h= guidearm_totallen, $fn=80);
 873   translate([0,0, guidearm_armcorelen]){
 874     hull(){
 875       FilamentGuideArmStop(guidearm_hookprotrflat);
 876       translate([0,0, guidearm_slopelen])
 877         cylinder(r=r, h=guidearm_hookprotrflat, $fn=80);
 878     }
 879   }
 880   mirror([0,0,1])
 881     FilamentGuideArmStop(guidearm_stopthick);
 882 }
 883
 884 module FilamentGuideArmBase(){
 885   translate([0,
 886              (guidearm_screwplatewd - guidearm_armwidth)/2,
 887              guidearm_base_z0]){
 888     difference(){
 889       translate([0,0, guidearm_screwplateth/2])
 890         cube(center=true,
 891              [guidearm_armdia + guidearm_screwplatesz*2,
 892               guidearm_screwplatewd,
 893               guidearm_screwplateth]);
 894       for (ts=[-1,+1]) {
 895         translate([ts * (guidearm_armdia/2 + guidearm_screwplatesz/2),
 896                    0,
 897                    -20])
 898           cylinder(r= guidearm_screwhole/2, h=40, $fn=20);
 899       }
 900     }
 901   }
 902 }
 903
 904 module FilamentGuideArm(){ ///toplevel
 905   intersection(){
 906     difference(){
 907       FilamentGuideArmShaftPositive();
 908       translate([-guidearm_bendslot/2,
 909                  -50,
 910                  -guidearm_realbendlen + guidearm_armcorelen])
 911         cube([guidearm_bendslot,
 912               100,
 913               guidearm_realbendlen + 100]);
 914       hull(){
 915         for (zx=[ [ 0, guidearm_bendslot ],
 916                   [ guidearm_armcorelen + guidearm_slopelen,
 917                     guidearm_hookprotr*2 + guidearm_protrslop ]
 918                   ]) {
 919           translate([-zx[1]/2, -50, zx[0]])
 920           cube([zx[1], 100, 1]);
 921         }
 922       }
 923     }
 924     cube(center=true,
 925          [guidearm_armdia*2,
 926           guidearm_armwidth,
 927           guidearm_totallen*3]);
 928   }
 929   FilamentGuideArmBase();
 930 }
 931
 932 module FilamentGuideArmPrint(){ ////toplevel
 933   rotate([90,0,0])
 934     FilamentGuideArm();
 935 }
 936
 937 module Demo(){ ////toplevel
 938   translate([-real_exteffrad,-20,0]) Hub();
 939   ArmEnd();
 940   translate([ratchettooth*2, 30, 0]) FilamentCup();
 941 }
 942
 943 //ArmEnd();
 944 //FilamentCup();
 945 //FilamentCupPair();
 946 //CupSecuringClip();
 947 //Hub();
 948 //ArmExtender();
 949 //Axle();
 950 //AxleWasher();
 951 //AxlePin();
 952 //AxleFrictionWasher();
 953 //StorageArmLeft();
 954 //StorArmHoleTest();
 955 //FilamentGuideSpacer();
 956 //FilamentGuideArm();
 957 //FilamentGuideArmPrint();
 958 //Demo();