fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25
  26 case_th_bottom = 2.5;
  27 case_th_lid = 2.5;
  28 case_th_side = 2;
  29 case_th_lip = 1.2;
  30
  31 case_struts_count = 6;
  32 case_struts_solid_below = 1.00;
  33 case_struts_solid_above = 0.75;
  34 case_struts_width = 0.10;
  35
  36 keeper_th_z = 0.75;
  37 keeper_th_x = 0.75;
  38 keeper_inner_width = 2.75;
  39 keeper_inner_height = 2.75;
  40 keeper_slant_slope = 2; // larger means steeper
  41
  42 keeper_gap_z_top = 0.25;
  43 keeper_gap_z_bot = 0.75;
  44 keeper_gap_x     = 0.25;
  45 keeper_gap_x_holes = 0.75;
  46
  47 case_lip = 1.25;
  48
  49 lid_gap_x = 0.25;
  50 lid_gap_z = 0.25;
  51 lid_lip = 1.75;
  52
  53 $fa = 5;
  54 $fs = 0.1;
  55
  56 button_l_fudge = 4.4;
  57 buttonishleg_default_l_is_fudge = 10;
  58
  59 strut_min_at_end = 1.5;
  60
  61 // ---------- calculated ----------
  62
  63 phone_width =  (phone + bumper*2)[0];
  64 phone_height = (phone + bumper*2)[1];
  65
  66 inside_br = [phone_width, -phone_height];
  67
  68 //echo(camera_pos_tl + bumper,
  69 //     camera_pos_br + bumper);
  70
  71 // ----- could be changed -----
  72 lid_buttoncover_gap = lid_gap_x;
  73 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  74
  75 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  76
  77 //lid_lip_overlap_width xxx bad name = ;
  78 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  79
  80 epp0 = [0,0];
  81 epp1 = [0, -phone_edge_thick];
  82 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  83 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  84 epp3 = epp2i + [10, 0];
  85 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  86 epp4 = epp5 + [-1,0] * case_th_side;
  87
  88 kppe = [0,0];
  89 kppd = kppe + [1,0] * keeper_inner_width;
  90 kppc = kppd + [0,1] * keeper_th_z;
  91 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  92 kppf = kppe - [0,1] * keeper_inner_height;
  93 kppa = [ kppb[0], kppf[1] ];
  94
  95 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  96 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  97
  98 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  99
 100 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 101 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 102
 103 // button profile
 104 bppM = epp4 + [0,5];
 105 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 106 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 107 bppS = [ epp1[0], bppR[1] ];
 108 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 109 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 110 bppO = [ bppN[0], bppP[1] ];
 111 bppL = lpp10 + [5,0];
 112 bppK = [ bppL[0], bppN[1] ];
 113 bppJ = [ bppN[0], bppL[1] ];
 114
 115 module rectfromto(a,b) {
 116   ab = b - a;
 117   translate([min(a[0], b[0]), min(a[1], b[1])])
 118     square([abs(ab[0]), abs(ab[1])]);
 119 }
 120 module circleat(c,r) { translate(c) circle(r); }
 121
 122 module KeeperProfile(slant=0){
 123   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 124   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 125 }
 126
 127 module EdgeProfile(){
 128   difference(){
 129     hull(){
 130       translate(epp3) square(case_th_bottom*2, center=true);
 131       circleat(epp2o, r=case_th_bottom);
 132       circleat(epp1, r=case_th_side);
 133       rectfromto(epp0, epp4);
 134     }
 135     polygon([ epp5 + [0,10],
 136               epp1,
 137               epp2i,
 138               epp3 + [10,0] ]);
 139   }
 140 }
 141
 142 module LidEdgeProfile(){
 143   polygon([ lpp10,
 144             lpp11,
 145             lpp12,
 146             lpp13,
 147             lpp13 + [10, 0],
 148             lpp10 + [10, 0]
 149             ]);
 150   intersection(){
 151     circleat(lpp12, r=lp_r12);
 152     rectfromto( lpp12 + [-10,   0],
 153                 lpp12 + [+10, +10] );
 154   }
 155 }
 156
 157 module ButtonCoverProfile(){
 158   intersection(){
 159     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 160     hull(){
 161       EdgeProfile();
 162       LidEdgeProfile();
 163     }
 164   }
 165 }
 166
 167 module ButtonPlan(l, deep, cut){
 168   epsilon =
 169     (cut  ? 0 : lid_buttoncover_gap);
 170
 171   delta =
 172     (deep ? lid_buttoncover_overlap : 0);
 173
 174   C = [0,0]; // by definition
 175   T = [ 0, epp4[1] ];
 176   G = T + [0,10];
 177
 178   B0 = C + [0,-1] * button_cutout_depth;
 179   B1 = B0 + [0,1] * epsilon;
 180
 181   r0 = 0.5 * (T[1] - B0[1]);
 182   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 183   H = A + [0,-1] * delta;
 184
 185   D = A + [-2,0] * r0;
 186   F = D + [0,10];
 187
 188   E0 = 0.5 * (D + A);
 189   E1 = E0 + [1,0] * epsilon;
 190
 191   I0 = [ E0[0], H[1] ];
 192   I1 = [ E1[0], H[1] ];
 193
 194   hull(){
 195     for (m=[0,1]) mirror([m,0])
 196       circleat(H, r0 - epsilon);
 197   }
 198   for (m=[0,1]) mirror([m,0]) {
 199     difference(){
 200       polygon([ E1,
 201                 I1,
 202                 H,
 203                 B1,
 204                 G,
 205                 F,
 206                 D
 207                 ]);
 208       circleat(D, r0 + epsilon);
 209     }
 210   }
 211 }
 212
 213 module CaseBase_rhsflip(yn=[0,1]) {
 214   for ($rhsflip=yn) {
 215     translate([phone_width/2, 0, 0])
 216       mirror([$rhsflip,0,0])
 217       translate([-phone_width/2, 0, 0])
 218       children();
 219   }
 220 }
 221
 222 module CaseBase_botflip() {
 223   for (bot=[0,1]) {
 224     translate([0, -phone_height/2, 0])
 225       mirror([0, bot, 0])
 226       translate([0, phone_height/2, 0])
 227       children();
 228   }
 229 }
 230
 231 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 232   // sides
 233   CaseBase_rhsflip(){
 234     translate([0, -phone_cnr_rad, 0])
 235       rotate([90,0,0])
 236       linear_extrude(height = phone_height - phone_cnr_rad*2)
 237       children(0);
 238   }
 239   // corners
 240   CaseBase_rhsflip() CaseBase_botflip() {
 241     translate([+1,-1] * phone_cnr_rad)
 242       intersection(){
 243         rotate_extrude()
 244           intersection(){
 245             mirror([1,0,0])
 246               translate([-1,0] * phone_cnr_rad)
 247               children(0);
 248             rectfromto([0,-20],[10,20]);
 249           }
 250         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 251           cube([10,10,40]);
 252       }
 253   }
 254   // top and bottom
 255   CaseBase_botflip(){
 256     translate([ phone_width - phone_cnr_rad, 0,0 ])
 257       rotate([90,0,-90])
 258       linear_extrude(height = phone_width - phone_cnr_rad*2)
 259       children(0);
 260   }
 261   // fill
 262   translate([0,0, fill_zstart])
 263     mirror([0,0, fill_downwards])
 264     linear_extrude(height = fill_th)
 265     rectfromto([+1,-1] * phone_cnr_rad,
 266                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 267 }
 268
 269 module SideButton(y, y_ref_sign, l){
 270   // y_ref_sign:
 271   //   +1  measured from top    of actual phone to top    of button
 272   //   -1  measured from bottom of actual phone to bottom of button
 273   //    0  y is centre of button in coordinate system
 274   $button_l= l;
 275   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 276           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 277           y;
 278   echo(eff_y);
 279   translate([0, eff_y, 0])
 280     children();
 281 }
 282
 283 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 284   $button_leg_only = true;
 285   SideButton(y, y_ref_sign, l) children();
 286 }
 287
 288 module Buttons(){
 289   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 290   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 291   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 292   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 293 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 294 }
 295
 296 module Struts(x_start, z_min, th){
 297   // if th is negative, starts at z_min and works towards -ve z
 298   // and object should then be printed other way up
 299   for (i= [1 : 1 : case_struts_count]) {
 300     translate([0,
 301                0,
 302                z_min])
 303       mirror([0,0, th<0 ? 1 : 0])
 304       translate([0,
 305                  -phone_height * i / (case_struts_count+1),
 306                  case_struts_solid_below])
 307       linear_extrude(height= abs(th)
 308                      -(case_struts_solid_below+case_struts_solid_above))
 309       rectfromto([               x_start, -0.5 * case_struts_width ],
 310                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 311   }
 312 }
 313
 314 module CaseBase(){
 315   AroundEdges(epp3[1], case_th_bottom, 1)
 316     EdgeProfile();
 317 }
 318
 319 module Case(){ ////toplevel
 320   difference(){
 321     union(){
 322       CaseBase();
 323
 324       // ledge (fixed keeper)
 325       intersection(){
 326         rotate([90, 0, 0])
 327           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 328           KeeperProfile(1);
 329
 330         // outline of the whole case, to stop it protruding
 331         translate([0,0, -25])
 332           linear_extrude(height = 50)
 333           hull()
 334           // CaseBase_rhsflip() // actually, we only care about the LH
 335           CaseBase_botflip()
 336           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 337       }
 338     }
 339
 340     // slot for keeper
 341     CaseBase_rhsflip(1)
 342       translate([0, -phone_cnr_rad, 0])
 343       rotate([90, 0, 0])
 344       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 345       minkowski(){
 346         KeeperProfile();
 347         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 348                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 349       }
 350
 351     // front camera
 352     CaseBase_rhsflip([1])
 353       mirror([0, 0, 1])
 354       linear_extrude(height = 20)
 355       mirror([0, 1, 0])
 356       translate(bumper)
 357       rectfromto(camera_pos_tl, camera_pos_br);
 358
 359     // struts (invisible, because they're buried in the case)
 360     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 361
 362     Buttons(){
 363       mirror([1,0,0])
 364         rotate([90,0,90]) {
 365           intersection(){
 366             translate([0,0,-10])
 367               linear_extrude(height= 20)
 368               ButtonPlan($button_l, 0,1);
 369             if ($button_leg_only)
 370               rotate([-90,90,0])
 371                 translate([phone_width/2, -400, kppe[1]])
 372                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 373           }
 374           translate([0,0, -bppR[0]])
 375             linear_extrude(height= 20)
 376             ButtonPlan($button_l, 1,1);
 377         }
 378     }
 379
 380     // jack
 381     translate([ jack_pos[0] + bumper[0],
 382                 -epp2i[0],
 383                 -jack_pos[1] ])
 384       rotate([-90, 22.5, 0])
 385       cylinder(r = jack_dia/2 / cos(22.5),
 386                h = 60,
 387                $fn=8);
 388   }
 389 }
 390
 391 module Lid(){ ////toplevel
 392   difference(){
 393     union(){
 394       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 395         LidEdgeProfile();
 396
 397       // button covers
 398       Buttons(){
 399         intersection(){
 400           rotate([90,0,90])
 401             translate([0,0,-10])
 402             linear_extrude(height= 20)
 403             ButtonPlan($button_l, 1,0);
 404           rotate([90,0,0])
 405              translate([0,0,-100])
 406             linear_extrude(height= 200)
 407             ButtonCoverProfile();
 408         }
 409       }
 410     }
 411     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 412   }
 413 }
 414
 415 module TestLength(){ ////toplevel
 416   intersection(){
 417     Case();
 418     translate([-30, -200, -20])
 419     cube([30 + 15, 250, 40]);
 420   }
 421 }
 422
 423 module TestSelectWidth(){
 424   translate([-30, -(phone_height - 25), -20])
 425     mirror([0, 1, 0])
 426     cube([200, 50, 40]);
 427 }
 428
 429 module TestWidth(){ ////toplevel
 430   intersection(){
 431     Case();
 432     TestSelectWidth();
 433   }
 434 }
 435
 436 module TestLidWidthPrint(){ ////toplevel
 437   rotate([0,180.0]) intersection(){
 438     Lid();
 439     TestSelectWidth();
 440   }
 441 }
 442
 443 module TestSelectCamera(){
 444   CaseBase_rhsflip(1)
 445     translate([0,0,-25])
 446     linear_extrude(height = 50)
 447     mirror([0, 1, 0])
 448     rectfromto([-20, -20],
 449                camera_pos_br + bumper + [ 5, 5 ]);
 450 }
 451
 452 module TestCamera(){ ////toplevel
 453   intersection(){
 454     Case();
 455     TestSelectCamera();
 456   }
 457 }
 458
 459 module TestLidByCamera(){ ////toplevel
 460   intersection(){
 461     Lid();
 462     TestSelectCamera();
 463   }
 464 }
 465
 466 module TestLidByCameraPrint(){ ////toplevel
 467   rotate([180,0,0]) TestLidByCamera();
 468 }
 469
 470 module DemoByCamera(){ ////toplevel
 471   color("blue") TestLidByCamera();
 472   color("red")  TestCamera();
 473 }
 474
 475 module OneKeeper(){ ////toplevel
 476   translate([0, -phone_cnr_rad, 0])
 477     rotate([90, 0, 0])
 478     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 479     KeeperProfile();
 480 }
 481
 482 module OneKeeperPrint(){ ////toplevel
 483   rotate([0,180,0])
 484     OneKeeper();
 485 }
 486
 487 module LidPrint(){ ////toplevel
 488   rotate([0,180,0])
 489     Lid();
 490 }
 491
 492 module TestSelectFrame(){
 493   include = [1,-1] * (epp2i[0] + 4);
 494
 495   difference(){
 496     cube(1000, center=true);
 497     translate([0,0, -100])
 498       linear_extrude(height=200)
 499       rectfromto(include,  inside_br - include);
 500   }
 501 }
 502
 503 module TestFrameCase(){ ////toplevel
 504   intersection(){
 505     Case();
 506     union(){
 507       TestSelectFrame();
 508       TestSelectCamera();
 509     }
 510   }
 511 }
 512
 513 module TestFrameLidPrint(){ ////toplevel
 514   rotate([0,0,180]) intersection(){
 515     Lid();
 516     TestSelectFrame();
 517   }
 518 }
 519
 520 module Keeper(){ ////toplevel
 521   CaseBase_rhsflip()
 522     OneKeeper();
 523 }
 524
 525 module ButtonPlanForDemo(z, deep, cut){
 526   translate([0,0,z])
 527     ButtonPlan(8, deep, cut);
 528 }
 529
 530 module DemoProfiles(){ ////toplevel
 531   LidEdgeProfile();
 532   %EdgeProfile();
 533   KeeperProfile();
 534   translate([0,0,-1]) color("black") KeeperProfile(1);
 535
 536   translate([20,0]) {
 537     LidEdgeProfile();
 538     %EdgeProfile();
 539
 540     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 541
 542     color("blue") ButtonCoverProfile();
 543     color("red") {
 544       rectfromto(bppQ, demopoint_QR);
 545       rectfromto(bppR, demopoint_QR);
 546     }
 547   }
 548
 549   translate([-20,0]) {
 550     color("black") ButtonPlanForDemo(-2, 0,1);
 551     color("red" )  ButtonPlanForDemo(-4, 1,1);
 552     color("blue")  ButtonPlanForDemo(-6, 1,0);
 553   }
 554 }
 555
 556 //EdgeProfile();
 557 //KeeperProfile();
 558 //CaseBase();
 559 //%Case();
 560 //Keeper();
 561 //LidEdgeProfile();
 562 //KeeperProfile();
 563 //DemoProfiles();