fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 thumbrecess_depth = 1.3;
 256 thumbrecess_width = 16.5;
 257
 258 catch_slop = -0.75;
 259
 260 catch_len = 4.5;
 261 catch_thickness = 1.3;
 262
 263 catch_depth = 0.75;
 264 catch_height = 0.35;
 265 catch_finger_height = 1.5;
 266 catch_finger_depth = 2.5;
 267 catch_catch_slope = 2.00;
 268 catch_close_slope = 3.00;
 269
 270 catch_topcurve_r = 5.0;
 271
 272 prop_recess_under = 0.50;
 273 prop_recess_slop = 0.200; // each side
 274 prop_end_dia = 0.5;
 275 prop_main_th = 3;
 276 prop_taper_len = 6;
 277 prop_main_width = 4;
 278 prop_side_gap = 0.75; // each side
 279 prop_lidrecess_behind = 0.75;
 280 prop_caserecess_behind = 0.75;
 281 prop_caserecess_taper = 0.45; // one side only
 282 prop_prop_gap = 0.5;
 283 prop_prong_heel_slope = 0.5;
 284
 285 lid_fold_clearance_antislop = 0.5;
 286
 287 // ---------- calculated ----------
 288
 289 phone_width =  (phone + bumper*2)[0];
 290 phone_height = (phone + bumper*2)[1];
 291
 292 inside_br = [phone_width, -phone_height];
 293
 294 prop_prong_h = prop_main_th;
 295
 296 //echo(camera_pos_tl + bumper,
 297 //     camera_pos_br + bumper);
 298
 299 // ----- could be changed -----
 300 lid_buttoncover_gap = lid_gap_x;
 301 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 302
 303 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 304
 305 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 306
 307 //prop_nose_len = case_th_lid - prop_recess_under;
 308 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 309 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 310
 311
 312 //lid_lip_overlap_width xxx bad name = ;
 313 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 314
 315 epp0 = [0,0];
 316 epp1 = [0, -phone_edge_thick];
 317 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 318 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 319 epp3 = epp2i + [10, 0];
 320 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 321 epp4 = epp5 + [-1,0] * case_th_side;
 322
 323 kppe = [0,0];
 324 kppd = kppe + [1,0] * keeper_inner_width;
 325 kppc = kppd + [0,1] * keeper_th_z;
 326 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 327 kppf = kppe - [0,1] * keeper_inner_height;
 328 kppa = [ kppb[0], kppf[1] ];
 329
 330 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 331 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 332
 333 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 334 // exact x posn not very important; must extend past end of keeper
 335
 336 lpp15 = [ lpp14[0],
 337           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 338           + lid_screen_gap_extra ];
 339 // ^ beam theory says to maximise force before contact,
 340 //   the gap below the `beam' (the lid) must be 1/3
 341 //   the thickness (ie the lid thickness) if the beam
 342 //   is solid, or 1/2 if it has a top and bottom only.
 343 //   ours is mostly solid.
 344
 345 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 346              case_th_lip);
 347
 348 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 349 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 350
 351 case_bottom_z = epp2o[1] - case_th_bottom;
 352
 353 // button profile
 354 bppM = epp4 + [0,5];
 355 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 356 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 357 bppS = [ epp1[0], bppR[1] ];
 358 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 359 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 360 bppO = [ bppN[0], bppP[1] ];
 361 bppL = lpp10 + [5,0];
 362 bppK = [ bppL[0], bppN[1] ];
 363 bppJ = [ bppN[0], bppL[1] ];
 364 bppU = [ bppJ[0], lpp12[1] ];
 365 bppV = lpp11;
 366 bppW = lpp10;
 367
 368 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 369
 370 // notification led aperture
 371
 372 nla_r0 = led_aperture/2;
 373 nla_r1 = nla_r0 + led_window_ledge;
 374 nla_r2 = nla_r1 + multicolour_gap;
 375 nla_t =
 376   led_window_style >= 3 ? initial_layer_thick :
 377   led_window_style >= 2 ? led_window_ledge : 0;
 378
 379
 380 // hinge plan
 381 hp_rn = hingescrew_nut_access_dia/2;
 382 hp_r2_min = hp_rn + lever_cover_th;
 383 hp_rs = hingescrew_shaft_dia/2;
 384 hp_r1_min = hp_rs + hingemount_th;
 385
 386 hp_r1 = max(hp_r1_min, hp_r2_min);
 387 hp_r2 = hp_r1;
 388
 389 hppU = lpp13;
 390 hppS = epp2o + [0,-1] * case_th_bottom;
 391 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 392
 393 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 394          0.5 * (hppU + hppS)[1] ];
 395 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 396 hppB = hppT + [0,-1] * hp_k;
 397
 398 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 399 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 400 hppE = [ hppE_x, hppE_y ];
 401
 402 // hinge elevation x coords
 403
 404 hex20 = max(epp2o[0],
 405             phone_cnr_rad,
 406             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 407 hex21 = hex20 + hingemount_wd;
 408 hex22 = hex21 + hinge_x_gap;
 409 hex27 = hex20 + hingescrew_shaft_len;
 410 hex24 = hex27 + hinge_x_postscrew_gap;
 411 hex23 = hex27 - (hingescrew_nut_thick*2
 412                  + hingescrew_fasteners_extra_thick);
 413 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 414
 415 echo(hex20, hex21, hex22, hex23, hex24);
 416 //  6, 10.8725, 10.9975, 13.74, 18.75
 417 module chk(act,exp) {
 418   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 419   else echo("ok", act);
 420 }
 421 chk(hex20, 6);
 422 chk(hex21, 10.8725);
 423 chk(hex22, 10.9975);
 424 chk(hex23, 13.74);
 425 chk(hex24, 18.75);
 426
 427 lid_fold_clearance_skew =
 428   (lpp10[1] - hppB[1]) /
 429   (lpp10[0] - hppB[0]);
 430
 431 echo("SK",lid_fold_clearance_skew);
 432
 433 // thumb recess (used to be "catch" hence cpp*
 434
 435 cppA = epp4 + [thumbrecess_depth, 0];
 436 cppB = [ cppA[0], epp1[1] ];
 437
 438 // lanyard
 439
 440 ly_r = lanyard_half_dia / 2;
 441 ly_rc = ly_r * 2;
 442
 443 ly_theta = -atan2vector(epp2i - epp1);
 444 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 445
 446 max_case_bottom_edge_thickness =
 447   case_th_bottom
 448   + sin(ly_theta) * (epp2i-epp2o)[0];
 449
 450 ly_q_z = -(ly_rc + ly_r);
 451 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 452
 453 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 454
 455 // prop recess in case
 456
 457 prop_x_pos = phone_width/2;
 458
 459 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 460
 461 prc_r1 = prop_end_dia/2;
 462 prc_r3 = prc_r1 + prop_recess_slop;
 463
 464 prcp2 = [ epp4[0] + prop_buildout_less,
 465           case_bottom_z ];
 466
 467 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 468
 469 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 470           epp2i[1] - prc_r3 - prop_recess_under];
 471
 472 // prop recess in lid
 473
 474 prl_r10 = prop_end_dia/2;
 475 prl_r10o = prl_r10 + prop_recess_slop;
 476
 477 prlp10 = lpp10 + [1,1] * prl_r10o
 478   + [1,0] * prop_lidrecess_behind
 479   + [0,1] * prop_recess_under;
 480
 481 // prop
 482
 483 $prpp10 = [0,0];
 484 $prpp11 = [0, prop_taper_len];
 485
 486 $prp_r10 = prl_r10;
 487
 488 // ---------- modules ----------
 489
 490 module AdhocMultiprintFrame(phase, z0, zs) {
 491   // from z0 to z0 + zs*layer
 492   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 493   xextra = extra + -epp4[0];
 494   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 495   yextra = extra + -epp4[0];
 496   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 497   p0 = [ xrange[0], yrange[0] ];
 498   p1 = [ xrange[1], yrange[1] ];
 499   echo(p0, p1);
 500   translate([0,0, z0])
 501     mirror([0,0, zs<0 ? 1 : 0])
 502     linear_extrude(height= initial_layer_thick)
 503     difference(){
 504       rectfromto(p0 - [1,1] * initial_layer_width,
 505                  p1 + [1,1] * initial_layer_width);
 506       rectfromto(p0, p1);
 507     }
 508 }
 509
 510 module KeeperProfile(slant=0){
 511   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 512   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 513 }
 514
 515 module EdgeProfile(){
 516   difference(){
 517     hull(){
 518       translate(epp3) square(case_th_bottom*2, center=true);
 519       circleat(epp2o, r=case_th_bottom);
 520       circleat(epp1, r=case_th_side);
 521       rectfromto(epp0, epp4);
 522     }
 523     polygon([ epp5 + [0,10],
 524               epp1,
 525               epp2i,
 526               epp3 + [10,0] ]);
 527   }
 528 }
 529
 530 module LanyardLanyardProfile(entry=false){
 531   hull(){
 532     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 533       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 534         circle(r= lanyard_half_dia/2);
 535   }
 536 }
 537
 538 module LanyardCurveChannelProfile(){
 539   translate([0, -ly_r])
 540     LanyardLanyardProfile();
 541 }
 542
 543 module LanyardEntryChannelProfile(){
 544   LanyardLanyardProfile(true);
 545 }
 546
 547 module LanyardMainChannelProfile(){
 548   LanyardCurveChannelProfile();
 549   difference(){
 550     square(center=true, ly_r * [6, 2]);
 551     for (xs=[-1,+1])
 552       translate(ly_r * [3 * xs, -1])
 553         circle(r = ly_r);
 554   }
 555 }
 556
 557 module LanyardEntryOuterProfile(){
 558   circleat([ly_re + ly_r, 0], ly_re);
 559 }
 560
 561 module LanyardEntry(){
 562   q_z = ly_q_z;
 563   oec_y = ly_oec_y;
 564
 565   d_x = -ly_rc;
 566
 567   translate([d_x, 0, q_z]) {
 568     intersection(){
 569       rotate([90,0,0])
 570         rotate_extrude(convexity=10)
 571         rotate(90)
 572         translate([0, -q_z])
 573         LanyardCurveChannelProfile();
 574       translate([0,-10,0])
 575         cube([20,20,20]);
 576     }
 577   }
 578
 579   mirror([0,0,1])
 580     translate([0,0,-1])
 581     linear_extrude(height=20)
 582     rotate(-90)
 583     LanyardEntryChannelProfile();
 584
 585   translate([0, ly_r*2, 0])
 586     rotate([90,0,0])
 587     linear_extrude(height = ly_r*4){
 588     difference(){
 589       rectfromto([d_x, q_z], [ly_r, 0]);
 590       circleat([d_x, q_z], ly_rc);
 591     }
 592   }
 593
 594   translate([0,0,q_z]){
 595     for (my=[0,1])
 596       mirror([0,my,0]){
 597         translate([0, oec_y, 0]){
 598           difference(){
 599             translate(ly_re * [-1,0,-2])
 600               cube(ly_re * [2,1,2]);
 601             rotate_extrude(convexity=10)
 602               LanyardEntryOuterProfile();
 603           }
 604         }
 605       }
 606     difference(){
 607       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 608         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 609       for (mx=[0,1])
 610         mirror([mx,0,0])
 611           rotate([90,0,0])
 612           translate([0,0,-10])
 613           linear_extrude(height=20)
 614           LanyardEntryOuterProfile();
 615     }
 616   }
 617 }
 618
 619 module LanyardCutout(l){
 620   rotate([0,-90,0])
 621     linear_extrude(height=l)
 622     rotate(-90)
 623     LanyardMainChannelProfile();
 624
 625   for (ee=[0,1]){
 626     translate(ee * l * [-1,0])
 627       mirror([ee,0,0])
 628       LanyardEntry();
 629   }
 630 }
 631
 632 module LidEdgeProfile(){
 633   polygon([ lpp10,
 634             lpp11,
 635             lpp12,
 636             lpp13,
 637             lpp13 + [10, 0],
 638             lpp15 + [10, 0],
 639             lpp15,
 640             lpp14,
 641             ]);
 642   intersection(){
 643     circleat(lpp12, r=lp_r12);
 644     rectfromto( lpp12 + [-10,   0],
 645                 lpp12 + [+10, +10] );
 646   }
 647 }
 648
 649 module LidEdgeFoldClearanceProfile(){
 650   translate([-lid_fold_clearance_antislop, 0])
 651     polygon([ lpp10,
 652               lpp11,
 653               lpp11 + [-20,  0],
 654               lpp11 + [-20, 20],
 655               lpp11 + [+20, 20],
 656               lpp10 + [+20,  0] ]);
 657 }
 658
 659 module ButtonCoverProfile(){
 660   intersection(){
 661     polygon(concat([ bppM, bppP, bppO, bppJ ],
 662                    (enable_support && !$button_suppress_over_keeper
 663                     ? [ bppU, bppV, bppW ] : []),
 664                    [ bppL, bppK ]));
 665     hull(){
 666       EdgeProfile();
 667       LidEdgeProfile();
 668     }
 669   }
 670 }
 671
 672 module ButtonPlan(l, deep, cut){
 673   epsilon =
 674     (cut  ? 0 : lid_buttoncover_gap);
 675
 676   delta =
 677     (deep ? lid_buttoncover_overlap : 0);
 678
 679   C = [0,0]; // by definition
 680   T = [ 0, epp4[1] ];
 681   G = T + [0,10];
 682
 683   B0 = C + [0,-1] * button_cutout_depth;
 684   B1 = B0 + [0,1] * epsilon;
 685
 686   r0 = 0.5 * (T[1] - B0[1]);
 687   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 688   H = A + [0,-1] * delta;
 689
 690   D = A + [-2,0] * r0;
 691   F = D + [0,10];
 692
 693   E0 = 0.5 * (D + A);
 694   E1 = E0 + [1,0] * epsilon;
 695
 696   I0 = [ E0[0], H[1] ];
 697   I1 = [ E1[0], H[1] ];
 698
 699   hull(){
 700     for (m=[0,1]) mirror([m,0])
 701       circleat(H, r0 - epsilon);
 702   }
 703   for (m=[0,1]) mirror([m,0]) {
 704     difference(){
 705       polygon([ E1,
 706                 I1,
 707                 H,
 708                 B1,
 709                 G,
 710                 F,
 711                 D
 712                 ]);
 713       circleat(D, r0 + epsilon);
 714     }
 715   }
 716 }
 717
 718 module ButtonCoverReinf(){ ////toplevel
 719   minkowski(){
 720     rotate([90,0,0])
 721       linear_extrude(height=0.01)
 722       intersection(){
 723         ButtonCoverProfile();
 724         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 725           square([100,100]);
 726     }
 727     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 728       circle(r= lid_buttoncover_reinf);
 729       translate([-20,0]) square(40, center=true);
 730     }
 731   }
 732 }
 733
 734 module CatchCutProfile(){
 735   difference(){
 736     polygon([ cppA + [-10,0],
 737               cppB + [-10,0],
 738               cppB,
 739               cppA ]);
 740     circleat(epp1, r=case_th_side);
 741   }
 742 }
 743
 744 module Flip_rhs(yn=[0,1]) {
 745   for ($rhsflip=yn) {
 746     translate([phone_width/2, 0, 0])
 747       mirror([$rhsflip,0,0])
 748       translate([-phone_width/2, 0, 0])
 749       children();
 750   }
 751 }
 752
 753 module Flip_bot(yn=[0,1]) {
 754   for ($botflip=yn) {
 755     translate([0, -phone_height/2, 0])
 756       mirror([0, $botflip, 0])
 757       translate([0, phone_height/2, 0])
 758       children();
 759   }
 760 }
 761
 762 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 763   // sides
 764   Flip_rhs(){
 765     translate([0, -phone_cnr_rad, 0])
 766       rotate([90,0,0])
 767       linear_extrude(height = phone_height - phone_cnr_rad*2)
 768       children(0);
 769   }
 770   // corners
 771   Flip_rhs() Flip_bot() {
 772     translate([+1,-1] * phone_cnr_rad)
 773       intersection(){
 774         rotate_extrude()
 775           intersection(){
 776             mirror([1,0,0])
 777               translate([-1,0] * phone_cnr_rad)
 778               children(0);
 779             rectfromto([0,-20],[10,20]);
 780           }
 781         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 782           cube([10,10,40]);
 783       }
 784   }
 785   // top and bottom
 786   Flip_bot(){
 787     translate([ phone_width - phone_cnr_rad, 0,0 ])
 788       rotate([90,0,-90])
 789       linear_extrude(height = phone_width - phone_cnr_rad*2)
 790       children(0);
 791   }
 792   // fill
 793   translate([0,0, fill_zstart])
 794     mirror([0,0, fill_downwards])
 795     linear_extrude(height = fill_th)
 796     rectfromto([+1,-1] * phone_cnr_rad,
 797                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 798 }
 799
 800 module CaseAperture(pos, dia, $fn) {
 801   theta = 180/$fn;
 802   translate([ pos[0] + bumper[0],
 803               -epp2i[0],
 804               -pos[1] ])
 805     rotate([-90, theta, 0])
 806     cylinder(r = dia/2 / cos(theta),
 807              h = 60);
 808 }
 809
 810 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 811   // y_ref_sign:
 812   //   +1  measured from top    of actual phone to top    of button
 813   //   -1  measured from bottom of actual phone to bottom of button
 814   //    0  y is centre of button in coordinate system
 815   $button_l= l;
 816   $button_suppress_over_keeper= suppress_over_keeper;
 817   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 818           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 819           y;
 820   //echo(eff_y);
 821   translate([0, eff_y, 0])
 822     children();
 823 }
 824
 825 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 826   $button_leg_only = true;
 827   SideButton(y, y_ref_sign, l) children();
 828 }
 829
 830 module Buttons(){
 831   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 832   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 833   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 834   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 835 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 836 }
 837
 838 module Struts(x_start, z_min, th){
 839   // if th is negative, starts at z_min and works towards -ve z
 840   // and object should then be printed other way up
 841   for (i= [1 : 1 : case_struts_count]) {
 842     translate([0,
 843                0,
 844                z_min])
 845       mirror([0,0, th<0 ? 1 : 0])
 846       translate([0,
 847                  -phone_height * i / (case_struts_count+1),
 848                  case_struts_solid_below])
 849       linear_extrude(height= abs(th)
 850                      -(case_struts_solid_below+case_struts_solid_above))
 851       rectfromto([               x_start, -0.5 * case_struts_width ],
 852                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 853   }
 854 }
 855
 856 module OrdinaryRearAperture(rhs,bot, pos){
 857   Flip_rhs(rhs) Flip_bot(bot)
 858     linextr(-20, 20)
 859     mirror([0,1])
 860     translate(pos + bumper)
 861     children();
 862 }
 863
 864 module MicroUSB(){
 865   Flip_bot(1){
 866     rotate([90,0,0])
 867       mirror([0,0,1])
 868       linextr(-epp2i[0], 60)
 869       translate([0.5 * phone_width, 0, 0])
 870       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 871                  [+microusb_width/2, epp0[1] + -microusb_above]);
 872   }
 873 }
 874
 875 module OrdinaryRearApertures(){
 876   // rear speaker
 877   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 878     rectfromto(-rearspeaker_gap,
 879                rearspeaker_size + rearspeaker_gap);
 880
 881   // finger hole to remove phone
 882   if (len(fingerpushhole_dias))
 883     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 884                                 phone[1]/2 ])
 885     scale(fingerpushhole_dias)
 886     circle(r= 0.5 );
 887 }
 888
 889 module RearCameraAperture(){
 890   Flip_rhs(1)
 891     mirror([0, 0, 1])
 892     linear_extrude(height = 20)
 893     mirror([0, 1, 0])
 894     translate(bumper)
 895     rectfromto(camera_pos_tl, camera_pos_br);
 896 }
 897
 898 module HingeLidProfile(){
 899   hull(){
 900     circleat(hppT, hp_r1);
 901     circleat(lpp12, lp_r12);
 902     polygon([lpp10,
 903              lpp13 + [2,0],
 904              lpp12,
 905              hppT]);
 906   }
 907 }
 908
 909 module HingeBaseProfile(){
 910   difference(){
 911     hull(){
 912       circleat(hppB, hp_r1);
 913       circleat(hppE, hp_r1);
 914       circleat(epp2o, case_th_bottom);
 915       circleat(hppB + [10,0], hp_r1);
 916     }
 917     polygon([epp5, epp1, epp2i, epp3, bppL]);
 918   }
 919 }
 920
 921 module HingeLeverOuterProfile(){
 922   hull(){
 923     circleat(hppT, hp_r2);
 924     circleat(hppB, hp_r2);
 925   }
 926 }
 927
 928 module HingeLeverInnerProfile(){
 929   for (s = [-1,+1]) {
 930     c = s > 0 ? hppT : hppB;
 931     translate(c)
 932       mirror([0,0,s>0])
 933       rotate(s<0 ? -40 : 0)
 934       hull()
 935       for (x=[-20,20])
 936         for (y=[0, s * 10])
 937           translate([x,y])
 938             circle(hp_rn);
 939   }
 940 }
 941
 942 module HingeLeverNutProfile(){
 943   for (c= [hppB, hppT]) {
 944     translate(c)
 945       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 946   }
 947 }
 948
 949 module Flip_hinge(doflip=1){
 950   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 951   translate(hinge_origin)
 952     rotate([doflip*180,0,0])
 953     translate(-hinge_origin)
 954     children();
 955 }
 956
 957 module HingePortion(x0,x1){
 958   Flip_rhs() Flip_bot(1)
 959     translate([x0,0,0])
 960     mirror([1,0,0])
 961     rotate([90,0,-90])
 962     linear_extrude(height=x1-x0)
 963     children();
 964 }
 965
 966 module CatchPortion(ztop){
 967   width = thumbrecess_width;
 968   w = width + catch_topcurve_r*2 + 1;
 969   translate([phone_width/2, 0,0]){
 970     difference(){
 971       rotate([90,0,-90])
 972         linextr(-w/2, w/2)
 973         children(0);
 974       translate([0, 50, 0])
 975         rotate([90,0,0])
 976         linear_extrude(height=100){
 977         for (m=[0,1]) mirror([m,0,0]) {
 978           hull(){
 979             translate([w/2, ztop - catch_topcurve_r])
 980               circle(catch_topcurve_r);
 981             translate([w/2, -50])
 982               square(catch_topcurve_r*2, center=true);
 983           }
 984         }
 985       }
 986     }
 987   }
 988 }
 989
 990 module CaseBase(){
 991   AroundEdges(epp3[1], case_th_bottom, 1)
 992     EdgeProfile();
 993 }
 994
 995 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 996
 997 module PropProfileAssignments(gamma){
 998   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 999   x = prop_x(gamma);
1000   p = phone_height + prlp10[0] - hppB[0];
1001   b = p + x;
1002
1003   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1004   a = q + x;
1005   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1006   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1007
1008   $prp_theta = 90 - $prp_alpha;
1009   beta = 180 - $prp_alpha - gamma;
1010   psi = 90 - beta;
1011
1012   //echo("abc", a,b,c);
1013
1014   v1 = [ [ cos(psi), -sin(psi) ],    // x
1015          [ sin(psi),  cos(psi) ] ];  // y
1016
1017   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1018
1019   $prp_r1 = prc_r1;
1020   $prp_r11 = prop_main_th/2;
1021
1022   $prpp1 = $prpp7 + [1,0] *
1023     // this is approximate, but will do
1024     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1025   $prpp3 = $prpp1 +
1026     v1[0] * -$prp_r1 +
1027     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1028   $prpp12 = $prpp3 + v1[0] *
1029     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1030   $prp_r8 = prop_main_th;
1031   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1032   $prp_r5 = $prp_r8;
1033   $prpp5 = [ $prpp12[0] - $prp_r5,
1034             $prpp3[1] - prop_prong_h + $prp_r5 ];
1035   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1036          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1037   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1038   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1039
1040   children();
1041 }
1042
1043 module PropProfile(gamma, cut=0, rot=0){
1044   PropProfileAssignments(gamma){
1045
1046     //#circleat($prpp3,1);
1047     //#circleat($prpp12,1);
1048
1049     if (!cut) {
1050       hull(){
1051         translate($prpp8)
1052           intersection(){
1053             circle($prp_r8);
1054             polygon([[-20,-0], [20,20], [0,0]]);
1055           }
1056         rectfromto($prpp6, $prpp9);
1057         translate($prpp5) intersection(){
1058           circle($prp_r5);
1059           polygon([[-10,-10], [0,0], [10,0]]);
1060         }
1061         rectfromto($prpp12 + [0,-0.1], $prpp3);
1062       }
1063       hull(){
1064         circleat($prpp1, $prp_r1);
1065         rectfromto($prpp12 + [0,-0.1], $prpp3);
1066       }
1067     }
1068     // main shaft
1069     rotate([0,0, rot*-$prp_theta]){
1070       hull(){
1071         extra = cut ? prop_recess_slop : 0;
1072         rectfromto($prpp6, $prpp9);
1073         circleat($prpp11, $prp_r11 + extra);
1074         circleat($prpp10, $prp_r10 + extra);
1075       }
1076     }
1077   }
1078 }
1079
1080 module PropAggregateProfile(){
1081   for (angle = prop_angles)
1082     PropProfile(angle, 0,0);
1083 }
1084
1085 module Prop(){ ////toplevel
1086   hw = prop_main_width/2;
1087   linextr(-hw, +hw)
1088     PropAggregateProfile();
1089 }
1090
1091 module Case(){ ////toplevel
1092   difference(){
1093     union(){
1094       CaseBase();
1095
1096       // ledge (fixed keeper)
1097       Flip_rhs(1-keeper_side) intersection(){
1098         rotate([90, 0, 0])
1099           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1100           KeeperProfile(1);
1101
1102         // outline of the whole case, to stop it protruding
1103         translate([0,0, -25])
1104           linear_extrude(height = 50)
1105           hull()
1106           Flip_bot()
1107           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1108       }
1109
1110       // hinge
1111       HingePortion(hex20, hex21) HingeBaseProfile();
1112
1113       // buildout for prop recess
1114       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1115         linextr(case_bottom_z, epp2i[1])
1116         hull() {
1117           for (dxs = [-1,+1])
1118             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1119                        -epp2o[0] ],
1120                      r = epp2o[0] - prcp2[0]);
1121         }
1122     }
1123
1124     // slot for keeper
1125     Flip_rhs(keeper_side)
1126       translate([0, -phone_cnr_rad, 0])
1127       rotate([90, 0, 0])
1128       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1129       minkowski(){
1130         KeeperProfile();
1131         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1132                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1133       }
1134
1135     // front camera
1136     RearCameraAperture();
1137
1138     // struts (invisible, because they're buried in the case)
1139     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1140
1141     Buttons(){
1142       mirror([1,0,0])
1143         rotate([90,0,90]) {
1144           if (!($button_leg_only && enable_support))
1145           intersection(){
1146             translate([0,0,-10])
1147               linear_extrude(height= 20)
1148               ButtonPlan($button_l, 0,1);
1149             if ($button_leg_only)
1150               rotate([-90,90,0])
1151                 translate([phone_width/2, -400, kppe[1]])
1152                 mirror([1-abs($rhsflip - keeper_side),0,0])
1153                 cube([400, 800, 50]);
1154             if (enable_support && !$button_suppress_over_keeper)
1155               rotate([-90,90,0])
1156               translate([-400, -400, kppd[1]])
1157                 mirror([0,0,1])
1158                 cube([800,800,100]);
1159           }
1160           translate([0,0, -bppR[0]])
1161             linear_extrude(height= 20)
1162             ButtonPlan($button_l, 1,1);
1163         }
1164
1165     }
1166
1167     // apertures along top edge
1168     CaseAperture(jack_pos, jack_dia, 8);
1169     Flip_rhs(1)
1170       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1171
1172     OrdinaryRearApertures();
1173
1174     MicroUSB();
1175
1176     // gaps for the lid's hinge arms
1177     HingePortion(hex20 - hinge_x_arms_gap,
1178                  hex21 + hinge_x_arms_gap)
1179       minkowski(){
1180         HingeLidProfile();
1181         circle(r= hinge_r_arms_gap, $fn= 8);
1182       }
1183
1184     // screw holes in the hinge arms
1185     HingeScrews();
1186
1187     // catch striker
1188     CatchPortion(epp4[1])
1189       CatchCutProfile();
1190
1191     // lanyard
1192     Flip_bot(1)
1193       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1194       rotate([0, ly_theta, 0])
1195       rotate([0,0,90])
1196       LanyardCutout(lanyard_channel_len);
1197
1198     // prop recess
1199     Flip_rhs(1)
1200       translate([prop_x_pos,0,0])
1201       mirror([0,1,0])
1202       rotate([90,0,90])
1203       linextr(-prop_recess_hw, +prop_recess_hw)
1204       hull(){
1205         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1206           circleat(prcp1 + 20*d,
1207                    prc_r3);
1208       }
1209   }
1210 }
1211
1212 module LidAdhocMultiprintFrame(phase){
1213   if (led_window_style >= 3) {
1214     AdhocMultiprintFrame(phase, lpp13[1], -1);
1215   }
1216 }
1217
1218 module LidAroundEdges(){
1219   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1220     children();
1221 }
1222
1223 module Lid(){ ////toplevel
1224   skew_centre = [0, lpp11[0], lpp11[1]];
1225   difference(){
1226     union(){
1227       intersection(){
1228         LidAroundEdges()
1229           LidEdgeProfile();
1230
1231         translate(skew_centre)
1232           multmatrix([[ 1, 0, 0, 0 ],
1233                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1234                       [ 0, 0, 1, 0 ],
1235                       [ 0, 0, 0, 1 ]])
1236           translate(-skew_centre)
1237           LidAroundEdges()
1238           LidEdgeFoldClearanceProfile();
1239       }
1240
1241       // button covers
1242       Buttons(){
1243         intersection(){
1244           rotate([90,0,90])
1245             translate([0,0,-10])
1246             linear_extrude(height= 20)
1247             ButtonPlan($button_l, 1,0);
1248           union(){
1249             rotate([90,0,0])
1250               translate([0,0,-100])
1251               linear_extrude(height= 200)
1252               ButtonCoverProfile();
1253             hull()
1254               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1255                                  - lid_buttoncover_reinf))
1256                 translate([0,y,0])
1257                   ButtonCoverReinf();
1258           }
1259         }
1260       }
1261
1262       // hinge arms
1263       HingePortion(hex20, hex21) {
1264         LidEdgeProfile();
1265         HingeLidProfile();
1266       }
1267     }
1268     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1269
1270     // screw holes in the hinge arms
1271     HingeScrews();
1272
1273     // prop recess
1274     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1275       mirror([0,1,0])
1276       rotate([90,0,90])
1277       linextr(-prop_recess_hw, +prop_recess_hw)
1278       hull()
1279       for (pa = prop_angles)
1280         PropProfile(pa, 1,1);
1281
1282     // notification led aperture
1283     if (led_window_style)
1284       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1285         translate([0,0,-10])
1286           cylinder(r=nla_r0, h=20);
1287         if (led_window_style >= 2)
1288           translate([0,0, -nla_t])
1289             cylinder(r=nla_r2, height=20);
1290       }
1291
1292     }
1293
1294   LidAdhocMultiprintFrame(1);
1295 }
1296
1297 module HingeLever(){ ////toplevel
1298   difference() {
1299     // outer body, positive
1300     HingePortion(hex22, hex22 + phone_width/2)
1301       HingeLeverOuterProfile();
1302
1303     // space for the screws
1304     HingePortion(hex26, hex24)
1305       HingeLeverInnerProfile();
1306
1307     // recesses for the nuts
1308     HingePortion(hex23, hex26+1)
1309       HingeLeverNutProfile();
1310
1311     // bores for the screws
1312     HingeScrews();
1313
1314     // space for the charging cable
1315     MicroUSB();
1316     Flip_hinge() MicroUSB();
1317   }
1318 }
1319
1320 module LidWindow(){ ////toplevel
1321   translate([led_pos[0], -led_pos[1], lpp13[1]])
1322     mirror([0,0,1])
1323     cylinder(r= nla_r1, h=nla_t);
1324   LidAdhocMultiprintFrame(0);
1325 }
1326
1327 module LidWindowPrint(){ ////toplevel
1328   rotate([0,180,0])
1329     LidWindow();
1330 }
1331
1332 module DemoLidWindowSelect(){
1333   translate([led_pos[0], led_pos[1], -100]) {
1334     translate([0, -30, 0]) cube([400, 400, 200]);
1335   }
1336 }
1337
1338 module DemoLidWindow(){ ////toplevel
1339   %Lid();
1340   LidWindow();
1341   translate([0,40,0]){
1342     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1343     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1344   }
1345 }
1346
1347 module HingeLeverPrint(){ ////toplevel
1348   rotate([-90,0,0])
1349     translate([-phone_width/2, phone_height, 0])
1350     HingeLever();
1351 }
1352
1353 module TestSelectLength(){
1354   translate([-30, -200, -20])
1355     cube([30 + 15, 250, 40]);
1356 }
1357
1358 module TestLength(){ ////toplevel
1359   intersection(){
1360     Case();
1361     TestSelectLength();
1362   }
1363 }
1364
1365 module TestLengthRight(){ ////toplevel
1366   intersection(){
1367     Case();
1368     Flip_rhs(1)
1369       TestSelectLength();
1370   }
1371 }
1372
1373 module TestSelectWidth(){
1374   translate([-30, -(phone_height - 25), -20])
1375     mirror([0, 1, 0])
1376     cube([200, 50, 40]);
1377 }
1378
1379 module TestWidth(){ ////toplevel
1380   intersection(){
1381     Case();
1382     TestSelectWidth();
1383   }
1384 }
1385
1386 module TestLidWidthPrint(){ ////toplevel
1387   rotate([0,180.0]) intersection(){
1388     Lid();
1389     TestSelectWidth();
1390   }
1391 }
1392
1393 module TestSelectRearAperture(){
1394   minkowski(){
1395     union() children();
1396     translate([20, 0,0])
1397       cube([42, 2, 1], center=true);
1398   }
1399 }
1400
1401 module TestSelectCamera(){
1402   minkowski(){
1403     TestSelectRearAperture()
1404       RearCameraAperture();
1405     cube([0.1, 50, 0.1]);
1406   }
1407 }
1408
1409 module TestSelectOrdinaryRearApertures(){
1410   TestSelectRearAperture()
1411     OrdinaryRearApertures();
1412 }
1413
1414 module TestCamera(){ ////toplevel
1415   intersection(){
1416     Case();
1417     TestSelectCamera();
1418   }
1419 }
1420
1421 module TestLidByCamera(){ ////toplevel
1422   intersection(){
1423     Lid();
1424     TestSelectCamera();
1425   }
1426 }
1427
1428 module TestLidByCameraPrint(){ ////toplevel
1429   rotate([180,0,0]) TestLidByCamera();
1430 }
1431
1432 module DemoByCamera(){ ////toplevel
1433   color("blue") TestLidByCamera();
1434   color("red")  TestCamera();
1435 }
1436
1437 module OneKeeper(){ ////toplevel
1438   translate([0, -phone_cnr_rad, 0])
1439     rotate([90, 0, 0])
1440     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1441     KeeperProfile();
1442 }
1443
1444 module OneKeeperPrint(){ ////toplevel
1445   rotate([0,180,0])
1446     OneKeeper();
1447 }
1448
1449 module LidPrint(){ ////toplevel
1450   rotate([0,180,0])
1451     Lid();
1452 }
1453
1454 module TestSelectFrame(){
1455   include = [1,-1] * (epp2i[0] + 4);
1456
1457   difference(){
1458     cube(1000, center=true);
1459     translate([0,0, -100])
1460       linear_extrude(height=200)
1461       rectfromto(include,  inside_br - include);
1462   }
1463 }
1464
1465 module TestSelectLidFrame(){
1466   TestSelectFrame();
1467   translate([led_pos[0], -led_pos[1], -50])
1468     cylinder(r= nla_r2+3, h=100);
1469 }
1470
1471 module TestFrameCase(){ ////toplevel
1472   intersection(){
1473     Case();
1474     union(){
1475       TestSelectFrame();
1476       TestSelectCamera();
1477       TestSelectOrdinaryRearApertures();
1478     }
1479   }
1480 }
1481
1482 module TestSelectTopApertures(){
1483   translate([-100, -35, -100])
1484     cube([400, 100, 200]);
1485   LidAdhocMultiprintFrame(0);
1486   LidAdhocMultiprintFrame(1);
1487 }
1488
1489 module TestTopApertures(){ ////toplevel
1490   intersection(){
1491     Case();
1492     TestSelectFrame();
1493     TestSelectTopApertures();
1494   }
1495 }
1496
1497 module TestLidTopAperturesPrint(){ ////toplevel
1498   rotate([0,180,0]) intersection(){
1499     Lid();
1500     TestSelectLidFrame();
1501     TestSelectTopApertures();
1502   }
1503 }
1504
1505 module TestLidWindowTopAperturesPrint(){ ////toplevel
1506   rotate([0,180,0]) intersection(){
1507     LidWindow();
1508     TestSelectTopApertures();
1509   }
1510 }
1511
1512 module TestFrameLidPrint(){ ////toplevel
1513   rotate([0,180,0]) intersection(){
1514     Lid();
1515     TestSelectLidFrame();
1516   }
1517 }
1518
1519 module ButtonPlanForDemo(z, deep, cut){
1520   translate([0,0,z])
1521     ButtonPlan(8, deep, cut);
1522 }
1523
1524 module HingeScrews(){
1525   Flip_rhs() Flip_bot(1){
1526     for (c= [ hppT, hppB ])
1527       translate([ hex20,
1528                   -c[0],
1529                   c[1] ]){
1530         rotate([0,90,0])
1531           translate([0,0,-.2])
1532           cylinder( r= hingescrew_shaft_dia/2,
1533                     h = hingescrew_shaft_len+0.2 );
1534         rotate([0,-90,0])
1535           translate([0,0,+.1])
1536           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1537       }
1538   }
1539 }
1540
1541 module DemoPropAngleSelect(c){
1542   color(c) difference(){
1543     union(){ children(); }
1544     translate([ prop_x_pos, -400, -200 ])
1545       cube([ 400,800,400 ]);
1546   }
1547 }
1548
1549 module DemoPropAngle(ang){
1550   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1551   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1552
1553   translate(hL)
1554     rotate([ang/2,0,0])
1555     translate(-hL)
1556     translate(hC)
1557     rotate([ang/2,0,0])
1558     translate(-hC) {
1559       DemoPropAngleSelect("red") Case();
1560
1561       color("orange")
1562         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1563         PropProfileAssignments(ang) {
1564           echo($prpp1);
1565           rotate([-$prp_theta, 0, 0])
1566           translate([0, $prpp1[0], -$prpp1[1]])
1567           rotate([90,0,-90])
1568           Prop();
1569         }
1570     }
1571
1572   translate([0,0, -hp_k*2])
1573     DemoPropAngleSelect("blue")
1574     Lid();
1575 }
1576
1577 module DemoPropAngles(){ ////toplevel
1578   for (i=[0 : len(prop_angles)-1])
1579     translate(i * [0, -100, 100])
1580     DemoPropAngle(prop_angles[i]);
1581 }
1582
1583 module DemoHingeAngle(ang1,ang2){
1584   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1585   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1586
1587   translate(hL)
1588     rotate([ang2,0,0])
1589     translate(-hL)
1590     translate(hC)
1591     rotate([ang1,0,0])
1592     translate(-hC) {
1593       color("red") Lid();
1594     }
1595
1596   color("blue") intersection(){
1597     Case();
1598     union(){
1599       translate([bppJ[0], -400, -200])
1600         mirror([1,0,0])
1601         cube([400, 800, 400]);
1602       translate([10, -400, -200])
1603         cube([10, 800, 400]);
1604     }
1605   }
1606 }
1607
1608 module DemoHingeAngles(){ ////toplevel
1609   angles = [ 0, 4, 8, 12 ];
1610   echo("angles",angles);
1611   for (i=[0 : len(angles)-1]) {
1612     translate(i * [0, 0, 30]) {
1613       DemoHingeAngle(0,angles[i]);
1614       translate([0, 200, 0])
1615         DemoHingeAngle(angles[i],0);
1616     }
1617   }
1618 }
1619
1620 module DemoSelectAdhocLeftRight(right=0) {
1621   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1622     mirror([1-right, 0,0])
1623     cube([400, 800, 200]);
1624 }
1625
1626 module DemoLeft(){ ////toplevel
1627   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1628   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1629 }
1630
1631 module DemoFrame(){ ////toplevel
1632   color("red") TestFrameCase();
1633   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1634   color("black") HingeScrews();
1635   %HingeLever();
1636 }
1637
1638 module DemoLanyardCutout(){ ////toplevel
1639   LanyardCutout(25);
1640 }
1641
1642 module DemoHingedFrame(){ ///toplevel
1643   color("red") TestFrameCase();
1644   translate([0,0, -2*hp_k])
1645   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1646
1647   Flip_hinge(){
1648     color("orange") HingeLever();
1649     color("black") HingeScrews();
1650   }
1651 }
1652
1653 module DemoHinge(){ ////toplevel
1654   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1655     DemoFrame();
1656     translate([0,0, -hp_k*3])
1657       DemoHingedFrame();
1658   }
1659 }
1660
1661 module DemoProfiles(){ ////toplevel
1662   LidEdgeProfile();
1663   %EdgeProfile();
1664   KeeperProfile();
1665   translate([0,0,-1]) color("black") KeeperProfile(1);
1666   translate(ly_o){
1667     rotate(-ly_theta){
1668       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1669       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1670       translate([0, ly_q_z]){
1671         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1672         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1673       }
1674     }
1675   }
1676   translate([0,0,-5]) color("white") translate(epp2i)
1677     rotate(-ly_theta)
1678     rectfromto([-15, 0],
1679                [+15, -max_case_bottom_edge_thickness]);
1680
1681   translate([0,20]) {
1682     LanyardMainChannelProfile();
1683     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1684     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1685   }
1686
1687   translate([20,0]) {
1688     LidEdgeProfile();
1689     %EdgeProfile();
1690
1691     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1692
1693     color("blue") ButtonCoverProfile();
1694     color("red") {
1695       rectfromto(bppQ, demopoint_QR);
1696       rectfromto(bppR, demopoint_QR);
1697     }
1698   }
1699
1700   translate([-20,0]) {
1701     color("black") ButtonPlanForDemo(-2, 0,1);
1702     color("red" )  ButtonPlanForDemo(-4, 1,1);
1703     color("blue")  ButtonPlanForDemo(-6, 1,0);
1704   }
1705
1706   translate([0, -30]) {
1707     %LidEdgeProfile();
1708     %EdgeProfile();
1709     color("blue") HingeLidProfile();
1710     color("red")  HingeBaseProfile();
1711     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1712   }
1713
1714   for (f=[0,1]) {
1715     translate([-30, -60 + 30*f]) {
1716       translate([0,0,-4]) EdgeProfile();
1717       %translate([0,0,-10]) HingeBaseProfile();
1718       translate([0,-2] * f * hp_k) {
1719         translate([0,0,-4]) LidEdgeProfile();
1720         %translate([0,0,-10]) %HingeLidProfile();
1721       }
1722       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1723         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1724         translate([0,0,0]) color("red") difference(){
1725           HingeLeverOuterProfile();
1726           HingeLeverInnerProfile();
1727         }
1728         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1729       }
1730     }
1731   }
1732
1733   translate([20,-30]) {
1734     %EdgeProfile();
1735     %LidEdgeProfile();
1736     //translate([0,0,1]) CatchCutProfile();
1737     translate([0,0,+1]) color("red")
1738       difference(){ EdgeProfile(); CatchCutProfile(); }
1739   }
1740
1741   translate([40,-30]) {
1742     difference(){
1743       LidEdgeProfile();
1744       translate(prlp10)
1745         PropProfile(10, 1, 0);
1746     }
1747     translate(prlp10)
1748       PropProfile(15, 0);
1749   }
1750   translate([60,-30]) {
1751     PropAggregateProfile();
1752   }
1753 }
1754
1755 //EdgeProfile();
1756 //KeeperProfile();
1757 //CaseBase();
1758 //%Case();
1759 //Keeper();
1760 //LidEdgeProfile();
1761 //KeeperProfile();
1762 //DemoProfiles();
1763 //PropRecess();