fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25
  26 case_th_bottom = 2.5;
  27 case_th_lid = 2.5;
  28 case_th_side = 2;
  29 case_th_lip = 1.2;
  30
  31 case_struts_count = 6;
  32 case_struts_solid_below = 1.00;
  33 case_struts_solid_above = 0.75;
  34 case_struts_width = 0.10;
  35
  36 keeper_th_z = 0.75;
  37 keeper_th_x = 0.75;
  38 keeper_inner_width = 2.75;
  39 keeper_inner_height = 2.75;
  40 keeper_slant_slope = 2; // larger means steeper
  41
  42 keeper_gap_z_top = 0.25;
  43 keeper_gap_z_bot = 0.75;
  44 keeper_gap_x     = 0.25;
  45 keeper_gap_x_holes = 0.75;
  46
  47 case_lip = 1.25;
  48
  49 lid_gap_x = 0.25;
  50 lid_gap_z = 0.25;
  51 lid_lip = 1.75;
  52
  53 $fa = 5;
  54 $fs = 0.1;
  55
  56 button_l_fudge = 4.4;
  57 buttonishleg_default_l_is_fudge = 10;
  58
  59 strut_min_at_end = 1.5;
  60
  61 // ---------- calculated ----------
  62
  63 phone_width =  (phone + bumper*2)[0];
  64 phone_height = (phone + bumper*2)[1];
  65
  66 inside_br = [phone_width, -phone_height];
  67
  68 //echo(camera_pos_tl + bumper,
  69 //     camera_pos_br + bumper);
  70
  71 // ----- could be changed -----
  72 lid_buttoncover_gap = lid_gap_x;
  73 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  74
  75 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  76
  77 //lid_lip_overlap_width xxx bad name = ;
  78 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  79
  80 epp0 = [0,0];
  81 epp1 = [0, -phone_edge_thick];
  82 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  83 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  84 epp3 = epp2i + [10, 0];
  85 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  86 epp4 = epp5 + [-1,0] * case_th_side;
  87
  88 kppe = [0,0];
  89 kppd = kppe + [1,0] * keeper_inner_width;
  90 kppc = kppd + [0,1] * keeper_th_z;
  91 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  92 kppf = kppe - [0,1] * keeper_inner_height;
  93 kppa = [ kppb[0], kppf[1] ];
  94
  95 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  96 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  97
  98 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  99
 100 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 101 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 102
 103 // button profile
 104 bppM = epp4 + [0,5];
 105 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 106 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 107 bppS = [ epp1[0], bppR[1] ];
 108 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 109 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 110 bppO = [ bppN[0], bppP[1] ];
 111 bppL = lpp10 + [5,0];
 112 bppK = [ bppL[0], bppN[1] ];
 113 bppJ = [ bppN[0], bppL[1] ];
 114
 115 module rectfromto(a,b) {
 116   ab = b - a;
 117   translate([min(a[0], b[0]), min(a[1], b[1])])
 118     square([abs(ab[0]), abs(ab[1])]);
 119 }
 120 module circleat(c,r) { translate(c) circle(r); }
 121
 122 module KeeperProfile(slant=0){
 123   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 124   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 125 }
 126
 127 module EdgeProfile(){
 128   difference(){
 129     hull(){
 130       translate(epp3) square(case_th_bottom*2, center=true);
 131       circleat(epp2o, r=case_th_bottom);
 132       circleat(epp1, r=case_th_side);
 133       rectfromto(epp0, epp4);
 134     }
 135     polygon([ epp5 + [0,10],
 136               epp1,
 137               epp2i,
 138               epp3 + [10,0] ]);
 139   }
 140 }
 141
 142 module LidEdgeProfile(){
 143   polygon([ lpp10,
 144             lpp11,
 145             lpp12,
 146             lpp13,
 147             lpp13 + [10, 0],
 148             lpp10 + [10, 0]
 149             ]);
 150   intersection(){
 151     circleat(lpp12, r=lp_r12);
 152     rectfromto( lpp12 + [-10,   0],
 153                 lpp12 + [+10, +10] );
 154   }
 155 }
 156
 157 module ButtonCoverProfile(){
 158   intersection(){
 159     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 160     hull(){
 161       EdgeProfile();
 162       LidEdgeProfile();
 163     }
 164   }
 165 }
 166
 167 module ButtonPlan(l, deep, cut){
 168   epsilon =
 169     (cut  ? 0 : lid_buttoncover_gap);
 170
 171   delta =
 172     (deep ? lid_buttoncover_overlap : 0);
 173
 174   C = [0,0]; // by definition
 175   T = [ 0, epp4[1] ];
 176   G = T + [0,10];
 177
 178   B0 = C + [0,-1] * button_cutout_depth;
 179   B1 = B0 + [0,1] * epsilon;
 180
 181   r0 = 0.5 * (T[1] - B0[1]);
 182   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 183   H = A + [0,-1] * delta;
 184
 185   D = A + [-2,0] * r0;
 186   F = D + [0,10];
 187
 188   E0 = 0.5 * (D + A);
 189   E1 = E0 + [1,0] * epsilon;
 190
 191   I0 = [ E0[0], H[1] ];
 192   I1 = [ E1[0], H[1] ];
 193
 194   hull(){
 195     for (m=[0,1]) mirror([m,0])
 196       circleat(H, r0 - epsilon);
 197   }
 198   for (m=[0,1]) mirror([m,0]) {
 199     difference(){
 200       polygon([ E1,
 201                 I1,
 202                 H,
 203                 B1,
 204                 G,
 205                 F,
 206                 D
 207                 ]);
 208       circleat(D, r0 + epsilon);
 209     }
 210   }
 211 }
 212
 213 module CaseBase_rhsflip(yn=[0,1]) {
 214   for ($rhsflip=yn) {
 215     translate([phone_width/2, 0, 0])
 216       mirror([$rhsflip,0,0])
 217       translate([-phone_width/2, 0, 0])
 218       children();
 219   }
 220 }
 221
 222 module CaseBase_botflip() {
 223   for (bot=[0,1]) {
 224     translate([0, -phone_height/2, 0])
 225       mirror([0, bot, 0])
 226       translate([0, phone_height/2, 0])
 227       children();
 228   }
 229 }
 230
 231 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 232   // sides
 233   CaseBase_rhsflip(){
 234     translate([0, -phone_cnr_rad, 0])
 235       rotate([90,0,0])
 236       linear_extrude(height = phone_height - phone_cnr_rad*2)
 237       children(0);
 238   }
 239   // corners
 240   CaseBase_rhsflip() CaseBase_botflip() {
 241     translate([+1,-1] * phone_cnr_rad)
 242       intersection(){
 243         rotate_extrude()
 244           intersection(){
 245             mirror([1,0,0])
 246               translate([-1,0] * phone_cnr_rad)
 247               children(0);
 248             rectfromto([0,-20],[10,20]);
 249           }
 250         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 251           cube([10,10,40]);
 252       }
 253   }
 254   // top and bottom
 255   CaseBase_botflip(){
 256     translate([ phone_width - phone_cnr_rad, 0,0 ])
 257       rotate([90,0,-90])
 258       linear_extrude(height = phone_width - phone_cnr_rad*2)
 259       children(0);
 260   }
 261   // fill
 262   translate([0,0, fill_zstart])
 263     mirror([0,0, fill_downwards])
 264     linear_extrude(height = fill_th)
 265     rectfromto([+1,-1] * phone_cnr_rad,
 266                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 267 }
 268
 269 module CaseAperture(pos, dia) { // pass $fn too
 270   theta = 180/$fn;
 271   translate([ pos[0] + bumper[0],
 272               -epp2i[0],
 273               -pos[1] ])
 274     rotate([-90, theta, 0])
 275     cylinder(r = jack_dia/2 / cos(theta),
 276              h = 60);
 277 }
 278
 279 module SideButton(y, y_ref_sign, l){
 280   // y_ref_sign:
 281   //   +1  measured from top    of actual phone to top    of button
 282   //   -1  measured from bottom of actual phone to bottom of button
 283   //    0  y is centre of button in coordinate system
 284   $button_l= l;
 285   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 286           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 287           y;
 288   echo(eff_y);
 289   translate([0, eff_y, 0])
 290     children();
 291 }
 292
 293 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 294   $button_leg_only = true;
 295   SideButton(y, y_ref_sign, l) children();
 296 }
 297
 298 module Buttons(){
 299   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 300   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 301   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 302   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 303 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 304 }
 305
 306 module Struts(x_start, z_min, th){
 307   // if th is negative, starts at z_min and works towards -ve z
 308   // and object should then be printed other way up
 309   for (i= [1 : 1 : case_struts_count]) {
 310     translate([0,
 311                0,
 312                z_min])
 313       mirror([0,0, th<0 ? 1 : 0])
 314       translate([0,
 315                  -phone_height * i / (case_struts_count+1),
 316                  case_struts_solid_below])
 317       linear_extrude(height= abs(th)
 318                      -(case_struts_solid_below+case_struts_solid_above))
 319       rectfromto([               x_start, -0.5 * case_struts_width ],
 320                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 321   }
 322 }
 323
 324 module CaseBase(){
 325   AroundEdges(epp3[1], case_th_bottom, 1)
 326     EdgeProfile();
 327 }
 328
 329 module Case(){ ////toplevel
 330   difference(){
 331     union(){
 332       CaseBase();
 333
 334       // ledge (fixed keeper)
 335       intersection(){
 336         rotate([90, 0, 0])
 337           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 338           KeeperProfile(1);
 339
 340         // outline of the whole case, to stop it protruding
 341         translate([0,0, -25])
 342           linear_extrude(height = 50)
 343           hull()
 344           // CaseBase_rhsflip() // actually, we only care about the LH
 345           CaseBase_botflip()
 346           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 347       }
 348     }
 349
 350     // slot for keeper
 351     CaseBase_rhsflip(1)
 352       translate([0, -phone_cnr_rad, 0])
 353       rotate([90, 0, 0])
 354       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 355       minkowski(){
 356         KeeperProfile();
 357         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 358                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 359       }
 360
 361     // front camera
 362     CaseBase_rhsflip([1])
 363       mirror([0, 0, 1])
 364       linear_extrude(height = 20)
 365       mirror([0, 1, 0])
 366       translate(bumper)
 367       rectfromto(camera_pos_tl, camera_pos_br);
 368
 369     // struts (invisible, because they're buried in the case)
 370     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 371
 372     Buttons(){
 373       mirror([1,0,0])
 374         rotate([90,0,90]) {
 375           intersection(){
 376             translate([0,0,-10])
 377               linear_extrude(height= 20)
 378               ButtonPlan($button_l, 0,1);
 379             if ($button_leg_only)
 380               rotate([-90,90,0])
 381                 translate([phone_width/2, -400, kppe[1]])
 382                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 383           }
 384           translate([0,0, -bppR[0]])
 385             linear_extrude(height= 20)
 386             ButtonPlan($button_l, 1,1);
 387         }
 388     }
 389
 390     // apertures along top edge
 391     CaseAperture(jack_pos, jack_dia, $fn=8);
 392   }
 393 }
 394
 395 module Lid(){ ////toplevel
 396   difference(){
 397     union(){
 398       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 399         LidEdgeProfile();
 400
 401       // button covers
 402       Buttons(){
 403         intersection(){
 404           rotate([90,0,90])
 405             translate([0,0,-10])
 406             linear_extrude(height= 20)
 407             ButtonPlan($button_l, 1,0);
 408           rotate([90,0,0])
 409              translate([0,0,-100])
 410             linear_extrude(height= 200)
 411             ButtonCoverProfile();
 412         }
 413       }
 414     }
 415     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 416   }
 417 }
 418
 419 module TestLength(){ ////toplevel
 420   intersection(){
 421     Case();
 422     translate([-30, -200, -20])
 423     cube([30 + 15, 250, 40]);
 424   }
 425 }
 426
 427 module TestSelectWidth(){
 428   translate([-30, -(phone_height - 25), -20])
 429     mirror([0, 1, 0])
 430     cube([200, 50, 40]);
 431 }
 432
 433 module TestWidth(){ ////toplevel
 434   intersection(){
 435     Case();
 436     TestSelectWidth();
 437   }
 438 }
 439
 440 module TestLidWidthPrint(){ ////toplevel
 441   rotate([0,180.0]) intersection(){
 442     Lid();
 443     TestSelectWidth();
 444   }
 445 }
 446
 447 module TestSelectCamera(){
 448   CaseBase_rhsflip(1)
 449     translate([0,0,-25])
 450     linear_extrude(height = 50)
 451     mirror([0, 1, 0])
 452     rectfromto([-20, -20],
 453                camera_pos_br + bumper + [ 5, 5 ]);
 454 }
 455
 456 module TestCamera(){ ////toplevel
 457   intersection(){
 458     Case();
 459     TestSelectCamera();
 460   }
 461 }
 462
 463 module TestLidByCamera(){ ////toplevel
 464   intersection(){
 465     Lid();
 466     TestSelectCamera();
 467   }
 468 }
 469
 470 module TestLidByCameraPrint(){ ////toplevel
 471   rotate([180,0,0]) TestLidByCamera();
 472 }
 473
 474 module DemoByCamera(){ ////toplevel
 475   color("blue") TestLidByCamera();
 476   color("red")  TestCamera();
 477 }
 478
 479 module OneKeeper(){ ////toplevel
 480   translate([0, -phone_cnr_rad, 0])
 481     rotate([90, 0, 0])
 482     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 483     KeeperProfile();
 484 }
 485
 486 module OneKeeperPrint(){ ////toplevel
 487   rotate([0,180,0])
 488     OneKeeper();
 489 }
 490
 491 module LidPrint(){ ////toplevel
 492   rotate([0,180,0])
 493     Lid();
 494 }
 495
 496 module TestSelectFrame(){
 497   include = [1,-1] * (epp2i[0] + 4);
 498
 499   difference(){
 500     cube(1000, center=true);
 501     translate([0,0, -100])
 502       linear_extrude(height=200)
 503       rectfromto(include,  inside_br - include);
 504   }
 505 }
 506
 507 module TestFrameCase(){ ////toplevel
 508   intersection(){
 509     Case();
 510     union(){
 511       TestSelectFrame();
 512       TestSelectCamera();
 513     }
 514   }
 515 }
 516
 517 module TestFrameLidPrint(){ ////toplevel
 518   rotate([0,0,180]) intersection(){
 519     Lid();
 520     TestSelectFrame();
 521   }
 522 }
 523
 524 module Keeper(){ ////toplevel
 525   CaseBase_rhsflip()
 526     OneKeeper();
 527 }
 528
 529 module ButtonPlanForDemo(z, deep, cut){
 530   translate([0,0,z])
 531     ButtonPlan(8, deep, cut);
 532 }
 533
 534 module DemoProfiles(){ ////toplevel
 535   LidEdgeProfile();
 536   %EdgeProfile();
 537   KeeperProfile();
 538   translate([0,0,-1]) color("black") KeeperProfile(1);
 539
 540   translate([20,0]) {
 541     LidEdgeProfile();
 542     %EdgeProfile();
 543
 544     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 545
 546     color("blue") ButtonCoverProfile();
 547     color("red") {
 548       rectfromto(bppQ, demopoint_QR);
 549       rectfromto(bppR, demopoint_QR);
 550     }
 551   }
 552
 553   translate([-20,0]) {
 554     color("black") ButtonPlanForDemo(-2, 0,1);
 555     color("red" )  ButtonPlanForDemo(-4, 1,1);
 556     color("blue")  ButtonPlanForDemo(-6, 1,0);
 557   }
 558 }
 559
 560 //EdgeProfile();
 561 //KeeperProfile();
 562 //CaseBase();
 563 //%Case();
 564 //Keeper();
 565 //LidEdgeProfile();
 566 //KeeperProfile();
 567 //DemoProfiles();