fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25 noisecancelmic_dia = 1.75;
  26
  27 case_th_bottom = 2.5;
  28 case_th_lid = 2.5;
  29 case_th_side = 2;
  30 case_th_lip = 1.2;
  31
  32 case_struts_count = 6;
  33 case_struts_solid_below = 1.00;
  34 case_struts_solid_above = 0.75;
  35 case_struts_width = 0.10;
  36
  37 keeper_th_z = 0.75;
  38 keeper_th_x = 0.75;
  39 keeper_inner_width = 2.75;
  40 keeper_inner_height = 2.75;
  41 keeper_slant_slope = 2; // larger means steeper
  42
  43 keeper_gap_z_top = 0.25;
  44 keeper_gap_z_bot = 0.75;
  45 keeper_gap_x     = 0.25;
  46 keeper_gap_x_holes = 0.75;
  47
  48 case_lip = 1.25;
  49
  50 lid_gap_x = 0.25;
  51 lid_gap_z = 0.25;
  52 lid_lip = 1.75;
  53
  54 $fa = 5;
  55 $fs = 0.1;
  56
  57 button_l_fudge = 4.4;
  58 buttonishleg_default_l_is_fudge = 10;
  59
  60 strut_min_at_end = 1.5;
  61
  62 // ---------- calculated ----------
  63
  64 phone_width =  (phone + bumper*2)[0];
  65 phone_height = (phone + bumper*2)[1];
  66
  67 inside_br = [phone_width, -phone_height];
  68
  69 //echo(camera_pos_tl + bumper,
  70 //     camera_pos_br + bumper);
  71
  72 // ----- could be changed -----
  73 lid_buttoncover_gap = lid_gap_x;
  74 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  75
  76 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  77
  78 //lid_lip_overlap_width xxx bad name = ;
  79 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  80
  81 epp0 = [0,0];
  82 epp1 = [0, -phone_edge_thick];
  83 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  84 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  85 epp3 = epp2i + [10, 0];
  86 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  87 epp4 = epp5 + [-1,0] * case_th_side;
  88
  89 kppe = [0,0];
  90 kppd = kppe + [1,0] * keeper_inner_width;
  91 kppc = kppd + [0,1] * keeper_th_z;
  92 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  93 kppf = kppe - [0,1] * keeper_inner_height;
  94 kppa = [ kppb[0], kppf[1] ];
  95
  96 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  97 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  98
  99 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 100
 101 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 102 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 103
 104 // button profile
 105 bppM = epp4 + [0,5];
 106 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 107 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 108 bppS = [ epp1[0], bppR[1] ];
 109 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 110 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 111 bppO = [ bppN[0], bppP[1] ];
 112 bppL = lpp10 + [5,0];
 113 bppK = [ bppL[0], bppN[1] ];
 114 bppJ = [ bppN[0], bppL[1] ];
 115
 116 module rectfromto(a,b) {
 117   ab = b - a;
 118   translate([min(a[0], b[0]), min(a[1], b[1])])
 119     square([abs(ab[0]), abs(ab[1])]);
 120 }
 121 module circleat(c,r) { translate(c) circle(r); }
 122 module linextr(z0,z1) {
 123   translate([0,0,z0])
 124     linear_extrude(height=z1-z0)
 125     children();
 126 }
 127
 128 module KeeperProfile(slant=0){
 129   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 130   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 131 }
 132
 133 module EdgeProfile(){
 134   difference(){
 135     hull(){
 136       translate(epp3) square(case_th_bottom*2, center=true);
 137       circleat(epp2o, r=case_th_bottom);
 138       circleat(epp1, r=case_th_side);
 139       rectfromto(epp0, epp4);
 140     }
 141     polygon([ epp5 + [0,10],
 142               epp1,
 143               epp2i,
 144               epp3 + [10,0] ]);
 145   }
 146 }
 147
 148 module LidEdgeProfile(){
 149   polygon([ lpp10,
 150             lpp11,
 151             lpp12,
 152             lpp13,
 153             lpp13 + [10, 0],
 154             lpp10 + [10, 0]
 155             ]);
 156   intersection(){
 157     circleat(lpp12, r=lp_r12);
 158     rectfromto( lpp12 + [-10,   0],
 159                 lpp12 + [+10, +10] );
 160   }
 161 }
 162
 163 module ButtonCoverProfile(){
 164   intersection(){
 165     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 166     hull(){
 167       EdgeProfile();
 168       LidEdgeProfile();
 169     }
 170   }
 171 }
 172
 173 module ButtonPlan(l, deep, cut){
 174   epsilon =
 175     (cut  ? 0 : lid_buttoncover_gap);
 176
 177   delta =
 178     (deep ? lid_buttoncover_overlap : 0);
 179
 180   C = [0,0]; // by definition
 181   T = [ 0, epp4[1] ];
 182   G = T + [0,10];
 183
 184   B0 = C + [0,-1] * button_cutout_depth;
 185   B1 = B0 + [0,1] * epsilon;
 186
 187   r0 = 0.5 * (T[1] - B0[1]);
 188   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 189   H = A + [0,-1] * delta;
 190
 191   D = A + [-2,0] * r0;
 192   F = D + [0,10];
 193
 194   E0 = 0.5 * (D + A);
 195   E1 = E0 + [1,0] * epsilon;
 196
 197   I0 = [ E0[0], H[1] ];
 198   I1 = [ E1[0], H[1] ];
 199
 200   hull(){
 201     for (m=[0,1]) mirror([m,0])
 202       circleat(H, r0 - epsilon);
 203   }
 204   for (m=[0,1]) mirror([m,0]) {
 205     difference(){
 206       polygon([ E1,
 207                 I1,
 208                 H,
 209                 B1,
 210                 G,
 211                 F,
 212                 D
 213                 ]);
 214       circleat(D, r0 + epsilon);
 215     }
 216   }
 217 }
 218
 219 module CaseBase_rhsflip(yn=[0,1]) {
 220   for ($rhsflip=yn) {
 221     translate([phone_width/2, 0, 0])
 222       mirror([$rhsflip,0,0])
 223       translate([-phone_width/2, 0, 0])
 224       children();
 225   }
 226 }
 227
 228 module CaseBase_botflip(yn=[0,1]) {
 229   for ($botflip=yn) {
 230     translate([0, -phone_height/2, 0])
 231       mirror([0, $botflip, 0])
 232       translate([0, phone_height/2, 0])
 233       children();
 234   }
 235 }
 236
 237 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 238   // sides
 239   CaseBase_rhsflip(){
 240     translate([0, -phone_cnr_rad, 0])
 241       rotate([90,0,0])
 242       linear_extrude(height = phone_height - phone_cnr_rad*2)
 243       children(0);
 244   }
 245   // corners
 246   CaseBase_rhsflip() CaseBase_botflip() {
 247     translate([+1,-1] * phone_cnr_rad)
 248       intersection(){
 249         rotate_extrude()
 250           intersection(){
 251             mirror([1,0,0])
 252               translate([-1,0] * phone_cnr_rad)
 253               children(0);
 254             rectfromto([0,-20],[10,20]);
 255           }
 256         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 257           cube([10,10,40]);
 258       }
 259   }
 260   // top and bottom
 261   CaseBase_botflip(){
 262     translate([ phone_width - phone_cnr_rad, 0,0 ])
 263       rotate([90,0,-90])
 264       linear_extrude(height = phone_width - phone_cnr_rad*2)
 265       children(0);
 266   }
 267   // fill
 268   translate([0,0, fill_zstart])
 269     mirror([0,0, fill_downwards])
 270     linear_extrude(height = fill_th)
 271     rectfromto([+1,-1] * phone_cnr_rad,
 272                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 273 }
 274
 275 module CaseAperture(pos, dia, $fn) {
 276   theta = 180/$fn;
 277   translate([ pos[0] + bumper[0],
 278               -epp2i[0],
 279               -pos[1] ])
 280     rotate([-90, theta, 0])
 281     cylinder(r = dia/2 / cos(theta),
 282              h = 60);
 283 }
 284
 285 module SideButton(y, y_ref_sign, l){
 286   // y_ref_sign:
 287   //   +1  measured from top    of actual phone to top    of button
 288   //   -1  measured from bottom of actual phone to bottom of button
 289   //    0  y is centre of button in coordinate system
 290   $button_l= l;
 291   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 292           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 293           y;
 294   echo(eff_y);
 295   translate([0, eff_y, 0])
 296     children();
 297 }
 298
 299 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 300   $button_leg_only = true;
 301   SideButton(y, y_ref_sign, l) children();
 302 }
 303
 304 module Buttons(){
 305   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 306   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 307   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 308   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 309 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 310 }
 311
 312 module Struts(x_start, z_min, th){
 313   // if th is negative, starts at z_min and works towards -ve z
 314   // and object should then be printed other way up
 315   for (i= [1 : 1 : case_struts_count]) {
 316     translate([0,
 317                0,
 318                z_min])
 319       mirror([0,0, th<0 ? 1 : 0])
 320       translate([0,
 321                  -phone_height * i / (case_struts_count+1),
 322                  case_struts_solid_below])
 323       linear_extrude(height= abs(th)
 324                      -(case_struts_solid_below+case_struts_solid_above))
 325       rectfromto([               x_start, -0.5 * case_struts_width ],
 326                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 327   }
 328 }
 329
 330 module CaseBase(){
 331   AroundEdges(epp3[1], case_th_bottom, 1)
 332     EdgeProfile();
 333 }
 334
 335 module Case(){ ////toplevel
 336   difference(){
 337     union(){
 338       CaseBase();
 339
 340       // ledge (fixed keeper)
 341       intersection(){
 342         rotate([90, 0, 0])
 343           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 344           KeeperProfile(1);
 345
 346         // outline of the whole case, to stop it protruding
 347         translate([0,0, -25])
 348           linear_extrude(height = 50)
 349           hull()
 350           // CaseBase_rhsflip() // actually, we only care about the LH
 351           CaseBase_botflip()
 352           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 353       }
 354     }
 355
 356     // slot for keeper
 357     CaseBase_rhsflip(1)
 358       translate([0, -phone_cnr_rad, 0])
 359       rotate([90, 0, 0])
 360       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 361       minkowski(){
 362         KeeperProfile();
 363         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 364                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 365       }
 366
 367     // front camera
 368     CaseBase_rhsflip([1])
 369       mirror([0, 0, 1])
 370       linear_extrude(height = 20)
 371       mirror([0, 1, 0])
 372       translate(bumper)
 373       rectfromto(camera_pos_tl, camera_pos_br);
 374
 375     // struts (invisible, because they're buried in the case)
 376     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 377
 378     Buttons(){
 379       mirror([1,0,0])
 380         rotate([90,0,90]) {
 381           intersection(){
 382             translate([0,0,-10])
 383               linear_extrude(height= 20)
 384               ButtonPlan($button_l, 0,1);
 385             if ($button_leg_only)
 386               rotate([-90,90,0])
 387                 translate([phone_width/2, -400, kppe[1]])
 388                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 389           }
 390           translate([0,0, -bppR[0]])
 391             linear_extrude(height= 20)
 392             ButtonPlan($button_l, 1,1);
 393         }
 394     }
 395
 396     // apertures along top edge
 397     CaseAperture(jack_pos, jack_dia, 8);
 398     CaseBase_rhsflip([1])
 399       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 400   }
 401 }
 402
 403 module Lid(){ ////toplevel
 404   difference(){
 405     union(){
 406       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 407         LidEdgeProfile();
 408
 409       // button covers
 410       Buttons(){
 411         intersection(){
 412           rotate([90,0,90])
 413             translate([0,0,-10])
 414             linear_extrude(height= 20)
 415             ButtonPlan($button_l, 1,0);
 416           rotate([90,0,0])
 417              translate([0,0,-100])
 418             linear_extrude(height= 200)
 419             ButtonCoverProfile();
 420         }
 421       }
 422     }
 423     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 424   }
 425 }
 426
 427 module TestLength(){ ////toplevel
 428   intersection(){
 429     Case();
 430     translate([-30, -200, -20])
 431     cube([30 + 15, 250, 40]);
 432   }
 433 }
 434
 435 module TestSelectWidth(){
 436   translate([-30, -(phone_height - 25), -20])
 437     mirror([0, 1, 0])
 438     cube([200, 50, 40]);
 439 }
 440
 441 module TestWidth(){ ////toplevel
 442   intersection(){
 443     Case();
 444     TestSelectWidth();
 445   }
 446 }
 447
 448 module TestLidWidthPrint(){ ////toplevel
 449   rotate([0,180.0]) intersection(){
 450     Lid();
 451     TestSelectWidth();
 452   }
 453 }
 454
 455 module TestSelectCamera(){
 456   CaseBase_rhsflip(1)
 457     translate([0,0,-25])
 458     linear_extrude(height = 50)
 459     mirror([0, 1, 0])
 460     rectfromto([-20, -20],
 461                camera_pos_br + bumper + [ 5, 5 ]);
 462 }
 463
 464 module TestCamera(){ ////toplevel
 465   intersection(){
 466     Case();
 467     TestSelectCamera();
 468   }
 469 }
 470
 471 module TestLidByCamera(){ ////toplevel
 472   intersection(){
 473     Lid();
 474     TestSelectCamera();
 475   }
 476 }
 477
 478 module TestLidByCameraPrint(){ ////toplevel
 479   rotate([180,0,0]) TestLidByCamera();
 480 }
 481
 482 module DemoByCamera(){ ////toplevel
 483   color("blue") TestLidByCamera();
 484   color("red")  TestCamera();
 485 }
 486
 487 module OneKeeper(){ ////toplevel
 488   translate([0, -phone_cnr_rad, 0])
 489     rotate([90, 0, 0])
 490     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 491     KeeperProfile();
 492 }
 493
 494 module OneKeeperPrint(){ ////toplevel
 495   rotate([0,180,0])
 496     OneKeeper();
 497 }
 498
 499 module LidPrint(){ ////toplevel
 500   rotate([0,180,0])
 501     Lid();
 502 }
 503
 504 module TestSelectFrame(){
 505   include = [1,-1] * (epp2i[0] + 4);
 506
 507   difference(){
 508     cube(1000, center=true);
 509     translate([0,0, -100])
 510       linear_extrude(height=200)
 511       rectfromto(include,  inside_br - include);
 512   }
 513 }
 514
 515 module TestFrameCase(){ ////toplevel
 516   intersection(){
 517     Case();
 518     union(){
 519       TestSelectFrame();
 520       TestSelectCamera();
 521     }
 522   }
 523 }
 524
 525 module TestFrameLidPrint(){ ////toplevel
 526   rotate([0,0,180]) intersection(){
 527     Lid();
 528     TestSelectFrame();
 529   }
 530 }
 531
 532 module Keeper(){ ////toplevel
 533   CaseBase_rhsflip()
 534     OneKeeper();
 535 }
 536
 537 module ButtonPlanForDemo(z, deep, cut){
 538   translate([0,0,z])
 539     ButtonPlan(8, deep, cut);
 540 }
 541
 542 module DemoProfiles(){ ////toplevel
 543   LidEdgeProfile();
 544   %EdgeProfile();
 545   KeeperProfile();
 546   translate([0,0,-1]) color("black") KeeperProfile(1);
 547
 548   translate([20,0]) {
 549     LidEdgeProfile();
 550     %EdgeProfile();
 551
 552     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 553
 554     color("blue") ButtonCoverProfile();
 555     color("red") {
 556       rectfromto(bppQ, demopoint_QR);
 557       rectfromto(bppR, demopoint_QR);
 558     }
 559   }
 560
 561   translate([-20,0]) {
 562     color("black") ButtonPlanForDemo(-2, 0,1);
 563     color("red" )  ButtonPlanForDemo(-4, 1,1);
 564     color("blue")  ButtonPlanForDemo(-6, 1,0);
 565   }
 566 }
 567
 568 //EdgeProfile();
 569 //KeeperProfile();
 570 //CaseBase();
 571 //%Case();
 572 //Keeper();
 573 //LidEdgeProfile();
 574 //KeeperProfile();
 575 //DemoProfiles();