fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 phone_cnr_rad = 6.0;
  12
  13 button_cutout_depth = 9;
  14
  15 phone_edge_thick = 9.0;
  16 phone_total_thick = 12.0;
  17 phone_backside_slope_inner = 1.5; // larger means shallower
  18 phone_backside_slope_outer = 1.0; // larger means shallower
  19
  20 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  21 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  22
  23 jack_pos = [ 13.92, 7.96 ];
  24 jack_dia = 9.1 + .5; // some jack I had lying around
  25
  26 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  27 noisecancelmic_dia = 1.75;
  28
  29 fingerpushhole_dias = [ 15, 18 ];
  30
  31 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  32 rearspeaker_size   = [  3.76,  7.36 ];
  33
  34 microusb_above = 3.27 - 0.25;
  35 microusb_below = 0.0;
  36 microusb_width = 16.12 + 0.25;
  37
  38 case_th_bottom = 2.5;
  39 case_th_lid = 2.5;
  40 case_th_side = 2;
  41 case_th_lip = 1.2;
  42
  43 case_struts_count = 6;
  44 case_struts_solid_below = 1.00;
  45 case_struts_solid_above = 0.75;
  46 case_struts_width = 0.10;
  47
  48 keeper_th_z = 0.75;
  49 keeper_th_x = 0.75;
  50 keeper_inner_width = 2.75;
  51 keeper_inner_height = 2.75;
  52 keeper_slant_slope = 2; // larger means steeper
  53
  54 keeper_gap_z_top = 0.25;
  55 keeper_gap_z_bot = 0.75;
  56 keeper_gap_x     = 0.25;
  57 keeper_gap_x_holes = 0.75;
  58
  59 case_lip = 1.25;
  60
  61 lid_gap_x = 0.25;
  62 lid_gap_z = 0.25;
  63 lid_lip = 1.75;
  64
  65 catch_slop = 0.25;
  66
  67 foldover_gap = 0.50;
  68 foldover_lever_gap = 0.50;
  69
  70 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  71 hingescrew_shaft_len = 12;
  72 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  73 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  74 hingescrew_head_th = 1.38 + 0.75;
  75 hingescrew_head_dia = 3.92;
  76 lever_cover_th = 0.75;
  77 hingemount_th = 2.5;
  78
  79 $fa = 5;
  80 $fs = 0.1;
  81
  82 button_l_fudge = 4.4;
  83 buttonishleg_default_l_is_fudge = 10;
  84
  85 hinge_base_slope = 1.5; // bigger is steeper
  86
  87 strut_min_at_end = 1.5;
  88
  89 hinge_x_gap = 0.125;
  90 hinge_x_postscrew_gap = 0.75;
  91 hinge_x_arms_gap = 0.35;
  92 hinge_r_arms_gap = 0.55;
  93
  94 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  95
  96 catch_len = 7.5;
  97 catch_width = 15;
  98 catch_thickness = 1.0;
  99 catch_side_gap = 0.75; // each side
 100
 101 catch_depth = 1.25;
 102 catch_height = 0.35;
 103 catch_finger_height = 1.5;
 104 catch_finger_depth = 2.5;
 105
 106 // ---------- calculated ----------
 107
 108 phone_width =  (phone + bumper*2)[0];
 109 phone_height = (phone + bumper*2)[1];
 110
 111 inside_br = [phone_width, -phone_height];
 112
 113 //echo(camera_pos_tl + bumper,
 114 //     camera_pos_br + bumper);
 115
 116 // ----- could be changed -----
 117 lid_buttoncover_gap = lid_gap_x;
 118 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 119
 120 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 121
 122 //lid_lip_overlap_width xxx bad name = ;
 123 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 124
 125 epp0 = [0,0];
 126 epp1 = [0, -phone_edge_thick];
 127 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 128 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 129 epp3 = epp2i + [10, 0];
 130 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 131 epp4 = epp5 + [-1,0] * case_th_side;
 132
 133 kppe = [0,0];
 134 kppd = kppe + [1,0] * keeper_inner_width;
 135 kppc = kppd + [0,1] * keeper_th_z;
 136 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 137 kppf = kppe - [0,1] * keeper_inner_height;
 138 kppa = [ kppb[0], kppf[1] ];
 139
 140 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 141 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 142
 143 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 144
 145 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 146 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 147
 148 // button profile
 149 bppM = epp4 + [0,5];
 150 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 151 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 152 bppS = [ epp1[0], bppR[1] ];
 153 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 154 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 155 bppO = [ bppN[0], bppP[1] ];
 156 bppL = lpp10 + [5,0];
 157 bppK = [ bppL[0], bppN[1] ];
 158 bppJ = [ bppN[0], bppL[1] ];
 159
 160 // hinge plan
 161 hp_rn = hingescrew_nut_dia/2;
 162 hp_r2_min = hp_rn + lever_cover_th;
 163 hp_rs = hingescrew_shaft_dia/2;
 164 hp_r1_min = hp_rs + hingemount_th;
 165
 166 hp_r1 = max(hp_r1_min, hp_r2_min);
 167 hp_r2 = hp_r1;
 168
 169 hppU = lpp13;
 170 hppS = epp2o + [0,-1] * case_th_bottom;
 171 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 172
 173 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 174          0.5 * (hppU + hppS)[1] ];
 175 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 176 hppB = hppT + [0,-1] * hp_k;
 177
 178 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 179 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 180 hppE = [ hppE_x, hppE_y ];
 181
 182 // hinge elevation x coords
 183
 184 hingescrew_portion_len =
 185   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 186
 187 hex20 = max(epp2o[0],
 188             phone_cnr_rad,
 189             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 190 hex21 = hex20 + hingescrew_portion_len;
 191 hex22 = hex21 + hinge_x_gap;
 192 hex23 = hex22 + hingescrew_portion_len
 193   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 194 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 195 echo(hex20, hex21, hex22, hex23, hex24);
 196 echo(hingescrew_portion_len);
 197
 198 // catch
 199
 200 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 201 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 202 cppB = [ epp0[0], cppA[1] ];
 203 cppP = [ epp4[0], cppJ[1] ];
 204
 205 cppS = cppJ + [0,-1] * catch_len;
 206 cppD = [ cppA[0], cppS[1] + catch_slop ];
 207 cppC = [ cppB[0], cppD[1] ];
 208 cppT = cppS + [1,0] * catch_depth;
 209 cppU = cppT + [0,-1] * catch_height;
 210 cppV = [ cppS[0], cppU[1] - catch_depth ];
 211
 212 cppR = 0.5*(cppP + cppJ);
 213
 214 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 215 cppQ = [ cppR[0],
 216          cppV[1] - (catch_finger_height - cp_rQ) ];
 217 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 218
 219 // ---------- modules ----------
 220
 221 module KeeperProfile(slant=0){
 222   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 223   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 224 }
 225
 226 module EdgeProfile(){
 227   difference(){
 228     hull(){
 229       translate(epp3) square(case_th_bottom*2, center=true);
 230       circleat(epp2o, r=case_th_bottom);
 231       circleat(epp1, r=case_th_side);
 232       rectfromto(epp0, epp4);
 233     }
 234     polygon([ epp5 + [0,10],
 235               epp1,
 236               epp2i,
 237               epp3 + [10,0] ]);
 238   }
 239 }
 240
 241 module LidEdgeProfile(){
 242   polygon([ lpp10,
 243             lpp11,
 244             lpp12,
 245             lpp13,
 246             lpp13 + [10, 0],
 247             lpp10 + [10, 0]
 248             ]);
 249   intersection(){
 250     circleat(lpp12, r=lp_r12);
 251     rectfromto( lpp12 + [-10,   0],
 252                 lpp12 + [+10, +10] );
 253   }
 254 }
 255
 256 module ButtonCoverProfile(){
 257   intersection(){
 258     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 259     hull(){
 260       EdgeProfile();
 261       LidEdgeProfile();
 262     }
 263   }
 264 }
 265
 266 module ButtonPlan(l, deep, cut){
 267   epsilon =
 268     (cut  ? 0 : lid_buttoncover_gap);
 269
 270   delta =
 271     (deep ? lid_buttoncover_overlap : 0);
 272
 273   C = [0,0]; // by definition
 274   T = [ 0, epp4[1] ];
 275   G = T + [0,10];
 276
 277   B0 = C + [0,-1] * button_cutout_depth;
 278   B1 = B0 + [0,1] * epsilon;
 279
 280   r0 = 0.5 * (T[1] - B0[1]);
 281   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 282   H = A + [0,-1] * delta;
 283
 284   D = A + [-2,0] * r0;
 285   F = D + [0,10];
 286
 287   E0 = 0.5 * (D + A);
 288   E1 = E0 + [1,0] * epsilon;
 289
 290   I0 = [ E0[0], H[1] ];
 291   I1 = [ E1[0], H[1] ];
 292
 293   hull(){
 294     for (m=[0,1]) mirror([m,0])
 295       circleat(H, r0 - epsilon);
 296   }
 297   for (m=[0,1]) mirror([m,0]) {
 298     difference(){
 299       polygon([ E1,
 300                 I1,
 301                 H,
 302                 B1,
 303                 G,
 304                 F,
 305                 D
 306                 ]);
 307       circleat(D, r0 + epsilon);
 308     }
 309   }
 310 }
 311
 312 module CatchCatchProfile(){
 313   hull(){
 314     for (c=[ cppR, cppQ ])
 315       circleat(c, cp_rQ);
 316   }
 317   hull(){
 318     circleat(lpp12, lp_r12);
 319     circleat(lpp12 + [5,0], lp_r12);
 320     rectfromto(cppP, cppP + [5,0.1]);
 321   }
 322   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 323 }
 324
 325 module CatchCutProfile(){
 326   polygon([ cppB,
 327             cppA,
 328             cppD,
 329             cppF,
 330             cppF + [0,-10],
 331             cppF + [-10,-10],
 332             lpp12 + [-10,0],
 333             lpp12 + [10,0]
 334             ]);
 335 }
 336
 337 module Flip_rhs(yn=[0,1]) {
 338   for ($rhsflip=yn) {
 339     translate([phone_width/2, 0, 0])
 340       mirror([$rhsflip,0,0])
 341       translate([-phone_width/2, 0, 0])
 342       children();
 343   }
 344 }
 345
 346 module Flip_bot(yn=[0,1]) {
 347   for ($botflip=yn) {
 348     translate([0, -phone_height/2, 0])
 349       mirror([0, $botflip, 0])
 350       translate([0, phone_height/2, 0])
 351       children();
 352   }
 353 }
 354
 355 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 356   // sides
 357   Flip_rhs(){
 358     translate([0, -phone_cnr_rad, 0])
 359       rotate([90,0,0])
 360       linear_extrude(height = phone_height - phone_cnr_rad*2)
 361       children(0);
 362   }
 363   // corners
 364   Flip_rhs() Flip_bot() {
 365     translate([+1,-1] * phone_cnr_rad)
 366       intersection(){
 367         rotate_extrude()
 368           intersection(){
 369             mirror([1,0,0])
 370               translate([-1,0] * phone_cnr_rad)
 371               children(0);
 372             rectfromto([0,-20],[10,20]);
 373           }
 374         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 375           cube([10,10,40]);
 376       }
 377   }
 378   // top and bottom
 379   Flip_bot(){
 380     translate([ phone_width - phone_cnr_rad, 0,0 ])
 381       rotate([90,0,-90])
 382       linear_extrude(height = phone_width - phone_cnr_rad*2)
 383       children(0);
 384   }
 385   // fill
 386   translate([0,0, fill_zstart])
 387     mirror([0,0, fill_downwards])
 388     linear_extrude(height = fill_th)
 389     rectfromto([+1,-1] * phone_cnr_rad,
 390                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 391 }
 392
 393 module CaseAperture(pos, dia, $fn) {
 394   theta = 180/$fn;
 395   translate([ pos[0] + bumper[0],
 396               -epp2i[0],
 397               -pos[1] ])
 398     rotate([-90, theta, 0])
 399     cylinder(r = dia/2 / cos(theta),
 400              h = 60);
 401 }
 402
 403 module SideButton(y, y_ref_sign, l){
 404   // y_ref_sign:
 405   //   +1  measured from top    of actual phone to top    of button
 406   //   -1  measured from bottom of actual phone to bottom of button
 407   //    0  y is centre of button in coordinate system
 408   $button_l= l;
 409   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 410           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 411           y;
 412   //echo(eff_y);
 413   translate([0, eff_y, 0])
 414     children();
 415 }
 416
 417 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 418   $button_leg_only = true;
 419   SideButton(y, y_ref_sign, l) children();
 420 }
 421
 422 module Buttons(){
 423   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 424   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 425   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 426   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 427 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 428 }
 429
 430 module Struts(x_start, z_min, th){
 431   // if th is negative, starts at z_min and works towards -ve z
 432   // and object should then be printed other way up
 433   for (i= [1 : 1 : case_struts_count]) {
 434     translate([0,
 435                0,
 436                z_min])
 437       mirror([0,0, th<0 ? 1 : 0])
 438       translate([0,
 439                  -phone_height * i / (case_struts_count+1),
 440                  case_struts_solid_below])
 441       linear_extrude(height= abs(th)
 442                      -(case_struts_solid_below+case_struts_solid_above))
 443       rectfromto([               x_start, -0.5 * case_struts_width ],
 444                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 445   }
 446 }
 447
 448 module OrdinaryRearAperture(rhs,bot, pos){
 449   Flip_rhs(rhs) Flip_bot(bot)
 450     linextr(-20, 20)
 451     mirror([0,1])
 452     translate(pos + bumper)
 453     children();
 454 }
 455
 456 module MicroUSB(){
 457   Flip_bot(1){
 458     rotate([90,0,0])
 459       mirror([0,0,1])
 460       linextr(-epp2i[0], 60)
 461       translate([0.5 * phone_width, 0, 0])
 462       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 463                  [+microusb_width/2, epp0[1] + -microusb_above]);
 464   }
 465 }
 466
 467 module OrdinaryRearApertures(){
 468   // rear speaker
 469   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 470     rectfromto(-rearspeaker_gap,
 471                rearspeaker_size + rearspeaker_gap);
 472
 473   // finger hole to remove phone
 474   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 475                               phone[1]/2 ])
 476     scale(fingerpushhole_dias)
 477     circle(r= 0.5 );
 478 }
 479
 480 module RearCameraAperture(){
 481   Flip_rhs(1)
 482     mirror([0, 0, 1])
 483     linear_extrude(height = 20)
 484     mirror([0, 1, 0])
 485     translate(bumper)
 486     rectfromto(camera_pos_tl, camera_pos_br);
 487 }
 488
 489 module HingeLidProfile(){
 490   hull(){
 491     circleat(hppT, hp_r1);
 492     circleat(lpp12, lp_r12);
 493     polygon([lpp10,
 494              lpp13 + [2,0],
 495              lpp12,
 496              hppT]);
 497   }
 498 }
 499
 500 module HingeBaseProfile(){
 501   difference(){
 502     hull(){
 503       circleat(hppB, hp_r1);
 504       circleat(hppE, hp_r1);
 505       circleat(epp2o, case_th_bottom);
 506       circleat(hppB + [10,0], hp_r1);
 507     }
 508     polygon([epp5, epp1, epp2i, epp3, bppL]);
 509   }
 510 }
 511
 512 module HingeLeverOuterProfile(){
 513   hull(){
 514     circleat(hppT, hp_r2);
 515     circleat(hppB, hp_r2);
 516   }
 517 }
 518
 519 module HingeLeverInnerProfile(){
 520   for (c = [hppT, hppB]) {
 521     hull()
 522       for (x=[-20,20])
 523         for (y=[0, c[1] - hppM[1]])
 524           translate([x,y])
 525             circleat(c, hp_rn);
 526   }
 527 }
 528
 529 module Flip_hinge(){
 530   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 531   translate(hinge_origin)
 532     rotate([180,0,0])
 533     translate(-hinge_origin)
 534     children();
 535 }
 536
 537 module HingePortion(x0,x1){
 538   Flip_rhs() Flip_bot(1)
 539     translate([x0,0,0])
 540     mirror([1,0,0])
 541     rotate([90,0,-90])
 542     linear_extrude(height=x1-x0)
 543     children(0);
 544 }
 545
 546 module CatchPortion(width){
 547   translate([phone_width/2, 0,0])
 548     rotate([90,0,-90])
 549     linextr(-width/2, width/2)
 550     children(0);
 551 }
 552
 553 module CaseBase(){
 554   AroundEdges(epp3[1], case_th_bottom, 1)
 555     EdgeProfile();
 556 }
 557
 558 module Case(){ ////toplevel
 559   difference(){
 560     union(){
 561       CaseBase();
 562
 563       // ledge (fixed keeper)
 564       intersection(){
 565         rotate([90, 0, 0])
 566           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 567           KeeperProfile(1);
 568
 569         // outline of the whole case, to stop it protruding
 570         translate([0,0, -25])
 571           linear_extrude(height = 50)
 572           hull()
 573           // Flip_rhs() // actually, we only care about the LH
 574           Flip_bot()
 575           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 576       }
 577
 578       // hinge
 579       HingePortion(hex20, hex21) HingeBaseProfile();
 580     }
 581
 582     // slot for keeper
 583     Flip_rhs(1)
 584       translate([0, -phone_cnr_rad, 0])
 585       rotate([90, 0, 0])
 586       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 587       minkowski(){
 588         KeeperProfile();
 589         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 590                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 591       }
 592
 593     // front camera
 594     RearCameraAperture();
 595
 596     // struts (invisible, because they're buried in the case)
 597     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 598
 599     Buttons(){
 600       mirror([1,0,0])
 601         rotate([90,0,90]) {
 602           intersection(){
 603             translate([0,0,-10])
 604               linear_extrude(height= 20)
 605               ButtonPlan($button_l, 0,1);
 606             if ($button_leg_only)
 607               rotate([-90,90,0])
 608                 translate([phone_width/2, -400, kppe[1]])
 609                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 610           }
 611           translate([0,0, -bppR[0]])
 612             linear_extrude(height= 20)
 613             ButtonPlan($button_l, 1,1);
 614         }
 615     }
 616
 617     // apertures along top edge
 618     CaseAperture(jack_pos, jack_dia, 8);
 619     Flip_rhs(1)
 620       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 621
 622     OrdinaryRearApertures();
 623
 624     MicroUSB();
 625
 626     // gaps for the lid's hinge arms
 627     HingePortion(hex20 - hinge_x_arms_gap,
 628                  hex21 + hinge_x_arms_gap)
 629       minkowski(){
 630         HingeLidProfile();
 631         circle(r= hinge_r_arms_gap, $fn= 8);
 632       }
 633
 634     // screw holes in the hinge arms
 635     HingeScrews();
 636
 637     // catch striker
 638     CatchPortion(catch_width + catch_side_gap*2)
 639       CatchCutProfile();
 640   }
 641 }
 642
 643 module Lid(){ ////toplevel
 644   difference(){
 645     union(){
 646       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 647         LidEdgeProfile();
 648
 649       // button covers
 650       Buttons(){
 651         intersection(){
 652           rotate([90,0,90])
 653             translate([0,0,-10])
 654             linear_extrude(height= 20)
 655             ButtonPlan($button_l, 1,0);
 656           rotate([90,0,0])
 657              translate([0,0,-100])
 658             linear_extrude(height= 200)
 659             ButtonCoverProfile();
 660         }
 661       }
 662
 663       // hinge arms
 664       HingePortion(hex20, hex21) HingeLidProfile();
 665
 666       // catch
 667       CatchPortion(catch_width)
 668         CatchCatchProfile();
 669     }
 670     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 671
 672     // screw holes in the hinge arms
 673     HingeScrews();
 674   }
 675 }
 676
 677 module HingeLever(){ ////toplevel
 678   difference() {
 679     // outer body, positive
 680     HingePortion(hex22, hex22 + phone_width/2)
 681       HingeLeverOuterProfile();
 682
 683     // space for the screws
 684     HingePortion(hex23, hex24)
 685       HingeLeverInnerProfile();
 686
 687     // bores for the screws
 688     HingeScrews();
 689
 690     // space for the charging cable
 691     MicroUSB();
 692     Flip_hinge() MicroUSB();
 693   }
 694 }
 695
 696 module HingeLeverPrint(){ ////toplevel
 697   rotate([90,0,0])
 698     HingeLever();
 699 }
 700
 701 module TestSelectLength(){
 702   translate([-30, -200, -20])
 703     cube([30 + 15, 250, 40]);
 704 }
 705
 706 module TestLength(){ ////toplevel
 707   intersection(){
 708     Case();
 709     TestSelectLength();
 710   }
 711 }
 712
 713 module TestLengthRight(){ ////toplevel
 714   intersection(){
 715     Case();
 716     Flip_rhs(1)
 717       TestSelectLength();
 718   }
 719 }
 720
 721 module TestSelectWidth(){
 722   translate([-30, -(phone_height - 25), -20])
 723     mirror([0, 1, 0])
 724     cube([200, 50, 40]);
 725 }
 726
 727 module TestWidth(){ ////toplevel
 728   intersection(){
 729     Case();
 730     TestSelectWidth();
 731   }
 732 }
 733
 734 module TestLidWidthPrint(){ ////toplevel
 735   rotate([0,180.0]) intersection(){
 736     Lid();
 737     TestSelectWidth();
 738   }
 739 }
 740
 741 module TestSelectRearAperture(){
 742   minkowski(){
 743     union() children();
 744     translate([20, 0,0])
 745       cube([42, 2, 1], center=true);
 746   }
 747 }
 748
 749 module TestSelectCamera(){
 750   minkowski(){
 751     TestSelectRearAperture()
 752       RearCameraAperture();
 753     cube([0.1, 50, 0.1]);
 754   }
 755 }
 756
 757 module TestSelectOrdinaryRearApertures(){
 758   TestSelectRearAperture()
 759     OrdinaryRearApertures();
 760 }
 761
 762 module TestCamera(){ ////toplevel
 763   intersection(){
 764     Case();
 765     TestSelectCamera();
 766   }
 767 }
 768
 769 module TestLidByCamera(){ ////toplevel
 770   intersection(){
 771     Lid();
 772     TestSelectCamera();
 773   }
 774 }
 775
 776 module TestLidByCameraPrint(){ ////toplevel
 777   rotate([180,0,0]) TestLidByCamera();
 778 }
 779
 780 module DemoByCamera(){ ////toplevel
 781   color("blue") TestLidByCamera();
 782   color("red")  TestCamera();
 783 }
 784
 785 module OneKeeper(){ ////toplevel
 786   translate([0, -phone_cnr_rad, 0])
 787     rotate([90, 0, 0])
 788     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 789     KeeperProfile();
 790 }
 791
 792 module OneKeeperPrint(){ ////toplevel
 793   rotate([0,180,0])
 794     OneKeeper();
 795 }
 796
 797 module LidPrint(){ ////toplevel
 798   rotate([0,180,0])
 799     Lid();
 800 }
 801
 802 module TestSelectFrame(){
 803   include = [1,-1] * (epp2i[0] + 4);
 804
 805   difference(){
 806     cube(1000, center=true);
 807     translate([0,0, -100])
 808       linear_extrude(height=200)
 809       rectfromto(include,  inside_br - include);
 810   }
 811 }
 812
 813 module TestFrameCase(){ ////toplevel
 814   intersection(){
 815     Case();
 816     union(){
 817       TestSelectFrame();
 818       TestSelectCamera();
 819       TestSelectOrdinaryRearApertures();
 820     }
 821   }
 822 }
 823
 824 module TestFrameLidPrint(){ ////toplevel
 825   rotate([0,180,0]) intersection(){
 826     Lid();
 827     TestSelectFrame();
 828   }
 829 }
 830
 831 module Keeper(){ ////toplevel
 832   Flip_rhs()
 833     OneKeeper();
 834 }
 835
 836 module ButtonPlanForDemo(z, deep, cut){
 837   translate([0,0,z])
 838     ButtonPlan(8, deep, cut);
 839 }
 840
 841 module HingeScrews(){
 842   Flip_rhs() Flip_bot(1){
 843     for (c= [ hppT, hppB ])
 844       translate([ hex20,
 845                   -c[0],
 846                   c[1] ]){
 847         rotate([0,90,0])
 848           translate([0,0,-.2])
 849           cylinder( r= hingescrew_shaft_dia/2,
 850                     h = hingescrew_shaft_len+0.2 );
 851         rotate([0,-90,0])
 852           translate([0,0,+.1])
 853           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 854       }
 855   }
 856 }
 857
 858 module DemoFrame(){ ////toplevel
 859   color("red") TestFrameCase();
 860   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 861   color("black") HingeScrews();
 862   %HingeLever();
 863 }
 864
 865 module DemoHingedFrame(){ ///toplevel
 866   color("red") TestFrameCase();
 867   translate([0,0, -2*hp_k])
 868   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 869
 870   Flip_hinge(){
 871     color("orange") HingeLever();
 872     color("black") HingeScrews();
 873   }
 874 }
 875
 876 module DemoHinge(){ ////toplevel
 877   DemoFrame();
 878   translate([0,0, -hp_k*3])
 879     DemoHingedFrame();
 880 }
 881
 882 module DemoProfiles(){ ////toplevel
 883   LidEdgeProfile();
 884   %EdgeProfile();
 885   KeeperProfile();
 886   translate([0,0,-1]) color("black") KeeperProfile(1);
 887
 888   translate([20,0]) {
 889     LidEdgeProfile();
 890     %EdgeProfile();
 891
 892     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 893
 894     color("blue") ButtonCoverProfile();
 895     color("red") {
 896       rectfromto(bppQ, demopoint_QR);
 897       rectfromto(bppR, demopoint_QR);
 898     }
 899   }
 900
 901   translate([-20,0]) {
 902     color("black") ButtonPlanForDemo(-2, 0,1);
 903     color("red" )  ButtonPlanForDemo(-4, 1,1);
 904     color("blue")  ButtonPlanForDemo(-6, 1,0);
 905   }
 906
 907   translate([0, -30]) {
 908     %LidEdgeProfile();
 909     %EdgeProfile();
 910     color("blue") HingeLidProfile();
 911     color("red")  HingeBaseProfile();
 912     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 913     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 914   }
 915
 916   translate([20,-30]) {
 917     %EdgeProfile();
 918     %LidEdgeProfile();
 919     //translate([0,0,1]) CatchCutProfile();
 920     color("blue") CatchCatchProfile();
 921     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
 922   }
 923 }
 924
 925 //EdgeProfile();
 926 //KeeperProfile();
 927 //CaseBase();
 928 //%Case();
 929 //Keeper();
 930 //LidEdgeProfile();
 931 //KeeperProfile();
 932 //DemoProfiles();