fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25 noisecancelmic_dia = 1.75;
  26
  27 case_th_bottom = 2.5;
  28 case_th_lid = 2.5;
  29 case_th_side = 2;
  30 case_th_lip = 1.2;
  31
  32 case_struts_count = 6;
  33 case_struts_solid_below = 1.00;
  34 case_struts_solid_above = 0.75;
  35 case_struts_width = 0.10;
  36
  37 keeper_th_z = 0.75;
  38 keeper_th_x = 0.75;
  39 keeper_inner_width = 2.75;
  40 keeper_inner_height = 2.75;
  41 keeper_slant_slope = 2; // larger means steeper
  42
  43 keeper_gap_z_top = 0.25;
  44 keeper_gap_z_bot = 0.75;
  45 keeper_gap_x     = 0.25;
  46 keeper_gap_x_holes = 0.75;
  47
  48 case_lip = 1.25;
  49
  50 lid_gap_x = 0.25;
  51 lid_gap_z = 0.25;
  52 lid_lip = 1.75;
  53
  54 $fa = 5;
  55 $fs = 0.1;
  56
  57 button_l_fudge = 4.4;
  58 buttonishleg_default_l_is_fudge = 10;
  59
  60 strut_min_at_end = 1.5;
  61
  62 // ---------- calculated ----------
  63
  64 phone_width =  (phone + bumper*2)[0];
  65 phone_height = (phone + bumper*2)[1];
  66
  67 inside_br = [phone_width, -phone_height];
  68
  69 //echo(camera_pos_tl + bumper,
  70 //     camera_pos_br + bumper);
  71
  72 // ----- could be changed -----
  73 lid_buttoncover_gap = lid_gap_x;
  74 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  75
  76 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  77
  78 //lid_lip_overlap_width xxx bad name = ;
  79 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  80
  81 epp0 = [0,0];
  82 epp1 = [0, -phone_edge_thick];
  83 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  84 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  85 epp3 = epp2i + [10, 0];
  86 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  87 epp4 = epp5 + [-1,0] * case_th_side;
  88
  89 kppe = [0,0];
  90 kppd = kppe + [1,0] * keeper_inner_width;
  91 kppc = kppd + [0,1] * keeper_th_z;
  92 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  93 kppf = kppe - [0,1] * keeper_inner_height;
  94 kppa = [ kppb[0], kppf[1] ];
  95
  96 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  97 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  98
  99 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 100
 101 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 102 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 103
 104 // button profile
 105 bppM = epp4 + [0,5];
 106 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 107 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 108 bppS = [ epp1[0], bppR[1] ];
 109 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 110 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 111 bppO = [ bppN[0], bppP[1] ];
 112 bppL = lpp10 + [5,0];
 113 bppK = [ bppL[0], bppN[1] ];
 114 bppJ = [ bppN[0], bppL[1] ];
 115
 116 module rectfromto(a,b) {
 117   ab = b - a;
 118   translate([min(a[0], b[0]), min(a[1], b[1])])
 119     square([abs(ab[0]), abs(ab[1])]);
 120 }
 121 module circleat(c,r) { translate(c) circle(r); }
 122
 123 module KeeperProfile(slant=0){
 124   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 125   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 126 }
 127
 128 module EdgeProfile(){
 129   difference(){
 130     hull(){
 131       translate(epp3) square(case_th_bottom*2, center=true);
 132       circleat(epp2o, r=case_th_bottom);
 133       circleat(epp1, r=case_th_side);
 134       rectfromto(epp0, epp4);
 135     }
 136     polygon([ epp5 + [0,10],
 137               epp1,
 138               epp2i,
 139               epp3 + [10,0] ]);
 140   }
 141 }
 142
 143 module LidEdgeProfile(){
 144   polygon([ lpp10,
 145             lpp11,
 146             lpp12,
 147             lpp13,
 148             lpp13 + [10, 0],
 149             lpp10 + [10, 0]
 150             ]);
 151   intersection(){
 152     circleat(lpp12, r=lp_r12);
 153     rectfromto( lpp12 + [-10,   0],
 154                 lpp12 + [+10, +10] );
 155   }
 156 }
 157
 158 module ButtonCoverProfile(){
 159   intersection(){
 160     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 161     hull(){
 162       EdgeProfile();
 163       LidEdgeProfile();
 164     }
 165   }
 166 }
 167
 168 module ButtonPlan(l, deep, cut){
 169   epsilon =
 170     (cut  ? 0 : lid_buttoncover_gap);
 171
 172   delta =
 173     (deep ? lid_buttoncover_overlap : 0);
 174
 175   C = [0,0]; // by definition
 176   T = [ 0, epp4[1] ];
 177   G = T + [0,10];
 178
 179   B0 = C + [0,-1] * button_cutout_depth;
 180   B1 = B0 + [0,1] * epsilon;
 181
 182   r0 = 0.5 * (T[1] - B0[1]);
 183   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 184   H = A + [0,-1] * delta;
 185
 186   D = A + [-2,0] * r0;
 187   F = D + [0,10];
 188
 189   E0 = 0.5 * (D + A);
 190   E1 = E0 + [1,0] * epsilon;
 191
 192   I0 = [ E0[0], H[1] ];
 193   I1 = [ E1[0], H[1] ];
 194
 195   hull(){
 196     for (m=[0,1]) mirror([m,0])
 197       circleat(H, r0 - epsilon);
 198   }
 199   for (m=[0,1]) mirror([m,0]) {
 200     difference(){
 201       polygon([ E1,
 202                 I1,
 203                 H,
 204                 B1,
 205                 G,
 206                 F,
 207                 D
 208                 ]);
 209       circleat(D, r0 + epsilon);
 210     }
 211   }
 212 }
 213
 214 module CaseBase_rhsflip(yn=[0,1]) {
 215   for ($rhsflip=yn) {
 216     translate([phone_width/2, 0, 0])
 217       mirror([$rhsflip,0,0])
 218       translate([-phone_width/2, 0, 0])
 219       children();
 220   }
 221 }
 222
 223 module CaseBase_botflip() {
 224   for (bot=[0,1]) {
 225     translate([0, -phone_height/2, 0])
 226       mirror([0, bot, 0])
 227       translate([0, phone_height/2, 0])
 228       children();
 229   }
 230 }
 231
 232 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 233   // sides
 234   CaseBase_rhsflip(){
 235     translate([0, -phone_cnr_rad, 0])
 236       rotate([90,0,0])
 237       linear_extrude(height = phone_height - phone_cnr_rad*2)
 238       children(0);
 239   }
 240   // corners
 241   CaseBase_rhsflip() CaseBase_botflip() {
 242     translate([+1,-1] * phone_cnr_rad)
 243       intersection(){
 244         rotate_extrude()
 245           intersection(){
 246             mirror([1,0,0])
 247               translate([-1,0] * phone_cnr_rad)
 248               children(0);
 249             rectfromto([0,-20],[10,20]);
 250           }
 251         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 252           cube([10,10,40]);
 253       }
 254   }
 255   // top and bottom
 256   CaseBase_botflip(){
 257     translate([ phone_width - phone_cnr_rad, 0,0 ])
 258       rotate([90,0,-90])
 259       linear_extrude(height = phone_width - phone_cnr_rad*2)
 260       children(0);
 261   }
 262   // fill
 263   translate([0,0, fill_zstart])
 264     mirror([0,0, fill_downwards])
 265     linear_extrude(height = fill_th)
 266     rectfromto([+1,-1] * phone_cnr_rad,
 267                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 268 }
 269
 270 module CaseAperture(pos, dia, $fn) {
 271   theta = 180/$fn;
 272   translate([ pos[0] + bumper[0],
 273               -epp2i[0],
 274               -pos[1] ])
 275     rotate([-90, theta, 0])
 276     cylinder(r = dia/2 / cos(theta),
 277              h = 60);
 278 }
 279
 280 module SideButton(y, y_ref_sign, l){
 281   // y_ref_sign:
 282   //   +1  measured from top    of actual phone to top    of button
 283   //   -1  measured from bottom of actual phone to bottom of button
 284   //    0  y is centre of button in coordinate system
 285   $button_l= l;
 286   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 287           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 288           y;
 289   echo(eff_y);
 290   translate([0, eff_y, 0])
 291     children();
 292 }
 293
 294 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 295   $button_leg_only = true;
 296   SideButton(y, y_ref_sign, l) children();
 297 }
 298
 299 module Buttons(){
 300   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 301   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 302   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 303   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 304 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 305 }
 306
 307 module Struts(x_start, z_min, th){
 308   // if th is negative, starts at z_min and works towards -ve z
 309   // and object should then be printed other way up
 310   for (i= [1 : 1 : case_struts_count]) {
 311     translate([0,
 312                0,
 313                z_min])
 314       mirror([0,0, th<0 ? 1 : 0])
 315       translate([0,
 316                  -phone_height * i / (case_struts_count+1),
 317                  case_struts_solid_below])
 318       linear_extrude(height= abs(th)
 319                      -(case_struts_solid_below+case_struts_solid_above))
 320       rectfromto([               x_start, -0.5 * case_struts_width ],
 321                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 322   }
 323 }
 324
 325 module CaseBase(){
 326   AroundEdges(epp3[1], case_th_bottom, 1)
 327     EdgeProfile();
 328 }
 329
 330 module Case(){ ////toplevel
 331   difference(){
 332     union(){
 333       CaseBase();
 334
 335       // ledge (fixed keeper)
 336       intersection(){
 337         rotate([90, 0, 0])
 338           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 339           KeeperProfile(1);
 340
 341         // outline of the whole case, to stop it protruding
 342         translate([0,0, -25])
 343           linear_extrude(height = 50)
 344           hull()
 345           // CaseBase_rhsflip() // actually, we only care about the LH
 346           CaseBase_botflip()
 347           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 348       }
 349     }
 350
 351     // slot for keeper
 352     CaseBase_rhsflip(1)
 353       translate([0, -phone_cnr_rad, 0])
 354       rotate([90, 0, 0])
 355       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 356       minkowski(){
 357         KeeperProfile();
 358         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 359                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 360       }
 361
 362     // front camera
 363     CaseBase_rhsflip([1])
 364       mirror([0, 0, 1])
 365       linear_extrude(height = 20)
 366       mirror([0, 1, 0])
 367       translate(bumper)
 368       rectfromto(camera_pos_tl, camera_pos_br);
 369
 370     // struts (invisible, because they're buried in the case)
 371     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 372
 373     Buttons(){
 374       mirror([1,0,0])
 375         rotate([90,0,90]) {
 376           intersection(){
 377             translate([0,0,-10])
 378               linear_extrude(height= 20)
 379               ButtonPlan($button_l, 0,1);
 380             if ($button_leg_only)
 381               rotate([-90,90,0])
 382                 translate([phone_width/2, -400, kppe[1]])
 383                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 384           }
 385           translate([0,0, -bppR[0]])
 386             linear_extrude(height= 20)
 387             ButtonPlan($button_l, 1,1);
 388         }
 389     }
 390
 391     // apertures along top edge
 392     CaseAperture(jack_pos, jack_dia, 8);
 393     CaseBase_rhsflip([1])
 394       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 395   }
 396 }
 397
 398 module Lid(){ ////toplevel
 399   difference(){
 400     union(){
 401       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 402         LidEdgeProfile();
 403
 404       // button covers
 405       Buttons(){
 406         intersection(){
 407           rotate([90,0,90])
 408             translate([0,0,-10])
 409             linear_extrude(height= 20)
 410             ButtonPlan($button_l, 1,0);
 411           rotate([90,0,0])
 412              translate([0,0,-100])
 413             linear_extrude(height= 200)
 414             ButtonCoverProfile();
 415         }
 416       }
 417     }
 418     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 419   }
 420 }
 421
 422 module TestLength(){ ////toplevel
 423   intersection(){
 424     Case();
 425     translate([-30, -200, -20])
 426     cube([30 + 15, 250, 40]);
 427   }
 428 }
 429
 430 module TestSelectWidth(){
 431   translate([-30, -(phone_height - 25), -20])
 432     mirror([0, 1, 0])
 433     cube([200, 50, 40]);
 434 }
 435
 436 module TestWidth(){ ////toplevel
 437   intersection(){
 438     Case();
 439     TestSelectWidth();
 440   }
 441 }
 442
 443 module TestLidWidthPrint(){ ////toplevel
 444   rotate([0,180.0]) intersection(){
 445     Lid();
 446     TestSelectWidth();
 447   }
 448 }
 449
 450 module TestSelectCamera(){
 451   CaseBase_rhsflip(1)
 452     translate([0,0,-25])
 453     linear_extrude(height = 50)
 454     mirror([0, 1, 0])
 455     rectfromto([-20, -20],
 456                camera_pos_br + bumper + [ 5, 5 ]);
 457 }
 458
 459 module TestCamera(){ ////toplevel
 460   intersection(){
 461     Case();
 462     TestSelectCamera();
 463   }
 464 }
 465
 466 module TestLidByCamera(){ ////toplevel
 467   intersection(){
 468     Lid();
 469     TestSelectCamera();
 470   }
 471 }
 472
 473 module TestLidByCameraPrint(){ ////toplevel
 474   rotate([180,0,0]) TestLidByCamera();
 475 }
 476
 477 module DemoByCamera(){ ////toplevel
 478   color("blue") TestLidByCamera();
 479   color("red")  TestCamera();
 480 }
 481
 482 module OneKeeper(){ ////toplevel
 483   translate([0, -phone_cnr_rad, 0])
 484     rotate([90, 0, 0])
 485     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 486     KeeperProfile();
 487 }
 488
 489 module OneKeeperPrint(){ ////toplevel
 490   rotate([0,180,0])
 491     OneKeeper();
 492 }
 493
 494 module LidPrint(){ ////toplevel
 495   rotate([0,180,0])
 496     Lid();
 497 }
 498
 499 module TestSelectFrame(){
 500   include = [1,-1] * (epp2i[0] + 4);
 501
 502   difference(){
 503     cube(1000, center=true);
 504     translate([0,0, -100])
 505       linear_extrude(height=200)
 506       rectfromto(include,  inside_br - include);
 507   }
 508 }
 509
 510 module TestFrameCase(){ ////toplevel
 511   intersection(){
 512     Case();
 513     union(){
 514       TestSelectFrame();
 515       TestSelectCamera();
 516     }
 517   }
 518 }
 519
 520 module TestFrameLidPrint(){ ////toplevel
 521   rotate([0,0,180]) intersection(){
 522     Lid();
 523     TestSelectFrame();
 524   }
 525 }
 526
 527 module Keeper(){ ////toplevel
 528   CaseBase_rhsflip()
 529     OneKeeper();
 530 }
 531
 532 module ButtonPlanForDemo(z, deep, cut){
 533   translate([0,0,z])
 534     ButtonPlan(8, deep, cut);
 535 }
 536
 537 module DemoProfiles(){ ////toplevel
 538   LidEdgeProfile();
 539   %EdgeProfile();
 540   KeeperProfile();
 541   translate([0,0,-1]) color("black") KeeperProfile(1);
 542
 543   translate([20,0]) {
 544     LidEdgeProfile();
 545     %EdgeProfile();
 546
 547     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 548
 549     color("blue") ButtonCoverProfile();
 550     color("red") {
 551       rectfromto(bppQ, demopoint_QR);
 552       rectfromto(bppR, demopoint_QR);
 553     }
 554   }
 555
 556   translate([-20,0]) {
 557     color("black") ButtonPlanForDemo(-2, 0,1);
 558     color("red" )  ButtonPlanForDemo(-4, 1,1);
 559     color("blue")  ButtonPlanForDemo(-6, 1,0);
 560   }
 561 }
 562
 563 //EdgeProfile();
 564 //KeeperProfile();
 565 //CaseBase();
 566 //%Case();
 567 //Keeper();
 568 //LidEdgeProfile();
 569 //KeeperProfile();
 570 //DemoProfiles();