fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 145.0, 75.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 case_th_bottom = 2.5;
  22 case_th_lid = 2.5;
  23 case_th_side = 2;
  24 case_th_lip = 1.2;
  25
  26 case_struts_count = 6;
  27 case_struts_solid_below = 1.00;
  28 case_struts_solid_above = 0.75;
  29 case_struts_width = 0.10;
  30
  31 keeper_th_z = 0.75;
  32 keeper_th_x = 0.75;
  33 keeper_inner_width = 2.75;
  34 keeper_inner_height = 2.75;
  35 keeper_slant_slope = 2; // larger means steeper
  36
  37 keeper_gap_z_top = 0.25;
  38 keeper_gap_z_bot = 0.75;
  39 keeper_gap_x     = 0.25;
  40 keeper_gap_x_holes = 0.75;
  41
  42 case_lip = 1.25;
  43
  44 lid_gap_x = 0.25;
  45 lid_gap_z = 0.25;
  46 lid_lip = 1.75;
  47
  48 $fa = 5;
  49 $fs = 0.1;
  50
  51 button_l_fudge = 4.4;
  52
  53 strut_min_at_end = 1.5;
  54
  55 // ---------- calculated ----------
  56
  57 phone_height = (phone + bumper*2)[0];
  58 phone_width =  (phone + bumper*2)[1];
  59
  60 echo(camera_pos_tl + bumper,
  61      camera_pos_br + bumper);
  62
  63 // ----- could be changed -----
  64 lid_buttoncover_gap = lid_gap_x;
  65 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  66
  67 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  68
  69 //lid_lip_overlap_width xxx bad name = ;
  70 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  71
  72 epp0 = [0,0];
  73 epp1 = [0, -phone_edge_thick];
  74 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  75 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  76 epp3 = epp2i + [10, 0];
  77 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  78 epp4 = epp5 + [-1,0] * case_th_side;
  79
  80 kppe = [0,0];
  81 kppd = kppe + [1,0] * keeper_inner_width;
  82 kppc = kppd + [0,1] * keeper_th_z;
  83 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  84 kppf = kppe - [0,1] * keeper_inner_height;
  85 kppa = [ kppb[0], kppf[1] ];
  86
  87 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  88 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  89
  90 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  91
  92 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
  93 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
  94
  95 // button profile
  96 bppM = epp4 + [0,5];
  97 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  98 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
  99 bppS = [ epp1[0], bppR[1] ];
 100 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 101 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 102 bppO = [ bppN[0], bppP[1] ];
 103 bppL = lpp10 + [5,0];
 104 bppK = [ bppL[0], bppN[1] ];
 105 bppJ = [ bppN[0], bppL[1] ];
 106
 107 module rectfromto(a,b) {
 108   ab = b - a;
 109   translate([min(a[0], b[0]), min(a[1], b[1])])
 110     square([abs(ab[0]), abs(ab[1])]);
 111 }
 112 module circleat(c,r) { translate(c) circle(r); }
 113
 114 module KeeperProfile(slant=0){
 115   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 116   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 117 }
 118
 119 module EdgeProfile(){
 120   difference(){
 121     hull(){
 122       translate(epp3) square(case_th_bottom*2, center=true);
 123       circleat(epp2o, r=case_th_bottom);
 124       circleat(epp1, r=case_th_side);
 125       rectfromto(epp0, epp4);
 126     }
 127     polygon([ epp5 + [0,10],
 128               epp1,
 129               epp2i,
 130               epp3 + [10,0] ]);
 131   }
 132 }
 133
 134 module LidEdgeProfile(){
 135   polygon([ lpp10,
 136             lpp11,
 137             lpp12,
 138             lpp13,
 139             lpp13 + [10, 0],
 140             lpp10 + [10, 0]
 141             ]);
 142   intersection(){
 143     circleat(lpp12, r=lp_r12);
 144     rectfromto( lpp12 + [-10,   0],
 145                 lpp12 + [+10, +10] );
 146   }
 147 }
 148
 149 module ButtonCoverProfile(){
 150   intersection(){
 151     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 152     hull(){
 153       EdgeProfile();
 154       LidEdgeProfile();
 155     }
 156   }
 157 }
 158
 159 module ButtonPlan(l, deep, cut){
 160   epsilon =
 161     (cut  ? 0 : lid_buttoncover_gap);
 162
 163   delta =
 164     (deep ? lid_buttoncover_overlap : 0);
 165
 166   C = [0,0]; // by definition
 167   T = [ 0, epp4[1] ];
 168   G = T + [0,10];
 169
 170   B0 = C + [0,-1] * button_cutout_depth;
 171   B1 = B0 + [0,1] * epsilon;
 172
 173   r0 = 0.5 * (T[1] - B0[1]);
 174   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 175   H = A + [0,-1] * delta;
 176
 177   D = A + [-2,0] * r0;
 178   F = D + [0,10];
 179
 180   E0 = 0.5 * (D + A);
 181   E1 = E0 + [1,0] * epsilon;
 182
 183   I0 = [ E0[0], H[1] ];
 184   I1 = [ E1[0], H[1] ];
 185
 186   hull(){
 187     for (m=[0,1]) mirror([m,0])
 188       circleat(H, r0 - epsilon);
 189   }
 190   for (m=[0,1]) mirror([m,0]) {
 191     difference(){
 192       polygon([ E1,
 193                 I1,
 194                 H,
 195                 B1,
 196                 G,
 197                 F,
 198                 D
 199                 ]);
 200       circleat(D, r0 + epsilon);
 201     }
 202   }
 203 }
 204
 205 module CaseBase_rhsflip(yn=[0,1]) {
 206   for (rhs=yn) {
 207     translate([phone_width/2, 0, 0])
 208       mirror([rhs,0,0])
 209       translate([-phone_width/2, 0, 0])
 210       children();
 211   }
 212 }
 213
 214 module CaseBase_botflip() {
 215   for (bot=[0,1]) {
 216     translate([0, -phone_height/2, 0])
 217       mirror([0, bot, 0])
 218       translate([0, phone_height/2, 0])
 219       children();
 220   }
 221 }
 222
 223 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 224   // sides
 225   CaseBase_rhsflip(){
 226     translate([0, -phone_cnr_rad, 0])
 227       rotate([90,0,0])
 228       linear_extrude(height = phone_height - phone_cnr_rad*2)
 229       children(0);
 230   }
 231   // corners
 232   CaseBase_rhsflip() CaseBase_botflip() {
 233     translate([+1,-1] * phone_cnr_rad)
 234       intersection(){
 235         rotate_extrude()
 236           intersection(){
 237             mirror([1,0,0])
 238               translate([-1,0] * phone_cnr_rad)
 239               children(0);
 240             rectfromto([0,-20],[10,20]);
 241           }
 242         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 243           cube([10,10,40]);
 244       }
 245   }
 246   // top and bottom
 247   CaseBase_botflip(){
 248     translate([ phone_width - phone_cnr_rad, 0,0 ])
 249       rotate([90,0,-90])
 250       linear_extrude(height = phone_width - phone_cnr_rad*2)
 251       children(0);
 252   }
 253   // fill
 254   translate([0,0, fill_zstart])
 255     mirror([0,0, fill_downwards])
 256     linear_extrude(height = fill_th)
 257     rectfromto([+1,-1] * phone_cnr_rad,
 258                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 259 }
 260
 261 module SideButton(y,l){
 262   $button_l= l;
 263   eff_y = -y;
 264   echo(eff_y);
 265   translate([0, eff_y, 0])
 266     children();
 267 }
 268
 269 module Buttons(){
 270   CaseBase_rhsflip([1]) SideButton(19.650, 8.9) children(); // power
 271 }
 272
 273 module Struts(x_start, z_min, th){
 274   // if th is negative, starts at z_min and works towards -ve z
 275   // and object should then be printed other way up
 276   for (i= [1 : 1 : case_struts_count]) {
 277     translate([0,
 278                0,
 279                z_min])
 280       mirror([0,0, th<0 ? 1 : 0])
 281       translate([0,
 282                  -phone_height * i / (case_struts_count+1),
 283                  case_struts_solid_below])
 284       linear_extrude(height= abs(th)
 285                      -(case_struts_solid_below+case_struts_solid_above))
 286       rectfromto([               x_start, -0.5 * case_struts_width ],
 287                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 288   }
 289 }
 290
 291 module CaseBase(){
 292   AroundEdges(epp3[1], case_th_bottom, 1)
 293     EdgeProfile();
 294 }
 295
 296 module Case(){ ////toplevel
 297   difference(){
 298     union(){
 299       CaseBase();
 300
 301       // ledge (fixed keeper)
 302       intersection(){
 303         rotate([90, 0, 0])
 304           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 305           KeeperProfile(1);
 306
 307         // outline of the whole case, to stop it protruding
 308         translate([0,0, -25])
 309           linear_extrude(height = 50)
 310           hull()
 311           // CaseBase_rhsflip() // actually, we only care about the LH
 312           CaseBase_botflip()
 313           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 314       }
 315     }
 316
 317     // slot for keeper
 318     CaseBase_rhsflip(1)
 319       translate([0, -phone_cnr_rad, 0])
 320       rotate([90, 0, 0])
 321       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 322       minkowski(){
 323         KeeperProfile();
 324         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 325                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 326       }
 327
 328     // front camera
 329     CaseBase_rhsflip([1])
 330       mirror([0, 0, 1])
 331       linear_extrude(height = 20)
 332       mirror([0, 1, 0])
 333       translate(bumper)
 334       rectfromto(camera_pos_tl, camera_pos_br);
 335
 336     // struts (invisible, because they're buried in the case)
 337     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 338
 339     Buttons(){
 340       mirror([1,0,0])
 341         rotate([90,0,90]) {
 342           translate([0,0,-10])
 343             linear_extrude(height= 20)
 344             ButtonPlan($button_l, 0,1);
 345           translate([0,0, -bppR[0]])
 346             linear_extrude(height= 20)
 347             ButtonPlan($button_l, 1,1);
 348         }
 349     }
 350   }
 351 }
 352
 353 module Lid(){ ////toplevel
 354   difference(){
 355     union(){
 356       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 357         LidEdgeProfile();
 358
 359       // button covers
 360       Buttons(){
 361         intersection(){
 362           rotate([90,0,90])
 363             translate([0,0,-10])
 364             linear_extrude(height= 20)
 365             ButtonPlan($button_l, 1,0);
 366           rotate([90,0,0])
 367              translate([0,0,-100])
 368             linear_extrude(height= 200)
 369             ButtonCoverProfile();
 370         }
 371       }
 372     }
 373     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 374   }
 375 }
 376
 377 module TestLength(){ ////toplevel
 378   intersection(){
 379     Case();
 380     translate([-30, -200, -20])
 381     cube([30 + 15, 250, 40]);
 382   }
 383 }
 384
 385 module TestSelectWidth(){
 386   translate([-30, -(phone_height - 25), -20])
 387     mirror([0, 1, 0])
 388     cube([200, 50, 40]);
 389 }
 390
 391 module TestWidth(){ ////toplevel
 392   intersection(){
 393     Case();
 394     TestSelectWidth();
 395   }
 396 }
 397
 398 module TestLidWidthPrint(){ ////toplevel
 399   rotate([0,180.0]) TestLidWidth();
 400 }
 401
 402 module TestSelectCamera(){
 403   CaseBase_rhsflip(1)
 404     translate([0,0,-25])
 405     linear_extrude(height = 50)
 406     mirror([0, 1, 0])
 407     rectfromto([-20, -20],
 408                camera_pos_br + bumper + [ 5, 5 ]);
 409 }
 410
 411 module TestCamera(){ ////toplevel
 412   intersection(){
 413     Case();
 414     TestSelectCamera();
 415   }
 416 }
 417
 418 module TestLidByCamera(){ ////toplevel
 419   intersection(){
 420     Lid();
 421     TestSelectCamera();
 422   }
 423 }
 424
 425 module TestLidByCameraPrint(){ ////toplevel
 426   rotate([180,0,0]) TestLidByCamera();
 427 }
 428
 429 module DemoByCamera(){ ////toplevel
 430   color("blue") TestLidByCamera();
 431   color("red")  TestCamera();
 432 }
 433
 434 module OneKeeper(){ ////toplevel
 435   translate([0, -phone_cnr_rad, 0])
 436     rotate([90, 0, 0])
 437     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 438     KeeperProfile();
 439 }
 440
 441 module OneKeeperPrint(){ ////toplevel
 442   rotate([0,180,0])
 443     OneKeeper();
 444 }
 445
 446 module Keeper(){ ////toplevel
 447   CaseBase_rhsflip()
 448     OneKeeper();
 449 }
 450
 451 module ButtonPlanForDemo(z, deep, cut){
 452   translate([0,0,z])
 453     ButtonPlan(8, deep, cut);
 454 }
 455
 456 module DemoProfiles(){ ////toplevel
 457   LidEdgeProfile();
 458   %EdgeProfile();
 459   KeeperProfile();
 460   translate([0,0,-1]) color("black") KeeperProfile(1);
 461
 462   translate([20,0]) {
 463     LidEdgeProfile();
 464     %EdgeProfile();
 465
 466     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 467
 468     color("blue") ButtonCoverProfile();
 469     color("red") {
 470       rectfromto(bppQ, demopoint_QR);
 471       rectfromto(bppR, demopoint_QR);
 472     }
 473   }
 474
 475   translate([-20,0]) {
 476     color("black") ButtonPlanForDemo(-2, 0,1);
 477     color("red" )  ButtonPlanForDemo(-4, 1,1);
 478     color("blue")  ButtonPlanForDemo(-6, 1,0);
 479   }
 480 }
 481
 482 //EdgeProfile();
 483 //KeeperProfile();
 484 //CaseBase();
 485 //%Case();
 486 //Keeper();
 487 //LidEdgeProfile();
 488 //KeeperProfile();
 489 //DemoProfiles();