fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 phone_cnr_rad = 6.0;
  12
  13 button_cutout_depth = 9;
  14
  15 phone_edge_thick = 9.0;
  16 phone_total_thick = 12.0;
  17 phone_backside_slope_inner = 1.5; // larger means shallower
  18 phone_backside_slope_outer = 1.0; // larger means shallower
  19
  20 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  21 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  22
  23 jack_pos = [ 13.92, 7.96 ];
  24 jack_dia = 9.1 + .5; // some jack I had lying around
  25
  26 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  27 noisecancelmic_dia = 1.75;
  28
  29 fingerpushhole_dias = [ 15, 18 ];
  30
  31 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  32 rearspeaker_size   = [  3.76,  7.36 ];
  33
  34 microusb_above = 3.27 - 0.25;
  35 microusb_below = 0.0;
  36 microusb_width = 16.12 + 0.25;
  37
  38 case_th_bottom = 2.5;
  39 case_th_lid = 2.5;
  40 case_th_side = 2;
  41 case_th_lip = 1.2;
  42
  43 case_struts_count = 6;
  44 case_struts_solid_below = 1.00;
  45 case_struts_solid_above = 0.75;
  46 case_struts_width = 0.10;
  47
  48 keeper_th_z = 0.75;
  49 keeper_th_x = 0.75;
  50 keeper_inner_width = 2.75;
  51 keeper_inner_height = 2.75;
  52 keeper_slant_slope = 2; // larger means steeper
  53
  54 keeper_gap_z_top = 0.25;
  55 keeper_gap_z_bot = 0.75;
  56 keeper_gap_x     = 0.25;
  57 keeper_gap_x_holes = 0.75;
  58
  59 case_lip = 1.25;
  60
  61 lid_gap_x = 0.25;
  62 lid_gap_z = 0.25;
  63 lid_lip = 1.75;
  64
  65 catch_slop = 0.25;
  66
  67 foldover_gap = 0.50;
  68 foldover_lever_gap = 0.50;
  69
  70 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  71 hingescrew_shaft_len = 12;
  72 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  73 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  74 hingescrew_head_th = 1.38 + 0.75;
  75 hingescrew_head_dia = 3.92;
  76 lever_cover_th = 0.75;
  77 hingemount_th = 2.5;
  78
  79 $fa = 5;
  80 $fs = 0.1;
  81
  82 button_l_fudge = 4.4;
  83 buttonishleg_default_l_is_fudge = 10;
  84
  85 hinge_base_slope = 1.5; // bigger is steeper
  86
  87 strut_min_at_end = 1.5;
  88
  89 hinge_x_gap = 0.125;
  90 hinge_x_postscrew_gap = 0.75;
  91 hinge_x_arms_gap = 0.35;
  92 hinge_r_arms_gap = 0.55;
  93
  94 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  95
  96 catch_len = 7.5;
  97 catch_width = 15;
  98 catch_thickness = 1.0;
  99
 100 catch_depth = 1.25;
 101 catch_height = 0.35;
 102 catch_finger_height = 1.5;
 103 catch_finger_depth = 2.5;
 104
 105 // ---------- calculated ----------
 106
 107 phone_width =  (phone + bumper*2)[0];
 108 phone_height = (phone + bumper*2)[1];
 109
 110 inside_br = [phone_width, -phone_height];
 111
 112 //echo(camera_pos_tl + bumper,
 113 //     camera_pos_br + bumper);
 114
 115 // ----- could be changed -----
 116 lid_buttoncover_gap = lid_gap_x;
 117 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 118
 119 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 120
 121 //lid_lip_overlap_width xxx bad name = ;
 122 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 123
 124 epp0 = [0,0];
 125 epp1 = [0, -phone_edge_thick];
 126 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 127 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 128 epp3 = epp2i + [10, 0];
 129 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 130 epp4 = epp5 + [-1,0] * case_th_side;
 131
 132 kppe = [0,0];
 133 kppd = kppe + [1,0] * keeper_inner_width;
 134 kppc = kppd + [0,1] * keeper_th_z;
 135 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 136 kppf = kppe - [0,1] * keeper_inner_height;
 137 kppa = [ kppb[0], kppf[1] ];
 138
 139 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 140 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 141
 142 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 143
 144 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 145 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 146
 147 // button profile
 148 bppM = epp4 + [0,5];
 149 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 150 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 151 bppS = [ epp1[0], bppR[1] ];
 152 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 153 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 154 bppO = [ bppN[0], bppP[1] ];
 155 bppL = lpp10 + [5,0];
 156 bppK = [ bppL[0], bppN[1] ];
 157 bppJ = [ bppN[0], bppL[1] ];
 158
 159 // hinge plan
 160 hp_rn = hingescrew_nut_dia/2;
 161 hp_r2_min = hp_rn + lever_cover_th;
 162 hp_rs = hingescrew_shaft_dia/2;
 163 hp_r1_min = hp_rs + hingemount_th;
 164
 165 hp_r1 = max(hp_r1_min, hp_r2_min);
 166 hp_r2 = hp_r1;
 167
 168 hppU = lpp13;
 169 hppS = epp2o + [0,-1] * case_th_bottom;
 170 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 171
 172 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 173          0.5 * (hppU + hppS)[1] ];
 174 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 175 hppB = hppT + [0,-1] * hp_k;
 176
 177 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 178 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 179 hppE = [ hppE_x, hppE_y ];
 180
 181 // hinge elevation x coords
 182
 183 hingescrew_portion_len =
 184   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 185
 186 hex20 = max(epp2o[0],
 187             phone_cnr_rad,
 188             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 189 hex21 = hex20 + hingescrew_portion_len;
 190 hex22 = hex21 - hinge_x_gap;
 191 hex23 = hex22 + hingescrew_portion_len;
 192 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 193 echo(hex20, hex21, hex22, hex23, hex24);
 194 echo(hingescrew_portion_len);
 195
 196 // catch
 197
 198 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 199 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 200 cppB = [ epp0[0], cppA[1] ];
 201 cppP = [ epp4[0], cppJ[1] ];
 202
 203 cppS = cppJ + [0,-1] * catch_len;
 204 cppD = [ cppA[0], cppS[1] + catch_slop ];
 205 cppC = [ cppB[0], cppD[1] ];
 206 cppT = cppS + [1,0] * catch_depth;
 207 cppU = cppT + [0,-1] * catch_height;
 208 cppV = [ cppS[0], cppU[1] - catch_depth ];
 209
 210 cppR = 0.5*(cppP + cppJ);
 211
 212 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 213 cppQ = [ cppR[0],
 214          cppV[1] - (catch_finger_height - cp_rQ) ];
 215 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 216
 217 // ---------- modules ----------
 218
 219 module KeeperProfile(slant=0){
 220   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 221   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 222 }
 223
 224 module EdgeProfile(){
 225   difference(){
 226     hull(){
 227       translate(epp3) square(case_th_bottom*2, center=true);
 228       circleat(epp2o, r=case_th_bottom);
 229       circleat(epp1, r=case_th_side);
 230       rectfromto(epp0, epp4);
 231     }
 232     polygon([ epp5 + [0,10],
 233               epp1,
 234               epp2i,
 235               epp3 + [10,0] ]);
 236   }
 237 }
 238
 239 module LidEdgeProfile(){
 240   polygon([ lpp10,
 241             lpp11,
 242             lpp12,
 243             lpp13,
 244             lpp13 + [10, 0],
 245             lpp10 + [10, 0]
 246             ]);
 247   intersection(){
 248     circleat(lpp12, r=lp_r12);
 249     rectfromto( lpp12 + [-10,   0],
 250                 lpp12 + [+10, +10] );
 251   }
 252 }
 253
 254 module ButtonCoverProfile(){
 255   intersection(){
 256     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 257     hull(){
 258       EdgeProfile();
 259       LidEdgeProfile();
 260     }
 261   }
 262 }
 263
 264 module ButtonPlan(l, deep, cut){
 265   epsilon =
 266     (cut  ? 0 : lid_buttoncover_gap);
 267
 268   delta =
 269     (deep ? lid_buttoncover_overlap : 0);
 270
 271   C = [0,0]; // by definition
 272   T = [ 0, epp4[1] ];
 273   G = T + [0,10];
 274
 275   B0 = C + [0,-1] * button_cutout_depth;
 276   B1 = B0 + [0,1] * epsilon;
 277
 278   r0 = 0.5 * (T[1] - B0[1]);
 279   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 280   H = A + [0,-1] * delta;
 281
 282   D = A + [-2,0] * r0;
 283   F = D + [0,10];
 284
 285   E0 = 0.5 * (D + A);
 286   E1 = E0 + [1,0] * epsilon;
 287
 288   I0 = [ E0[0], H[1] ];
 289   I1 = [ E1[0], H[1] ];
 290
 291   hull(){
 292     for (m=[0,1]) mirror([m,0])
 293       circleat(H, r0 - epsilon);
 294   }
 295   for (m=[0,1]) mirror([m,0]) {
 296     difference(){
 297       polygon([ E1,
 298                 I1,
 299                 H,
 300                 B1,
 301                 G,
 302                 F,
 303                 D
 304                 ]);
 305       circleat(D, r0 + epsilon);
 306     }
 307   }
 308 }
 309
 310 module CatchCatchProfile(){
 311   hull(){
 312     for (c=[ cppR, cppQ ])
 313       circleat(c, cp_rQ);
 314   }
 315   hull(){
 316     circleat(lpp12, lp_r12);
 317     circleat(lpp12 + [5,0], lp_r12);
 318     rectfromto(cppP, cppP + [5,0.1]);
 319   }
 320   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 321 }
 322
 323 module CatchCutProfile(){
 324   polygon([ cppB,
 325             cppA,
 326             cppD,
 327             cppF,
 328             cppF + [0,-10],
 329             cppF + [-10,-10],
 330             lpp12 + [-10,0],
 331             lpp12 + [10,0]
 332             ]);
 333 }
 334
 335 module Flip_rhs(yn=[0,1]) {
 336   for ($rhsflip=yn) {
 337     translate([phone_width/2, 0, 0])
 338       mirror([$rhsflip,0,0])
 339       translate([-phone_width/2, 0, 0])
 340       children();
 341   }
 342 }
 343
 344 module Flip_bot(yn=[0,1]) {
 345   for ($botflip=yn) {
 346     translate([0, -phone_height/2, 0])
 347       mirror([0, $botflip, 0])
 348       translate([0, phone_height/2, 0])
 349       children();
 350   }
 351 }
 352
 353 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 354   // sides
 355   Flip_rhs(){
 356     translate([0, -phone_cnr_rad, 0])
 357       rotate([90,0,0])
 358       linear_extrude(height = phone_height - phone_cnr_rad*2)
 359       children(0);
 360   }
 361   // corners
 362   Flip_rhs() Flip_bot() {
 363     translate([+1,-1] * phone_cnr_rad)
 364       intersection(){
 365         rotate_extrude()
 366           intersection(){
 367             mirror([1,0,0])
 368               translate([-1,0] * phone_cnr_rad)
 369               children(0);
 370             rectfromto([0,-20],[10,20]);
 371           }
 372         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 373           cube([10,10,40]);
 374       }
 375   }
 376   // top and bottom
 377   Flip_bot(){
 378     translate([ phone_width - phone_cnr_rad, 0,0 ])
 379       rotate([90,0,-90])
 380       linear_extrude(height = phone_width - phone_cnr_rad*2)
 381       children(0);
 382   }
 383   // fill
 384   translate([0,0, fill_zstart])
 385     mirror([0,0, fill_downwards])
 386     linear_extrude(height = fill_th)
 387     rectfromto([+1,-1] * phone_cnr_rad,
 388                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 389 }
 390
 391 module CaseAperture(pos, dia, $fn) {
 392   theta = 180/$fn;
 393   translate([ pos[0] + bumper[0],
 394               -epp2i[0],
 395               -pos[1] ])
 396     rotate([-90, theta, 0])
 397     cylinder(r = dia/2 / cos(theta),
 398              h = 60);
 399 }
 400
 401 module SideButton(y, y_ref_sign, l){
 402   // y_ref_sign:
 403   //   +1  measured from top    of actual phone to top    of button
 404   //   -1  measured from bottom of actual phone to bottom of button
 405   //    0  y is centre of button in coordinate system
 406   $button_l= l;
 407   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 408           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 409           y;
 410   //echo(eff_y);
 411   translate([0, eff_y, 0])
 412     children();
 413 }
 414
 415 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 416   $button_leg_only = true;
 417   SideButton(y, y_ref_sign, l) children();
 418 }
 419
 420 module Buttons(){
 421   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 422   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 423   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 424   Flip_rhs(   ) LidButtonishLeg(20, -1) children();
 425 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 426 }
 427
 428 module Struts(x_start, z_min, th){
 429   // if th is negative, starts at z_min and works towards -ve z
 430   // and object should then be printed other way up
 431   for (i= [1 : 1 : case_struts_count]) {
 432     translate([0,
 433                0,
 434                z_min])
 435       mirror([0,0, th<0 ? 1 : 0])
 436       translate([0,
 437                  -phone_height * i / (case_struts_count+1),
 438                  case_struts_solid_below])
 439       linear_extrude(height= abs(th)
 440                      -(case_struts_solid_below+case_struts_solid_above))
 441       rectfromto([               x_start, -0.5 * case_struts_width ],
 442                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 443   }
 444 }
 445
 446 module OrdinaryRearAperture(rhs,bot, pos){
 447   Flip_rhs(rhs) Flip_bot(bot)
 448     linextr(-20, 20)
 449     mirror([0,1])
 450     translate(pos + bumper)
 451     children();
 452 }
 453
 454 module MicroUSB(){
 455   Flip_bot(1){
 456     rotate([90,0,0])
 457       mirror([0,0,1])
 458       linextr(-epp2i[0], 60)
 459       translate([0.5 * phone_width, 0, 0])
 460       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 461                  [+microusb_width/2, epp0[1] + -microusb_above]);
 462   }
 463 }
 464
 465 module OrdinaryRearApertures(){
 466   // rear speaker
 467   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 468     rectfromto(-rearspeaker_gap,
 469                rearspeaker_size + rearspeaker_gap);
 470
 471   // finger hole to remove phone
 472   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 473                               phone[1]/2 ])
 474     scale(fingerpushhole_dias)
 475     circle(r= 0.5 );
 476 }
 477
 478 module RearCameraAperture(){
 479   Flip_rhs(1)
 480     mirror([0, 0, 1])
 481     linear_extrude(height = 20)
 482     mirror([0, 1, 0])
 483     translate(bumper)
 484     rectfromto(camera_pos_tl, camera_pos_br);
 485 }
 486
 487 module HingeLidProfile(){
 488   hull(){
 489     circleat(hppT, hp_r1);
 490     circleat(lpp12, lp_r12);
 491     polygon([lpp10,
 492              lpp13 + [2,0],
 493              lpp12,
 494              hppT]);
 495   }
 496 }
 497
 498 module HingeBaseProfile(){
 499   difference(){
 500     hull(){
 501       circleat(hppB, hp_r1);
 502       circleat(hppE, hp_r1);
 503       circleat(epp2o, case_th_bottom);
 504       circleat(hppB + [10,0], hp_r1);
 505     }
 506     polygon([epp5, epp1, epp2i, epp3, bppL]);
 507   }
 508 }
 509
 510 module HingeLeverOuterProfile(){
 511   hull(){
 512     circleat(hppT, hp_r2);
 513     circleat(hppB, hp_r2);
 514   }
 515 }
 516
 517 module HingeLeverInnerProfile(){
 518   for (c = [hppT, hppB]) {
 519     hull()
 520       for (x=[0,20])
 521         translate([x,0])
 522           circleat(c, hp_rn);
 523         circleat(hppB, hp_rn);
 524   }
 525 }
 526
 527 module Flip_hinge(){
 528   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 529   translate(hinge_origin)
 530     rotate([180,0,0])
 531     translate(-hinge_origin)
 532     children();
 533 }
 534
 535 module HingePortion(x0,x1){
 536   Flip_rhs() Flip_bot(1)
 537     translate([x0,0,0])
 538     mirror([1,0,0])
 539     rotate([90,0,-90])
 540     linear_extrude(height=x1-x0)
 541     children(0);
 542 }
 543
 544 module CaseBase(){
 545   AroundEdges(epp3[1], case_th_bottom, 1)
 546     EdgeProfile();
 547 }
 548
 549 module Case(){ ////toplevel
 550   difference(){
 551     union(){
 552       CaseBase();
 553
 554       // ledge (fixed keeper)
 555       intersection(){
 556         rotate([90, 0, 0])
 557           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 558           KeeperProfile(1);
 559
 560         // outline of the whole case, to stop it protruding
 561         translate([0,0, -25])
 562           linear_extrude(height = 50)
 563           hull()
 564           // Flip_rhs() // actually, we only care about the LH
 565           Flip_bot()
 566           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 567       }
 568
 569       // hinge
 570       HingePortion(hex20, hex21) HingeBaseProfile();
 571     }
 572
 573     // slot for keeper
 574     Flip_rhs(1)
 575       translate([0, -phone_cnr_rad, 0])
 576       rotate([90, 0, 0])
 577       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 578       minkowski(){
 579         KeeperProfile();
 580         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 581                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 582       }
 583
 584     // front camera
 585     RearCameraAperture();
 586
 587     // struts (invisible, because they're buried in the case)
 588     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 589
 590     Buttons(){
 591       mirror([1,0,0])
 592         rotate([90,0,90]) {
 593           intersection(){
 594             translate([0,0,-10])
 595               linear_extrude(height= 20)
 596               ButtonPlan($button_l, 0,1);
 597             if ($button_leg_only)
 598               rotate([-90,90,0])
 599                 translate([phone_width/2, -400, kppe[1]])
 600                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 601           }
 602           translate([0,0, -bppR[0]])
 603             linear_extrude(height= 20)
 604             ButtonPlan($button_l, 1,1);
 605         }
 606     }
 607
 608     // apertures along top edge
 609     CaseAperture(jack_pos, jack_dia, 8);
 610     Flip_rhs(1)
 611       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 612
 613     OrdinaryRearApertures();
 614
 615     MicroUSB();
 616
 617     // gaps for the lid's hinge arms
 618     HingePortion(hex20 - hinge_x_arms_gap,
 619                  hex21 + hinge_x_arms_gap)
 620       minkowski(){
 621         HingeLidProfile();
 622         circle(r= hinge_r_arms_gap, $fn= 8);
 623       }
 624
 625     // screw holes in the hinge arms
 626     HingeScrews();
 627   }
 628 }
 629
 630 module Lid(){ ////toplevel
 631   difference(){
 632     union(){
 633       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 634         LidEdgeProfile();
 635
 636       // button covers
 637       Buttons(){
 638         intersection(){
 639           rotate([90,0,90])
 640             translate([0,0,-10])
 641             linear_extrude(height= 20)
 642             ButtonPlan($button_l, 1,0);
 643           rotate([90,0,0])
 644              translate([0,0,-100])
 645             linear_extrude(height= 200)
 646             ButtonCoverProfile();
 647         }
 648       }
 649
 650       // hinge arms
 651       HingePortion(hex20, hex21) HingeLidProfile();
 652     }
 653     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 654
 655     // screw holes in the hinge arms
 656     HingeScrews();
 657   }
 658 }
 659
 660 module HingeLever(){ ////toplevel
 661   difference() {
 662     // outer body, positive
 663     HingePortion(hex22, hex22 + phone_width/2)
 664       HingeLeverOuterProfile();
 665
 666     // space for the screws
 667     HingePortion(hex23, hex24)
 668       HingeLeverInnerProfile();
 669
 670     // bores for the screws
 671     HingeScrews();
 672
 673     // space for the charging cable
 674     MicroUSB();
 675     Flip_hinge() MicroUSB();
 676   }
 677 }
 678
 679 module HingeLeverPrint(){ ////toplevel
 680   rotate([90,0,0])
 681     HingeLever();
 682 }
 683
 684 module TestSelectLength(){
 685   translate([-30, -200, -20])
 686     cube([30 + 15, 250, 40]);
 687 }
 688
 689 module TestLength(){ ////toplevel
 690   intersection(){
 691     Case();
 692     TestSelectLength();
 693   }
 694 }
 695
 696 module TestLengthRight(){ ////toplevel
 697   intersection(){
 698     Case();
 699     Flip_rhs(1)
 700       TestSelectLength();
 701   }
 702 }
 703
 704 module TestSelectWidth(){
 705   translate([-30, -(phone_height - 25), -20])
 706     mirror([0, 1, 0])
 707     cube([200, 50, 40]);
 708 }
 709
 710 module TestWidth(){ ////toplevel
 711   intersection(){
 712     Case();
 713     TestSelectWidth();
 714   }
 715 }
 716
 717 module TestLidWidthPrint(){ ////toplevel
 718   rotate([0,180.0]) intersection(){
 719     Lid();
 720     TestSelectWidth();
 721   }
 722 }
 723
 724 module TestSelectRearAperture(){
 725   minkowski(){
 726     union() children();
 727     translate([20, 0,0])
 728       cube([42, 2, 1], center=true);
 729   }
 730 }
 731
 732 module TestSelectCamera(){
 733   minkowski(){
 734     TestSelectRearAperture()
 735       RearCameraAperture();
 736     cube([0.1, 50, 0.1]);
 737   }
 738 }
 739
 740 module TestSelectOrdinaryRearApertures(){
 741   TestSelectRearAperture()
 742     OrdinaryRearApertures();
 743 }
 744
 745 module TestCamera(){ ////toplevel
 746   intersection(){
 747     Case();
 748     TestSelectCamera();
 749   }
 750 }
 751
 752 module TestLidByCamera(){ ////toplevel
 753   intersection(){
 754     Lid();
 755     TestSelectCamera();
 756   }
 757 }
 758
 759 module TestLidByCameraPrint(){ ////toplevel
 760   rotate([180,0,0]) TestLidByCamera();
 761 }
 762
 763 module DemoByCamera(){ ////toplevel
 764   color("blue") TestLidByCamera();
 765   color("red")  TestCamera();
 766 }
 767
 768 module OneKeeper(){ ////toplevel
 769   translate([0, -phone_cnr_rad, 0])
 770     rotate([90, 0, 0])
 771     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 772     KeeperProfile();
 773 }
 774
 775 module OneKeeperPrint(){ ////toplevel
 776   rotate([0,180,0])
 777     OneKeeper();
 778 }
 779
 780 module LidPrint(){ ////toplevel
 781   rotate([0,180,0])
 782     Lid();
 783 }
 784
 785 module TestSelectFrame(){
 786   include = [1,-1] * (epp2i[0] + 4);
 787
 788   difference(){
 789     cube(1000, center=true);
 790     translate([0,0, -100])
 791       linear_extrude(height=200)
 792       rectfromto(include,  inside_br - include);
 793   }
 794 }
 795
 796 module TestFrameCase(){ ////toplevel
 797   intersection(){
 798     Case();
 799     union(){
 800       TestSelectFrame();
 801       TestSelectCamera();
 802       TestSelectOrdinaryRearApertures();
 803     }
 804   }
 805 }
 806
 807 module TestFrameLidPrint(){ ////toplevel
 808   rotate([0,180,0]) intersection(){
 809     Lid();
 810     TestSelectFrame();
 811   }
 812 }
 813
 814 module Keeper(){ ////toplevel
 815   Flip_rhs()
 816     OneKeeper();
 817 }
 818
 819 module ButtonPlanForDemo(z, deep, cut){
 820   translate([0,0,z])
 821     ButtonPlan(8, deep, cut);
 822 }
 823
 824 module HingeScrews(){
 825   Flip_rhs() Flip_bot(1){
 826     for (c= [ hppT, hppB ])
 827       translate([ hex20,
 828                   -c[0],
 829                   c[1] ]){
 830         rotate([0,90,0])
 831           translate([0,0,-.2])
 832           cylinder( r= hingescrew_shaft_dia/2,
 833                     h = hingescrew_shaft_len+0.2 );
 834         rotate([0,-90,0])
 835           translate([0,0,+.1])
 836           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 837       }
 838   }
 839 }
 840
 841 module DemoFrame(){ ////toplevel
 842   color("red") TestFrameCase();
 843   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 844   color("black") HingeScrews();
 845   %HingeLever();
 846 }
 847
 848 module DemoHingedFrame(){ ///toplevel
 849   color("red") TestFrameCase();
 850   translate([0,0, -2*hp_k])
 851   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 852
 853   Flip_hinge(){
 854     color("orange") HingeLever();
 855     color("black") HingeScrews();
 856   }
 857 }
 858
 859 module DemoHinge(){ ////toplevel
 860   DemoFrame();
 861   translate([0,0, -hp_k*3])
 862     DemoHingedFrame();
 863 }
 864
 865 module DemoProfiles(){ ////toplevel
 866   LidEdgeProfile();
 867   %EdgeProfile();
 868   KeeperProfile();
 869   translate([0,0,-1]) color("black") KeeperProfile(1);
 870
 871   translate([20,0]) {
 872     LidEdgeProfile();
 873     %EdgeProfile();
 874
 875     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 876
 877     color("blue") ButtonCoverProfile();
 878     color("red") {
 879       rectfromto(bppQ, demopoint_QR);
 880       rectfromto(bppR, demopoint_QR);
 881     }
 882   }
 883
 884   translate([-20,0]) {
 885     color("black") ButtonPlanForDemo(-2, 0,1);
 886     color("red" )  ButtonPlanForDemo(-4, 1,1);
 887     color("blue")  ButtonPlanForDemo(-6, 1,0);
 888   }
 889
 890   translate([0, -30]) {
 891     %LidEdgeProfile();
 892     %EdgeProfile();
 893     color("blue") HingeLidProfile();
 894     color("red")  HingeBaseProfile();
 895     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 896     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 897   }
 898
 899   translate([20,-30]) {
 900     %EdgeProfile();
 901     %LidEdgeProfile();
 902     //translate([0,0,1]) CatchCutProfile();
 903     color("blue") CatchCatchProfile();
 904     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
 905   }
 906 }
 907
 908 //EdgeProfile();
 909 //KeeperProfile();
 910 //CaseBase();
 911 //%Case();
 912 //Keeper();
 913 //LidEdgeProfile();
 914 //KeeperProfile();
 915 //DemoProfiles();