fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 phone_cnr_rad = 6.0;
  12
  13 button_cutout_depth = 9;
  14
  15 phone_edge_thick = 9.0;
  16 phone_total_thick = 12.0;
  17 phone_backside_slope_inner = 1.5; // larger means shallower
  18 phone_backside_slope_outer = 1.0; // larger means shallower
  19
  20 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  21 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  22
  23 jack_pos = [ 13.92, 7.96 ];
  24 jack_dia = 9.1 + .5; // some jack I had lying around
  25
  26 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  27 noisecancelmic_dia = 1.75;
  28
  29 fingerpushhole_dias = [ 15, 18 ];
  30
  31 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  32 rearspeaker_size   = [  3.76,  7.36 ];
  33
  34 microusb_above = 3.27 - 0.25;
  35 microusb_below = 0.0;
  36 microusb_width = 16.12 + 0.25;
  37
  38 case_th_bottom = 2.5;
  39 case_th_lid = 2.5;
  40 case_th_side = 2;
  41 case_th_lip = 1.2;
  42
  43 case_struts_count = 6;
  44 case_struts_solid_below = 1.00;
  45 case_struts_solid_above = 0.75;
  46 case_struts_width = 0.10;
  47
  48 keeper_th_z = 0.75;
  49 keeper_th_x = 0.75;
  50 keeper_inner_width = 2.75;
  51 keeper_inner_height = 2.75;
  52 keeper_slant_slope = 2; // larger means steeper
  53
  54 keeper_gap_z_top = 0.25;
  55 keeper_gap_z_bot = 0.75;
  56 keeper_gap_x     = 0.25;
  57 keeper_gap_x_holes = 0.75;
  58
  59 case_lip = 1.25;
  60
  61 lid_gap_x = 0.25;
  62 lid_gap_z = 0.25;
  63 lid_lip = 1.75;
  64
  65 catch_slop = 0.25;
  66
  67 foldover_gap = 0.50;
  68 foldover_lever_gap = 0.50;
  69
  70 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  71 hingescrew_shaft_len = 12;
  72 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  73 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  74 hingescrew_head_th = 1.38 + 0.75;
  75 hingescrew_head_dia = 3.92;
  76 lever_cover_th = 0.75;
  77 hingemount_th = 2.5;
  78
  79 $fa = 5;
  80 $fs = 0.1;
  81
  82 button_l_fudge = 4.4;
  83 buttonishleg_default_l_is_fudge = 10;
  84
  85 hinge_base_slope = 1.5; // bigger is steeper
  86
  87 strut_min_at_end = 1.5;
  88
  89 hinge_x_gap = 0.125;
  90 hinge_x_postscrew_gap = 0.75;
  91 hinge_x_arms_gap = 0.35;
  92 hinge_r_arms_gap = 0.55;
  93
  94 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  95
  96 catch_len = 9;
  97
  98 catch_depth = 0.75;
  99 catch_height = 0.35;
 100 catch_finger_height = 1.5;
 101 catch_finger_depth = 2.5;
 102
 103 // ---------- calculated ----------
 104
 105 phone_width =  (phone + bumper*2)[0];
 106 phone_height = (phone + bumper*2)[1];
 107
 108 inside_br = [phone_width, -phone_height];
 109
 110 //echo(camera_pos_tl + bumper,
 111 //     camera_pos_br + bumper);
 112
 113 // ----- could be changed -----
 114 lid_buttoncover_gap = lid_gap_x;
 115 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 116
 117 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 118
 119 //lid_lip_overlap_width xxx bad name = ;
 120 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 121
 122 epp0 = [0,0];
 123 epp1 = [0, -phone_edge_thick];
 124 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 125 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 126 epp3 = epp2i + [10, 0];
 127 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 128 epp4 = epp5 + [-1,0] * case_th_side;
 129
 130 kppe = [0,0];
 131 kppd = kppe + [1,0] * keeper_inner_width;
 132 kppc = kppd + [0,1] * keeper_th_z;
 133 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 134 kppf = kppe - [0,1] * keeper_inner_height;
 135 kppa = [ kppb[0], kppf[1] ];
 136
 137 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 138 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 139
 140 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 141
 142 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 143 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 144
 145 // button profile
 146 bppM = epp4 + [0,5];
 147 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 148 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 149 bppS = [ epp1[0], bppR[1] ];
 150 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 151 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 152 bppO = [ bppN[0], bppP[1] ];
 153 bppL = lpp10 + [5,0];
 154 bppK = [ bppL[0], bppN[1] ];
 155 bppJ = [ bppN[0], bppL[1] ];
 156
 157 // hinge plan
 158 hp_rn = hingescrew_nut_dia/2;
 159 hp_r2_min = hp_rn + lever_cover_th;
 160 hp_rs = hingescrew_shaft_dia/2;
 161 hp_r1_min = hp_rs + hingemount_th;
 162
 163 hp_r1 = max(hp_r1_min, hp_r2_min);
 164 hp_r2 = hp_r1;
 165
 166 hppU = lpp13;
 167 hppS = epp2o + [0,-1] * case_th_bottom;
 168 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 169
 170 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 171          0.5 * (hppU + hppS)[1] ];
 172 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 173 hppB = hppT + [0,-1] * hp_k;
 174
 175 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 176 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 177 hppE = [ hppE_x, hppE_y ];
 178
 179 // hinge elevation x coords
 180
 181 hingescrew_portion_len =
 182   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 183
 184 hex20 = max(epp2o[0],
 185             phone_cnr_rad,
 186             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 187 hex21 = hex20 + hingescrew_portion_len;
 188 hex22 = hex21 - hinge_x_gap;
 189 hex23 = hex22 + hingescrew_portion_len;
 190 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 191 echo(hex20, hex21, hex22, hex23, hex24);
 192 echo(hingescrew_portion_len);
 193
 194 // catch
 195
 196 cppJ = bppJ;
 197 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 198 cppB = [ epp0[0], cppA[1] ];
 199 cppP = [ epp4[0], cppJ[1] ];
 200
 201 cppS = cppJ + [0,-1] * catch_len;
 202 cppD = [ cppA[0], cppS[1] + catch_slop ];
 203 cppC = [ cppB[0], cppD[1] ];
 204 cppT = cppS + [1,0] * catch_depth;
 205 cppU = cppT + [0,-1] * catch_height;
 206 cppV = [ cppS[0], cppU[1] - catch_height ];
 207
 208 cppR = 0.5*(cppP + cppJ);
 209
 210 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 211 cppQ = [ cppR[0],
 212          cppV[1] - (catch_finger_height - cp_rQ) ];
 213 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 214
 215 // ---------- modules ----------
 216
 217 module KeeperProfile(slant=0){
 218   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 219   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 220 }
 221
 222 module EdgeProfile(){
 223   difference(){
 224     hull(){
 225       translate(epp3) square(case_th_bottom*2, center=true);
 226       circleat(epp2o, r=case_th_bottom);
 227       circleat(epp1, r=case_th_side);
 228       rectfromto(epp0, epp4);
 229     }
 230     polygon([ epp5 + [0,10],
 231               epp1,
 232               epp2i,
 233               epp3 + [10,0] ]);
 234   }
 235 }
 236
 237 module LidEdgeProfile(){
 238   polygon([ lpp10,
 239             lpp11,
 240             lpp12,
 241             lpp13,
 242             lpp13 + [10, 0],
 243             lpp10 + [10, 0]
 244             ]);
 245   intersection(){
 246     circleat(lpp12, r=lp_r12);
 247     rectfromto( lpp12 + [-10,   0],
 248                 lpp12 + [+10, +10] );
 249   }
 250 }
 251
 252 module ButtonCoverProfile(){
 253   intersection(){
 254     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 255     hull(){
 256       EdgeProfile();
 257       LidEdgeProfile();
 258     }
 259   }
 260 }
 261
 262 module ButtonPlan(l, deep, cut){
 263   epsilon =
 264     (cut  ? 0 : lid_buttoncover_gap);
 265
 266   delta =
 267     (deep ? lid_buttoncover_overlap : 0);
 268
 269   C = [0,0]; // by definition
 270   T = [ 0, epp4[1] ];
 271   G = T + [0,10];
 272
 273   B0 = C + [0,-1] * button_cutout_depth;
 274   B1 = B0 + [0,1] * epsilon;
 275
 276   r0 = 0.5 * (T[1] - B0[1]);
 277   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 278   H = A + [0,-1] * delta;
 279
 280   D = A + [-2,0] * r0;
 281   F = D + [0,10];
 282
 283   E0 = 0.5 * (D + A);
 284   E1 = E0 + [1,0] * epsilon;
 285
 286   I0 = [ E0[0], H[1] ];
 287   I1 = [ E1[0], H[1] ];
 288
 289   hull(){
 290     for (m=[0,1]) mirror([m,0])
 291       circleat(H, r0 - epsilon);
 292   }
 293   for (m=[0,1]) mirror([m,0]) {
 294     difference(){
 295       polygon([ E1,
 296                 I1,
 297                 H,
 298                 B1,
 299                 G,
 300                 F,
 301                 D
 302                 ]);
 303       circleat(D, r0 + epsilon);
 304     }
 305   }
 306 }
 307
 308 module CatchCatchProfile(){
 309   hull(){
 310     for (c=[ cppR, cppQ ])
 311       circleat(c, cp_rQ);
 312   }
 313   hull(){
 314     circleat(lpp12, lp_r12);
 315     circleat(lpp12 + [5,0], lp_r12);
 316     rectfromto(cppP, cppP + [5,0.1]);
 317   }
 318   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 319 }
 320
 321 module CatchCutProfile(){
 322   polygon([ cppB,
 323             cppA,
 324             cppD,
 325             cppF,
 326             cppF + [0,-10],
 327             cppF + [-10,-10],
 328             lpp12 + [-10,0],
 329             lpp12 + [10,0]
 330             ]);
 331 }
 332
 333 module Flip_rhs(yn=[0,1]) {
 334   for ($rhsflip=yn) {
 335     translate([phone_width/2, 0, 0])
 336       mirror([$rhsflip,0,0])
 337       translate([-phone_width/2, 0, 0])
 338       children();
 339   }
 340 }
 341
 342 module Flip_bot(yn=[0,1]) {
 343   for ($botflip=yn) {
 344     translate([0, -phone_height/2, 0])
 345       mirror([0, $botflip, 0])
 346       translate([0, phone_height/2, 0])
 347       children();
 348   }
 349 }
 350
 351 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 352   // sides
 353   Flip_rhs(){
 354     translate([0, -phone_cnr_rad, 0])
 355       rotate([90,0,0])
 356       linear_extrude(height = phone_height - phone_cnr_rad*2)
 357       children(0);
 358   }
 359   // corners
 360   Flip_rhs() Flip_bot() {
 361     translate([+1,-1] * phone_cnr_rad)
 362       intersection(){
 363         rotate_extrude()
 364           intersection(){
 365             mirror([1,0,0])
 366               translate([-1,0] * phone_cnr_rad)
 367               children(0);
 368             rectfromto([0,-20],[10,20]);
 369           }
 370         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 371           cube([10,10,40]);
 372       }
 373   }
 374   // top and bottom
 375   Flip_bot(){
 376     translate([ phone_width - phone_cnr_rad, 0,0 ])
 377       rotate([90,0,-90])
 378       linear_extrude(height = phone_width - phone_cnr_rad*2)
 379       children(0);
 380   }
 381   // fill
 382   translate([0,0, fill_zstart])
 383     mirror([0,0, fill_downwards])
 384     linear_extrude(height = fill_th)
 385     rectfromto([+1,-1] * phone_cnr_rad,
 386                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 387 }
 388
 389 module CaseAperture(pos, dia, $fn) {
 390   theta = 180/$fn;
 391   translate([ pos[0] + bumper[0],
 392               -epp2i[0],
 393               -pos[1] ])
 394     rotate([-90, theta, 0])
 395     cylinder(r = dia/2 / cos(theta),
 396              h = 60);
 397 }
 398
 399 module SideButton(y, y_ref_sign, l){
 400   // y_ref_sign:
 401   //   +1  measured from top    of actual phone to top    of button
 402   //   -1  measured from bottom of actual phone to bottom of button
 403   //    0  y is centre of button in coordinate system
 404   $button_l= l;
 405   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 406           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 407           y;
 408   //echo(eff_y);
 409   translate([0, eff_y, 0])
 410     children();
 411 }
 412
 413 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 414   $button_leg_only = true;
 415   SideButton(y, y_ref_sign, l) children();
 416 }
 417
 418 module Buttons(){
 419   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 420   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 421   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 422   Flip_rhs(   ) LidButtonishLeg(20, -1) children();
 423 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 424 }
 425
 426 module Struts(x_start, z_min, th){
 427   // if th is negative, starts at z_min and works towards -ve z
 428   // and object should then be printed other way up
 429   for (i= [1 : 1 : case_struts_count]) {
 430     translate([0,
 431                0,
 432                z_min])
 433       mirror([0,0, th<0 ? 1 : 0])
 434       translate([0,
 435                  -phone_height * i / (case_struts_count+1),
 436                  case_struts_solid_below])
 437       linear_extrude(height= abs(th)
 438                      -(case_struts_solid_below+case_struts_solid_above))
 439       rectfromto([               x_start, -0.5 * case_struts_width ],
 440                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 441   }
 442 }
 443
 444 module OrdinaryRearAperture(rhs,bot, pos){
 445   Flip_rhs(rhs) Flip_bot(bot)
 446     linextr(-20, 20)
 447     mirror([0,1])
 448     translate(pos + bumper)
 449     children();
 450 }
 451
 452 module MicroUSB(){
 453   Flip_bot(1){
 454     rotate([90,0,0])
 455       mirror([0,0,1])
 456       linextr(-epp2i[0], 60)
 457       translate([0.5 * phone_width, 0, 0])
 458       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 459                  [+microusb_width/2, epp0[1] + -microusb_above]);
 460   }
 461 }
 462
 463 module OrdinaryRearApertures(){
 464   // rear speaker
 465   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 466     rectfromto(-rearspeaker_gap,
 467                rearspeaker_size + rearspeaker_gap);
 468
 469   // finger hole to remove phone
 470   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 471                               phone[1]/2 ])
 472     scale(fingerpushhole_dias)
 473     circle(r= 0.5 );
 474 }
 475
 476 module RearCameraAperture(){
 477   Flip_rhs(1)
 478     mirror([0, 0, 1])
 479     linear_extrude(height = 20)
 480     mirror([0, 1, 0])
 481     translate(bumper)
 482     rectfromto(camera_pos_tl, camera_pos_br);
 483 }
 484
 485 module HingeLidProfile(){
 486   hull(){
 487     circleat(hppT, hp_r1);
 488     circleat(lpp12, lp_r12);
 489     polygon([lpp10,
 490              lpp13 + [2,0],
 491              lpp12,
 492              hppT]);
 493   }
 494 }
 495
 496 module HingeBaseProfile(){
 497   difference(){
 498     hull(){
 499       circleat(hppB, hp_r1);
 500       circleat(hppE, hp_r1);
 501       circleat(epp2o, case_th_bottom);
 502       circleat(hppB + [10,0], hp_r1);
 503     }
 504     polygon([epp5, epp1, epp2i, epp3, bppL]);
 505   }
 506 }
 507
 508 module HingeLeverOuterProfile(){
 509   hull(){
 510     circleat(hppT, hp_r2);
 511     circleat(hppB, hp_r2);
 512   }
 513 }
 514
 515 module HingeLeverInnerProfile(){
 516   for (c = [hppT, hppB]) {
 517     hull()
 518       for (x=[0,20])
 519         translate([x,0])
 520           circleat(c, hp_rn);
 521         circleat(hppB, hp_rn);
 522   }
 523 }
 524
 525 module Flip_hinge(){
 526   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 527   translate(hinge_origin)
 528     rotate([180,0,0])
 529     translate(-hinge_origin)
 530     children();
 531 }
 532
 533 module HingePortion(x0,x1){
 534   Flip_rhs() Flip_bot(1)
 535     translate([x0,0,0])
 536     mirror([1,0,0])
 537     rotate([90,0,-90])
 538     linear_extrude(height=x1-x0)
 539     children(0);
 540 }
 541
 542 module CaseBase(){
 543   AroundEdges(epp3[1], case_th_bottom, 1)
 544     EdgeProfile();
 545 }
 546
 547 module Case(){ ////toplevel
 548   difference(){
 549     union(){
 550       CaseBase();
 551
 552       // ledge (fixed keeper)
 553       intersection(){
 554         rotate([90, 0, 0])
 555           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 556           KeeperProfile(1);
 557
 558         // outline of the whole case, to stop it protruding
 559         translate([0,0, -25])
 560           linear_extrude(height = 50)
 561           hull()
 562           // Flip_rhs() // actually, we only care about the LH
 563           Flip_bot()
 564           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 565       }
 566
 567       // hinge
 568       HingePortion(hex20, hex21) HingeBaseProfile();
 569     }
 570
 571     // slot for keeper
 572     Flip_rhs(1)
 573       translate([0, -phone_cnr_rad, 0])
 574       rotate([90, 0, 0])
 575       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 576       minkowski(){
 577         KeeperProfile();
 578         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 579                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 580       }
 581
 582     // front camera
 583     RearCameraAperture();
 584
 585     // struts (invisible, because they're buried in the case)
 586     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 587
 588     Buttons(){
 589       mirror([1,0,0])
 590         rotate([90,0,90]) {
 591           intersection(){
 592             translate([0,0,-10])
 593               linear_extrude(height= 20)
 594               ButtonPlan($button_l, 0,1);
 595             if ($button_leg_only)
 596               rotate([-90,90,0])
 597                 translate([phone_width/2, -400, kppe[1]])
 598                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 599           }
 600           translate([0,0, -bppR[0]])
 601             linear_extrude(height= 20)
 602             ButtonPlan($button_l, 1,1);
 603         }
 604     }
 605
 606     // apertures along top edge
 607     CaseAperture(jack_pos, jack_dia, 8);
 608     Flip_rhs(1)
 609       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 610
 611     OrdinaryRearApertures();
 612
 613     MicroUSB();
 614
 615     // gaps for the lid's hinge arms
 616     HingePortion(hex20 - hinge_x_arms_gap,
 617                  hex21 + hinge_x_arms_gap)
 618       minkowski(){
 619         HingeLidProfile();
 620         circle(r= hinge_r_arms_gap, $fn= 8);
 621       }
 622
 623     // screw holes in the hinge arms
 624     HingeScrews();
 625   }
 626 }
 627
 628 module Lid(){ ////toplevel
 629   difference(){
 630     union(){
 631       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 632         LidEdgeProfile();
 633
 634       // button covers
 635       Buttons(){
 636         intersection(){
 637           rotate([90,0,90])
 638             translate([0,0,-10])
 639             linear_extrude(height= 20)
 640             ButtonPlan($button_l, 1,0);
 641           rotate([90,0,0])
 642              translate([0,0,-100])
 643             linear_extrude(height= 200)
 644             ButtonCoverProfile();
 645         }
 646       }
 647
 648       // hinge arms
 649       HingePortion(hex20, hex21) HingeLidProfile();
 650     }
 651     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 652
 653     // screw holes in the hinge arms
 654     HingeScrews();
 655   }
 656 }
 657
 658 module HingeLever(){ ////toplevel
 659   difference() {
 660     // outer body, positive
 661     HingePortion(hex22, hex22 + phone_width/2)
 662       HingeLeverOuterProfile();
 663
 664     // space for the screws
 665     HingePortion(hex23, hex24)
 666       HingeLeverInnerProfile();
 667
 668     // bores for the screws
 669     HingeScrews();
 670
 671     // space for the charging cable
 672     MicroUSB();
 673     Flip_hinge() MicroUSB();
 674   }
 675 }
 676
 677 module HingeLeverPrint(){ ////toplevel
 678   rotate([90,0,0])
 679     HingeLever();
 680 }
 681
 682 module TestSelectLength(){
 683   translate([-30, -200, -20])
 684     cube([30 + 15, 250, 40]);
 685 }
 686
 687 module TestLength(){ ////toplevel
 688   intersection(){
 689     Case();
 690     TestSelectLength();
 691   }
 692 }
 693
 694 module TestLengthRight(){ ////toplevel
 695   intersection(){
 696     Case();
 697     Flip_rhs(1)
 698       TestSelectLength();
 699   }
 700 }
 701
 702 module TestSelectWidth(){
 703   translate([-30, -(phone_height - 25), -20])
 704     mirror([0, 1, 0])
 705     cube([200, 50, 40]);
 706 }
 707
 708 module TestWidth(){ ////toplevel
 709   intersection(){
 710     Case();
 711     TestSelectWidth();
 712   }
 713 }
 714
 715 module TestLidWidthPrint(){ ////toplevel
 716   rotate([0,180.0]) intersection(){
 717     Lid();
 718     TestSelectWidth();
 719   }
 720 }
 721
 722 module TestSelectRearAperture(){
 723   minkowski(){
 724     union() children();
 725     translate([20, 0,0])
 726       cube([42, 2, 1], center=true);
 727   }
 728 }
 729
 730 module TestSelectCamera(){
 731   minkowski(){
 732     TestSelectRearAperture()
 733       RearCameraAperture();
 734     cube([0.1, 50, 0.1]);
 735   }
 736 }
 737
 738 module TestSelectOrdinaryRearApertures(){
 739   TestSelectRearAperture()
 740     OrdinaryRearApertures();
 741 }
 742
 743 module TestCamera(){ ////toplevel
 744   intersection(){
 745     Case();
 746     TestSelectCamera();
 747   }
 748 }
 749
 750 module TestLidByCamera(){ ////toplevel
 751   intersection(){
 752     Lid();
 753     TestSelectCamera();
 754   }
 755 }
 756
 757 module TestLidByCameraPrint(){ ////toplevel
 758   rotate([180,0,0]) TestLidByCamera();
 759 }
 760
 761 module DemoByCamera(){ ////toplevel
 762   color("blue") TestLidByCamera();
 763   color("red")  TestCamera();
 764 }
 765
 766 module OneKeeper(){ ////toplevel
 767   translate([0, -phone_cnr_rad, 0])
 768     rotate([90, 0, 0])
 769     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 770     KeeperProfile();
 771 }
 772
 773 module OneKeeperPrint(){ ////toplevel
 774   rotate([0,180,0])
 775     OneKeeper();
 776 }
 777
 778 module LidPrint(){ ////toplevel
 779   rotate([0,180,0])
 780     Lid();
 781 }
 782
 783 module TestSelectFrame(){
 784   include = [1,-1] * (epp2i[0] + 4);
 785
 786   difference(){
 787     cube(1000, center=true);
 788     translate([0,0, -100])
 789       linear_extrude(height=200)
 790       rectfromto(include,  inside_br - include);
 791   }
 792 }
 793
 794 module TestFrameCase(){ ////toplevel
 795   intersection(){
 796     Case();
 797     union(){
 798       TestSelectFrame();
 799       TestSelectCamera();
 800       TestSelectOrdinaryRearApertures();
 801     }
 802   }
 803 }
 804
 805 module TestFrameLidPrint(){ ////toplevel
 806   rotate([0,180,0]) intersection(){
 807     Lid();
 808     TestSelectFrame();
 809   }
 810 }
 811
 812 module Keeper(){ ////toplevel
 813   Flip_rhs()
 814     OneKeeper();
 815 }
 816
 817 module ButtonPlanForDemo(z, deep, cut){
 818   translate([0,0,z])
 819     ButtonPlan(8, deep, cut);
 820 }
 821
 822 module HingeScrews(){
 823   Flip_rhs() Flip_bot(1){
 824     for (c= [ hppT, hppB ])
 825       translate([ hex20,
 826                   -c[0],
 827                   c[1] ]){
 828         rotate([0,90,0])
 829           translate([0,0,-.2])
 830           cylinder( r= hingescrew_shaft_dia/2,
 831                     h = hingescrew_shaft_len+0.2 );
 832         rotate([0,-90,0])
 833           translate([0,0,+.1])
 834           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 835       }
 836   }
 837 }
 838
 839 module DemoFrame(){ ////toplevel
 840   color("red") TestFrameCase();
 841   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 842   color("black") HingeScrews();
 843   %HingeLever();
 844 }
 845
 846 module DemoHingedFrame(){ ///toplevel
 847   color("red") TestFrameCase();
 848   translate([0,0, -2*hp_k])
 849   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 850
 851   Flip_hinge(){
 852     color("orange") HingeLever();
 853     color("black") HingeScrews();
 854   }
 855 }
 856
 857 module DemoHinge(){ ////toplevel
 858   DemoFrame();
 859   translate([0,0, -hp_k*3])
 860     DemoHingedFrame();
 861 }
 862
 863 module DemoProfiles(){ ////toplevel
 864   LidEdgeProfile();
 865   %EdgeProfile();
 866   KeeperProfile();
 867   translate([0,0,-1]) color("black") KeeperProfile(1);
 868
 869   translate([20,0]) {
 870     LidEdgeProfile();
 871     %EdgeProfile();
 872
 873     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 874
 875     color("blue") ButtonCoverProfile();
 876     color("red") {
 877       rectfromto(bppQ, demopoint_QR);
 878       rectfromto(bppR, demopoint_QR);
 879     }
 880   }
 881
 882   translate([-20,0]) {
 883     color("black") ButtonPlanForDemo(-2, 0,1);
 884     color("red" )  ButtonPlanForDemo(-4, 1,1);
 885     color("blue")  ButtonPlanForDemo(-6, 1,0);
 886   }
 887
 888   translate([0, -30]) {
 889     %LidEdgeProfile();
 890     %EdgeProfile();
 891     color("blue") HingeLidProfile();
 892     color("red")  HingeBaseProfile();
 893     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 894     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 895   }
 896
 897   translate([20,-30]) {
 898     %EdgeProfile();
 899     %LidEdgeProfile();
 900     //translate([0,0,1]) CatchCutProfile();
 901     color("blue") CatchCatchProfile();
 902     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
 903   }
 904 }
 905
 906 //EdgeProfile();
 907 //KeeperProfile();
 908 //CaseBase();
 909 //%Case();
 910 //Keeper();
 911 //LidEdgeProfile();
 912 //KeeperProfile();
 913 //DemoProfiles();