fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 phone_cnr_rad = 6.0;
  12
  13 button_cutout_depth = 9;
  14
  15 phone_edge_thick = 9.0;
  16 phone_total_thick = 12.0;
  17 phone_backside_slope_inner = 1.5; // larger means shallower
  18 phone_backside_slope_outer = 1.0; // larger means shallower
  19
  20 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  21 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  22
  23 jack_pos = [ 13.92, 7.96 ];
  24 jack_dia = 9.1 + .5; // some jack I had lying around
  25
  26 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  27 noisecancelmic_dia = 1.75;
  28
  29 fingerpushhole_dias = [ 15, 18 ];
  30
  31 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  32 rearspeaker_size   = [  3.76,  7.36 ];
  33
  34 microusb_above = 3.27 - 0.25;
  35 microusb_below = 0.0;
  36 microusb_width = 16.12 + 0.25;
  37
  38 case_th_bottom = 2.5;
  39 case_th_lid = 2.5;
  40 case_th_side = 2;
  41 case_th_lip = 1.2;
  42
  43 case_struts_count = 6;
  44 case_struts_solid_below = 1.00;
  45 case_struts_solid_above = 0.75;
  46 case_struts_width = 0.10;
  47
  48 keeper_th_z = 0.75;
  49 keeper_th_x = 0.75;
  50 keeper_inner_width = 2.75;
  51 keeper_inner_height = 2.75;
  52 keeper_slant_slope = 2; // larger means steeper
  53
  54 keeper_gap_z_top = 0.25;
  55 keeper_gap_z_bot = 0.75;
  56 keeper_gap_x     = 0.25;
  57 keeper_gap_x_holes = 0.75;
  58
  59 case_lip = 1.25;
  60
  61 lid_gap_x = 0.25;
  62 lid_gap_z = 0.25;
  63 lid_lip = 1.75;
  64
  65 foldover_gap = 0.50;
  66 foldover_lever_gap = 0.50;
  67
  68 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  69 hingescrew_shaft_len = 12;
  70 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  71 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  72 hingescrew_head_th = 1.38 + 0.75;
  73 hingescrew_head_dia = 3.92;
  74 lever_cover_th = 0.75;
  75 hingemount_th = 2.5;
  76
  77 $fa = 5;
  78 $fs = 0.1;
  79
  80 button_l_fudge = 4.4;
  81 buttonishleg_default_l_is_fudge = 10;
  82
  83 hinge_base_slope = 1.5; // bigger is steeper
  84
  85 strut_min_at_end = 1.5;
  86
  87 hinge_x_gap = 0.125;
  88 hinge_x_postscrew_gap = 0.75;
  89 hinge_x_arms_gap = 0.35;
  90 hinge_r_arms_gap = 0.55;
  91
  92 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  93
  94 // ---------- calculated ----------
  95
  96 phone_width =  (phone + bumper*2)[0];
  97 phone_height = (phone + bumper*2)[1];
  98
  99 inside_br = [phone_width, -phone_height];
 100
 101 //echo(camera_pos_tl + bumper,
 102 //     camera_pos_br + bumper);
 103
 104 // ----- could be changed -----
 105 lid_buttoncover_gap = lid_gap_x;
 106 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 107
 108 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 109
 110 //lid_lip_overlap_width xxx bad name = ;
 111 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 112
 113 epp0 = [0,0];
 114 epp1 = [0, -phone_edge_thick];
 115 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 116 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 117 epp3 = epp2i + [10, 0];
 118 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 119 epp4 = epp5 + [-1,0] * case_th_side;
 120
 121 kppe = [0,0];
 122 kppd = kppe + [1,0] * keeper_inner_width;
 123 kppc = kppd + [0,1] * keeper_th_z;
 124 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 125 kppf = kppe - [0,1] * keeper_inner_height;
 126 kppa = [ kppb[0], kppf[1] ];
 127
 128 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 129 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 130
 131 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 132
 133 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 134 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 135
 136 // button profile
 137 bppM = epp4 + [0,5];
 138 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 139 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 140 bppS = [ epp1[0], bppR[1] ];
 141 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 142 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 143 bppO = [ bppN[0], bppP[1] ];
 144 bppL = lpp10 + [5,0];
 145 bppK = [ bppL[0], bppN[1] ];
 146 bppJ = [ bppN[0], bppL[1] ];
 147
 148 // hinge plan
 149 hp_rn = hingescrew_nut_dia/2;
 150 hp_r2_min = hp_rn + lever_cover_th;
 151 hp_rs = hingescrew_shaft_dia/2;
 152 hp_r1_min = hp_rs + hingemount_th;
 153
 154 hp_r1 = max(hp_r1_min, hp_r2_min);
 155 hp_r2 = hp_r1;
 156
 157 hppU = lpp13;
 158 hppS = epp2o + [0,-1] * case_th_bottom;
 159 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 160
 161 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 162          0.5 * (hppU + hppS)[1] ];
 163 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 164 hppB = hppT + [0,-1] * hp_k;
 165
 166 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 167 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 168 hppE = [ hppE_x, hppE_y ];
 169
 170 // hinge elevation x coords
 171
 172 hingescrew_portion_len =
 173   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 174
 175 hex20 = max(epp2o[0],
 176             phone_cnr_rad,
 177             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 178 hex21 = hex20 + hingescrew_portion_len;
 179 hex22 = hex21 - hinge_x_gap;
 180 hex23 = hex22 + hingescrew_portion_len;
 181 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 182 echo(hex20, hex21, hex22, hex23, hex24);
 183 echo(hingescrew_portion_len);
 184
 185 // ---------- modules ----------
 186
 187 module KeeperProfile(slant=0){
 188   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 189   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 190 }
 191
 192 module EdgeProfile(){
 193   difference(){
 194     hull(){
 195       translate(epp3) square(case_th_bottom*2, center=true);
 196       circleat(epp2o, r=case_th_bottom);
 197       circleat(epp1, r=case_th_side);
 198       rectfromto(epp0, epp4);
 199     }
 200     polygon([ epp5 + [0,10],
 201               epp1,
 202               epp2i,
 203               epp3 + [10,0] ]);
 204   }
 205 }
 206
 207 module LidEdgeProfile(){
 208   polygon([ lpp10,
 209             lpp11,
 210             lpp12,
 211             lpp13,
 212             lpp13 + [10, 0],
 213             lpp10 + [10, 0]
 214             ]);
 215   intersection(){
 216     circleat(lpp12, r=lp_r12);
 217     rectfromto( lpp12 + [-10,   0],
 218                 lpp12 + [+10, +10] );
 219   }
 220 }
 221
 222 module ButtonCoverProfile(){
 223   intersection(){
 224     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 225     hull(){
 226       EdgeProfile();
 227       LidEdgeProfile();
 228     }
 229   }
 230 }
 231
 232 module ButtonPlan(l, deep, cut){
 233   epsilon =
 234     (cut  ? 0 : lid_buttoncover_gap);
 235
 236   delta =
 237     (deep ? lid_buttoncover_overlap : 0);
 238
 239   C = [0,0]; // by definition
 240   T = [ 0, epp4[1] ];
 241   G = T + [0,10];
 242
 243   B0 = C + [0,-1] * button_cutout_depth;
 244   B1 = B0 + [0,1] * epsilon;
 245
 246   r0 = 0.5 * (T[1] - B0[1]);
 247   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 248   H = A + [0,-1] * delta;
 249
 250   D = A + [-2,0] * r0;
 251   F = D + [0,10];
 252
 253   E0 = 0.5 * (D + A);
 254   E1 = E0 + [1,0] * epsilon;
 255
 256   I0 = [ E0[0], H[1] ];
 257   I1 = [ E1[0], H[1] ];
 258
 259   hull(){
 260     for (m=[0,1]) mirror([m,0])
 261       circleat(H, r0 - epsilon);
 262   }
 263   for (m=[0,1]) mirror([m,0]) {
 264     difference(){
 265       polygon([ E1,
 266                 I1,
 267                 H,
 268                 B1,
 269                 G,
 270                 F,
 271                 D
 272                 ]);
 273       circleat(D, r0 + epsilon);
 274     }
 275   }
 276 }
 277
 278 module Flip_rhs(yn=[0,1]) {
 279   for ($rhsflip=yn) {
 280     translate([phone_width/2, 0, 0])
 281       mirror([$rhsflip,0,0])
 282       translate([-phone_width/2, 0, 0])
 283       children();
 284   }
 285 }
 286
 287 module Flip_bot(yn=[0,1]) {
 288   for ($botflip=yn) {
 289     translate([0, -phone_height/2, 0])
 290       mirror([0, $botflip, 0])
 291       translate([0, phone_height/2, 0])
 292       children();
 293   }
 294 }
 295
 296 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 297   // sides
 298   Flip_rhs(){
 299     translate([0, -phone_cnr_rad, 0])
 300       rotate([90,0,0])
 301       linear_extrude(height = phone_height - phone_cnr_rad*2)
 302       children(0);
 303   }
 304   // corners
 305   Flip_rhs() Flip_bot() {
 306     translate([+1,-1] * phone_cnr_rad)
 307       intersection(){
 308         rotate_extrude()
 309           intersection(){
 310             mirror([1,0,0])
 311               translate([-1,0] * phone_cnr_rad)
 312               children(0);
 313             rectfromto([0,-20],[10,20]);
 314           }
 315         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 316           cube([10,10,40]);
 317       }
 318   }
 319   // top and bottom
 320   Flip_bot(){
 321     translate([ phone_width - phone_cnr_rad, 0,0 ])
 322       rotate([90,0,-90])
 323       linear_extrude(height = phone_width - phone_cnr_rad*2)
 324       children(0);
 325   }
 326   // fill
 327   translate([0,0, fill_zstart])
 328     mirror([0,0, fill_downwards])
 329     linear_extrude(height = fill_th)
 330     rectfromto([+1,-1] * phone_cnr_rad,
 331                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 332 }
 333
 334 module CaseAperture(pos, dia, $fn) {
 335   theta = 180/$fn;
 336   translate([ pos[0] + bumper[0],
 337               -epp2i[0],
 338               -pos[1] ])
 339     rotate([-90, theta, 0])
 340     cylinder(r = dia/2 / cos(theta),
 341              h = 60);
 342 }
 343
 344 module SideButton(y, y_ref_sign, l){
 345   // y_ref_sign:
 346   //   +1  measured from top    of actual phone to top    of button
 347   //   -1  measured from bottom of actual phone to bottom of button
 348   //    0  y is centre of button in coordinate system
 349   $button_l= l;
 350   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 351           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 352           y;
 353   //echo(eff_y);
 354   translate([0, eff_y, 0])
 355     children();
 356 }
 357
 358 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 359   $button_leg_only = true;
 360   SideButton(y, y_ref_sign, l) children();
 361 }
 362
 363 module Buttons(){
 364   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 365   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 366   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 367   Flip_rhs(   ) LidButtonishLeg(20, -1) children();
 368 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 369 }
 370
 371 module Struts(x_start, z_min, th){
 372   // if th is negative, starts at z_min and works towards -ve z
 373   // and object should then be printed other way up
 374   for (i= [1 : 1 : case_struts_count]) {
 375     translate([0,
 376                0,
 377                z_min])
 378       mirror([0,0, th<0 ? 1 : 0])
 379       translate([0,
 380                  -phone_height * i / (case_struts_count+1),
 381                  case_struts_solid_below])
 382       linear_extrude(height= abs(th)
 383                      -(case_struts_solid_below+case_struts_solid_above))
 384       rectfromto([               x_start, -0.5 * case_struts_width ],
 385                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 386   }
 387 }
 388
 389 module OrdinaryRearAperture(rhs,bot, pos){
 390   Flip_rhs(rhs) Flip_bot(bot)
 391     linextr(-20, 20)
 392     mirror([0,1])
 393     translate(pos + bumper)
 394     children();
 395 }
 396
 397 module MicroUSB(){
 398   Flip_bot(1){
 399     rotate([90,0,0])
 400       mirror([0,0,1])
 401       linextr(-epp2i[0], 60)
 402       translate([0.5 * phone_width, 0, 0])
 403       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 404                  [+microusb_width/2, epp0[1] + -microusb_above]);
 405   }
 406 }
 407
 408 module OrdinaryRearApertures(){
 409   // rear speaker
 410   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 411     rectfromto(-rearspeaker_gap,
 412                rearspeaker_size + rearspeaker_gap);
 413
 414   // finger hole to remove phone
 415   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 416                               phone[1]/2 ])
 417     scale(fingerpushhole_dias)
 418     circle(r= 0.5 );
 419 }
 420
 421 module RearCameraAperture(){
 422   Flip_rhs(1)
 423     mirror([0, 0, 1])
 424     linear_extrude(height = 20)
 425     mirror([0, 1, 0])
 426     translate(bumper)
 427     rectfromto(camera_pos_tl, camera_pos_br);
 428 }
 429
 430 module HingeLidProfile(){
 431   hull(){
 432     circleat(hppT, hp_r1);
 433     circleat(lpp12, lp_r12);
 434     polygon([lpp10,
 435              lpp13 + [2,0],
 436              lpp12,
 437              hppT]);
 438   }
 439 }
 440
 441 module HingeBaseProfile(){
 442   difference(){
 443     hull(){
 444       circleat(hppB, hp_r1);
 445       circleat(hppE, hp_r1);
 446       circleat(epp2o, case_th_bottom);
 447       circleat(hppB + [10,0], hp_r1);
 448     }
 449     polygon([epp5, epp1, epp2i, epp3, bppL]);
 450   }
 451 }
 452
 453 module HingeLeverOuterProfile(){
 454   hull(){
 455     circleat(hppT, hp_r2);
 456     circleat(hppB, hp_r2);
 457   }
 458 }
 459
 460 module HingeLeverInnerProfile(){
 461   for (c = [hppT, hppB]) {
 462     hull()
 463       for (x=[0,20])
 464         translate([x,0])
 465           circleat(c, hp_rn);
 466         circleat(hppB, hp_rn);
 467   }
 468 }
 469
 470 module Flip_hinge(){
 471   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 472   translate(hinge_origin)
 473     rotate([180,0,0])
 474     translate(-hinge_origin)
 475     children();
 476 }
 477
 478 module HingePortion(x0,x1){
 479   Flip_rhs() Flip_bot(1)
 480     translate([x0,0,0])
 481     mirror([1,0,0])
 482     rotate([90,0,-90])
 483     linear_extrude(height=x1-x0)
 484     children(0);
 485 }
 486
 487 module CaseBase(){
 488   AroundEdges(epp3[1], case_th_bottom, 1)
 489     EdgeProfile();
 490 }
 491
 492 module Case(){ ////toplevel
 493   difference(){
 494     union(){
 495       CaseBase();
 496
 497       // ledge (fixed keeper)
 498       intersection(){
 499         rotate([90, 0, 0])
 500           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 501           KeeperProfile(1);
 502
 503         // outline of the whole case, to stop it protruding
 504         translate([0,0, -25])
 505           linear_extrude(height = 50)
 506           hull()
 507           // Flip_rhs() // actually, we only care about the LH
 508           Flip_bot()
 509           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 510       }
 511
 512       // hinge
 513       HingePortion(hex20, hex21) HingeBaseProfile();
 514     }
 515
 516     // slot for keeper
 517     Flip_rhs(1)
 518       translate([0, -phone_cnr_rad, 0])
 519       rotate([90, 0, 0])
 520       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 521       minkowski(){
 522         KeeperProfile();
 523         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 524                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 525       }
 526
 527     // front camera
 528     RearCameraAperture();
 529
 530     // struts (invisible, because they're buried in the case)
 531     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 532
 533     Buttons(){
 534       mirror([1,0,0])
 535         rotate([90,0,90]) {
 536           intersection(){
 537             translate([0,0,-10])
 538               linear_extrude(height= 20)
 539               ButtonPlan($button_l, 0,1);
 540             if ($button_leg_only)
 541               rotate([-90,90,0])
 542                 translate([phone_width/2, -400, kppe[1]])
 543                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 544           }
 545           translate([0,0, -bppR[0]])
 546             linear_extrude(height= 20)
 547             ButtonPlan($button_l, 1,1);
 548         }
 549     }
 550
 551     // apertures along top edge
 552     CaseAperture(jack_pos, jack_dia, 8);
 553     Flip_rhs(1)
 554       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 555
 556     OrdinaryRearApertures();
 557
 558     MicroUSB();
 559
 560     // gaps for the lid's hinge arms
 561     HingePortion(hex20 - hinge_x_arms_gap,
 562                  hex21 + hinge_x_arms_gap)
 563       minkowski(){
 564         HingeLidProfile();
 565         circle(r= hinge_r_arms_gap, $fn= 8);
 566       }
 567
 568     // screw holes in the hinge arms
 569     HingeScrews();
 570   }
 571 }
 572
 573 module Lid(){ ////toplevel
 574   difference(){
 575     union(){
 576       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 577         LidEdgeProfile();
 578
 579       // button covers
 580       Buttons(){
 581         intersection(){
 582           rotate([90,0,90])
 583             translate([0,0,-10])
 584             linear_extrude(height= 20)
 585             ButtonPlan($button_l, 1,0);
 586           rotate([90,0,0])
 587              translate([0,0,-100])
 588             linear_extrude(height= 200)
 589             ButtonCoverProfile();
 590         }
 591       }
 592
 593       // hinge arms
 594       HingePortion(hex20, hex21) HingeLidProfile();
 595     }
 596     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 597
 598     // screw holes in the hinge arms
 599     HingeScrews();
 600   }
 601 }
 602
 603 module HingeLever(){ ////toplevel
 604   difference() {
 605     // outer body, positive
 606     HingePortion(hex22, hex22 + phone_width/2)
 607       HingeLeverOuterProfile();
 608
 609     // space for the screws
 610     HingePortion(hex23, hex24)
 611       HingeLeverInnerProfile();
 612
 613     // bores for the screws
 614     HingeScrews();
 615
 616     // space for the charging cable
 617     MicroUSB();
 618     Flip_hinge() MicroUSB();
 619   }
 620 }
 621
 622 module HingeLeverPrint(){ ////toplevel
 623   rotate([90,0,0])
 624     HingeLever();
 625 }
 626
 627 module TestSelectLength(){
 628   translate([-30, -200, -20])
 629     cube([30 + 15, 250, 40]);
 630 }
 631
 632 module TestLength(){ ////toplevel
 633   intersection(){
 634     Case();
 635     TestSelectLength();
 636   }
 637 }
 638
 639 module TestLengthRight(){ ////toplevel
 640   intersection(){
 641     Case();
 642     Flip_rhs(1)
 643       TestSelectLength();
 644   }
 645 }
 646
 647 module TestSelectWidth(){
 648   translate([-30, -(phone_height - 25), -20])
 649     mirror([0, 1, 0])
 650     cube([200, 50, 40]);
 651 }
 652
 653 module TestWidth(){ ////toplevel
 654   intersection(){
 655     Case();
 656     TestSelectWidth();
 657   }
 658 }
 659
 660 module TestLidWidthPrint(){ ////toplevel
 661   rotate([0,180.0]) intersection(){
 662     Lid();
 663     TestSelectWidth();
 664   }
 665 }
 666
 667 module TestSelectRearAperture(){
 668   minkowski(){
 669     union() children();
 670     translate([20, 0,0])
 671       cube([42, 2, 1], center=true);
 672   }
 673 }
 674
 675 module TestSelectCamera(){
 676   minkowski(){
 677     TestSelectRearAperture()
 678       RearCameraAperture();
 679     cube([0.1, 50, 0.1]);
 680   }
 681 }
 682
 683 module TestSelectOrdinaryRearApertures(){
 684   TestSelectRearAperture()
 685     OrdinaryRearApertures();
 686 }
 687
 688 module TestCamera(){ ////toplevel
 689   intersection(){
 690     Case();
 691     TestSelectCamera();
 692   }
 693 }
 694
 695 module TestLidByCamera(){ ////toplevel
 696   intersection(){
 697     Lid();
 698     TestSelectCamera();
 699   }
 700 }
 701
 702 module TestLidByCameraPrint(){ ////toplevel
 703   rotate([180,0,0]) TestLidByCamera();
 704 }
 705
 706 module DemoByCamera(){ ////toplevel
 707   color("blue") TestLidByCamera();
 708   color("red")  TestCamera();
 709 }
 710
 711 module OneKeeper(){ ////toplevel
 712   translate([0, -phone_cnr_rad, 0])
 713     rotate([90, 0, 0])
 714     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 715     KeeperProfile();
 716 }
 717
 718 module OneKeeperPrint(){ ////toplevel
 719   rotate([0,180,0])
 720     OneKeeper();
 721 }
 722
 723 module LidPrint(){ ////toplevel
 724   rotate([0,180,0])
 725     Lid();
 726 }
 727
 728 module TestSelectFrame(){
 729   include = [1,-1] * (epp2i[0] + 4);
 730
 731   difference(){
 732     cube(1000, center=true);
 733     translate([0,0, -100])
 734       linear_extrude(height=200)
 735       rectfromto(include,  inside_br - include);
 736   }
 737 }
 738
 739 module TestFrameCase(){ ////toplevel
 740   intersection(){
 741     Case();
 742     union(){
 743       TestSelectFrame();
 744       TestSelectCamera();
 745       TestSelectOrdinaryRearApertures();
 746     }
 747   }
 748 }
 749
 750 module TestFrameLidPrint(){ ////toplevel
 751   rotate([0,180,0]) intersection(){
 752     Lid();
 753     TestSelectFrame();
 754   }
 755 }
 756
 757 module Keeper(){ ////toplevel
 758   Flip_rhs()
 759     OneKeeper();
 760 }
 761
 762 module ButtonPlanForDemo(z, deep, cut){
 763   translate([0,0,z])
 764     ButtonPlan(8, deep, cut);
 765 }
 766
 767 module HingeScrews(){
 768   Flip_rhs() Flip_bot(1){
 769     for (c= [ hppT, hppB ])
 770       translate([ hex20,
 771                   -c[0],
 772                   c[1] ]){
 773         rotate([0,90,0])
 774           translate([0,0,-.2])
 775           cylinder( r= hingescrew_shaft_dia/2,
 776                     h = hingescrew_shaft_len+0.2 );
 777         rotate([0,-90,0])
 778           translate([0,0,+.1])
 779           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 780       }
 781   }
 782 }
 783
 784 module DemoFrame(){ ////toplevel
 785   color("red") TestFrameCase();
 786   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 787   color("black") HingeScrews();
 788   %HingeLever();
 789 }
 790
 791 module DemoHingedFrame(){ ///toplevel
 792   color("red") TestFrameCase();
 793   translate([0,0, -2*hp_k])
 794   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 795
 796   Flip_hinge(){
 797     color("orange") HingeLever();
 798     color("black") HingeScrews();
 799   }
 800 }
 801
 802 module DemoHinge(){ ////toplevel
 803   DemoFrame();
 804   translate([0,0, -hp_k*3])
 805     DemoHingedFrame();
 806 }
 807
 808 module DemoProfiles(){ ////toplevel
 809   LidEdgeProfile();
 810   %EdgeProfile();
 811   KeeperProfile();
 812   translate([0,0,-1]) color("black") KeeperProfile(1);
 813
 814   translate([20,0]) {
 815     LidEdgeProfile();
 816     %EdgeProfile();
 817
 818     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 819
 820     color("blue") ButtonCoverProfile();
 821     color("red") {
 822       rectfromto(bppQ, demopoint_QR);
 823       rectfromto(bppR, demopoint_QR);
 824     }
 825   }
 826
 827   translate([-20,0]) {
 828     color("black") ButtonPlanForDemo(-2, 0,1);
 829     color("red" )  ButtonPlanForDemo(-4, 1,1);
 830     color("blue")  ButtonPlanForDemo(-6, 1,0);
 831   }
 832
 833   translate([0, -30]) {
 834     %LidEdgeProfile();
 835     %EdgeProfile();
 836     color("blue") HingeLidProfile();
 837     color("red")  HingeBaseProfile();
 838     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 839     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 840   }
 841 }
 842
 843 //EdgeProfile();
 844 //KeeperProfile();
 845 //CaseBase();
 846 //%Case();
 847 //Keeper();
 848 //LidEdgeProfile();
 849 //KeeperProfile();
 850 //DemoProfiles();