fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 thumbrecess_depth = 1.3;
 256 thumbrecess_width = 16.5;
 257 thumbrecess_topcurve_r = 5.0;
 258
 259 catch_slop = -0.75;
 260
 261 catch_len = 4.5;
 262 catch_thickness = 1.3;
 263
 264 catch_depth = 0.75;
 265 catch_height = 0.35;
 266 catch_finger_height = 1.5;
 267 catch_finger_depth = 2.5;
 268 catch_catch_slope = 2.00;
 269 catch_close_slope = 3.00;
 270
 271 prop_recess_under = 0.50;
 272 prop_recess_slop = 0.200; // each side
 273 prop_end_dia = 0.5;
 274 prop_main_th = 3;
 275 prop_taper_len = 6;
 276 prop_main_width = 4;
 277 prop_side_gap = 0.75; // each side
 278 prop_lidrecess_behind = 0.75;
 279 prop_caserecess_behind = 0.75;
 280 prop_caserecess_taper = 0.45; // one side only
 281 prop_prop_gap = 0.5;
 282 prop_prong_heel_slope = 0.5;
 283
 284 lid_fold_clearance_antislop = 0.5;
 285
 286 // ---------- calculated ----------
 287
 288 phone_width =  (phone + bumper*2)[0];
 289 phone_height = (phone + bumper*2)[1];
 290
 291 inside_br = [phone_width, -phone_height];
 292
 293 prop_prong_h = prop_main_th;
 294
 295 //echo(camera_pos_tl + bumper,
 296 //     camera_pos_br + bumper);
 297
 298 // ----- could be changed -----
 299 lid_buttoncover_gap = lid_gap_x;
 300 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 301
 302 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 303
 304 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 305
 306 //prop_nose_len = case_th_lid - prop_recess_under;
 307 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 308 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 309
 310
 311 //lid_lip_overlap_width xxx bad name = ;
 312 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 313
 314 epp0 = [0,0];
 315 epp1 = [0, -phone_edge_thick];
 316 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 317 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 318 epp3 = epp2i + [10, 0];
 319 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 320 epp4 = epp5 + [-1,0] * case_th_side;
 321
 322 kppe = [0,0];
 323 kppd = kppe + [1,0] * keeper_inner_width;
 324 kppc = kppd + [0,1] * keeper_th_z;
 325 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 326 kppf = kppe - [0,1] * keeper_inner_height;
 327 kppa = [ kppb[0], kppf[1] ];
 328
 329 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 330 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 331
 332 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 333 // exact x posn not very important; must extend past end of keeper
 334
 335 lpp15 = [ lpp14[0],
 336           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 337           + lid_screen_gap_extra ];
 338 // ^ beam theory says to maximise force before contact,
 339 //   the gap below the `beam' (the lid) must be 1/3
 340 //   the thickness (ie the lid thickness) if the beam
 341 //   is solid, or 1/2 if it has a top and bottom only.
 342 //   ours is mostly solid.
 343
 344 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 345              case_th_lip);
 346
 347 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 348 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 349
 350 case_bottom_z = epp2o[1] - case_th_bottom;
 351
 352 // button profile
 353 bppM = epp4 + [0,5];
 354 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 355 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 356 bppS = [ epp1[0], bppR[1] ];
 357 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 358 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 359 bppO = [ bppN[0], bppP[1] ];
 360 bppL = lpp10 + [5,0];
 361 bppK = [ bppL[0], bppN[1] ];
 362 bppJ = [ bppN[0], bppL[1] ];
 363 bppU = [ bppJ[0], lpp12[1] ];
 364 bppV = lpp11;
 365 bppW = lpp10;
 366
 367 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 368
 369 // notification led aperture
 370
 371 nla_r0 = led_aperture/2;
 372 nla_r1 = nla_r0 + led_window_ledge;
 373 nla_r2 = nla_r1 + multicolour_gap;
 374 nla_t =
 375   led_window_style >= 3 ? initial_layer_thick :
 376   led_window_style >= 2 ? led_window_ledge : 0;
 377
 378
 379 // hinge plan
 380 hp_rn = hingescrew_nut_access_dia/2;
 381 hp_r2_min = hp_rn + lever_cover_th;
 382 hp_rs = hingescrew_shaft_dia/2;
 383 hp_r1_min = hp_rs + hingemount_th;
 384
 385 hp_r1 = max(hp_r1_min, hp_r2_min);
 386 hp_r2 = hp_r1;
 387
 388 hppU = lpp13;
 389 hppS = epp2o + [0,-1] * case_th_bottom;
 390 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 391
 392 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 393          0.5 * (hppU + hppS)[1] ];
 394 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 395 hppB = hppT + [0,-1] * hp_k;
 396
 397 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 398 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 399 hppE = [ hppE_x, hppE_y ];
 400
 401 // hinge elevation x coords
 402
 403 hex20 = max(epp2o[0],
 404             phone_cnr_rad,
 405             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 406 hex21 = hex20 + hingemount_wd;
 407 hex22 = hex21 + hinge_x_gap;
 408 hex27 = hex20 + hingescrew_shaft_len;
 409 hex24 = hex27 + hinge_x_postscrew_gap;
 410 hex23 = hex27 - (hingescrew_nut_thick*2
 411                  + hingescrew_fasteners_extra_thick);
 412 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 413
 414 echo(hex20, hex21, hex22, hex23, hex24);
 415 //  6, 10.8725, 10.9975, 13.74, 18.75
 416 module chk(act,exp) {
 417   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 418   else echo("ok", act);
 419 }
 420 chk(hex20, 6);
 421 chk(hex21, 10.8725);
 422 chk(hex22, 10.9975);
 423 chk(hex23, 13.74);
 424 chk(hex24, 18.75);
 425
 426 lid_fold_clearance_skew =
 427   (lpp10[1] - hppB[1]) /
 428   (lpp10[0] - hppB[0]);
 429
 430 echo("SK",lid_fold_clearance_skew);
 431
 432 // thumb recess (used to be "catch" hence cpp*
 433
 434 cppA = epp4 + [thumbrecess_depth, 0];
 435 cppB = [ cppA[0], epp1[1] ];
 436
 437 // lanyard
 438
 439 ly_r = lanyard_half_dia / 2;
 440 ly_rc = ly_r * 2;
 441
 442 ly_theta = -atan2vector(epp2i - epp1);
 443 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 444
 445 max_case_bottom_edge_thickness =
 446   case_th_bottom
 447   + sin(ly_theta) * (epp2i-epp2o)[0];
 448
 449 ly_q_z = -(ly_rc + ly_r);
 450 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 451
 452 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 453
 454 // prop recess in case
 455
 456 prop_x_pos = phone_width/2;
 457
 458 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 459
 460 prc_r1 = prop_end_dia/2;
 461 prc_r3 = prc_r1 + prop_recess_slop;
 462
 463 prcp2 = [ epp4[0] + prop_buildout_less,
 464           case_bottom_z ];
 465
 466 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 467
 468 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 469           epp2i[1] - prc_r3 - prop_recess_under];
 470
 471 // prop recess in lid
 472
 473 prl_r10 = prop_end_dia/2;
 474 prl_r10o = prl_r10 + prop_recess_slop;
 475
 476 prlp10 = lpp10 + [1,1] * prl_r10o
 477   + [1,0] * prop_lidrecess_behind
 478   + [0,1] * prop_recess_under;
 479
 480 // prop
 481
 482 $prpp10 = [0,0];
 483 $prpp11 = [0, prop_taper_len];
 484
 485 $prp_r10 = prl_r10;
 486
 487 // ---------- modules ----------
 488
 489 module AdhocMultiprintFrame(phase, z0, zs) {
 490   // from z0 to z0 + zs*layer
 491   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 492   xextra = extra + -epp4[0];
 493   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 494   yextra = extra + -epp4[0];
 495   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 496   p0 = [ xrange[0], yrange[0] ];
 497   p1 = [ xrange[1], yrange[1] ];
 498   echo(p0, p1);
 499   translate([0,0, z0])
 500     mirror([0,0, zs<0 ? 1 : 0])
 501     linear_extrude(height= initial_layer_thick)
 502     difference(){
 503       rectfromto(p0 - [1,1] * initial_layer_width,
 504                  p1 + [1,1] * initial_layer_width);
 505       rectfromto(p0, p1);
 506     }
 507 }
 508
 509 module KeeperProfile(slant=0){
 510   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 511   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 512 }
 513
 514 module EdgeProfile(){
 515   difference(){
 516     hull(){
 517       translate(epp3) square(case_th_bottom*2, center=true);
 518       circleat(epp2o, r=case_th_bottom);
 519       circleat(epp1, r=case_th_side);
 520       rectfromto(epp0, epp4);
 521     }
 522     polygon([ epp5 + [0,10],
 523               epp1,
 524               epp2i,
 525               epp3 + [10,0] ]);
 526   }
 527 }
 528
 529 module LanyardLanyardProfile(entry=false){
 530   hull(){
 531     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 532       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 533         circle(r= lanyard_half_dia/2);
 534   }
 535 }
 536
 537 module LanyardCurveChannelProfile(){
 538   translate([0, -ly_r])
 539     LanyardLanyardProfile();
 540 }
 541
 542 module LanyardEntryChannelProfile(){
 543   LanyardLanyardProfile(true);
 544 }
 545
 546 module LanyardMainChannelProfile(){
 547   LanyardCurveChannelProfile();
 548   difference(){
 549     square(center=true, ly_r * [6, 2]);
 550     for (xs=[-1,+1])
 551       translate(ly_r * [3 * xs, -1])
 552         circle(r = ly_r);
 553   }
 554 }
 555
 556 module LanyardEntryOuterProfile(){
 557   circleat([ly_re + ly_r, 0], ly_re);
 558 }
 559
 560 module LanyardEntry(){
 561   q_z = ly_q_z;
 562   oec_y = ly_oec_y;
 563
 564   d_x = -ly_rc;
 565
 566   translate([d_x, 0, q_z]) {
 567     intersection(){
 568       rotate([90,0,0])
 569         rotate_extrude(convexity=10)
 570         rotate(90)
 571         translate([0, -q_z])
 572         LanyardCurveChannelProfile();
 573       translate([0,-10,0])
 574         cube([20,20,20]);
 575     }
 576   }
 577
 578   mirror([0,0,1])
 579     translate([0,0,-1])
 580     linear_extrude(height=20)
 581     rotate(-90)
 582     LanyardEntryChannelProfile();
 583
 584   translate([0, ly_r*2, 0])
 585     rotate([90,0,0])
 586     linear_extrude(height = ly_r*4){
 587     difference(){
 588       rectfromto([d_x, q_z], [ly_r, 0]);
 589       circleat([d_x, q_z], ly_rc);
 590     }
 591   }
 592
 593   translate([0,0,q_z]){
 594     for (my=[0,1])
 595       mirror([0,my,0]){
 596         translate([0, oec_y, 0]){
 597           difference(){
 598             translate(ly_re * [-1,0,-2])
 599               cube(ly_re * [2,1,2]);
 600             rotate_extrude(convexity=10)
 601               LanyardEntryOuterProfile();
 602           }
 603         }
 604       }
 605     difference(){
 606       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 607         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 608       for (mx=[0,1])
 609         mirror([mx,0,0])
 610           rotate([90,0,0])
 611           translate([0,0,-10])
 612           linear_extrude(height=20)
 613           LanyardEntryOuterProfile();
 614     }
 615   }
 616 }
 617
 618 module LanyardCutout(l){
 619   rotate([0,-90,0])
 620     linear_extrude(height=l)
 621     rotate(-90)
 622     LanyardMainChannelProfile();
 623
 624   for (ee=[0,1]){
 625     translate(ee * l * [-1,0])
 626       mirror([ee,0,0])
 627       LanyardEntry();
 628   }
 629 }
 630
 631 module LidEdgeProfile(){
 632   polygon([ lpp10,
 633             lpp11,
 634             lpp12,
 635             lpp13,
 636             lpp13 + [10, 0],
 637             lpp15 + [10, 0],
 638             lpp15,
 639             lpp14,
 640             ]);
 641   intersection(){
 642     circleat(lpp12, r=lp_r12);
 643     rectfromto( lpp12 + [-10,   0],
 644                 lpp12 + [+10, +10] );
 645   }
 646 }
 647
 648 module LidEdgeFoldClearanceProfile(){
 649   translate([-lid_fold_clearance_antislop, 0])
 650     polygon([ lpp10,
 651               lpp11,
 652               lpp11 + [-20,  0],
 653               lpp11 + [-20, 20],
 654               lpp11 + [+20, 20],
 655               lpp10 + [+20,  0] ]);
 656 }
 657
 658 module ButtonCoverProfile(){
 659   intersection(){
 660     polygon(concat([ bppM, bppP, bppO, bppJ ],
 661                    (enable_support && !$button_suppress_over_keeper
 662                     ? [ bppU, bppV, bppW ] : []),
 663                    [ bppL, bppK ]));
 664     hull(){
 665       EdgeProfile();
 666       LidEdgeProfile();
 667     }
 668   }
 669 }
 670
 671 module ButtonPlan(l, deep, cut){
 672   epsilon =
 673     (cut  ? 0 : lid_buttoncover_gap);
 674
 675   delta =
 676     (deep ? lid_buttoncover_overlap : 0);
 677
 678   C = [0,0]; // by definition
 679   T = [ 0, epp4[1] ];
 680   G = T + [0,10];
 681
 682   B0 = C + [0,-1] * button_cutout_depth;
 683   B1 = B0 + [0,1] * epsilon;
 684
 685   r0 = 0.5 * (T[1] - B0[1]);
 686   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 687   H = A + [0,-1] * delta;
 688
 689   D = A + [-2,0] * r0;
 690   F = D + [0,10];
 691
 692   E0 = 0.5 * (D + A);
 693   E1 = E0 + [1,0] * epsilon;
 694
 695   I0 = [ E0[0], H[1] ];
 696   I1 = [ E1[0], H[1] ];
 697
 698   hull(){
 699     for (m=[0,1]) mirror([m,0])
 700       circleat(H, r0 - epsilon);
 701   }
 702   for (m=[0,1]) mirror([m,0]) {
 703     difference(){
 704       polygon([ E1,
 705                 I1,
 706                 H,
 707                 B1,
 708                 G,
 709                 F,
 710                 D
 711                 ]);
 712       circleat(D, r0 + epsilon);
 713     }
 714   }
 715 }
 716
 717 module ButtonCoverReinf(){ ////toplevel
 718   minkowski(){
 719     rotate([90,0,0])
 720       linear_extrude(height=0.01)
 721       intersection(){
 722         ButtonCoverProfile();
 723         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 724           square([100,100]);
 725     }
 726     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 727       circle(r= lid_buttoncover_reinf);
 728       translate([-20,0]) square(40, center=true);
 729     }
 730   }
 731 }
 732
 733 module CatchCutProfile(){
 734   difference(){
 735     polygon([ cppA + [-10,0],
 736               cppB + [-10,0],
 737               cppB,
 738               cppA ]);
 739     circleat(epp1, r=case_th_side);
 740   }
 741 }
 742
 743 module Flip_rhs(yn=[0,1]) {
 744   for ($rhsflip=yn) {
 745     translate([phone_width/2, 0, 0])
 746       mirror([$rhsflip,0,0])
 747       translate([-phone_width/2, 0, 0])
 748       children();
 749   }
 750 }
 751
 752 module Flip_bot(yn=[0,1]) {
 753   for ($botflip=yn) {
 754     translate([0, -phone_height/2, 0])
 755       mirror([0, $botflip, 0])
 756       translate([0, phone_height/2, 0])
 757       children();
 758   }
 759 }
 760
 761 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 762   // sides
 763   Flip_rhs(){
 764     translate([0, -phone_cnr_rad, 0])
 765       rotate([90,0,0])
 766       linear_extrude(height = phone_height - phone_cnr_rad*2)
 767       children(0);
 768   }
 769   // corners
 770   Flip_rhs() Flip_bot() {
 771     translate([+1,-1] * phone_cnr_rad)
 772       intersection(){
 773         rotate_extrude()
 774           intersection(){
 775             mirror([1,0,0])
 776               translate([-1,0] * phone_cnr_rad)
 777               children(0);
 778             rectfromto([0,-20],[10,20]);
 779           }
 780         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 781           cube([10,10,40]);
 782       }
 783   }
 784   // top and bottom
 785   Flip_bot(){
 786     translate([ phone_width - phone_cnr_rad, 0,0 ])
 787       rotate([90,0,-90])
 788       linear_extrude(height = phone_width - phone_cnr_rad*2)
 789       children(0);
 790   }
 791   // fill
 792   translate([0,0, fill_zstart])
 793     mirror([0,0, fill_downwards])
 794     linear_extrude(height = fill_th)
 795     rectfromto([+1,-1] * phone_cnr_rad,
 796                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 797 }
 798
 799 module CaseAperture(pos, dia, $fn) {
 800   theta = 180/$fn;
 801   translate([ pos[0] + bumper[0],
 802               -epp2i[0],
 803               -pos[1] ])
 804     rotate([-90, theta, 0])
 805     cylinder(r = dia/2 / cos(theta),
 806              h = 60);
 807 }
 808
 809 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 810   // y_ref_sign:
 811   //   +1  measured from top    of actual phone to top    of button
 812   //   -1  measured from bottom of actual phone to bottom of button
 813   //    0  y is centre of button in coordinate system
 814   $button_l= l;
 815   $button_suppress_over_keeper= suppress_over_keeper;
 816   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 817           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 818           y;
 819   //echo(eff_y);
 820   translate([0, eff_y, 0])
 821     children();
 822 }
 823
 824 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 825   $button_leg_only = true;
 826   SideButton(y, y_ref_sign, l) children();
 827 }
 828
 829 module Buttons(){
 830   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 831   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 832   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 833   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 834 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 835 }
 836
 837 module Struts(x_start, z_min, th){
 838   // if th is negative, starts at z_min and works towards -ve z
 839   // and object should then be printed other way up
 840   for (i= [1 : 1 : case_struts_count]) {
 841     translate([0,
 842                0,
 843                z_min])
 844       mirror([0,0, th<0 ? 1 : 0])
 845       translate([0,
 846                  -phone_height * i / (case_struts_count+1),
 847                  case_struts_solid_below])
 848       linear_extrude(height= abs(th)
 849                      -(case_struts_solid_below+case_struts_solid_above))
 850       rectfromto([               x_start, -0.5 * case_struts_width ],
 851                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 852   }
 853 }
 854
 855 module OrdinaryRearAperture(rhs,bot, pos){
 856   Flip_rhs(rhs) Flip_bot(bot)
 857     linextr(-20, 20)
 858     mirror([0,1])
 859     translate(pos + bumper)
 860     children();
 861 }
 862
 863 module MicroUSB(){
 864   Flip_bot(1){
 865     rotate([90,0,0])
 866       mirror([0,0,1])
 867       linextr(-epp2i[0], 60)
 868       translate([0.5 * phone_width, 0, 0])
 869       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 870                  [+microusb_width/2, epp0[1] + -microusb_above]);
 871   }
 872 }
 873
 874 module OrdinaryRearApertures(){
 875   // rear speaker
 876   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 877     rectfromto(-rearspeaker_gap,
 878                rearspeaker_size + rearspeaker_gap);
 879
 880   // finger hole to remove phone
 881   if (len(fingerpushhole_dias))
 882     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 883                                 phone[1]/2 ])
 884     scale(fingerpushhole_dias)
 885     circle(r= 0.5 );
 886 }
 887
 888 module RearCameraAperture(){
 889   Flip_rhs(1)
 890     mirror([0, 0, 1])
 891     linear_extrude(height = 20)
 892     mirror([0, 1, 0])
 893     translate(bumper)
 894     rectfromto(camera_pos_tl, camera_pos_br);
 895 }
 896
 897 module HingeLidProfile(){
 898   hull(){
 899     circleat(hppT, hp_r1);
 900     circleat(lpp12, lp_r12);
 901     polygon([lpp10,
 902              lpp13 + [2,0],
 903              lpp12,
 904              hppT]);
 905   }
 906 }
 907
 908 module HingeBaseProfile(){
 909   difference(){
 910     hull(){
 911       circleat(hppB, hp_r1);
 912       circleat(hppE, hp_r1);
 913       circleat(epp2o, case_th_bottom);
 914       circleat(hppB + [10,0], hp_r1);
 915     }
 916     polygon([epp5, epp1, epp2i, epp3, bppL]);
 917   }
 918 }
 919
 920 module HingeLeverOuterProfile(){
 921   hull(){
 922     circleat(hppT, hp_r2);
 923     circleat(hppB, hp_r2);
 924   }
 925 }
 926
 927 module HingeLeverInnerProfile(){
 928   for (s = [-1,+1]) {
 929     c = s > 0 ? hppT : hppB;
 930     translate(c)
 931       mirror([0,0,s>0])
 932       rotate(s<0 ? -40 : 0)
 933       hull()
 934       for (x=[-20,20])
 935         for (y=[0, s * 10])
 936           translate([x,y])
 937             circle(hp_rn);
 938   }
 939 }
 940
 941 module HingeLeverNutProfile(){
 942   for (c= [hppB, hppT]) {
 943     translate(c)
 944       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 945   }
 946 }
 947
 948 module Flip_hinge(doflip=1){
 949   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 950   translate(hinge_origin)
 951     rotate([doflip*180,0,0])
 952     translate(-hinge_origin)
 953     children();
 954 }
 955
 956 module HingePortion(x0,x1){
 957   Flip_rhs() Flip_bot(1)
 958     translate([x0,0,0])
 959     mirror([1,0,0])
 960     rotate([90,0,-90])
 961     linear_extrude(height=x1-x0)
 962     children();
 963 }
 964
 965 module CatchPortion(ztop){
 966   width = thumbrecess_width;
 967   w = width + thumbrecess_topcurve_r*2 + 1;
 968   translate([phone_width/2, 0,0]){
 969     difference(){
 970       rotate([90,0,-90])
 971         linextr(-w/2, w/2)
 972         children(0);
 973       translate([0, 50, 0])
 974         rotate([90,0,0])
 975         linear_extrude(height=100){
 976         for (m=[0,1]) mirror([m,0,0]) {
 977           hull(){
 978             translate([w/2, ztop - thumbrecess_topcurve_r])
 979               circle(thumbrecess_topcurve_r);
 980             translate([w/2, -50])
 981               square(thumbrecess_topcurve_r*2, center=true);
 982           }
 983         }
 984       }
 985     }
 986   }
 987 }
 988
 989 module CaseBase(){
 990   AroundEdges(epp3[1], case_th_bottom, 1)
 991     EdgeProfile();
 992 }
 993
 994 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 995
 996 module PropProfileAssignments(gamma){
 997   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 998   x = prop_x(gamma);
 999   p = phone_height + prlp10[0] - hppB[0];
1000   b = p + x;
1001
1002   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1003   a = q + x;
1004   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1005   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1006
1007   $prp_theta = 90 - $prp_alpha;
1008   beta = 180 - $prp_alpha - gamma;
1009   psi = 90 - beta;
1010
1011   //echo("abc", a,b,c);
1012
1013   v1 = [ [ cos(psi), -sin(psi) ],    // x
1014          [ sin(psi),  cos(psi) ] ];  // y
1015
1016   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1017
1018   $prp_r1 = prc_r1;
1019   $prp_r11 = prop_main_th/2;
1020
1021   $prpp1 = $prpp7 + [1,0] *
1022     // this is approximate, but will do
1023     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1024   $prpp3 = $prpp1 +
1025     v1[0] * -$prp_r1 +
1026     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1027   $prpp12 = $prpp3 + v1[0] *
1028     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1029   $prp_r8 = prop_main_th;
1030   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1031   $prp_r5 = $prp_r8;
1032   $prpp5 = [ $prpp12[0] - $prp_r5,
1033             $prpp3[1] - prop_prong_h + $prp_r5 ];
1034   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1035          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1036   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1037   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1038
1039   children();
1040 }
1041
1042 module PropProfile(gamma, cut=0, rot=0){
1043   PropProfileAssignments(gamma){
1044
1045     //#circleat($prpp3,1);
1046     //#circleat($prpp12,1);
1047
1048     if (!cut) {
1049       hull(){
1050         translate($prpp8)
1051           intersection(){
1052             circle($prp_r8);
1053             polygon([[-20,-0], [20,20], [0,0]]);
1054           }
1055         rectfromto($prpp6, $prpp9);
1056         translate($prpp5) intersection(){
1057           circle($prp_r5);
1058           polygon([[-10,-10], [0,0], [10,0]]);
1059         }
1060         rectfromto($prpp12 + [0,-0.1], $prpp3);
1061       }
1062       hull(){
1063         circleat($prpp1, $prp_r1);
1064         rectfromto($prpp12 + [0,-0.1], $prpp3);
1065       }
1066     }
1067     // main shaft
1068     rotate([0,0, rot*-$prp_theta]){
1069       hull(){
1070         extra = cut ? prop_recess_slop : 0;
1071         rectfromto($prpp6, $prpp9);
1072         circleat($prpp11, $prp_r11 + extra);
1073         circleat($prpp10, $prp_r10 + extra);
1074       }
1075     }
1076   }
1077 }
1078
1079 module PropAggregateProfile(){
1080   for (angle = prop_angles)
1081     PropProfile(angle, 0,0);
1082 }
1083
1084 module Prop(){ ////toplevel
1085   hw = prop_main_width/2;
1086   linextr(-hw, +hw)
1087     PropAggregateProfile();
1088 }
1089
1090 module Case(){ ////toplevel
1091   difference(){
1092     union(){
1093       CaseBase();
1094
1095       // ledge (fixed keeper)
1096       Flip_rhs(1-keeper_side) intersection(){
1097         rotate([90, 0, 0])
1098           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1099           KeeperProfile(1);
1100
1101         // outline of the whole case, to stop it protruding
1102         translate([0,0, -25])
1103           linear_extrude(height = 50)
1104           hull()
1105           Flip_bot()
1106           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1107       }
1108
1109       // hinge
1110       HingePortion(hex20, hex21) HingeBaseProfile();
1111
1112       // buildout for prop recess
1113       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1114         linextr(case_bottom_z, epp2i[1])
1115         hull() {
1116           for (dxs = [-1,+1])
1117             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1118                        -epp2o[0] ],
1119                      r = epp2o[0] - prcp2[0]);
1120         }
1121     }
1122
1123     // slot for keeper
1124     Flip_rhs(keeper_side)
1125       translate([0, -phone_cnr_rad, 0])
1126       rotate([90, 0, 0])
1127       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1128       minkowski(){
1129         KeeperProfile();
1130         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1131                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1132       }
1133
1134     // front camera
1135     RearCameraAperture();
1136
1137     // struts (invisible, because they're buried in the case)
1138     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1139
1140     Buttons(){
1141       mirror([1,0,0])
1142         rotate([90,0,90]) {
1143           if (!($button_leg_only && enable_support))
1144           intersection(){
1145             translate([0,0,-10])
1146               linear_extrude(height= 20)
1147               ButtonPlan($button_l, 0,1);
1148             if ($button_leg_only)
1149               rotate([-90,90,0])
1150                 translate([phone_width/2, -400, kppe[1]])
1151                 mirror([1-abs($rhsflip - keeper_side),0,0])
1152                 cube([400, 800, 50]);
1153             if (enable_support && !$button_suppress_over_keeper)
1154               rotate([-90,90,0])
1155               translate([-400, -400, kppd[1]])
1156                 mirror([0,0,1])
1157                 cube([800,800,100]);
1158           }
1159           translate([0,0, -bppR[0]])
1160             linear_extrude(height= 20)
1161             ButtonPlan($button_l, 1,1);
1162         }
1163
1164     }
1165
1166     // apertures along top edge
1167     CaseAperture(jack_pos, jack_dia, 8);
1168     Flip_rhs(1)
1169       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1170
1171     OrdinaryRearApertures();
1172
1173     MicroUSB();
1174
1175     // gaps for the lid's hinge arms
1176     HingePortion(hex20 - hinge_x_arms_gap,
1177                  hex21 + hinge_x_arms_gap)
1178       minkowski(){
1179         HingeLidProfile();
1180         circle(r= hinge_r_arms_gap, $fn= 8);
1181       }
1182
1183     // screw holes in the hinge arms
1184     HingeScrews();
1185
1186     // catch striker
1187     CatchPortion(epp4[1])
1188       CatchCutProfile();
1189
1190     // lanyard
1191     Flip_bot(1)
1192       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1193       rotate([0, ly_theta, 0])
1194       rotate([0,0,90])
1195       LanyardCutout(lanyard_channel_len);
1196
1197     // prop recess
1198     Flip_rhs(1)
1199       translate([prop_x_pos,0,0])
1200       mirror([0,1,0])
1201       rotate([90,0,90])
1202       linextr(-prop_recess_hw, +prop_recess_hw)
1203       hull(){
1204         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1205           circleat(prcp1 + 20*d,
1206                    prc_r3);
1207       }
1208   }
1209 }
1210
1211 module LidAdhocMultiprintFrame(phase){
1212   if (led_window_style >= 3) {
1213     AdhocMultiprintFrame(phase, lpp13[1], -1);
1214   }
1215 }
1216
1217 module LidAroundEdges(){
1218   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1219     children();
1220 }
1221
1222 module Lid(){ ////toplevel
1223   skew_centre = [0, lpp11[0], lpp11[1]];
1224   difference(){
1225     union(){
1226       intersection(){
1227         LidAroundEdges()
1228           LidEdgeProfile();
1229
1230         translate(skew_centre)
1231           multmatrix([[ 1, 0, 0, 0 ],
1232                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1233                       [ 0, 0, 1, 0 ],
1234                       [ 0, 0, 0, 1 ]])
1235           translate(-skew_centre)
1236           LidAroundEdges()
1237           LidEdgeFoldClearanceProfile();
1238       }
1239
1240       // button covers
1241       Buttons(){
1242         intersection(){
1243           rotate([90,0,90])
1244             translate([0,0,-10])
1245             linear_extrude(height= 20)
1246             ButtonPlan($button_l, 1,0);
1247           union(){
1248             rotate([90,0,0])
1249               translate([0,0,-100])
1250               linear_extrude(height= 200)
1251               ButtonCoverProfile();
1252             hull()
1253               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1254                                  - lid_buttoncover_reinf))
1255                 translate([0,y,0])
1256                   ButtonCoverReinf();
1257           }
1258         }
1259       }
1260
1261       // hinge arms
1262       HingePortion(hex20, hex21) {
1263         LidEdgeProfile();
1264         HingeLidProfile();
1265       }
1266     }
1267     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1268
1269     // screw holes in the hinge arms
1270     HingeScrews();
1271
1272     // prop recess
1273     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1274       mirror([0,1,0])
1275       rotate([90,0,90])
1276       linextr(-prop_recess_hw, +prop_recess_hw)
1277       hull()
1278       for (pa = prop_angles)
1279         PropProfile(pa, 1,1);
1280
1281     // notification led aperture
1282     if (led_window_style)
1283       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1284         translate([0,0,-10])
1285           cylinder(r=nla_r0, h=20);
1286         if (led_window_style >= 2)
1287           translate([0,0, -nla_t])
1288             cylinder(r=nla_r2, height=20);
1289       }
1290
1291     }
1292
1293   LidAdhocMultiprintFrame(1);
1294 }
1295
1296 module HingeLever(){ ////toplevel
1297   difference() {
1298     // outer body, positive
1299     HingePortion(hex22, hex22 + phone_width/2)
1300       HingeLeverOuterProfile();
1301
1302     // space for the screws
1303     HingePortion(hex26, hex24)
1304       HingeLeverInnerProfile();
1305
1306     // recesses for the nuts
1307     HingePortion(hex23, hex26+1)
1308       HingeLeverNutProfile();
1309
1310     // bores for the screws
1311     HingeScrews();
1312
1313     // space for the charging cable
1314     MicroUSB();
1315     Flip_hinge() MicroUSB();
1316   }
1317 }
1318
1319 module LidWindow(){ ////toplevel
1320   translate([led_pos[0], -led_pos[1], lpp13[1]])
1321     mirror([0,0,1])
1322     cylinder(r= nla_r1, h=nla_t);
1323   LidAdhocMultiprintFrame(0);
1324 }
1325
1326 module LidWindowPrint(){ ////toplevel
1327   rotate([0,180,0])
1328     LidWindow();
1329 }
1330
1331 module DemoLidWindowSelect(){
1332   translate([led_pos[0], led_pos[1], -100]) {
1333     translate([0, -30, 0]) cube([400, 400, 200]);
1334   }
1335 }
1336
1337 module DemoLidWindow(){ ////toplevel
1338   %Lid();
1339   LidWindow();
1340   translate([0,40,0]){
1341     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1342     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1343   }
1344 }
1345
1346 module HingeLeverPrint(){ ////toplevel
1347   rotate([-90,0,0])
1348     translate([-phone_width/2, phone_height, 0])
1349     HingeLever();
1350 }
1351
1352 module TestSelectLength(){
1353   translate([-30, -200, -20])
1354     cube([30 + 15, 250, 40]);
1355 }
1356
1357 module TestLength(){ ////toplevel
1358   intersection(){
1359     Case();
1360     TestSelectLength();
1361   }
1362 }
1363
1364 module TestLengthRight(){ ////toplevel
1365   intersection(){
1366     Case();
1367     Flip_rhs(1)
1368       TestSelectLength();
1369   }
1370 }
1371
1372 module TestSelectWidth(){
1373   translate([-30, -(phone_height - 25), -20])
1374     mirror([0, 1, 0])
1375     cube([200, 50, 40]);
1376 }
1377
1378 module TestWidth(){ ////toplevel
1379   intersection(){
1380     Case();
1381     TestSelectWidth();
1382   }
1383 }
1384
1385 module TestLidWidthPrint(){ ////toplevel
1386   rotate([0,180.0]) intersection(){
1387     Lid();
1388     TestSelectWidth();
1389   }
1390 }
1391
1392 module TestSelectRearAperture(){
1393   minkowski(){
1394     union() children();
1395     translate([20, 0,0])
1396       cube([42, 2, 1], center=true);
1397   }
1398 }
1399
1400 module TestSelectCamera(){
1401   minkowski(){
1402     TestSelectRearAperture()
1403       RearCameraAperture();
1404     cube([0.1, 50, 0.1]);
1405   }
1406 }
1407
1408 module TestSelectOrdinaryRearApertures(){
1409   TestSelectRearAperture()
1410     OrdinaryRearApertures();
1411 }
1412
1413 module TestCamera(){ ////toplevel
1414   intersection(){
1415     Case();
1416     TestSelectCamera();
1417   }
1418 }
1419
1420 module TestLidByCamera(){ ////toplevel
1421   intersection(){
1422     Lid();
1423     TestSelectCamera();
1424   }
1425 }
1426
1427 module TestLidByCameraPrint(){ ////toplevel
1428   rotate([180,0,0]) TestLidByCamera();
1429 }
1430
1431 module DemoByCamera(){ ////toplevel
1432   color("blue") TestLidByCamera();
1433   color("red")  TestCamera();
1434 }
1435
1436 module OneKeeper(){ ////toplevel
1437   translate([0, -phone_cnr_rad, 0])
1438     rotate([90, 0, 0])
1439     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1440     KeeperProfile();
1441 }
1442
1443 module OneKeeperPrint(){ ////toplevel
1444   rotate([0,180,0])
1445     OneKeeper();
1446 }
1447
1448 module LidPrint(){ ////toplevel
1449   rotate([0,180,0])
1450     Lid();
1451 }
1452
1453 module TestSelectFrame(){
1454   include = [1,-1] * (epp2i[0] + 4);
1455
1456   difference(){
1457     cube(1000, center=true);
1458     translate([0,0, -100])
1459       linear_extrude(height=200)
1460       rectfromto(include,  inside_br - include);
1461   }
1462 }
1463
1464 module TestSelectLidFrame(){
1465   TestSelectFrame();
1466   translate([led_pos[0], -led_pos[1], -50])
1467     cylinder(r= nla_r2+3, h=100);
1468 }
1469
1470 module TestFrameCase(){ ////toplevel
1471   intersection(){
1472     Case();
1473     union(){
1474       TestSelectFrame();
1475       TestSelectCamera();
1476       TestSelectOrdinaryRearApertures();
1477     }
1478   }
1479 }
1480
1481 module TestSelectTopApertures(){
1482   translate([-100, -35, -100])
1483     cube([400, 100, 200]);
1484   LidAdhocMultiprintFrame(0);
1485   LidAdhocMultiprintFrame(1);
1486 }
1487
1488 module TestTopApertures(){ ////toplevel
1489   intersection(){
1490     Case();
1491     TestSelectFrame();
1492     TestSelectTopApertures();
1493   }
1494 }
1495
1496 module TestLidTopAperturesPrint(){ ////toplevel
1497   rotate([0,180,0]) intersection(){
1498     Lid();
1499     TestSelectLidFrame();
1500     TestSelectTopApertures();
1501   }
1502 }
1503
1504 module TestLidWindowTopAperturesPrint(){ ////toplevel
1505   rotate([0,180,0]) intersection(){
1506     LidWindow();
1507     TestSelectTopApertures();
1508   }
1509 }
1510
1511 module TestFrameLidPrint(){ ////toplevel
1512   rotate([0,180,0]) intersection(){
1513     Lid();
1514     TestSelectLidFrame();
1515   }
1516 }
1517
1518 module ButtonPlanForDemo(z, deep, cut){
1519   translate([0,0,z])
1520     ButtonPlan(8, deep, cut);
1521 }
1522
1523 module HingeScrews(){
1524   Flip_rhs() Flip_bot(1){
1525     for (c= [ hppT, hppB ])
1526       translate([ hex20,
1527                   -c[0],
1528                   c[1] ]){
1529         rotate([0,90,0])
1530           translate([0,0,-.2])
1531           cylinder( r= hingescrew_shaft_dia/2,
1532                     h = hingescrew_shaft_len+0.2 );
1533         rotate([0,-90,0])
1534           translate([0,0,+.1])
1535           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1536       }
1537   }
1538 }
1539
1540 module DemoPropAngleSelect(c){
1541   color(c) difference(){
1542     union(){ children(); }
1543     translate([ prop_x_pos, -400, -200 ])
1544       cube([ 400,800,400 ]);
1545   }
1546 }
1547
1548 module DemoPropAngle(ang){
1549   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1550   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1551
1552   translate(hL)
1553     rotate([ang/2,0,0])
1554     translate(-hL)
1555     translate(hC)
1556     rotate([ang/2,0,0])
1557     translate(-hC) {
1558       DemoPropAngleSelect("red") Case();
1559
1560       color("orange")
1561         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1562         PropProfileAssignments(ang) {
1563           echo($prpp1);
1564           rotate([-$prp_theta, 0, 0])
1565           translate([0, $prpp1[0], -$prpp1[1]])
1566           rotate([90,0,-90])
1567           Prop();
1568         }
1569     }
1570
1571   translate([0,0, -hp_k*2])
1572     DemoPropAngleSelect("blue")
1573     Lid();
1574 }
1575
1576 module DemoPropAngles(){ ////toplevel
1577   for (i=[0 : len(prop_angles)-1])
1578     translate(i * [0, -100, 100])
1579     DemoPropAngle(prop_angles[i]);
1580 }
1581
1582 module DemoHingeAngle(ang1,ang2){
1583   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1584   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1585
1586   translate(hL)
1587     rotate([ang2,0,0])
1588     translate(-hL)
1589     translate(hC)
1590     rotate([ang1,0,0])
1591     translate(-hC) {
1592       color("red") Lid();
1593     }
1594
1595   color("blue") intersection(){
1596     Case();
1597     union(){
1598       translate([bppJ[0], -400, -200])
1599         mirror([1,0,0])
1600         cube([400, 800, 400]);
1601       translate([10, -400, -200])
1602         cube([10, 800, 400]);
1603     }
1604   }
1605 }
1606
1607 module DemoHingeAngles(){ ////toplevel
1608   angles = [ 0, 4, 8, 12 ];
1609   echo("angles",angles);
1610   for (i=[0 : len(angles)-1]) {
1611     translate(i * [0, 0, 30]) {
1612       DemoHingeAngle(0,angles[i]);
1613       translate([0, 200, 0])
1614         DemoHingeAngle(angles[i],0);
1615     }
1616   }
1617 }
1618
1619 module DemoSelectAdhocLeftRight(right=0) {
1620   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1621     mirror([1-right, 0,0])
1622     cube([400, 800, 200]);
1623 }
1624
1625 module DemoLeft(){ ////toplevel
1626   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1627   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1628 }
1629
1630 module DemoFrame(){ ////toplevel
1631   color("red") TestFrameCase();
1632   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1633   color("black") HingeScrews();
1634   %HingeLever();
1635 }
1636
1637 module DemoLanyardCutout(){ ////toplevel
1638   LanyardCutout(25);
1639 }
1640
1641 module DemoHingedFrame(){ ///toplevel
1642   color("red") TestFrameCase();
1643   translate([0,0, -2*hp_k])
1644   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1645
1646   Flip_hinge(){
1647     color("orange") HingeLever();
1648     color("black") HingeScrews();
1649   }
1650 }
1651
1652 module DemoHinge(){ ////toplevel
1653   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1654     DemoFrame();
1655     translate([0,0, -hp_k*3])
1656       DemoHingedFrame();
1657   }
1658 }
1659
1660 module DemoProfiles(){ ////toplevel
1661   LidEdgeProfile();
1662   %EdgeProfile();
1663   KeeperProfile();
1664   translate([0,0,-1]) color("black") KeeperProfile(1);
1665   translate(ly_o){
1666     rotate(-ly_theta){
1667       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1668       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1669       translate([0, ly_q_z]){
1670         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1671         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1672       }
1673     }
1674   }
1675   translate([0,0,-5]) color("white") translate(epp2i)
1676     rotate(-ly_theta)
1677     rectfromto([-15, 0],
1678                [+15, -max_case_bottom_edge_thickness]);
1679
1680   translate([0,20]) {
1681     LanyardMainChannelProfile();
1682     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1683     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1684   }
1685
1686   translate([20,0]) {
1687     LidEdgeProfile();
1688     %EdgeProfile();
1689
1690     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1691
1692     color("blue") ButtonCoverProfile();
1693     color("red") {
1694       rectfromto(bppQ, demopoint_QR);
1695       rectfromto(bppR, demopoint_QR);
1696     }
1697   }
1698
1699   translate([-20,0]) {
1700     color("black") ButtonPlanForDemo(-2, 0,1);
1701     color("red" )  ButtonPlanForDemo(-4, 1,1);
1702     color("blue")  ButtonPlanForDemo(-6, 1,0);
1703   }
1704
1705   translate([0, -30]) {
1706     %LidEdgeProfile();
1707     %EdgeProfile();
1708     color("blue") HingeLidProfile();
1709     color("red")  HingeBaseProfile();
1710     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1711   }
1712
1713   for (f=[0,1]) {
1714     translate([-30, -60 + 30*f]) {
1715       translate([0,0,-4]) EdgeProfile();
1716       %translate([0,0,-10]) HingeBaseProfile();
1717       translate([0,-2] * f * hp_k) {
1718         translate([0,0,-4]) LidEdgeProfile();
1719         %translate([0,0,-10]) %HingeLidProfile();
1720       }
1721       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1722         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1723         translate([0,0,0]) color("red") difference(){
1724           HingeLeverOuterProfile();
1725           HingeLeverInnerProfile();
1726         }
1727         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1728       }
1729     }
1730   }
1731
1732   translate([20,-30]) {
1733     %EdgeProfile();
1734     %LidEdgeProfile();
1735     //translate([0,0,1]) CatchCutProfile();
1736     translate([0,0,+1]) color("red")
1737       difference(){ EdgeProfile(); CatchCutProfile(); }
1738   }
1739
1740   translate([40,-30]) {
1741     difference(){
1742       LidEdgeProfile();
1743       translate(prlp10)
1744         PropProfile(10, 1, 0);
1745     }
1746     translate(prlp10)
1747       PropProfile(15, 0);
1748   }
1749   translate([60,-30]) {
1750     PropAggregateProfile();
1751   }
1752 }
1753
1754 //EdgeProfile();
1755 //KeeperProfile();
1756 //CaseBase();
1757 //%Case();
1758 //Keeper();
1759 //LidEdgeProfile();
1760 //KeeperProfile();
1761 //DemoProfiles();
1762 //PropRecess();