fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 prop_angles = [ 15, 30, 45, 60 ];
   8
   9 bumper = [ 0.250, -0.025 ];
  10 // ^ One side.  Overall size is increased by twice this.
  11 // If no bumpers, is the gap around the phone.
  12
  13 enable_support = 1;
  14
  15 phone_cnr_rad = 6.0;
  16
  17 button_cutout_depth = 9;
  18
  19 phone_edge_thick = 9.0;
  20 phone_total_thick = 12.0;
  21 phone_backside_slope_inner = 1.5; // larger means shallower
  22 phone_backside_slope_outer = 1.0; // larger means shallower
  23
  24 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  25 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  26
  27 jack_pos = [ 14.38, 7.96 ];
  28 jack_dia = 10.64 + .5; // some jack I had lying around
  29
  30 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  31 noisecancelmic_dia = 4.00;
  32
  33 //fingerpushhole_dias = [ 15, 18 ];
  34 fingerpushhole_dias = [];
  35
  36 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  37 rearspeaker_size   = [  3.76,  7.36 ];
  38
  39 microusb_above = 3.27 - 0.25;
  40 microusb_below = 0.0;
  41 microusb_width = 16.12 + 1.25;
  42
  43 case_th_bottom = 2.5;
  44 case_th_lid = 2.5;
  45 case_th_side = 2;
  46 case_th_lip = 1.2;
  47
  48 case_struts_count = 6;
  49 case_struts_solid_below = 1.00;
  50 case_struts_solid_above = 0.75;
  51 case_struts_width = 0.10;
  52
  53 keeper_th_z = 0.75;
  54 keeper_th_x = 0.75;
  55 keeper_inner_width = 2.75;
  56 keeper_inner_height = 2.75;
  57 keeper_slant_slope = 2; // larger means steeper
  58
  59 keeper_gap_z_top = 0.25;
  60 keeper_gap_z_bot = 0.75;
  61 keeper_gap_x     = 0.25;
  62 keeper_gap_x_holes = 0.75;
  63
  64 keeper_side = 0; // 0 = lhs; 1 = rhs
  65
  66 case_lip = 1.25;
  67
  68 lid_gap_x = 0.25;
  69 lid_gap_z = 0.25;
  70 lid_lip = 1.75;
  71
  72 catch_slop = 0.50;
  73
  74 foldover_gap = 0.50;
  75 foldover_lever_gap = 0.50;
  76
  77 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  78 hingescrew_shaft_len = 12;
  79 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  80 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  81 hingescrew_head_th = 1.38 + 0.75;
  82 hingescrew_head_dia = 3.92;
  83 lever_cover_th = 0.75;
  84 hingemount_th = 2.5;
  85
  86 $fa = 5;
  87 $fs = 0.1;
  88
  89 button_l_fudge = 4.4;
  90 buttonishleg_default_l_is_fudge = 10;
  91
  92 hinge_base_slope = 1.5; // bigger is steeper
  93
  94 strut_min_at_end = 1.5;
  95
  96 hinge_x_gap = 0.125;
  97 hinge_x_postscrew_gap = 0.75;
  98 hinge_x_arms_gap = 0.35;
  99 hinge_r_arms_gap = 0.55;
 100
 101 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 102
 103 catch_len = 7.5;
 104 catch_width = 15;
 105 catch_thickness = 1.0;
 106 catch_side_gap = 0.75; // each side
 107
 108 catch_depth = 0.75;
 109 catch_height = 0.35;
 110 catch_finger_height = 1.5;
 111 catch_finger_depth = 2.5;
 112
 113 prop_recess_under = 0.50;
 114 prop_recess_slop = 0.200; // each side
 115 prop_end_dia = 0.5;
 116 prop_main_th = 3;
 117 prop_taper_len = 6;
 118 prop_main_width = 3;
 119 prop_side_gap = 0.75; // each side
 120 prop_caserecess_behind = 0.75;
 121 prop_caserecess_taper = 0.25; // each side
 122 prop_x_pos = 30;
 123
 124 // ---------- calculated ----------
 125
 126 phone_width =  (phone + bumper*2)[0];
 127 phone_height = (phone + bumper*2)[1];
 128
 129 inside_br = [phone_width, -phone_height];
 130
 131 //echo(camera_pos_tl + bumper,
 132 //     camera_pos_br + bumper);
 133
 134 // ----- could be changed -----
 135 lid_buttoncover_gap = lid_gap_x;
 136 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 137
 138 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 139
 140 prop_lidrecess_depth = case_th_lid - prop_recess_under;
 141
 142 prop_nose_len = case_th_lid - prop_recess_under;
 143 prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 144 prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 145
 146
 147 //lid_lip_overlap_width xxx bad name = ;
 148 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 149
 150 epp0 = [0,0];
 151 epp1 = [0, -phone_edge_thick];
 152 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 153 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 154 epp3 = epp2i + [10, 0];
 155 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 156 epp4 = epp5 + [-1,0] * case_th_side;
 157
 158 kppe = [0,0];
 159 kppd = kppe + [1,0] * keeper_inner_width;
 160 kppc = kppd + [0,1] * keeper_th_z;
 161 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 162 kppf = kppe - [0,1] * keeper_inner_height;
 163 kppa = [ kppb[0], kppf[1] ];
 164
 165 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 166 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 167
 168 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 169
 170 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 171 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 172
 173 case_bottom_z = epp2o[1] - case_th_bottom;
 174
 175 // button profile
 176 bppM = epp4 + [0,5];
 177 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 178 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 179 bppS = [ epp1[0], bppR[1] ];
 180 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 181 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 182 bppO = [ bppN[0], bppP[1] ];
 183 bppL = lpp10 + [5,0];
 184 bppK = [ bppL[0], bppN[1] ];
 185 bppJ = [ bppN[0], bppL[1] ];
 186
 187 // hinge plan
 188 hp_rn = hingescrew_nut_dia/2;
 189 hp_r2_min = hp_rn + lever_cover_th;
 190 hp_rs = hingescrew_shaft_dia/2;
 191 hp_r1_min = hp_rs + hingemount_th;
 192
 193 hp_r1 = max(hp_r1_min, hp_r2_min);
 194 hp_r2 = hp_r1;
 195
 196 hppU = lpp13;
 197 hppS = epp2o + [0,-1] * case_th_bottom;
 198 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 199
 200 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 201          0.5 * (hppU + hppS)[1] ];
 202 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 203 hppB = hppT + [0,-1] * hp_k;
 204
 205 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 206 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 207 hppE = [ hppE_x, hppE_y ];
 208
 209 // hinge elevation x coords
 210
 211 hingescrew_portion_len =
 212   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 213
 214 hex20 = max(epp2o[0],
 215             phone_cnr_rad,
 216             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 217 hex21 = hex20 + hingescrew_portion_len;
 218 hex22 = hex21 + hinge_x_gap;
 219 hex23 = hex22 + hingescrew_portion_len
 220   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 221 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 222 //echo(hex20, hex21, hex22, hex23, hex24);
 223 //echo(hingescrew_portion_len);
 224
 225 // catch
 226
 227 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 228 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 229 cppB = [ epp0[0], cppA[1] ];
 230 cppP = [ epp4[0], cppJ[1] ];
 231
 232 cppS = cppJ + [0,-1] * catch_len;
 233 cppD = [ cppA[0], cppS[1] + catch_slop ];
 234 cppC = [ cppB[0], cppD[1] ];
 235 cppT = cppS + [1,0] * catch_depth;
 236 cppU = cppT + [0,-1] * catch_height;
 237 cppV = [ cppS[0], cppU[1] - catch_depth ];
 238
 239 cppR = 0.5*(cppP + cppJ);
 240
 241 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 242 cppQ = [ cppR[0],
 243          cppV[1] - (catch_finger_height - cp_rQ) ];
 244 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 245
 246 // prop recess in lid
 247
 248 prl_r1 = prop_end_dia/2 + prop_recess_slop; // radius of end
 249
 250 prlp1 = [ lpp10[0] + prop_recess_slop + prop_end_dia/2,
 251           lpp10[1] + prop_recess_slop + prop_end_dia/2 ];
 252
 253 // prop recess in case
 254
 255 prcp2 = [ epp1[0], case_bottom_z ]; // protrusion corner
 256
 257 prc_r2 = prop_end_dia/2 + prop_recess_slop; // radius of end
 258
 259 prcp1_y = epp2o[1] - prop_recess_under - prc_r2;
 260 prcp2_x = prcp2[0] + prop_caserecess_behind + prc_r2 +
 261   (prcp1_y - case_bottom_z) * prop_caserecess_taper;
 262 prcp2 = [ prcp1_x, prcp1_y ]; // centre of tip circle
 263
 264 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 265
 266 prop_caserecess_buildout_r = prcp2[0] - epp2o[0];
 267
 268 // ---------- modules ----------
 269
 270 module KeeperProfile(slant=0){
 271   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 272   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 273 }
 274
 275 module EdgeProfile(){
 276   difference(){
 277     hull(){
 278       translate(epp3) square(case_th_bottom*2, center=true);
 279       circleat(epp2o, r=case_th_bottom);
 280       circleat(epp1, r=case_th_side);
 281       rectfromto(epp0, epp4);
 282     }
 283     polygon([ epp5 + [0,10],
 284               epp1,
 285               epp2i,
 286               epp3 + [10,0] ]);
 287   }
 288 }
 289
 290 module LidEdgeProfile(){
 291   polygon([ lpp10,
 292             lpp11,
 293             lpp12,
 294             lpp13,
 295             lpp13 + [10, 0],
 296             lpp10 + [10, 0]
 297             ]);
 298   intersection(){
 299     circleat(lpp12, r=lp_r12);
 300     rectfromto( lpp12 + [-10,   0],
 301                 lpp12 + [+10, +10] );
 302   }
 303 }
 304
 305 module ButtonCoverProfile(){
 306   intersection(){
 307     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 308     hull(){
 309       EdgeProfile();
 310       LidEdgeProfile();
 311     }
 312   }
 313 }
 314
 315 module ButtonPlan(l, deep, cut){
 316   epsilon =
 317     (cut  ? 0 : lid_buttoncover_gap);
 318
 319   delta =
 320     (deep ? lid_buttoncover_overlap : 0);
 321
 322   C = [0,0]; // by definition
 323   T = [ 0, epp4[1] ];
 324   G = T + [0,10];
 325
 326   B0 = C + [0,-1] * button_cutout_depth;
 327   B1 = B0 + [0,1] * epsilon;
 328
 329   r0 = 0.5 * (T[1] - B0[1]);
 330   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 331   H = A + [0,-1] * delta;
 332
 333   D = A + [-2,0] * r0;
 334   F = D + [0,10];
 335
 336   E0 = 0.5 * (D + A);
 337   E1 = E0 + [1,0] * epsilon;
 338
 339   I0 = [ E0[0], H[1] ];
 340   I1 = [ E1[0], H[1] ];
 341
 342   hull(){
 343     for (m=[0,1]) mirror([m,0])
 344       circleat(H, r0 - epsilon);
 345   }
 346   for (m=[0,1]) mirror([m,0]) {
 347     difference(){
 348       polygon([ E1,
 349                 I1,
 350                 H,
 351                 B1,
 352                 G,
 353                 F,
 354                 D
 355                 ]);
 356       circleat(D, r0 + epsilon);
 357     }
 358   }
 359 }
 360
 361 module CatchCatchProfile(){
 362   hull(){
 363     for (c=[ cppR, cppQ ])
 364       circleat(c, cp_rQ);
 365   }
 366   hull(){
 367     circleat(lpp12, lp_r12);
 368     circleat(lpp12 + [5,0], lp_r12);
 369     rectfromto(cppP, cppP + [5,0.1]);
 370   }
 371   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 372 }
 373
 374 module CatchCutProfile(){
 375   polygon([ cppB,
 376             cppA,
 377             cppD,
 378             cppF,
 379             cppF + [0,-10],
 380             cppF + [-10,-10],
 381             lpp12 + [-10,0],
 382             lpp12 + [10,0]
 383             ]);
 384 }
 385
 386 module Flip_rhs(yn=[0,1]) {
 387   for ($rhsflip=yn) {
 388     translate([phone_width/2, 0, 0])
 389       mirror([$rhsflip,0,0])
 390       translate([-phone_width/2, 0, 0])
 391       children();
 392   }
 393 }
 394
 395 module Flip_bot(yn=[0,1]) {
 396   for ($botflip=yn) {
 397     translate([0, -phone_height/2, 0])
 398       mirror([0, $botflip, 0])
 399       translate([0, phone_height/2, 0])
 400       children();
 401   }
 402 }
 403
 404 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 405   // sides
 406   Flip_rhs(){
 407     translate([0, -phone_cnr_rad, 0])
 408       rotate([90,0,0])
 409       linear_extrude(height = phone_height - phone_cnr_rad*2)
 410       children(0);
 411   }
 412   // corners
 413   Flip_rhs() Flip_bot() {
 414     translate([+1,-1] * phone_cnr_rad)
 415       intersection(){
 416         rotate_extrude()
 417           intersection(){
 418             mirror([1,0,0])
 419               translate([-1,0] * phone_cnr_rad)
 420               children(0);
 421             rectfromto([0,-20],[10,20]);
 422           }
 423         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 424           cube([10,10,40]);
 425       }
 426   }
 427   // top and bottom
 428   Flip_bot(){
 429     translate([ phone_width - phone_cnr_rad, 0,0 ])
 430       rotate([90,0,-90])
 431       linear_extrude(height = phone_width - phone_cnr_rad*2)
 432       children(0);
 433   }
 434   // fill
 435   translate([0,0, fill_zstart])
 436     mirror([0,0, fill_downwards])
 437     linear_extrude(height = fill_th)
 438     rectfromto([+1,-1] * phone_cnr_rad,
 439                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 440 }
 441
 442 module CaseAperture(pos, dia, $fn) {
 443   theta = 180/$fn;
 444   translate([ pos[0] + bumper[0],
 445               -epp2i[0],
 446               -pos[1] ])
 447     rotate([-90, theta, 0])
 448     cylinder(r = dia/2 / cos(theta),
 449              h = 60);
 450 }
 451
 452 module SideButton(y, y_ref_sign, l){
 453   // y_ref_sign:
 454   //   +1  measured from top    of actual phone to top    of button
 455   //   -1  measured from bottom of actual phone to bottom of button
 456   //    0  y is centre of button in coordinate system
 457   $button_l= l;
 458   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 459           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 460           y;
 461   //echo(eff_y);
 462   translate([0, eff_y, 0])
 463     children();
 464 }
 465
 466 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 467   $button_leg_only = true;
 468   SideButton(y, y_ref_sign, l) children();
 469 }
 470
 471 module Buttons(){
 472   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 473   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 474   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 475   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 476 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 477 }
 478
 479 module Struts(x_start, z_min, th){
 480   // if th is negative, starts at z_min and works towards -ve z
 481   // and object should then be printed other way up
 482   for (i= [1 : 1 : case_struts_count]) {
 483     translate([0,
 484                0,
 485                z_min])
 486       mirror([0,0, th<0 ? 1 : 0])
 487       translate([0,
 488                  -phone_height * i / (case_struts_count+1),
 489                  case_struts_solid_below])
 490       linear_extrude(height= abs(th)
 491                      -(case_struts_solid_below+case_struts_solid_above))
 492       rectfromto([               x_start, -0.5 * case_struts_width ],
 493                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 494   }
 495 }
 496
 497 module OrdinaryRearAperture(rhs,bot, pos){
 498   Flip_rhs(rhs) Flip_bot(bot)
 499     linextr(-20, 20)
 500     mirror([0,1])
 501     translate(pos + bumper)
 502     children();
 503 }
 504
 505 module MicroUSB(){
 506   Flip_bot(1){
 507     rotate([90,0,0])
 508       mirror([0,0,1])
 509       linextr(-epp2i[0], 60)
 510       translate([0.5 * phone_width, 0, 0])
 511       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 512                  [+microusb_width/2, epp0[1] + -microusb_above]);
 513   }
 514 }
 515
 516 module OrdinaryRearApertures(){
 517   // rear speaker
 518   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 519     rectfromto(-rearspeaker_gap,
 520                rearspeaker_size + rearspeaker_gap);
 521
 522   // finger hole to remove phone
 523   if (len(fingerpushhole_dias))
 524     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 525                                 phone[1]/2 ])
 526     scale(fingerpushhole_dias)
 527     circle(r= 0.5 );
 528 }
 529
 530 module RearCameraAperture(){
 531   Flip_rhs(1)
 532     mirror([0, 0, 1])
 533     linear_extrude(height = 20)
 534     mirror([0, 1, 0])
 535     translate(bumper)
 536     rectfromto(camera_pos_tl, camera_pos_br);
 537 }
 538
 539 module HingeLidProfile(){
 540   hull(){
 541     circleat(hppT, hp_r1);
 542     circleat(lpp12, lp_r12);
 543     polygon([lpp10,
 544              lpp13 + [2,0],
 545              lpp12,
 546              hppT]);
 547   }
 548 }
 549
 550 module HingeBaseProfile(){
 551   difference(){
 552     hull(){
 553       circleat(hppB, hp_r1);
 554       circleat(hppE, hp_r1);
 555       circleat(epp2o, case_th_bottom);
 556       circleat(hppB + [10,0], hp_r1);
 557     }
 558     polygon([epp5, epp1, epp2i, epp3, bppL]);
 559   }
 560 }
 561
 562 module HingeLeverOuterProfile(){
 563   hull(){
 564     circleat(hppT, hp_r2);
 565     circleat(hppB, hp_r2);
 566   }
 567 }
 568
 569 module HingeLeverInnerProfile(){
 570   for (c = [hppT, hppB]) {
 571     hull()
 572       for (x=[-20,20])
 573         for (y=[0, c[1] - hppM[1]])
 574           translate([x,y])
 575             circleat(c, hp_rn);
 576   }
 577 }
 578
 579 module Flip_hinge(){
 580   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 581   translate(hinge_origin)
 582     rotate([180,0,0])
 583     translate(-hinge_origin)
 584     children();
 585 }
 586
 587 module HingePortion(x0,x1){
 588   Flip_rhs() Flip_bot(1)
 589     translate([x0,0,0])
 590     mirror([1,0,0])
 591     rotate([90,0,-90])
 592     linear_extrude(height=x1-x0)
 593     children(0);
 594 }
 595
 596 module CatchPortion(width){
 597   translate([phone_width/2, 0,0])
 598     rotate([90,0,-90])
 599     linextr(-width/2, width/2)
 600     children(0);
 601 }
 602
 603 module CaseBase(){
 604   AroundEdges(epp3[1], case_th_bottom, 1)
 605     EdgeProfile();
 606 }
 607
 608 module Case(){ ////toplevel
 609   difference(){
 610     union(){
 611       CaseBase();
 612
 613       // ledge (fixed keeper)
 614       Flip_rhs(1-keeper_side) intersection(){
 615         rotate([90, 0, 0])
 616           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 617           KeeperProfile(1);
 618
 619         // outline of the whole case, to stop it protruding
 620         translate([0,0, -25])
 621           linear_extrude(height = 50)
 622           hull()
 623           Flip_bot()
 624           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 625       }
 626
 627       // hinge
 628       HingePortion(hex20, hex21) HingeBaseProfile();
 629     }
 630
 631     // slot for keeper
 632     Flip_rhs(keeper_side)
 633       translate([0, -phone_cnr_rad, 0])
 634       rotate([90, 0, 0])
 635       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 636       minkowski(){
 637         KeeperProfile();
 638         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 639                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 640       }
 641
 642     // front camera
 643     RearCameraAperture();
 644
 645     // struts (invisible, because they're buried in the case)
 646     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 647
 648     Buttons(){
 649       mirror([1,0,0])
 650         rotate([90,0,90]) {
 651           if (!($button_leg_only && enable_support))
 652           intersection(){
 653             translate([0,0,-10])
 654               linear_extrude(height= 20)
 655               ButtonPlan($button_l, 0,1);
 656             if ($button_leg_only)
 657               rotate([-90,90,0])
 658                 translate([phone_width/2, -400, kppe[1]])
 659                 mirror([1-abs($rhsflip - keeper_side),0,0])
 660                 cube([400, 800, 50]);
 661             if (enable_support)
 662               rotate([-90,90,0])
 663               translate([-400, -400, kppd[1]])
 664                 mirror([0,0,1])
 665                 cube([800,800,100]);
 666           }
 667           translate([0,0, -bppR[0]])
 668             linear_extrude(height= 20)
 669             ButtonPlan($button_l, 1,1);
 670         }
 671
 672       // buildout for prop recess
 673       Flip_rhs(1)
 674         linextr(-case_th_bottom, epp2i)
 675         hull() {
 676           for (dxs = [-1,+1])
 677             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 678                        epp2o[0] ]);
 679         }
 680     }
 681
 682     // apertures along top edge
 683     CaseAperture(jack_pos, jack_dia, 8);
 684     Flip_rhs(1)
 685       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
 686
 687     OrdinaryRearApertures();
 688
 689     MicroUSB();
 690
 691     // gaps for the lid's hinge arms
 692     HingePortion(hex20 - hinge_x_arms_gap,
 693                  hex21 + hinge_x_arms_gap)
 694       minkowski(){
 695         HingeLidProfile();
 696         circle(r= hinge_r_arms_gap, $fn= 8);
 697       }
 698
 699     // screw holes in the hinge arms
 700     HingeScrews();
 701
 702     // catch striker
 703     CatchPortion(catch_width + catch_side_gap*2)
 704       CatchCutProfile();
 705
 706     // prop recess
 707     Flip_rhs(1)
 708       translate([0,0,x])
 709       rotate([90,0,90])
 710       linextr(-prop_recess_hw, +prop_recess_hw)
 711       hull(){
 712         for (zs=[ -1,0,+1 ])
 713           circleat(prcp2 + 20*(abs(zs) * [0,-1] +
 714                                zs * [1,0] * prop_caserecess_taper),
 715                    pr_r2);
 716       }
 717   }
 718 }
 719
 720 module Lid(){ ////toplevel
 721   difference(){
 722     union(){
 723       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 724         LidEdgeProfile();
 725
 726       // button covers
 727       Buttons(){
 728         intersection(){
 729           rotate([90,0,90])
 730             translate([0,0,-10])
 731             linear_extrude(height= 20)
 732             ButtonPlan($button_l, 1,0);
 733           rotate([90,0,0])
 734              translate([0,0,-100])
 735             linear_extrude(height= 200)
 736             ButtonCoverProfile();
 737         }
 738       }
 739
 740       // hinge arms
 741       HingePortion(hex20, hex21) HingeLidProfile();
 742
 743       // catch
 744       CatchPortion(catch_width)
 745         CatchCatchProfile();
 746     }
 747     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 748
 749     // screw holes in the hinge arms
 750     HingeScrews();
 751   }
 752 }
 753
 754 module HingeLever(){ ////toplevel
 755   difference() {
 756     // outer body, positive
 757     HingePortion(hex22, hex22 + phone_width/2)
 758       HingeLeverOuterProfile();
 759
 760     // space for the screws
 761     HingePortion(hex23, hex24)
 762       HingeLeverInnerProfile();
 763
 764     // bores for the screws
 765     HingeScrews();
 766
 767     // space for the charging cable
 768     MicroUSB();
 769     Flip_hinge() MicroUSB();
 770   }
 771 }
 772
 773 module HingeLeverPrint(){ ////toplevel
 774   rotate([90,0,0])
 775     HingeLever();
 776 }
 777
 778 module TestSelectLength(){
 779   translate([-30, -200, -20])
 780     cube([30 + 15, 250, 40]);
 781 }
 782
 783 module TestLength(){ ////toplevel
 784   intersection(){
 785     Case();
 786     TestSelectLength();
 787   }
 788 }
 789
 790 module TestLengthRight(){ ////toplevel
 791   intersection(){
 792     Case();
 793     Flip_rhs(1)
 794       TestSelectLength();
 795   }
 796 }
 797
 798 module TestSelectWidth(){
 799   translate([-30, -(phone_height - 25), -20])
 800     mirror([0, 1, 0])
 801     cube([200, 50, 40]);
 802 }
 803
 804 module TestWidth(){ ////toplevel
 805   intersection(){
 806     Case();
 807     TestSelectWidth();
 808   }
 809 }
 810
 811 module TestLidWidthPrint(){ ////toplevel
 812   rotate([0,180.0]) intersection(){
 813     Lid();
 814     TestSelectWidth();
 815   }
 816 }
 817
 818 module TestSelectRearAperture(){
 819   minkowski(){
 820     union() children();
 821     translate([20, 0,0])
 822       cube([42, 2, 1], center=true);
 823   }
 824 }
 825
 826 module TestSelectCamera(){
 827   minkowski(){
 828     TestSelectRearAperture()
 829       RearCameraAperture();
 830     cube([0.1, 50, 0.1]);
 831   }
 832 }
 833
 834 module TestSelectOrdinaryRearApertures(){
 835   TestSelectRearAperture()
 836     OrdinaryRearApertures();
 837 }
 838
 839 module TestCamera(){ ////toplevel
 840   intersection(){
 841     Case();
 842     TestSelectCamera();
 843   }
 844 }
 845
 846 module TestLidByCamera(){ ////toplevel
 847   intersection(){
 848     Lid();
 849     TestSelectCamera();
 850   }
 851 }
 852
 853 module TestLidByCameraPrint(){ ////toplevel
 854   rotate([180,0,0]) TestLidByCamera();
 855 }
 856
 857 module DemoByCamera(){ ////toplevel
 858   color("blue") TestLidByCamera();
 859   color("red")  TestCamera();
 860 }
 861
 862 module OneKeeper(){ ////toplevel
 863   translate([0, -phone_cnr_rad, 0])
 864     rotate([90, 0, 0])
 865     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 866     KeeperProfile();
 867 }
 868
 869 module OneKeeperPrint(){ ////toplevel
 870   rotate([0,180,0])
 871     OneKeeper();
 872 }
 873
 874 module LidPrint(){ ////toplevel
 875   rotate([0,180,0])
 876     Lid();
 877 }
 878
 879 module TestSelectPropRecesses(posns){
 880   linextr(-100,100){
 881     translate([phone_width/2, -phone_height]){
 882       square([ 3, 500 ], center=true);
 883       for (y=posns)
 884         hull()
 885           for (dy=[ -prp5[0], -prp2[0] ])
 886             translate([0,y+dy])
 887               square([prop_main_width+5, 5], center=true);
 888     }
 889   }
 890 }
 891
 892 module TestSelectFrame(){
 893   include = [1,-1] * (epp2i[0] + 4);
 894
 895   difference(){
 896     cube(1000, center=true);
 897     translate([0,0, -100])
 898       linear_extrude(height=200)
 899       rectfromto(include,  inside_br - include);
 900   }
 901 }
 902
 903 module TestSelectLidFrame(){
 904   TestSelectFrame();
 905   TestSelectPropRecesses(prop_lid_posns);
 906 }
 907
 908 module TestFrameCase(){ ////toplevel
 909   intersection(){
 910     Case();
 911     union(){
 912       TestSelectFrame();
 913       TestSelectCamera();
 914       TestSelectOrdinaryRearApertures();
 915     }
 916   }
 917 }
 918
 919 module TestFrameLidPrint(){ ////toplevel
 920   rotate([0,180,0]) intersection(){
 921     Lid();
 922     TestSelectLidFrame();
 923   }
 924 }
 925
 926 module ButtonPlanForDemo(z, deep, cut){
 927   translate([0,0,z])
 928     ButtonPlan(8, deep, cut);
 929 }
 930
 931 module HingeScrews(){
 932   Flip_rhs() Flip_bot(1){
 933     for (c= [ hppT, hppB ])
 934       translate([ hex20,
 935                   -c[0],
 936                   c[1] ]){
 937         rotate([0,90,0])
 938           translate([0,0,-.2])
 939           cylinder( r= hingescrew_shaft_dia/2,
 940                     h = hingescrew_shaft_len+0.2 );
 941         rotate([0,-90,0])
 942           translate([0,0,+.1])
 943           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 944       }
 945   }
 946 }
 947
 948 module DemoFrame(){ ////toplevel
 949   color("red") TestFrameCase();
 950   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
 951   color("black") HingeScrews();
 952   %HingeLever();
 953 }
 954
 955 module DemoHingedFrame(){ ///toplevel
 956   color("red") TestFrameCase();
 957   translate([0,0, -2*hp_k])
 958   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
 959
 960   Flip_hinge(){
 961     color("orange") HingeLever();
 962     color("black") HingeScrews();
 963   }
 964 }
 965
 966 module DemoHinge(){ ////toplevel
 967   DemoFrame();
 968   translate([0,0, -hp_k*3])
 969     DemoHingedFrame();
 970 }
 971
 972 module DemoProfiles(){ ////toplevel
 973   LidEdgeProfile();
 974   %EdgeProfile();
 975   KeeperProfile();
 976   translate([0,0,-1]) color("black") KeeperProfile(1);
 977
 978   translate([20,0]) {
 979     LidEdgeProfile();
 980     %EdgeProfile();
 981
 982     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 983
 984     color("blue") ButtonCoverProfile();
 985     color("red") {
 986       rectfromto(bppQ, demopoint_QR);
 987       rectfromto(bppR, demopoint_QR);
 988     }
 989   }
 990
 991   translate([-20,0]) {
 992     color("black") ButtonPlanForDemo(-2, 0,1);
 993     color("red" )  ButtonPlanForDemo(-4, 1,1);
 994     color("blue")  ButtonPlanForDemo(-6, 1,0);
 995   }
 996
 997   translate([0, -30]) {
 998     %LidEdgeProfile();
 999     %EdgeProfile();
1000     color("blue") HingeLidProfile();
1001     color("red")  HingeBaseProfile();
1002     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1003     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
1004   }
1005
1006   translate([20,-30]) {
1007     %EdgeProfile();
1008     %LidEdgeProfile();
1009     //translate([0,0,1]) CatchCutProfile();
1010     color("blue") CatchCatchProfile();
1011     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1012   }
1013 }
1014
1015 //EdgeProfile();
1016 //KeeperProfile();
1017 //CaseBase();
1018 //%Case();
1019 //Keeper();
1020 //LidEdgeProfile();
1021 //KeeperProfile();
1022 //DemoProfiles();
1023 //PropRecess();