fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 phone_cnr_rad = 6.0;
  12
  13 button_cutout_depth = 9;
  14
  15 phone_edge_thick = 9.0;
  16 phone_total_thick = 12.0;
  17 phone_backside_slope_inner = 1.5; // larger means shallower
  18 phone_backside_slope_outer = 1.0; // larger means shallower
  19
  20 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  21 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  22
  23 jack_pos = [ 13.92, 7.96 ];
  24 jack_dia = 9.1 + .5; // some jack I had lying around
  25
  26 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  27 noisecancelmic_dia = 1.75;
  28
  29 fingerpushhole_dias = [ 15, 18 ];
  30
  31 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  32 rearspeaker_size   = [  3.76,  7.36 ];
  33
  34 microusb_above = 3.27 - 0.25;
  35 microusb_below = 0.0;
  36 microusb_width = 16.12 + 0.25;
  37
  38 case_th_bottom = 2.5;
  39 case_th_lid = 2.5;
  40 case_th_side = 2;
  41 case_th_lip = 1.2;
  42
  43 case_struts_count = 6;
  44 case_struts_solid_below = 1.00;
  45 case_struts_solid_above = 0.75;
  46 case_struts_width = 0.10;
  47
  48 keeper_th_z = 0.75;
  49 keeper_th_x = 0.75;
  50 keeper_inner_width = 2.75;
  51 keeper_inner_height = 2.75;
  52 keeper_slant_slope = 2; // larger means steeper
  53
  54 keeper_gap_z_top = 0.25;
  55 keeper_gap_z_bot = 0.75;
  56 keeper_gap_x     = 0.25;
  57 keeper_gap_x_holes = 0.75;
  58
  59 case_lip = 1.25;
  60
  61 lid_gap_x = 0.25;
  62 lid_gap_z = 0.25;
  63 lid_lip = 1.75;
  64
  65 foldover_gap = 0.50;
  66 foldover_lever_gap = 0.50;
  67
  68 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  69 hingescrew_shaft_len = 12;
  70 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  71 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  72 hingescrew_head_th = 1.38 + 0.75;
  73 hingescrew_head_dia = 3.92;
  74 lever_cover_th = 0.75;
  75 hingemount_th = 2.5;
  76
  77 $fa = 5;
  78 $fs = 0.1;
  79
  80 button_l_fudge = 4.4;
  81 buttonishleg_default_l_is_fudge = 10;
  82
  83 strut_min_at_end = 1.5;
  84
  85 hinge_x_gap = 0.125;
  86 hinge_x_postscrew_gap = 0.75;
  87 hinge_x_arms_gap = 0.35;
  88 hinge_r_arms_gap = 0.55;
  89
  90 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  91
  92 // ---------- calculated ----------
  93
  94 phone_width =  (phone + bumper*2)[0];
  95 phone_height = (phone + bumper*2)[1];
  96
  97 inside_br = [phone_width, -phone_height];
  98
  99 //echo(camera_pos_tl + bumper,
 100 //     camera_pos_br + bumper);
 101
 102 // ----- could be changed -----
 103 lid_buttoncover_gap = lid_gap_x;
 104 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 105
 106 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 107
 108 //lid_lip_overlap_width xxx bad name = ;
 109 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 110
 111 epp0 = [0,0];
 112 epp1 = [0, -phone_edge_thick];
 113 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 114 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 115 epp3 = epp2i + [10, 0];
 116 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 117 epp4 = epp5 + [-1,0] * case_th_side;
 118
 119 kppe = [0,0];
 120 kppd = kppe + [1,0] * keeper_inner_width;
 121 kppc = kppd + [0,1] * keeper_th_z;
 122 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 123 kppf = kppe - [0,1] * keeper_inner_height;
 124 kppa = [ kppb[0], kppf[1] ];
 125
 126 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 127 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 128
 129 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 130
 131 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 132 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 133
 134 // button profile
 135 bppM = epp4 + [0,5];
 136 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 137 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 138 bppS = [ epp1[0], bppR[1] ];
 139 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 140 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 141 bppO = [ bppN[0], bppP[1] ];
 142 bppL = lpp10 + [5,0];
 143 bppK = [ bppL[0], bppN[1] ];
 144 bppJ = [ bppN[0], bppL[1] ];
 145
 146 // hinge plan
 147 hp_rn = hingescrew_nut_dia/2;
 148 hp_r2_min = hp_rn + lever_cover_th;
 149 hp_rs = hingescrew_shaft_dia/2;
 150 hp_r1_min = hp_rs + hingemount_th;
 151
 152 hp_r1 = max(hp_r1_min, hp_r2_min);
 153 hp_r2 = hp_r1;
 154
 155 hppU = lpp13;
 156 hppS = epp2o + [0,-1] * case_th_bottom;
 157 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 158
 159 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 160          0.5 * (hppU + hppS)[1] ];
 161 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 162 hppB = hppT + [0,-1] * hp_k;
 163
 164 // hinge elevation x coords
 165
 166 hingescrew_portion_len =
 167   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 168
 169 hex20 = max(epp2o[0],
 170             phone_cnr_rad,
 171             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 172 hex21 = hex20 + hingescrew_portion_len;
 173 hex22 = hex21 - hinge_x_gap;
 174 hex23 = hex22 + hingescrew_portion_len;
 175 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 176 echo(hex20, hex21, hex22, hex23, hex24);
 177 echo(hingescrew_portion_len);
 178
 179 // ---------- modules ----------
 180
 181 module KeeperProfile(slant=0){
 182   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 183   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 184 }
 185
 186 module EdgeProfile(){
 187   difference(){
 188     hull(){
 189       translate(epp3) square(case_th_bottom*2, center=true);
 190       circleat(epp2o, r=case_th_bottom);
 191       circleat(epp1, r=case_th_side);
 192       rectfromto(epp0, epp4);
 193     }
 194     polygon([ epp5 + [0,10],
 195               epp1,
 196               epp2i,
 197               epp3 + [10,0] ]);
 198   }
 199 }
 200
 201 module LidEdgeProfile(){
 202   polygon([ lpp10,
 203             lpp11,
 204             lpp12,
 205             lpp13,
 206             lpp13 + [10, 0],
 207             lpp10 + [10, 0]
 208             ]);
 209   intersection(){
 210     circleat(lpp12, r=lp_r12);
 211     rectfromto( lpp12 + [-10,   0],
 212                 lpp12 + [+10, +10] );
 213   }
 214 }
 215
 216 module ButtonCoverProfile(){
 217   intersection(){
 218     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 219     hull(){
 220       EdgeProfile();
 221       LidEdgeProfile();
 222     }
 223   }
 224 }
 225
 226 module ButtonPlan(l, deep, cut){
 227   epsilon =
 228     (cut  ? 0 : lid_buttoncover_gap);
 229
 230   delta =
 231     (deep ? lid_buttoncover_overlap : 0);
 232
 233   C = [0,0]; // by definition
 234   T = [ 0, epp4[1] ];
 235   G = T + [0,10];
 236
 237   B0 = C + [0,-1] * button_cutout_depth;
 238   B1 = B0 + [0,1] * epsilon;
 239
 240   r0 = 0.5 * (T[1] - B0[1]);
 241   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 242   H = A + [0,-1] * delta;
 243
 244   D = A + [-2,0] * r0;
 245   F = D + [0,10];
 246
 247   E0 = 0.5 * (D + A);
 248   E1 = E0 + [1,0] * epsilon;
 249
 250   I0 = [ E0[0], H[1] ];
 251   I1 = [ E1[0], H[1] ];
 252
 253   hull(){
 254     for (m=[0,1]) mirror([m,0])
 255       circleat(H, r0 - epsilon);
 256   }
 257   for (m=[0,1]) mirror([m,0]) {
 258     difference(){
 259       polygon([ E1,
 260                 I1,
 261                 H,
 262                 B1,
 263                 G,
 264                 F,
 265                 D
 266                 ]);
 267       circleat(D, r0 + epsilon);
 268     }
 269   }
 270 }
 271
 272 module Flip_rhs(yn=[0,1]) {
 273   for ($rhsflip=yn) {
 274     translate([phone_width/2, 0, 0])
 275       mirror([$rhsflip,0,0])
 276       translate([-phone_width/2, 0, 0])
 277       children();
 278   }
 279 }
 280
 281 module Flip_bot(yn=[0,1]) {
 282   for ($botflip=yn) {
 283     translate([0, -phone_height/2, 0])
 284       mirror([0, $botflip, 0])
 285       translate([0, phone_height/2, 0])
 286       children();
 287   }
 288 }
 289
 290 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 291   // sides
 292   Flip_rhs(){
 293     translate([0, -phone_cnr_rad, 0])
 294       rotate([90,0,0])
 295       linear_extrude(height = phone_height - phone_cnr_rad*2)
 296       children(0);
 297   }
 298   // corners
 299   Flip_rhs() Flip_bot() {
 300     translate([+1,-1] * phone_cnr_rad)
 301       intersection(){
 302         rotate_extrude()
 303           intersection(){
 304             mirror([1,0,0])
 305               translate([-1,0] * phone_cnr_rad)
 306               children(0);
 307             rectfromto([0,-20],[10,20]);
 308           }
 309         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 310           cube([10,10,40]);
 311       }
 312   }
 313   // top and bottom
 314   Flip_bot(){
 315     translate([ phone_width - phone_cnr_rad, 0,0 ])
 316       rotate([90,0,-90])
 317       linear_extrude(height = phone_width - phone_cnr_rad*2)
 318       children(0);
 319   }
 320   // fill
 321   translate([0,0, fill_zstart])
 322     mirror([0,0, fill_downwards])
 323     linear_extrude(height = fill_th)
 324     rectfromto([+1,-1] * phone_cnr_rad,
 325                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 326 }
 327
 328 module CaseAperture(pos, dia, $fn) {
 329   theta = 180/$fn;
 330   translate([ pos[0] + bumper[0],
 331               -epp2i[0],
 332               -pos[1] ])
 333     rotate([-90, theta, 0])
 334     cylinder(r = dia/2 / cos(theta),
 335              h = 60);
 336 }
 337
 338 module SideButton(y, y_ref_sign, l){
 339   // y_ref_sign:
 340   //   +1  measured from top    of actual phone to top    of button
 341   //   -1  measured from bottom of actual phone to bottom of button
 342   //    0  y is centre of button in coordinate system
 343   $button_l= l;
 344   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 345           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 346           y;
 347   //echo(eff_y);
 348   translate([0, eff_y, 0])
 349     children();
 350 }
 351
 352 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 353   $button_leg_only = true;
 354   SideButton(y, y_ref_sign, l) children();
 355 }
 356
 357 module Buttons(){
 358   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 359   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 360   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 361   Flip_rhs(   ) LidButtonishLeg(20, -1) children();
 362 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 363 }
 364
 365 module Struts(x_start, z_min, th){
 366   // if th is negative, starts at z_min and works towards -ve z
 367   // and object should then be printed other way up
 368   for (i= [1 : 1 : case_struts_count]) {
 369     translate([0,
 370                0,
 371                z_min])
 372       mirror([0,0, th<0 ? 1 : 0])
 373       translate([0,
 374                  -phone_height * i / (case_struts_count+1),
 375                  case_struts_solid_below])
 376       linear_extrude(height= abs(th)
 377                      -(case_struts_solid_below+case_struts_solid_above))
 378       rectfromto([               x_start, -0.5 * case_struts_width ],
 379                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 380   }
 381 }
 382
 383 module OrdinaryRearAperture(rhs,bot, pos){
 384   Flip_rhs(rhs) Flip_bot(bot)
 385     linextr(-20, 20)
 386     mirror([0,1])
 387     translate(pos + bumper)
 388     children();
 389 }
 390
 391 module MicroUSB(){
 392   Flip_bot(1){
 393     rotate([90,0,0])
 394       mirror([0,0,1])
 395       linextr(-epp2i[0], 60)
 396       translate([0.5 * phone_width, 0, 0])
 397       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 398                  [+microusb_width/2, epp0[1] + -microusb_above]);
 399   }
 400 }
 401
 402 module OrdinaryRearApertures(){
 403   // rear speaker
 404   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 405     rectfromto(-rearspeaker_gap,
 406                rearspeaker_size + rearspeaker_gap);
 407
 408   // finger hole to remove phone
 409   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 410                               phone[1]/2 ])
 411     scale(fingerpushhole_dias)
 412     circle(r= 0.5 );
 413 }
 414
 415 module RearCameraAperture(){
 416   Flip_rhs(1)
 417     mirror([0, 0, 1])
 418     linear_extrude(height = 20)
 419     mirror([0, 1, 0])
 420     translate(bumper)
 421     rectfromto(camera_pos_tl, camera_pos_br);
 422 }
 423
 424 module HingeLidProfile(){
 425   hull(){
 426     circleat(hppT, hp_r1);
 427     circleat(lpp12, lp_r12);
 428     polygon([lpp10,
 429              lpp13 + [2,0],
 430              lpp12,
 431              hppT]);
 432   }
 433 }
 434
 435 module HingeBaseProfile(){
 436   difference(){
 437     hull(){
 438       circleat(hppB, hp_r1);
 439       circleat(epp2o, case_th_bottom);
 440       circleat(hppB + [10,0], hp_r1);
 441     }
 442     polygon([epp5, epp1, epp2i, epp3, bppL]);
 443   }
 444 }
 445
 446 module HingeLeverOuterProfile(){
 447   hull(){
 448     circleat(hppT, hp_r2);
 449     circleat(hppB, hp_r2);
 450   }
 451 }
 452
 453 module HingeLeverInnerProfile(){
 454   for (c = [hppT, hppB]) {
 455     hull()
 456       for (x=[0,20])
 457         translate([x,0])
 458           circleat(c, hp_rn);
 459         circleat(hppB, hp_rn);
 460   }
 461 }
 462
 463 module Flip_hinge(){
 464   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 465   translate(hinge_origin)
 466     rotate([180,0,0])
 467     translate(-hinge_origin)
 468     children();
 469 }
 470
 471 module HingePortion(x0,x1){
 472   Flip_rhs() Flip_bot(1)
 473     translate([x0,0,0])
 474     mirror([1,0,0])
 475     rotate([90,0,-90])
 476     linear_extrude(height=x1-x0)
 477     children(0);
 478 }
 479
 480 module CaseBase(){
 481   AroundEdges(epp3[1], case_th_bottom, 1)
 482     EdgeProfile();
 483 }
 484
 485 module Case(){ ////toplevel
 486   difference(){
 487     union(){
 488       CaseBase();
 489
 490       // ledge (fixed keeper)
 491       intersection(){
 492         rotate([90, 0, 0])
 493           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 494           KeeperProfile(1);
 495
 496         // outline of the whole case, to stop it protruding
 497         translate([0,0, -25])
 498           linear_extrude(height = 50)
 499           hull()
 500           // Flip_rhs() // actually, we only care about the LH
 501           Flip_bot()
 502           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 503       }
 504
 505       // hinge
 506       HingePortion(hex20, hex21) HingeBaseProfile();
 507     }
 508
 509     // slot for keeper
 510     Flip_rhs(1)
 511       translate([0, -phone_cnr_rad, 0])
 512       rotate([90, 0, 0])
 513       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 514       minkowski(){
 515         KeeperProfile();
 516         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 517                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 518       }
 519
 520     // front camera
 521     RearCameraAperture();
 522
 523     // struts (invisible, because they're buried in the case)
 524     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 525
 526     Buttons(){
 527       mirror([1,0,0])
 528         rotate([90,0,90]) {
 529           intersection(){
 530             translate([0,0,-10])
 531               linear_extrude(height= 20)
 532               ButtonPlan($button_l, 0,1);
 533             if ($button_leg_only)
 534               rotate([-90,90,0])
 535                 translate([phone_width/2, -400, kppe[1]])
 536                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 537           }
 538           translate([0,0, -bppR[0]])
 539             linear_extrude(height= 20)
 540             ButtonPlan($button_l, 1,1);
 541         }
 542     }
 543
 544     // apertures along top edge
 545     CaseAperture(jack_pos, jack_dia, 8);
 546     Flip_rhs(1)
 547       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 548
 549     OrdinaryRearApertures();
 550
 551     MicroUSB();
 552
 553     // gaps for the lid's hinge arms
 554     HingePortion(hex20 - hinge_x_arms_gap,
 555                  hex21 + hinge_x_arms_gap)
 556       minkowski(){
 557         HingeLidProfile();
 558         circle(r= hinge_r_arms_gap, $fn= 8);
 559       }
 560
 561     // screw holes in the hinge arms
 562     HingeScrews();
 563   }
 564 }
 565
 566 module Lid(){ ////toplevel
 567   difference(){
 568     union(){
 569       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 570         LidEdgeProfile();
 571
 572       // button covers
 573       Buttons(){
 574         intersection(){
 575           rotate([90,0,90])
 576             translate([0,0,-10])
 577             linear_extrude(height= 20)
 578             ButtonPlan($button_l, 1,0);
 579           rotate([90,0,0])
 580              translate([0,0,-100])
 581             linear_extrude(height= 200)
 582             ButtonCoverProfile();
 583         }
 584       }
 585
 586       // hinge arms
 587       HingePortion(hex20, hex21) HingeLidProfile();
 588     }
 589     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 590
 591     // screw holes in the hinge arms
 592     HingeScrews();
 593   }
 594 }
 595
 596 module HingeLever(){ ////toplevel
 597   difference() {
 598     // outer body, positive
 599     HingePortion(hex22, hex22 + phone_width/2)
 600       HingeLeverOuterProfile();
 601
 602     // space for the screws
 603     HingePortion(hex23, hex24)
 604       HingeLeverInnerProfile();
 605
 606     // bores for the screws
 607     HingeScrews();
 608
 609     // space for the charging cable
 610     MicroUSB();
 611     Flip_hinge() MicroUSB();
 612   }
 613 }
 614
 615 module HingeLeverPrint(){ ////toplevel
 616   rotate([90,0,0])
 617     HingeLever();
 618 }
 619
 620 module TestSelectLength(){
 621   translate([-30, -200, -20])
 622     cube([30 + 15, 250, 40]);
 623 }
 624
 625 module TestLength(){ ////toplevel
 626   intersection(){
 627     Case();
 628     TestSelectLength();
 629   }
 630 }
 631
 632 module TestLengthRight(){ ////toplevel
 633   intersection(){
 634     Case();
 635     Flip_rhs(1)
 636       TestSelectLength();
 637   }
 638 }
 639
 640 module TestSelectWidth(){
 641   translate([-30, -(phone_height - 25), -20])
 642     mirror([0, 1, 0])
 643     cube([200, 50, 40]);
 644 }
 645
 646 module TestWidth(){ ////toplevel
 647   intersection(){
 648     Case();
 649     TestSelectWidth();
 650   }
 651 }
 652
 653 module TestLidWidthPrint(){ ////toplevel
 654   rotate([0,180.0]) intersection(){
 655     Lid();
 656     TestSelectWidth();
 657   }
 658 }
 659
 660 module TestSelectRearAperture(){
 661   minkowski(){
 662     union() children();
 663     translate([20, 0,0])
 664       cube([42, 2, 1], center=true);
 665   }
 666 }
 667
 668 module TestSelectCamera(){
 669   minkowski(){
 670     TestSelectRearAperture()
 671       RearCameraAperture();
 672     cube([0.1, 50, 0.1]);
 673   }
 674 }
 675
 676 module TestSelectOrdinaryRearApertures(){
 677   TestSelectRearAperture()
 678     OrdinaryRearApertures();
 679 }
 680
 681 module TestCamera(){ ////toplevel
 682   intersection(){
 683     Case();
 684     TestSelectCamera();
 685   }
 686 }
 687
 688 module TestLidByCamera(){ ////toplevel
 689   intersection(){
 690     Lid();
 691     TestSelectCamera();
 692   }
 693 }
 694
 695 module TestLidByCameraPrint(){ ////toplevel
 696   rotate([180,0,0]) TestLidByCamera();
 697 }
 698
 699 module DemoByCamera(){ ////toplevel
 700   color("blue") TestLidByCamera();
 701   color("red")  TestCamera();
 702 }
 703
 704 module OneKeeper(){ ////toplevel
 705   translate([0, -phone_cnr_rad, 0])
 706     rotate([90, 0, 0])
 707     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 708     KeeperProfile();
 709 }
 710
 711 module OneKeeperPrint(){ ////toplevel
 712   rotate([0,180,0])
 713     OneKeeper();
 714 }
 715
 716 module LidPrint(){ ////toplevel
 717   rotate([0,180,0])
 718     Lid();
 719 }
 720
 721 module TestSelectFrame(){
 722   include = [1,-1] * (epp2i[0] + 4);
 723
 724   difference(){
 725     cube(1000, center=true);
 726     translate([0,0, -100])
 727       linear_extrude(height=200)
 728       rectfromto(include,  inside_br - include);
 729   }
 730 }
 731
 732 module TestFrameCase(){ ////toplevel
 733   intersection(){
 734     Case();
 735     union(){
 736       TestSelectFrame();
 737       TestSelectCamera();
 738       TestSelectOrdinaryRearApertures();
 739     }
 740   }
 741 }
 742
 743 module TestFrameLidPrint(){ ////toplevel
 744   rotate([0,180,0]) intersection(){
 745     Lid();
 746     TestSelectFrame();
 747   }
 748 }
 749
 750 module Keeper(){ ////toplevel
 751   Flip_rhs()
 752     OneKeeper();
 753 }
 754
 755 module ButtonPlanForDemo(z, deep, cut){
 756   translate([0,0,z])
 757     ButtonPlan(8, deep, cut);
 758 }
 759
 760 module HingeScrews(){
 761   Flip_rhs() Flip_bot(1){
 762     for (c= [ hppT, hppB ])
 763       translate([ hex20,
 764                   -c[0],
 765                   c[1] ]){
 766         rotate([0,90,0])
 767           translate([0,0,-.2])
 768           cylinder( r= hingescrew_shaft_dia/2,
 769                     h = hingescrew_shaft_len+0.2 );
 770         rotate([0,-90,0])
 771           translate([0,0,+.1])
 772           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 773       }
 774   }
 775 }
 776
 777 module DemoFrame(){ ////toplevel
 778   color("red") TestFrameCase();
 779   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 780   color("black") HingeScrews();
 781   %HingeLever();
 782 }
 783
 784 module DemoHingedFrame(){ ///toplevel
 785   color("red") TestFrameCase();
 786   translate([0,0, -2*hp_k])
 787   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 788
 789   Flip_hinge(){
 790     color("orange") HingeLever();
 791     color("black") HingeScrews();
 792   }
 793 }
 794
 795 module DemoHinge(){ ////toplevel
 796   DemoFrame();
 797   translate([0,0, -hp_k*3])
 798     DemoHingedFrame();
 799 }
 800
 801 module DemoProfiles(){ ////toplevel
 802   LidEdgeProfile();
 803   %EdgeProfile();
 804   KeeperProfile();
 805   translate([0,0,-1]) color("black") KeeperProfile(1);
 806
 807   translate([20,0]) {
 808     LidEdgeProfile();
 809     %EdgeProfile();
 810
 811     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 812
 813     color("blue") ButtonCoverProfile();
 814     color("red") {
 815       rectfromto(bppQ, demopoint_QR);
 816       rectfromto(bppR, demopoint_QR);
 817     }
 818   }
 819
 820   translate([-20,0]) {
 821     color("black") ButtonPlanForDemo(-2, 0,1);
 822     color("red" )  ButtonPlanForDemo(-4, 1,1);
 823     color("blue")  ButtonPlanForDemo(-6, 1,0);
 824   }
 825
 826   translate([0, -30]) {
 827     %LidEdgeProfile();
 828     %EdgeProfile();
 829     color("blue") HingeLidProfile();
 830     color("red")  HingeBaseProfile();
 831     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 832     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 833   }
 834 }
 835
 836 //EdgeProfile();
 837 //KeeperProfile();
 838 //CaseBase();
 839 //%Case();
 840 //Keeper();
 841 //LidEdgeProfile();
 842 //KeeperProfile();
 843 //DemoProfiles();