fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 case_th_bottom = 2.5;
  22 case_th_lid = 2.5;
  23 case_th_side = 2;
  24 case_th_lip = 1.2;
  25
  26 case_struts_count = 6;
  27 case_struts_solid_below = 1.00;
  28 case_struts_solid_above = 0.75;
  29 case_struts_width = 0.10;
  30
  31 keeper_th_z = 0.75;
  32 keeper_th_x = 0.75;
  33 keeper_inner_width = 2.75;
  34 keeper_inner_height = 2.75;
  35 keeper_slant_slope = 2; // larger means steeper
  36
  37 keeper_gap_z_top = 0.25;
  38 keeper_gap_z_bot = 0.75;
  39 keeper_gap_x     = 0.25;
  40 keeper_gap_x_holes = 0.75;
  41
  42 case_lip = 1.25;
  43
  44 lid_gap_x = 0.25;
  45 lid_gap_z = 0.25;
  46 lid_lip = 1.75;
  47
  48 $fa = 5;
  49 $fs = 0.1;
  50
  51 button_l_fudge = 4.4;
  52 buttonishleg_default_l_is_fudge = 10;
  53
  54 strut_min_at_end = 1.5;
  55
  56 // ---------- calculated ----------
  57
  58 phone_width =  (phone + bumper*2)[0];
  59 phone_height = (phone + bumper*2)[1];
  60
  61 inside_br = [phone_width, -phone_height];
  62
  63 //echo(camera_pos_tl + bumper,
  64 //     camera_pos_br + bumper);
  65
  66 // ----- could be changed -----
  67 lid_buttoncover_gap = lid_gap_x;
  68 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  69
  70 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  71
  72 //lid_lip_overlap_width xxx bad name = ;
  73 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  74
  75 epp0 = [0,0];
  76 epp1 = [0, -phone_edge_thick];
  77 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  78 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  79 epp3 = epp2i + [10, 0];
  80 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  81 epp4 = epp5 + [-1,0] * case_th_side;
  82
  83 kppe = [0,0];
  84 kppd = kppe + [1,0] * keeper_inner_width;
  85 kppc = kppd + [0,1] * keeper_th_z;
  86 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  87 kppf = kppe - [0,1] * keeper_inner_height;
  88 kppa = [ kppb[0], kppf[1] ];
  89
  90 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  91 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  92
  93 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  94
  95 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
  96 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
  97
  98 // button profile
  99 bppM = epp4 + [0,5];
 100 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 101 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 102 bppS = [ epp1[0], bppR[1] ];
 103 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 104 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 105 bppO = [ bppN[0], bppP[1] ];
 106 bppL = lpp10 + [5,0];
 107 bppK = [ bppL[0], bppN[1] ];
 108 bppJ = [ bppN[0], bppL[1] ];
 109
 110 module rectfromto(a,b) {
 111   ab = b - a;
 112   translate([min(a[0], b[0]), min(a[1], b[1])])
 113     square([abs(ab[0]), abs(ab[1])]);
 114 }
 115 module circleat(c,r) { translate(c) circle(r); }
 116
 117 module KeeperProfile(slant=0){
 118   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 119   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 120 }
 121
 122 module EdgeProfile(){
 123   difference(){
 124     hull(){
 125       translate(epp3) square(case_th_bottom*2, center=true);
 126       circleat(epp2o, r=case_th_bottom);
 127       circleat(epp1, r=case_th_side);
 128       rectfromto(epp0, epp4);
 129     }
 130     polygon([ epp5 + [0,10],
 131               epp1,
 132               epp2i,
 133               epp3 + [10,0] ]);
 134   }
 135 }
 136
 137 module LidEdgeProfile(){
 138   polygon([ lpp10,
 139             lpp11,
 140             lpp12,
 141             lpp13,
 142             lpp13 + [10, 0],
 143             lpp10 + [10, 0]
 144             ]);
 145   intersection(){
 146     circleat(lpp12, r=lp_r12);
 147     rectfromto( lpp12 + [-10,   0],
 148                 lpp12 + [+10, +10] );
 149   }
 150 }
 151
 152 module ButtonCoverProfile(){
 153   intersection(){
 154     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 155     hull(){
 156       EdgeProfile();
 157       LidEdgeProfile();
 158     }
 159   }
 160 }
 161
 162 module ButtonPlan(l, deep, cut){
 163   epsilon =
 164     (cut  ? 0 : lid_buttoncover_gap);
 165
 166   delta =
 167     (deep ? lid_buttoncover_overlap : 0);
 168
 169   C = [0,0]; // by definition
 170   T = [ 0, epp4[1] ];
 171   G = T + [0,10];
 172
 173   B0 = C + [0,-1] * button_cutout_depth;
 174   B1 = B0 + [0,1] * epsilon;
 175
 176   r0 = 0.5 * (T[1] - B0[1]);
 177   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 178   H = A + [0,-1] * delta;
 179
 180   D = A + [-2,0] * r0;
 181   F = D + [0,10];
 182
 183   E0 = 0.5 * (D + A);
 184   E1 = E0 + [1,0] * epsilon;
 185
 186   I0 = [ E0[0], H[1] ];
 187   I1 = [ E1[0], H[1] ];
 188
 189   hull(){
 190     for (m=[0,1]) mirror([m,0])
 191       circleat(H, r0 - epsilon);
 192   }
 193   for (m=[0,1]) mirror([m,0]) {
 194     difference(){
 195       polygon([ E1,
 196                 I1,
 197                 H,
 198                 B1,
 199                 G,
 200                 F,
 201                 D
 202                 ]);
 203       circleat(D, r0 + epsilon);
 204     }
 205   }
 206 }
 207
 208 module CaseBase_rhsflip(yn=[0,1]) {
 209   for ($rhsflip=yn) {
 210     translate([phone_width/2, 0, 0])
 211       mirror([$rhsflip,0,0])
 212       translate([-phone_width/2, 0, 0])
 213       children();
 214   }
 215 }
 216
 217 module CaseBase_botflip() {
 218   for (bot=[0,1]) {
 219     translate([0, -phone_height/2, 0])
 220       mirror([0, bot, 0])
 221       translate([0, phone_height/2, 0])
 222       children();
 223   }
 224 }
 225
 226 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 227   // sides
 228   CaseBase_rhsflip(){
 229     translate([0, -phone_cnr_rad, 0])
 230       rotate([90,0,0])
 231       linear_extrude(height = phone_height - phone_cnr_rad*2)
 232       children(0);
 233   }
 234   // corners
 235   CaseBase_rhsflip() CaseBase_botflip() {
 236     translate([+1,-1] * phone_cnr_rad)
 237       intersection(){
 238         rotate_extrude()
 239           intersection(){
 240             mirror([1,0,0])
 241               translate([-1,0] * phone_cnr_rad)
 242               children(0);
 243             rectfromto([0,-20],[10,20]);
 244           }
 245         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 246           cube([10,10,40]);
 247       }
 248   }
 249   // top and bottom
 250   CaseBase_botflip(){
 251     translate([ phone_width - phone_cnr_rad, 0,0 ])
 252       rotate([90,0,-90])
 253       linear_extrude(height = phone_width - phone_cnr_rad*2)
 254       children(0);
 255   }
 256   // fill
 257   translate([0,0, fill_zstart])
 258     mirror([0,0, fill_downwards])
 259     linear_extrude(height = fill_th)
 260     rectfromto([+1,-1] * phone_cnr_rad,
 261                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 262 }
 263
 264 module SideButton(y, y_ref_sign, l){
 265   // y_ref_sign:
 266   //   +1  measured from top    of actual phone to top    of button
 267   //   -1  measured from bottom of actual phone to bottom of button
 268   //    0  y is centre of button in coordinate system
 269   $button_l= l;
 270   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 271           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 272           y;
 273   echo(eff_y);
 274   translate([0, eff_y, 0])
 275     children();
 276 }
 277
 278 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 279   $button_leg_only = true;
 280   SideButton(y, y_ref_sign, l) children();
 281 }
 282
 283 module Buttons(){
 284   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 285   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 286   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 287   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 288 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 289 }
 290
 291 module Struts(x_start, z_min, th){
 292   // if th is negative, starts at z_min and works towards -ve z
 293   // and object should then be printed other way up
 294   for (i= [1 : 1 : case_struts_count]) {
 295     translate([0,
 296                0,
 297                z_min])
 298       mirror([0,0, th<0 ? 1 : 0])
 299       translate([0,
 300                  -phone_height * i / (case_struts_count+1),
 301                  case_struts_solid_below])
 302       linear_extrude(height= abs(th)
 303                      -(case_struts_solid_below+case_struts_solid_above))
 304       rectfromto([               x_start, -0.5 * case_struts_width ],
 305                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 306   }
 307 }
 308
 309 module CaseBase(){
 310   AroundEdges(epp3[1], case_th_bottom, 1)
 311     EdgeProfile();
 312 }
 313
 314 module Case(){ ////toplevel
 315   difference(){
 316     union(){
 317       CaseBase();
 318
 319       // ledge (fixed keeper)
 320       intersection(){
 321         rotate([90, 0, 0])
 322           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 323           KeeperProfile(1);
 324
 325         // outline of the whole case, to stop it protruding
 326         translate([0,0, -25])
 327           linear_extrude(height = 50)
 328           hull()
 329           // CaseBase_rhsflip() // actually, we only care about the LH
 330           CaseBase_botflip()
 331           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 332       }
 333     }
 334
 335     // slot for keeper
 336     CaseBase_rhsflip(1)
 337       translate([0, -phone_cnr_rad, 0])
 338       rotate([90, 0, 0])
 339       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 340       minkowski(){
 341         KeeperProfile();
 342         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 343                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 344       }
 345
 346     // front camera
 347     CaseBase_rhsflip([1])
 348       mirror([0, 0, 1])
 349       linear_extrude(height = 20)
 350       mirror([0, 1, 0])
 351       translate(bumper)
 352       rectfromto(camera_pos_tl, camera_pos_br);
 353
 354     // struts (invisible, because they're buried in the case)
 355     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 356
 357     Buttons(){
 358       mirror([1,0,0])
 359         rotate([90,0,90]) {
 360           intersection(){
 361             translate([0,0,-10])
 362               linear_extrude(height= 20)
 363               ButtonPlan($button_l, 0,1);
 364             if ($button_leg_only)
 365               rotate([-90,90,0])
 366                 translate([phone_width/2, -400, kppe[1]])
 367                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 368           }
 369           translate([0,0, -bppR[0]])
 370             linear_extrude(height= 20)
 371             ButtonPlan($button_l, 1,1);
 372         }
 373     }
 374   }
 375 }
 376
 377 module Lid(){ ////toplevel
 378   difference(){
 379     union(){
 380       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 381         LidEdgeProfile();
 382
 383       // button covers
 384       Buttons(){
 385         intersection(){
 386           rotate([90,0,90])
 387             translate([0,0,-10])
 388             linear_extrude(height= 20)
 389             ButtonPlan($button_l, 1,0);
 390           rotate([90,0,0])
 391              translate([0,0,-100])
 392             linear_extrude(height= 200)
 393             ButtonCoverProfile();
 394         }
 395       }
 396     }
 397     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 398   }
 399 }
 400
 401 module TestLength(){ ////toplevel
 402   intersection(){
 403     Case();
 404     translate([-30, -200, -20])
 405     cube([30 + 15, 250, 40]);
 406   }
 407 }
 408
 409 module TestSelectWidth(){
 410   translate([-30, -(phone_height - 25), -20])
 411     mirror([0, 1, 0])
 412     cube([200, 50, 40]);
 413 }
 414
 415 module TestWidth(){ ////toplevel
 416   intersection(){
 417     Case();
 418     TestSelectWidth();
 419   }
 420 }
 421
 422 module TestLidWidthPrint(){ ////toplevel
 423   rotate([0,180.0]) TestLidWidth();
 424 }
 425
 426 module TestSelectCamera(){
 427   CaseBase_rhsflip(1)
 428     translate([0,0,-25])
 429     linear_extrude(height = 50)
 430     mirror([0, 1, 0])
 431     rectfromto([-20, -20],
 432                camera_pos_br + bumper + [ 5, 5 ]);
 433 }
 434
 435 module TestCamera(){ ////toplevel
 436   intersection(){
 437     Case();
 438     TestSelectCamera();
 439   }
 440 }
 441
 442 module TestLidByCamera(){ ////toplevel
 443   intersection(){
 444     Lid();
 445     TestSelectCamera();
 446   }
 447 }
 448
 449 module TestLidByCameraPrint(){ ////toplevel
 450   rotate([180,0,0]) TestLidByCamera();
 451 }
 452
 453 module DemoByCamera(){ ////toplevel
 454   color("blue") TestLidByCamera();
 455   color("red")  TestCamera();
 456 }
 457
 458 module OneKeeper(){ ////toplevel
 459   translate([0, -phone_cnr_rad, 0])
 460     rotate([90, 0, 0])
 461     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 462     KeeperProfile();
 463 }
 464
 465 module OneKeeperPrint(){ ////toplevel
 466   rotate([0,180,0])
 467     OneKeeper();
 468 }
 469
 470 module LidPrint(){ ////toplevel
 471   rotate([0,180,0])
 472     Lid();
 473 }
 474
 475 module TestSelectFrame(){
 476   include = [1,-1] * (epp2i[0] + 4);
 477
 478   difference(){
 479     cube(1000, center=true);
 480     translate([0,0, -100])
 481       linear_extrude(height=200)
 482       rectfromto(include,  inside_br - include);
 483   }
 484 }
 485
 486 module TestFrameCase(){ ////toplevel
 487   intersection(){
 488     Case();
 489     union(){
 490       TestSelectFrame();
 491       TestSelectCamera();
 492     }
 493   }
 494 }
 495
 496 module TestFrameLidPrint(){ ////toplevel
 497   rotate([0,0,180]) intersection(){
 498     Lid();
 499     TestSelectFrame();
 500   }
 501 }
 502
 503 module Keeper(){ ////toplevel
 504   CaseBase_rhsflip()
 505     OneKeeper();
 506 }
 507
 508 module ButtonPlanForDemo(z, deep, cut){
 509   translate([0,0,z])
 510     ButtonPlan(8, deep, cut);
 511 }
 512
 513 module DemoProfiles(){ ////toplevel
 514   LidEdgeProfile();
 515   %EdgeProfile();
 516   KeeperProfile();
 517   translate([0,0,-1]) color("black") KeeperProfile(1);
 518
 519   translate([20,0]) {
 520     LidEdgeProfile();
 521     %EdgeProfile();
 522
 523     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 524
 525     color("blue") ButtonCoverProfile();
 526     color("red") {
 527       rectfromto(bppQ, demopoint_QR);
 528       rectfromto(bppR, demopoint_QR);
 529     }
 530   }
 531
 532   translate([-20,0]) {
 533     color("black") ButtonPlanForDemo(-2, 0,1);
 534     color("red" )  ButtonPlanForDemo(-4, 1,1);
 535     color("blue")  ButtonPlanForDemo(-6, 1,0);
 536   }
 537 }
 538
 539 //EdgeProfile();
 540 //KeeperProfile();
 541 //CaseBase();
 542 //%Case();
 543 //Keeper();
 544 //LidEdgeProfile();
 545 //KeeperProfile();
 546 //DemoProfiles();