fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452
 453 // prop recess in case
 454
 455 prop_x_pos = phone_width/2;
 456
 457 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 458
 459 prc_r1 = prop_end_dia/2;
 460 prc_r3 = prc_r1 + prop_recess_slop;
 461
 462 prcp2 = [ epp4[0] + prop_buildout_less,
 463           case_bottom_z ];
 464
 465 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 466
 467 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 468           epp2i[1] - prc_r3 - prop_recess_under];
 469
 470 // prop recess in lid
 471
 472 prl_r10 = prop_end_dia/2;
 473 prl_r10o = prl_r10 + prop_recess_slop;
 474
 475 prlp10 = lpp10 + [1,1] * prl_r10o
 476   + [1,0] * prop_lidrecess_behind
 477   + [0,1] * prop_recess_under;
 478
 479 // prop
 480
 481 $prpp10 = [0,0];
 482 $prpp11 = [0, prop_taper_len];
 483
 484 $prp_r10 = prl_r10;
 485
 486 // ---------- modules ----------
 487
 488 module AdhocMultiprintFrame(phase, z0, zs) {
 489   // from z0 to z0 + zs*layer
 490   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 491   xextra = extra + -epp4[0];
 492   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 493   yextra = extra + -epp4[0];
 494   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 495   p0 = [ xrange[0], yrange[0] ];
 496   p1 = [ xrange[1], yrange[1] ];
 497   echo(p0, p1);
 498   translate([0,0, z0])
 499     mirror([0,0, zs<0 ? 1 : 0])
 500     linear_extrude(height= initial_layer_thick)
 501     difference(){
 502       rectfromto(p0 - [1,1] * initial_layer_width,
 503                  p1 + [1,1] * initial_layer_width);
 504       rectfromto(p0, p1);
 505     }
 506 }
 507
 508 module KeeperProfile(slant=0){
 509   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 510   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 511 }
 512
 513 module EdgeProfile(){
 514   difference(){
 515     hull(){
 516       translate(epp3) square(case_th_bottom*2, center=true);
 517       circleat(epp2o, r=case_th_bottom);
 518       circleat(epp1, r=case_th_side);
 519       rectfromto(epp0, epp4);
 520     }
 521     polygon([ epp5 + [0,10],
 522               epp1,
 523               epp2i,
 524               epp3 + [10,0] ]);
 525   }
 526 }
 527
 528 module LanyardLanyardProfile(entry=false){
 529   hull(){
 530     for (xs=[-1,+1] * (entry ? 2 : 1))
 531       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 532         circle(r= lanyard_half_dia/2);
 533   }
 534 }
 535
 536 module LanyardCurveChannelProfile(){
 537   translate([0, -ly_r])
 538     LanyardLanyardProfile();
 539 }
 540
 541 module LanyardEntryChannelProfile(){
 542   translate([0, -ly_r])
 543     LanyardLanyardProfile(true);
 544 }
 545
 546 module LanyardMainChannelProfile(){
 547   LanyardCurveChannelProfile();
 548   difference(){
 549     square(center=true, ly_r * [6, 2]);
 550     for (xs=[-1,+1])
 551       translate(ly_r * [3 * xs, -1])
 552         circle(r = ly_r);
 553   }
 554 }
 555
 556 module LidEdgeProfile(){
 557   polygon([ lpp10,
 558             lpp11,
 559             lpp12,
 560             lpp13,
 561             lpp13 + [10, 0],
 562             lpp15 + [10, 0],
 563             lpp15,
 564             lpp14,
 565             ]);
 566   intersection(){
 567     circleat(lpp12, r=lp_r12);
 568     rectfromto( lpp12 + [-10,   0],
 569                 lpp12 + [+10, +10] );
 570   }
 571 }
 572
 573 module LidEdgeFoldClearanceProfile(){
 574   translate([-lid_fold_clearance_antislop, 0])
 575     polygon([ lpp10,
 576               lpp11,
 577               lpp11 + [-20,  0],
 578               lpp11 + [-20, 20],
 579               lpp11 + [+20, 20],
 580               lpp10 + [+20,  0] ]);
 581 }
 582
 583 module ButtonCoverProfile(){
 584   intersection(){
 585     polygon(concat([ bppM, bppP, bppO, bppJ ],
 586                    (enable_support && !$button_suppress_over_keeper
 587                     ? [ bppU, bppV, bppW ] : []),
 588                    [ bppL, bppK ]));
 589     hull(){
 590       EdgeProfile();
 591       LidEdgeProfile();
 592     }
 593   }
 594 }
 595
 596 module ButtonPlan(l, deep, cut){
 597   epsilon =
 598     (cut  ? 0 : lid_buttoncover_gap);
 599
 600   delta =
 601     (deep ? lid_buttoncover_overlap : 0);
 602
 603   C = [0,0]; // by definition
 604   T = [ 0, epp4[1] ];
 605   G = T + [0,10];
 606
 607   B0 = C + [0,-1] * button_cutout_depth;
 608   B1 = B0 + [0,1] * epsilon;
 609
 610   r0 = 0.5 * (T[1] - B0[1]);
 611   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 612   H = A + [0,-1] * delta;
 613
 614   D = A + [-2,0] * r0;
 615   F = D + [0,10];
 616
 617   E0 = 0.5 * (D + A);
 618   E1 = E0 + [1,0] * epsilon;
 619
 620   I0 = [ E0[0], H[1] ];
 621   I1 = [ E1[0], H[1] ];
 622
 623   hull(){
 624     for (m=[0,1]) mirror([m,0])
 625       circleat(H, r0 - epsilon);
 626   }
 627   for (m=[0,1]) mirror([m,0]) {
 628     difference(){
 629       polygon([ E1,
 630                 I1,
 631                 H,
 632                 B1,
 633                 G,
 634                 F,
 635                 D
 636                 ]);
 637       circleat(D, r0 + epsilon);
 638     }
 639   }
 640 }
 641
 642 module CatchCatchProfile(){
 643   hull(){
 644     for (c=[ cppR, cppQ ])
 645       circleat(c, cp_rQ);
 646   }
 647   hull(){
 648     circleat(lpp12, lp_r12);
 649     circleat(lpp12 + [5,0], lp_r12);
 650     rectfromto(cppP, cppP + [5,0.1]);
 651   }
 652   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 653 }
 654
 655 module CatchCutProfile(){
 656   polygon([ cppB,
 657             cppA,
 658             cppD,
 659             cppF,
 660             cppF + [0,-10],
 661             cppF + [-10,-10],
 662             lpp12 + [-10,0],
 663             lpp12 + [10,0]
 664             ]);
 665 }
 666
 667 module Flip_rhs(yn=[0,1]) {
 668   for ($rhsflip=yn) {
 669     translate([phone_width/2, 0, 0])
 670       mirror([$rhsflip,0,0])
 671       translate([-phone_width/2, 0, 0])
 672       children();
 673   }
 674 }
 675
 676 module Flip_bot(yn=[0,1]) {
 677   for ($botflip=yn) {
 678     translate([0, -phone_height/2, 0])
 679       mirror([0, $botflip, 0])
 680       translate([0, phone_height/2, 0])
 681       children();
 682   }
 683 }
 684
 685 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 686   // sides
 687   Flip_rhs(){
 688     translate([0, -phone_cnr_rad, 0])
 689       rotate([90,0,0])
 690       linear_extrude(height = phone_height - phone_cnr_rad*2)
 691       children(0);
 692   }
 693   // corners
 694   Flip_rhs() Flip_bot() {
 695     translate([+1,-1] * phone_cnr_rad)
 696       intersection(){
 697         rotate_extrude()
 698           intersection(){
 699             mirror([1,0,0])
 700               translate([-1,0] * phone_cnr_rad)
 701               children(0);
 702             rectfromto([0,-20],[10,20]);
 703           }
 704         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 705           cube([10,10,40]);
 706       }
 707   }
 708   // top and bottom
 709   Flip_bot(){
 710     translate([ phone_width - phone_cnr_rad, 0,0 ])
 711       rotate([90,0,-90])
 712       linear_extrude(height = phone_width - phone_cnr_rad*2)
 713       children(0);
 714   }
 715   // fill
 716   translate([0,0, fill_zstart])
 717     mirror([0,0, fill_downwards])
 718     linear_extrude(height = fill_th)
 719     rectfromto([+1,-1] * phone_cnr_rad,
 720                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 721 }
 722
 723 module CaseAperture(pos, dia, $fn) {
 724   theta = 180/$fn;
 725   translate([ pos[0] + bumper[0],
 726               -epp2i[0],
 727               -pos[1] ])
 728     rotate([-90, theta, 0])
 729     cylinder(r = dia/2 / cos(theta),
 730              h = 60);
 731 }
 732
 733 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 734   // y_ref_sign:
 735   //   +1  measured from top    of actual phone to top    of button
 736   //   -1  measured from bottom of actual phone to bottom of button
 737   //    0  y is centre of button in coordinate system
 738   $button_l= l;
 739   $button_suppress_over_keeper= suppress_over_keeper;
 740   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 741           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 742           y;
 743   //echo(eff_y);
 744   translate([0, eff_y, 0])
 745     children();
 746 }
 747
 748 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 749   $button_leg_only = true;
 750   SideButton(y, y_ref_sign, l) children();
 751 }
 752
 753 module Buttons(){
 754   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 755   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 756   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 757   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 758 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 759 }
 760
 761 module Struts(x_start, z_min, th){
 762   // if th is negative, starts at z_min and works towards -ve z
 763   // and object should then be printed other way up
 764   for (i= [1 : 1 : case_struts_count]) {
 765     translate([0,
 766                0,
 767                z_min])
 768       mirror([0,0, th<0 ? 1 : 0])
 769       translate([0,
 770                  -phone_height * i / (case_struts_count+1),
 771                  case_struts_solid_below])
 772       linear_extrude(height= abs(th)
 773                      -(case_struts_solid_below+case_struts_solid_above))
 774       rectfromto([               x_start, -0.5 * case_struts_width ],
 775                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 776   }
 777 }
 778
 779 module OrdinaryRearAperture(rhs,bot, pos){
 780   Flip_rhs(rhs) Flip_bot(bot)
 781     linextr(-20, 20)
 782     mirror([0,1])
 783     translate(pos + bumper)
 784     children();
 785 }
 786
 787 module MicroUSB(){
 788   Flip_bot(1){
 789     rotate([90,0,0])
 790       mirror([0,0,1])
 791       linextr(-epp2i[0], 60)
 792       translate([0.5 * phone_width, 0, 0])
 793       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 794                  [+microusb_width/2, epp0[1] + -microusb_above]);
 795   }
 796 }
 797
 798 module OrdinaryRearApertures(){
 799   // rear speaker
 800   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 801     rectfromto(-rearspeaker_gap,
 802                rearspeaker_size + rearspeaker_gap);
 803
 804   // finger hole to remove phone
 805   if (len(fingerpushhole_dias))
 806     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 807                                 phone[1]/2 ])
 808     scale(fingerpushhole_dias)
 809     circle(r= 0.5 );
 810 }
 811
 812 module RearCameraAperture(){
 813   Flip_rhs(1)
 814     mirror([0, 0, 1])
 815     linear_extrude(height = 20)
 816     mirror([0, 1, 0])
 817     translate(bumper)
 818     rectfromto(camera_pos_tl, camera_pos_br);
 819 }
 820
 821 module HingeLidProfile(){
 822   hull(){
 823     circleat(hppT, hp_r1);
 824     circleat(lpp12, lp_r12);
 825     polygon([lpp10,
 826              lpp13 + [2,0],
 827              lpp12,
 828              hppT]);
 829   }
 830 }
 831
 832 module HingeBaseProfile(){
 833   difference(){
 834     hull(){
 835       circleat(hppB, hp_r1);
 836       circleat(hppE, hp_r1);
 837       circleat(epp2o, case_th_bottom);
 838       circleat(hppB + [10,0], hp_r1);
 839     }
 840     polygon([epp5, epp1, epp2i, epp3, bppL]);
 841   }
 842 }
 843
 844 module HingeLeverOuterProfile(){
 845   hull(){
 846     circleat(hppT, hp_r2);
 847     circleat(hppB, hp_r2);
 848   }
 849 }
 850
 851 module HingeLeverInnerProfile(){
 852   for (s = [-1,+1]) {
 853     c = s > 0 ? hppT : hppB;
 854     translate(c)
 855       mirror([0,0,s>0])
 856       rotate(s<0 ? -40 : 0)
 857       hull()
 858       for (x=[-20,20])
 859         for (y=[0, s * 10])
 860           translate([x,y])
 861             circle(hp_rn);
 862   }
 863 }
 864
 865 module HingeLeverNutProfile(){
 866   for (c= [hppB, hppT]) {
 867     translate(c)
 868       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 869   }
 870 }
 871
 872 module Flip_hinge(doflip=1){
 873   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 874   translate(hinge_origin)
 875     rotate([doflip*180,0,0])
 876     translate(-hinge_origin)
 877     children();
 878 }
 879
 880 module HingePortion(x0,x1){
 881   Flip_rhs() Flip_bot(1)
 882     translate([x0,0,0])
 883     mirror([1,0,0])
 884     rotate([90,0,-90])
 885     linear_extrude(height=x1-x0)
 886     children();
 887 }
 888
 889 module CatchPortion(xwidth, ztop){
 890   width = catch_width + xwidth;
 891   w = width + catch_topcurve_r*2 + 1;
 892   translate([phone_width/2, 0,0]){
 893     difference(){
 894       rotate([90,0,-90])
 895         linextr(-w/2, w/2)
 896         children(0);
 897       translate([0, 50, 0])
 898         rotate([90,0,0])
 899         linear_extrude(height=100){
 900         for (m=[0,1]) mirror([m,0,0]) {
 901           hull(){
 902             translate([w/2, ztop - catch_topcurve_r])
 903               circle(catch_topcurve_r);
 904             translate([w/2, -50])
 905               square(catch_topcurve_r*2, center=true);
 906           }
 907         }
 908       }
 909     }
 910   }
 911 }
 912
 913 module CaseBase(){
 914   AroundEdges(epp3[1], case_th_bottom, 1)
 915     EdgeProfile();
 916 }
 917
 918 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 919
 920 module PropProfileAssignments(gamma){
 921   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 922   x = prop_x(gamma);
 923   p = phone_height + prlp10[0] - hppB[0];
 924   b = p + x;
 925
 926   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 927   a = q + x;
 928   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 929   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 930
 931   $prp_theta = 90 - $prp_alpha;
 932   beta = 180 - $prp_alpha - gamma;
 933   psi = 90 - beta;
 934
 935   //echo("abc", a,b,c);
 936
 937   v1 = [ [ cos(psi), -sin(psi) ],    // x
 938          [ sin(psi),  cos(psi) ] ];  // y
 939
 940   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 941
 942   $prp_r1 = prc_r1;
 943   $prp_r11 = prop_main_th/2;
 944
 945   $prpp1 = $prpp7 + [1,0] *
 946     // this is approximate, but will do
 947     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 948   $prpp3 = $prpp1 +
 949     v1[0] * -$prp_r1 +
 950     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 951   $prpp12 = $prpp3 + v1[0] *
 952     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 953   $prp_r8 = prop_main_th;
 954   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 955   $prp_r5 = $prp_r8;
 956   $prpp5 = [ $prpp12[0] - $prp_r5,
 957             $prpp3[1] - prop_prong_h + $prp_r5 ];
 958   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 959          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 960   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 961   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 962
 963   children();
 964 }
 965
 966 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 967   PropProfileAssignments(gamma){
 968
 969     //#circleat($prpp3,1);
 970     //#circleat($prpp12,1);
 971
 972     if (!cut) {
 973       hull(){
 974         translate($prpp8)
 975           intersection(){
 976             circle($prp_r8);
 977             polygon([[-20,-0], [20,20], [0,0]]);
 978           }
 979         rectfromto($prpp6, $prpp9);
 980         translate($prpp5) intersection(){
 981           circle($prp_r5);
 982           polygon([[-10,-10], [0,0], [10,0]]);
 983         }
 984         rectfromto($prpp12 + [0,-0.1], $prpp3);
 985       }
 986       hull(){
 987         circleat($prpp1, $prp_r1);
 988         rectfromto($prpp12 + [0,-0.1], $prpp3);
 989       }
 990     }
 991     // main shaft
 992     rotate([0,0, rot*-$prp_theta]){
 993       hull(){
 994         extra = cut ? prop_recess_slop : 0;
 995         rectfromto($prpp6, $prpp9);
 996         circleat($prpp11, $prp_r11 + extra);
 997         circleat($prpp10, $prp_r10 + extra);
 998       }
 999     }
1000   }
1001 }
1002
1003 module PropAggregateProfile(){
1004   for (angle = prop_angles)
1005     PropProfile(angle, 0,0);
1006 }
1007
1008 module Prop(){ ////toplevel
1009   hw = prop_main_width/2;
1010   linextr(-hw, +hw)
1011     PropAggregateProfile();
1012 }
1013
1014 module Case(){ ////toplevel
1015   difference(){
1016     union(){
1017       CaseBase();
1018
1019       // ledge (fixed keeper)
1020       Flip_rhs(1-keeper_side) intersection(){
1021         rotate([90, 0, 0])
1022           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1023           KeeperProfile(1);
1024
1025         // outline of the whole case, to stop it protruding
1026         translate([0,0, -25])
1027           linear_extrude(height = 50)
1028           hull()
1029           Flip_bot()
1030           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1031       }
1032
1033       // hinge
1034       HingePortion(hex20, hex21) HingeBaseProfile();
1035
1036       // buildout for prop recess
1037       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1038         linextr(case_bottom_z, epp2i[1])
1039         hull() {
1040           for (dxs = [-1,+1])
1041             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1042                        -epp2o[0] ],
1043                      r = epp2o[0] - prcp2[0]);
1044         }
1045     }
1046
1047     // slot for keeper
1048     Flip_rhs(keeper_side)
1049       translate([0, -phone_cnr_rad, 0])
1050       rotate([90, 0, 0])
1051       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1052       minkowski(){
1053         KeeperProfile();
1054         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1055                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1056       }
1057
1058     // front camera
1059     RearCameraAperture();
1060
1061     // struts (invisible, because they're buried in the case)
1062     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1063
1064     Buttons(){
1065       mirror([1,0,0])
1066         rotate([90,0,90]) {
1067           if (!($button_leg_only && enable_support))
1068           intersection(){
1069             translate([0,0,-10])
1070               linear_extrude(height= 20)
1071               ButtonPlan($button_l, 0,1);
1072             if ($button_leg_only)
1073               rotate([-90,90,0])
1074                 translate([phone_width/2, -400, kppe[1]])
1075                 mirror([1-abs($rhsflip - keeper_side),0,0])
1076                 cube([400, 800, 50]);
1077             if (enable_support && !$button_suppress_over_keeper)
1078               rotate([-90,90,0])
1079               translate([-400, -400, kppd[1]])
1080                 mirror([0,0,1])
1081                 cube([800,800,100]);
1082           }
1083           translate([0,0, -bppR[0]])
1084             linear_extrude(height= 20)
1085             ButtonPlan($button_l, 1,1);
1086         }
1087
1088     }
1089
1090     // apertures along top edge
1091     CaseAperture(jack_pos, jack_dia, 8);
1092     Flip_rhs(1)
1093       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1094
1095     OrdinaryRearApertures();
1096
1097     MicroUSB();
1098
1099     // gaps for the lid's hinge arms
1100     HingePortion(hex20 - hinge_x_arms_gap,
1101                  hex21 + hinge_x_arms_gap)
1102       minkowski(){
1103         HingeLidProfile();
1104         circle(r= hinge_r_arms_gap, $fn= 8);
1105       }
1106
1107     // screw holes in the hinge arms
1108     HingeScrews();
1109
1110     // catch striker
1111     CatchPortion(catch_side_gap*2, epp4[1])
1112       CatchCutProfile();
1113
1114     // prop recess
1115     Flip_rhs(1)
1116       translate([prop_x_pos,0,0])
1117       mirror([0,1,0])
1118       rotate([90,0,90])
1119       linextr(-prop_recess_hw, +prop_recess_hw)
1120       hull(){
1121         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1122           circleat(prcp1 + 20*d,
1123                    prc_r3);
1124       }
1125   }
1126 }
1127
1128 module LidAdhocMultiprintFrame(phase){
1129   if (led_window_style >= 3) {
1130     AdhocMultiprintFrame(phase, lpp13[1], -1);
1131   }
1132 }
1133
1134 module LidAroundEdges(){
1135   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1136     children();
1137 }
1138
1139 module Lid(){ ////toplevel
1140   skew_centre = [0, lpp11[0], lpp11[1]];
1141   difference(){
1142     union(){
1143       intersection(){
1144         LidAroundEdges()
1145           LidEdgeProfile();
1146
1147         translate(skew_centre)
1148           multmatrix([[ 1, 0, 0, 0 ],
1149                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1150                       [ 0, 0, 1, 0 ],
1151                       [ 0, 0, 0, 1 ]])
1152           translate(-skew_centre)
1153           LidAroundEdges()
1154           LidEdgeFoldClearanceProfile();
1155       }
1156
1157       // button covers
1158       Buttons(){
1159         intersection(){
1160           rotate([90,0,90])
1161             translate([0,0,-10])
1162             linear_extrude(height= 20)
1163             ButtonPlan($button_l, 1,0);
1164           rotate([90,0,0])
1165              translate([0,0,-100])
1166             linear_extrude(height= 200)
1167             ButtonCoverProfile();
1168         }
1169       }
1170
1171       // hinge arms
1172       HingePortion(hex20, hex21) {
1173         LidEdgeProfile();
1174         HingeLidProfile();
1175       }
1176
1177       // catch
1178       CatchPortion(0, lpp12[1])
1179         CatchCatchProfile();
1180     }
1181     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1182
1183     // screw holes in the hinge arms
1184     HingeScrews();
1185
1186     // prop recess
1187     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1188       mirror([0,1,0])
1189       rotate([90,0,90])
1190       linextr(-prop_recess_hw, +prop_recess_hw)
1191       hull()
1192       for (pa = prop_angles)
1193         PropProfile(pa, 1,1);
1194
1195     // notification led aperture
1196     if (led_window_style)
1197       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1198         translate([0,0,-10])
1199           cylinder(r=nla_r0, h=20);
1200         if (led_window_style >= 2)
1201           translate([0,0, -nla_t])
1202             cylinder(r=nla_r2, height=20);
1203       }
1204
1205     }
1206
1207   LidAdhocMultiprintFrame(1);
1208 }
1209
1210 module HingeLever(){ ////toplevel
1211   difference() {
1212     // outer body, positive
1213     HingePortion(hex22, hex22 + phone_width/2)
1214       HingeLeverOuterProfile();
1215
1216     // space for the screws
1217     HingePortion(hex26, hex24)
1218       HingeLeverInnerProfile();
1219
1220     // recesses for the nuts
1221     HingePortion(hex23, hex26+1)
1222       HingeLeverNutProfile();
1223
1224     // bores for the screws
1225     HingeScrews();
1226
1227     // space for the charging cable
1228     MicroUSB();
1229     Flip_hinge() MicroUSB();
1230   }
1231 }
1232
1233 module LidWindow(){ ////toplevel
1234   translate([led_pos[0], -led_pos[1], lpp13[1]])
1235     mirror([0,0,1])
1236     cylinder(r= nla_r1, h=nla_t);
1237   LidAdhocMultiprintFrame(0);
1238 }
1239
1240 module LidWindowPrint(){ ////toplevel
1241   rotate([0,180,0])
1242     LidWindow();
1243 }
1244
1245 module DemoLidWindowSelect(){
1246   translate([led_pos[0], led_pos[1], -100]) {
1247     translate([0, -30, 0]) cube([400, 400, 200]);
1248   }
1249 }
1250
1251 module DemoLidWindow(){ ////toplevel
1252   %Lid();
1253   LidWindow();
1254   translate([0,40,0]){
1255     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1256     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1257   }
1258 }
1259
1260 module HingeLeverPrint(){ ////toplevel
1261   rotate([-90,0,0])
1262     translate([-phone_width/2, phone_height, 0])
1263     HingeLever();
1264 }
1265
1266 module TestSelectLength(){
1267   translate([-30, -200, -20])
1268     cube([30 + 15, 250, 40]);
1269 }
1270
1271 module TestLength(){ ////toplevel
1272   intersection(){
1273     Case();
1274     TestSelectLength();
1275   }
1276 }
1277
1278 module TestLengthRight(){ ////toplevel
1279   intersection(){
1280     Case();
1281     Flip_rhs(1)
1282       TestSelectLength();
1283   }
1284 }
1285
1286 module TestSelectWidth(){
1287   translate([-30, -(phone_height - 25), -20])
1288     mirror([0, 1, 0])
1289     cube([200, 50, 40]);
1290 }
1291
1292 module TestWidth(){ ////toplevel
1293   intersection(){
1294     Case();
1295     TestSelectWidth();
1296   }
1297 }
1298
1299 module TestLidWidthPrint(){ ////toplevel
1300   rotate([0,180.0]) intersection(){
1301     Lid();
1302     TestSelectWidth();
1303   }
1304 }
1305
1306 module TestSelectRearAperture(){
1307   minkowski(){
1308     union() children();
1309     translate([20, 0,0])
1310       cube([42, 2, 1], center=true);
1311   }
1312 }
1313
1314 module TestSelectCamera(){
1315   minkowski(){
1316     TestSelectRearAperture()
1317       RearCameraAperture();
1318     cube([0.1, 50, 0.1]);
1319   }
1320 }
1321
1322 module TestSelectOrdinaryRearApertures(){
1323   TestSelectRearAperture()
1324     OrdinaryRearApertures();
1325 }
1326
1327 module TestCamera(){ ////toplevel
1328   intersection(){
1329     Case();
1330     TestSelectCamera();
1331   }
1332 }
1333
1334 module TestLidByCamera(){ ////toplevel
1335   intersection(){
1336     Lid();
1337     TestSelectCamera();
1338   }
1339 }
1340
1341 module TestLidByCameraPrint(){ ////toplevel
1342   rotate([180,0,0]) TestLidByCamera();
1343 }
1344
1345 module DemoByCamera(){ ////toplevel
1346   color("blue") TestLidByCamera();
1347   color("red")  TestCamera();
1348 }
1349
1350 module OneKeeper(){ ////toplevel
1351   translate([0, -phone_cnr_rad, 0])
1352     rotate([90, 0, 0])
1353     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1354     KeeperProfile();
1355 }
1356
1357 module OneKeeperPrint(){ ////toplevel
1358   rotate([0,180,0])
1359     OneKeeper();
1360 }
1361
1362 module LidPrint(){ ////toplevel
1363   rotate([0,180,0])
1364     Lid();
1365 }
1366
1367 module TestSelectFrame(){
1368   include = [1,-1] * (epp2i[0] + 4);
1369
1370   difference(){
1371     cube(1000, center=true);
1372     translate([0,0, -100])
1373       linear_extrude(height=200)
1374       rectfromto(include,  inside_br - include);
1375   }
1376 }
1377
1378 module TestSelectLidFrame(){
1379   TestSelectFrame();
1380   translate([led_pos[0], -led_pos[1], -50])
1381     cylinder(r= nla_r2+3, h=100);
1382 }
1383
1384 module TestFrameCase(){ ////toplevel
1385   intersection(){
1386     Case();
1387     union(){
1388       TestSelectFrame();
1389       TestSelectCamera();
1390       TestSelectOrdinaryRearApertures();
1391     }
1392   }
1393 }
1394
1395 module TestSelectTopApertures(){
1396   translate([-100, -35, -100])
1397     cube([400, 100, 200]);
1398   LidAdhocMultiprintFrame(0);
1399   LidAdhocMultiprintFrame(1);
1400 }
1401
1402 module TestTopApertures(){ ////toplevel
1403   intersection(){
1404     Case();
1405     TestSelectFrame();
1406     TestSelectTopApertures();
1407   }
1408 }
1409
1410 module TestLidTopAperturesPrint(){ ////toplevel
1411   rotate([0,180,0]) intersection(){
1412     Lid();
1413     TestSelectLidFrame();
1414     TestSelectTopApertures();
1415   }
1416 }
1417
1418 module TestLidWindowTopAperturesPrint(){ ////toplevel
1419   rotate([0,180,0]) intersection(){
1420     LidWindow();
1421     TestSelectTopApertures();
1422   }
1423 }
1424
1425 module TestFrameLidPrint(){ ////toplevel
1426   rotate([0,180,0]) intersection(){
1427     Lid();
1428     TestSelectLidFrame();
1429   }
1430 }
1431
1432 module ButtonPlanForDemo(z, deep, cut){
1433   translate([0,0,z])
1434     ButtonPlan(8, deep, cut);
1435 }
1436
1437 module HingeScrews(){
1438   Flip_rhs() Flip_bot(1){
1439     for (c= [ hppT, hppB ])
1440       translate([ hex20,
1441                   -c[0],
1442                   c[1] ]){
1443         rotate([0,90,0])
1444           translate([0,0,-.2])
1445           cylinder( r= hingescrew_shaft_dia/2,
1446                     h = hingescrew_shaft_len+0.2 );
1447         rotate([0,-90,0])
1448           translate([0,0,+.1])
1449           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1450       }
1451   }
1452 }
1453
1454 module DemoPropAngleSelect(c){
1455   color(c) difference(){
1456     union(){ children(); }
1457     translate([ prop_x_pos, -400, -200 ])
1458       cube([ 400,800,400 ]);
1459   }
1460 }
1461
1462 module DemoPropAngle(ang){
1463   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1464   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1465
1466   translate(hL)
1467     rotate([ang/2,0,0])
1468     translate(-hL)
1469     translate(hC)
1470     rotate([ang/2,0,0])
1471     translate(-hC) {
1472       DemoPropAngleSelect("red") Case();
1473
1474       color("orange")
1475         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1476         PropProfileAssignments(ang) {
1477           echo($prpp1);
1478           rotate([-$prp_theta, 0, 0])
1479           translate([0, $prpp1[0], -$prpp1[1]])
1480           rotate([90,0,-90])
1481           Prop();
1482         }
1483     }
1484
1485   translate([0,0, -hp_k*2])
1486     DemoPropAngleSelect("blue")
1487     Lid();
1488 }
1489
1490 module DemoPropAngles(){ ////toplevel
1491   for (i=[0 : len(prop_angles)-1])
1492     translate(i * [0, -100, 100])
1493     DemoPropAngle(prop_angles[i]);
1494 }
1495
1496 module DemoHingeAngle(ang1,ang2){
1497   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1498   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1499
1500   translate(hL)
1501     rotate([ang2,0,0])
1502     translate(-hL)
1503     translate(hC)
1504     rotate([ang1,0,0])
1505     translate(-hC) {
1506       color("red") Lid();
1507     }
1508
1509   color("blue") intersection(){
1510     Case();
1511     union(){
1512       translate([bppJ[0], -400, -200])
1513         mirror([1,0,0])
1514         cube([400, 800, 400]);
1515       translate([10, -400, -200])
1516         cube([10, 800, 400]);
1517     }
1518   }
1519 }
1520
1521 module DemoHingeAngles(){ ////toplevel
1522   angles = [ 0, 4, 8, 12 ];
1523   echo("angles",angles);
1524   for (i=[0 : len(angles)-1]) {
1525     translate(i * [0, 0, 30]) {
1526       DemoHingeAngle(0,angles[i]);
1527       translate([0, 200, 0])
1528         DemoHingeAngle(angles[i],0);
1529     }
1530   }
1531 }
1532
1533 module DemoSelectAdhocLeftRight(right=0) {
1534   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1535     mirror([1-right, 0,0])
1536     cube([400, 800, 200]);
1537 }
1538
1539 module DemoLeft(){ ////toplevel
1540   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1541   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1542 }
1543
1544 module DemoFrame(){ ////toplevel
1545   color("red") TestFrameCase();
1546   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1547   color("black") HingeScrews();
1548   %HingeLever();
1549 }
1550
1551 module DemoHingedFrame(){ ///toplevel
1552   color("red") TestFrameCase();
1553   translate([0,0, -2*hp_k])
1554   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1555
1556   Flip_hinge(){
1557     color("orange") HingeLever();
1558     color("black") HingeScrews();
1559   }
1560 }
1561
1562 module DemoHinge(){ ////toplevel
1563   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1564     DemoFrame();
1565     translate([0,0, -hp_k*3])
1566       DemoHingedFrame();
1567   }
1568 }
1569
1570 module DemoProfiles(){ ////toplevel
1571   LidEdgeProfile();
1572   %EdgeProfile();
1573   KeeperProfile();
1574   translate([0,0,-1]) color("black") KeeperProfile(1);
1575   color("purple") translate(epp2i)
1576     rotate(atan2vector(epp2i - epp1)) {
1577     translate(lanyard_half_dia * 0.5 * [-3,-1])
1578       LanyardLanyardProfile();
1579     translate(lanyard_half_dia * 0.5 * [-3,+1])
1580       translate([0,-1] * case_th_side)
1581       LanyardLanyardProfile(true);
1582   }
1583
1584   translate([0,20]) {
1585     LanyardMainChannelProfile();
1586     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1587     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1588   }
1589
1590   translate([20,0]) {
1591     LidEdgeProfile();
1592     %EdgeProfile();
1593
1594     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1595
1596     color("blue") ButtonCoverProfile();
1597     color("red") {
1598       rectfromto(bppQ, demopoint_QR);
1599       rectfromto(bppR, demopoint_QR);
1600     }
1601   }
1602
1603   translate([-20,0]) {
1604     color("black") ButtonPlanForDemo(-2, 0,1);
1605     color("red" )  ButtonPlanForDemo(-4, 1,1);
1606     color("blue")  ButtonPlanForDemo(-6, 1,0);
1607   }
1608
1609   translate([0, -30]) {
1610     %LidEdgeProfile();
1611     %EdgeProfile();
1612     color("blue") HingeLidProfile();
1613     color("red")  HingeBaseProfile();
1614     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1615   }
1616
1617   for (f=[0,1]) {
1618     translate([-30, -60 + 30*f]) {
1619       translate([0,0,-4]) EdgeProfile();
1620       %translate([0,0,-10]) HingeBaseProfile();
1621       translate([0,-2] * f * hp_k) {
1622         translate([0,0,-4]) LidEdgeProfile();
1623         %translate([0,0,-10]) %HingeLidProfile();
1624       }
1625       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1626         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1627         translate([0,0,0]) color("red") difference(){
1628           HingeLeverOuterProfile();
1629           HingeLeverInnerProfile();
1630         }
1631         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1632       }
1633     }
1634   }
1635
1636   translate([20,-30]) {
1637     %EdgeProfile();
1638     %LidEdgeProfile();
1639     //translate([0,0,1]) CatchCutProfile();
1640     color("blue") CatchCatchProfile();
1641     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1642   }
1643
1644   translate([40,-30]) {
1645     difference(){
1646       LidEdgeProfile();
1647       translate(prlp10)
1648         PropProfile(10, 1, 0);
1649     }
1650     translate(prlp10)
1651       PropProfile(15, 0);
1652   }
1653   translate([60,-30]) {
1654     PropAggregateProfile();
1655   }
1656 }
1657
1658 //EdgeProfile();
1659 //KeeperProfile();
1660 //CaseBase();
1661 //%Case();
1662 //Keeper();
1663 //LidEdgeProfile();
1664 //KeeperProfile();
1665 //DemoProfiles();
1666 //PropRecess();