fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 case_th_bottom = 2.5;
  22 case_th_lid = 2.5;
  23 case_th_side = 2;
  24 case_th_lip = 1.2;
  25
  26 case_struts_count = 6;
  27 case_struts_solid_below = 1.00;
  28 case_struts_solid_above = 0.75;
  29 case_struts_width = 0.10;
  30
  31 keeper_th_z = 0.75;
  32 keeper_th_x = 0.75;
  33 keeper_inner_width = 2.75;
  34 keeper_inner_height = 2.75;
  35 keeper_slant_slope = 2; // larger means steeper
  36
  37 keeper_gap_z_top = 0.25;
  38 keeper_gap_z_bot = 0.75;
  39 keeper_gap_x     = 0.25;
  40 keeper_gap_x_holes = 0.75;
  41
  42 case_lip = 1.25;
  43
  44 lid_gap_x = 0.25;
  45 lid_gap_z = 0.25;
  46 lid_lip = 1.75;
  47
  48 $fa = 5;
  49 $fs = 0.1;
  50
  51 button_l_fudge = 4.4;
  52 buttonishleg_default_l_is_fudge = 10;
  53
  54 strut_min_at_end = 1.5;
  55
  56 // ---------- calculated ----------
  57
  58 phone_width =  (phone + bumper*2)[0];
  59 phone_height = (phone + bumper*2)[1];
  60
  61 //echo(camera_pos_tl + bumper,
  62 //     camera_pos_br + bumper);
  63
  64 // ----- could be changed -----
  65 lid_buttoncover_gap = lid_gap_x;
  66 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  67
  68 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  69
  70 //lid_lip_overlap_width xxx bad name = ;
  71 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  72
  73 epp0 = [0,0];
  74 epp1 = [0, -phone_edge_thick];
  75 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  76 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  77 epp3 = epp2i + [10, 0];
  78 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  79 epp4 = epp5 + [-1,0] * case_th_side;
  80
  81 kppe = [0,0];
  82 kppd = kppe + [1,0] * keeper_inner_width;
  83 kppc = kppd + [0,1] * keeper_th_z;
  84 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  85 kppf = kppe - [0,1] * keeper_inner_height;
  86 kppa = [ kppb[0], kppf[1] ];
  87
  88 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  89 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  90
  91 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  92
  93 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
  94 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
  95
  96 // button profile
  97 bppM = epp4 + [0,5];
  98 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  99 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 100 bppS = [ epp1[0], bppR[1] ];
 101 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 102 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 103 bppO = [ bppN[0], bppP[1] ];
 104 bppL = lpp10 + [5,0];
 105 bppK = [ bppL[0], bppN[1] ];
 106 bppJ = [ bppN[0], bppL[1] ];
 107
 108 module rectfromto(a,b) {
 109   ab = b - a;
 110   translate([min(a[0], b[0]), min(a[1], b[1])])
 111     square([abs(ab[0]), abs(ab[1])]);
 112 }
 113 module circleat(c,r) { translate(c) circle(r); }
 114
 115 module KeeperProfile(slant=0){
 116   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 117   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 118 }
 119
 120 module EdgeProfile(){
 121   difference(){
 122     hull(){
 123       translate(epp3) square(case_th_bottom*2, center=true);
 124       circleat(epp2o, r=case_th_bottom);
 125       circleat(epp1, r=case_th_side);
 126       rectfromto(epp0, epp4);
 127     }
 128     polygon([ epp5 + [0,10],
 129               epp1,
 130               epp2i,
 131               epp3 + [10,0] ]);
 132   }
 133 }
 134
 135 module LidEdgeProfile(){
 136   polygon([ lpp10,
 137             lpp11,
 138             lpp12,
 139             lpp13,
 140             lpp13 + [10, 0],
 141             lpp10 + [10, 0]
 142             ]);
 143   intersection(){
 144     circleat(lpp12, r=lp_r12);
 145     rectfromto( lpp12 + [-10,   0],
 146                 lpp12 + [+10, +10] );
 147   }
 148 }
 149
 150 module ButtonCoverProfile(){
 151   intersection(){
 152     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 153     hull(){
 154       EdgeProfile();
 155       LidEdgeProfile();
 156     }
 157   }
 158 }
 159
 160 module ButtonPlan(l, deep, cut){
 161   epsilon =
 162     (cut  ? 0 : lid_buttoncover_gap);
 163
 164   delta =
 165     (deep ? lid_buttoncover_overlap : 0);
 166
 167   C = [0,0]; // by definition
 168   T = [ 0, epp4[1] ];
 169   G = T + [0,10];
 170
 171   B0 = C + [0,-1] * button_cutout_depth;
 172   B1 = B0 + [0,1] * epsilon;
 173
 174   r0 = 0.5 * (T[1] - B0[1]);
 175   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 176   H = A + [0,-1] * delta;
 177
 178   D = A + [-2,0] * r0;
 179   F = D + [0,10];
 180
 181   E0 = 0.5 * (D + A);
 182   E1 = E0 + [1,0] * epsilon;
 183
 184   I0 = [ E0[0], H[1] ];
 185   I1 = [ E1[0], H[1] ];
 186
 187   hull(){
 188     for (m=[0,1]) mirror([m,0])
 189       circleat(H, r0 - epsilon);
 190   }
 191   for (m=[0,1]) mirror([m,0]) {
 192     difference(){
 193       polygon([ E1,
 194                 I1,
 195                 H,
 196                 B1,
 197                 G,
 198                 F,
 199                 D
 200                 ]);
 201       circleat(D, r0 + epsilon);
 202     }
 203   }
 204 }
 205
 206 module CaseBase_rhsflip(yn=[0,1]) {
 207   for ($rhsflip=yn) {
 208     translate([phone_width/2, 0, 0])
 209       mirror([$rhsflip,0,0])
 210       translate([-phone_width/2, 0, 0])
 211       children();
 212   }
 213 }
 214
 215 module CaseBase_botflip() {
 216   for (bot=[0,1]) {
 217     translate([0, -phone_height/2, 0])
 218       mirror([0, bot, 0])
 219       translate([0, phone_height/2, 0])
 220       children();
 221   }
 222 }
 223
 224 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 225   // sides
 226   CaseBase_rhsflip(){
 227     translate([0, -phone_cnr_rad, 0])
 228       rotate([90,0,0])
 229       linear_extrude(height = phone_height - phone_cnr_rad*2)
 230       children(0);
 231   }
 232   // corners
 233   CaseBase_rhsflip() CaseBase_botflip() {
 234     translate([+1,-1] * phone_cnr_rad)
 235       intersection(){
 236         rotate_extrude()
 237           intersection(){
 238             mirror([1,0,0])
 239               translate([-1,0] * phone_cnr_rad)
 240               children(0);
 241             rectfromto([0,-20],[10,20]);
 242           }
 243         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 244           cube([10,10,40]);
 245       }
 246   }
 247   // top and bottom
 248   CaseBase_botflip(){
 249     translate([ phone_width - phone_cnr_rad, 0,0 ])
 250       rotate([90,0,-90])
 251       linear_extrude(height = phone_width - phone_cnr_rad*2)
 252       children(0);
 253   }
 254   // fill
 255   translate([0,0, fill_zstart])
 256     mirror([0,0, fill_downwards])
 257     linear_extrude(height = fill_th)
 258     rectfromto([+1,-1] * phone_cnr_rad,
 259                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 260 }
 261
 262 module SideButton(y, y_ref_sign, l){
 263   // y_ref_sign:
 264   //   +1  measured from top    of actual phone to top    of button
 265   //   -1  measured from bottom of actual phone to bottom of button
 266   //    0  y is centre of button in coordinate system
 267   $button_l= l;
 268   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 269           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 270           y;
 271   echo(eff_y);
 272   translate([0, eff_y, 0])
 273     children();
 274 }
 275
 276 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 277   $button_leg_only = true;
 278   SideButton(y, y_ref_sign, l) children();
 279 }
 280
 281 module Buttons(){
 282   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 283   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 284   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 285   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 286 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 287 }
 288
 289 module Struts(x_start, z_min, th){
 290   // if th is negative, starts at z_min and works towards -ve z
 291   // and object should then be printed other way up
 292   for (i= [1 : 1 : case_struts_count]) {
 293     translate([0,
 294                0,
 295                z_min])
 296       mirror([0,0, th<0 ? 1 : 0])
 297       translate([0,
 298                  -phone_height * i / (case_struts_count+1),
 299                  case_struts_solid_below])
 300       linear_extrude(height= abs(th)
 301                      -(case_struts_solid_below+case_struts_solid_above))
 302       rectfromto([               x_start, -0.5 * case_struts_width ],
 303                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 304   }
 305 }
 306
 307 module CaseBase(){
 308   AroundEdges(epp3[1], case_th_bottom, 1)
 309     EdgeProfile();
 310 }
 311
 312 module Case(){ ////toplevel
 313   difference(){
 314     union(){
 315       CaseBase();
 316
 317       // ledge (fixed keeper)
 318       intersection(){
 319         rotate([90, 0, 0])
 320           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 321           KeeperProfile(1);
 322
 323         // outline of the whole case, to stop it protruding
 324         translate([0,0, -25])
 325           linear_extrude(height = 50)
 326           hull()
 327           // CaseBase_rhsflip() // actually, we only care about the LH
 328           CaseBase_botflip()
 329           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 330       }
 331     }
 332
 333     // slot for keeper
 334     CaseBase_rhsflip(1)
 335       translate([0, -phone_cnr_rad, 0])
 336       rotate([90, 0, 0])
 337       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 338       minkowski(){
 339         KeeperProfile();
 340         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 341                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 342       }
 343
 344     // front camera
 345     CaseBase_rhsflip([1])
 346       mirror([0, 0, 1])
 347       linear_extrude(height = 20)
 348       mirror([0, 1, 0])
 349       translate(bumper)
 350       rectfromto(camera_pos_tl, camera_pos_br);
 351
 352     // struts (invisible, because they're buried in the case)
 353     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 354
 355     Buttons(){
 356       mirror([1,0,0])
 357         rotate([90,0,90]) {
 358           intersection(){
 359             translate([0,0,-10])
 360               linear_extrude(height= 20)
 361               ButtonPlan($button_l, 0,1);
 362             if ($button_leg_only)
 363               rotate([-90,90,0])
 364                 translate([phone_width/2, -400, kppe[1]])
 365                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 366           }
 367           translate([0,0, -bppR[0]])
 368             linear_extrude(height= 20)
 369             ButtonPlan($button_l, 1,1);
 370         }
 371     }
 372   }
 373 }
 374
 375 module Lid(){ ////toplevel
 376   difference(){
 377     union(){
 378       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 379         LidEdgeProfile();
 380
 381       // button covers
 382       Buttons(){
 383         intersection(){
 384           rotate([90,0,90])
 385             translate([0,0,-10])
 386             linear_extrude(height= 20)
 387             ButtonPlan($button_l, 1,0);
 388           rotate([90,0,0])
 389              translate([0,0,-100])
 390             linear_extrude(height= 200)
 391             ButtonCoverProfile();
 392         }
 393       }
 394     }
 395     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 396   }
 397 }
 398
 399 module TestLength(){ ////toplevel
 400   intersection(){
 401     Case();
 402     translate([-30, -200, -20])
 403     cube([30 + 15, 250, 40]);
 404   }
 405 }
 406
 407 module TestSelectWidth(){
 408   translate([-30, -(phone_height - 25), -20])
 409     mirror([0, 1, 0])
 410     cube([200, 50, 40]);
 411 }
 412
 413 module TestWidth(){ ////toplevel
 414   intersection(){
 415     Case();
 416     TestSelectWidth();
 417   }
 418 }
 419
 420 module TestLidWidthPrint(){ ////toplevel
 421   rotate([0,180.0]) TestLidWidth();
 422 }
 423
 424 module TestSelectCamera(){
 425   CaseBase_rhsflip(1)
 426     translate([0,0,-25])
 427     linear_extrude(height = 50)
 428     mirror([0, 1, 0])
 429     rectfromto([-20, -20],
 430                camera_pos_br + bumper + [ 5, 5 ]);
 431 }
 432
 433 module TestCamera(){ ////toplevel
 434   intersection(){
 435     Case();
 436     TestSelectCamera();
 437   }
 438 }
 439
 440 module TestLidByCamera(){ ////toplevel
 441   intersection(){
 442     Lid();
 443     TestSelectCamera();
 444   }
 445 }
 446
 447 module TestLidByCameraPrint(){ ////toplevel
 448   rotate([180,0,0]) TestLidByCamera();
 449 }
 450
 451 module DemoByCamera(){ ////toplevel
 452   color("blue") TestLidByCamera();
 453   color("red")  TestCamera();
 454 }
 455
 456 module OneKeeper(){ ////toplevel
 457   translate([0, -phone_cnr_rad, 0])
 458     rotate([90, 0, 0])
 459     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 460     KeeperProfile();
 461 }
 462
 463 module OneKeeperPrint(){ ////toplevel
 464   rotate([0,180,0])
 465     OneKeeper();
 466 }
 467
 468 module LidPrint(){ ////toplevel
 469   rotate([0,180,0])
 470     Lid();
 471 }
 472
 473 module Keeper(){ ////toplevel
 474   CaseBase_rhsflip()
 475     OneKeeper();
 476 }
 477
 478 module ButtonPlanForDemo(z, deep, cut){
 479   translate([0,0,z])
 480     ButtonPlan(8, deep, cut);
 481 }
 482
 483 module DemoProfiles(){ ////toplevel
 484   LidEdgeProfile();
 485   %EdgeProfile();
 486   KeeperProfile();
 487   translate([0,0,-1]) color("black") KeeperProfile(1);
 488
 489   translate([20,0]) {
 490     LidEdgeProfile();
 491     %EdgeProfile();
 492
 493     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 494
 495     color("blue") ButtonCoverProfile();
 496     color("red") {
 497       rectfromto(bppQ, demopoint_QR);
 498       rectfromto(bppR, demopoint_QR);
 499     }
 500   }
 501
 502   translate([-20,0]) {
 503     color("black") ButtonPlanForDemo(-2, 0,1);
 504     color("red" )  ButtonPlanForDemo(-4, 1,1);
 505     color("blue")  ButtonPlanForDemo(-6, 1,0);
 506   }
 507 }
 508
 509 //EdgeProfile();
 510 //KeeperProfile();
 511 //CaseBase();
 512 //%Case();
 513 //Keeper();
 514 //LidEdgeProfile();
 515 //KeeperProfile();
 516 //DemoProfiles();