fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 145.0, 75.0 ];
   4
   5 bumpers = [ 1.5, 1.75 ]; // both sides together
   6
   7 phone_cnr_rad = 6.0;
   8
   9 button_cutout_depth = 9;
  10
  11 phone_edge_thick = 9.0;
  12 phone_total_thick = 12.0;
  13 phone_backside_slope_inner = 1.5; // larger means shallower
  14 phone_backside_slope_outer = 1.0; // larger means shallower
  15
  16 camera_pos_tl = [  7.0, 13.0 ]; // measured from tl corner
  17 camera_pos_br = [ 22.85,37.85]; // tl/br as seen from back
  18
  19 case_th_bottom = 2.5;
  20 case_th_lid = 2.5;
  21 case_th_side = 2;
  22 case_th_lip = 1.2;
  23
  24 case_struts_count = 6;
  25 case_struts_solid_below = 1.00;
  26 case_struts_solid_above = 0.75;
  27 case_struts_width = 0.10;
  28
  29 keeper_th_z = 0.75;
  30 keeper_th_x = 0.75;
  31 keeper_inner_width = 2.75;
  32 keeper_inner_height = 2.75;
  33 keeper_slant_slope = 2; // larger means steeper
  34
  35 keeper_gap_z_top = 0.25;
  36 keeper_gap_z_bot = 0.75;
  37 keeper_gap_x     = 0.25;
  38 keeper_gap_x_holes = 0.75;
  39
  40 case_lip = 1.25;
  41
  42 lid_gap_x = 0.25;
  43 lid_gap_z = 0.25;
  44 lid_lip = 1.75;
  45
  46 $fa = 5;
  47 $fs = 0.1;
  48
  49 button_l_fudge = 4.5;
  50
  51 strut_min_at_end = 1.5;
  52
  53 // ---------- calculated ----------
  54
  55 phone_height = (phone + bumpers)[0];
  56 phone_width =  (phone + bumpers)[1];
  57
  58 // ----- could be changed -----
  59 lid_buttoncover_gap = lid_gap_x;
  60 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  61
  62 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  63
  64 //lid_lip_overlap_width xxx bad name = ;
  65 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  66
  67 epp0 = [0,0];
  68 epp1 = [0, -phone_edge_thick];
  69 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  70 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  71 epp3 = epp2i + [10, 0];
  72 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  73 epp4 = epp5 + [-1,0] * case_th_side;
  74
  75 kppe = [0,0];
  76 kppd = kppe + [1,0] * keeper_inner_width;
  77 kppc = kppd + [0,1] * keeper_th_z;
  78 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  79 kppf = kppe - [0,1] * keeper_inner_height;
  80 kppa = [ kppb[0], kppf[1] ];
  81
  82 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  83 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  84
  85 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  86
  87 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
  88 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
  89
  90 echo(lpp13 - lpp10);
  91
  92 // button profile
  93 bppM = epp4 + [0,5];
  94 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  95 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
  96 bppS = [ epp1[0], bppR[1] ];
  97 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
  98 bppP = bppQ + [0,1] * lid_buttoncover_gap;
  99 bppO = [ bppN[0], bppP[1] ];
 100 bppL = lpp10 + [5,0];
 101 bppK = [ bppL[0], bppN[1] ];
 102 bppJ = [ bppN[0], bppL[1] ];
 103
 104 module rectfromto(a,b) {
 105   ab = b - a;
 106   translate([min(a[0], b[0]), min(a[1], b[1])])
 107     square([abs(ab[0]), abs(ab[1])]);
 108 }
 109 module circleat(c,r) { translate(c) circle(r); }
 110
 111 module KeeperProfile(slant=0){
 112   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 113   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 114 }
 115
 116 module EdgeProfile(){
 117   difference(){
 118     hull(){
 119       translate(epp3) square(case_th_bottom*2, center=true);
 120       circleat(epp2o, r=case_th_bottom);
 121       circleat(epp1, r=case_th_side);
 122       rectfromto(epp0, epp4);
 123     }
 124     polygon([ epp5 + [0,10],
 125               epp1,
 126               epp2i,
 127               epp3 + [10,0] ]);
 128   }
 129 }
 130
 131 module LidEdgeProfile(){
 132   polygon([ lpp10,
 133             lpp11,
 134             lpp12,
 135             lpp13,
 136             lpp13 + [10, 0],
 137             lpp10 + [10, 0]
 138             ]);
 139   intersection(){
 140     circleat(lpp12, r=lp_r12);
 141     rectfromto( lpp12 + [-10,   0],
 142                 lpp12 + [+10, +10] );
 143   }
 144 }
 145
 146 module ButtonCoverProfile(){
 147   intersection(){
 148     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 149     hull(){
 150       EdgeProfile();
 151       LidEdgeProfile();
 152     }
 153   }
 154 }
 155
 156 module ButtonPlan(l, deep, cut){
 157   epsilon =
 158     (cut  ? 0 : lid_buttoncover_gap);
 159
 160   delta =
 161     (deep ? lid_buttoncover_overlap : 0);
 162
 163   C = [0,0]; // by definition
 164   T = [ 0, epp4[1] ];
 165   G = T + [0,10];
 166
 167   B0 = C + [0,-1] * button_cutout_depth;
 168   B1 = B0 + [0,1] * epsilon;
 169
 170   r0 = 0.5 * (T[1] - B0[1]);
 171   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 172   H = A + [0,-1] * delta;
 173
 174   D = A + [-2,0] * r0;
 175   F = D + [0,10];
 176
 177   E0 = 0.5 * (D + A);
 178   E1 = E0 + [1,0] * epsilon;
 179
 180   I0 = [ E0[0], H[1] ];
 181   I1 = [ E1[0], H[1] ];
 182
 183   hull(){
 184     for (m=[0,1]) mirror([m,0])
 185       circleat(H, r0 - epsilon);
 186   }
 187   for (m=[0,1]) mirror([m,0]) {
 188     difference(){
 189       polygon([ E1,
 190                 I1,
 191                 H,
 192                 B1,
 193                 G,
 194                 F,
 195                 D
 196                 ]);
 197       circleat(D, r0 + epsilon);
 198     }
 199   }
 200 }
 201
 202 module CaseBase_rhsflip(yn=[0,1]) {
 203   for (rhs=yn) {
 204     translate([phone_width/2, 0, 0])
 205       mirror([rhs,0,0])
 206       translate([-phone_width/2, 0, 0])
 207       children();
 208   }
 209 }
 210
 211 module CaseBase_botflip() {
 212   for (bot=[0,1]) {
 213     translate([0, -phone_height/2, 0])
 214       mirror([0, bot, 0])
 215       translate([0, phone_height/2, 0])
 216       children();
 217   }
 218 }
 219
 220 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 221   // sides
 222   CaseBase_rhsflip(){
 223     translate([0, -phone_cnr_rad, 0])
 224       rotate([90,0,0])
 225       linear_extrude(height = phone_height - phone_cnr_rad*2)
 226       children(0);
 227   }
 228   // corners
 229   CaseBase_rhsflip() CaseBase_botflip() {
 230     translate([+1,-1] * phone_cnr_rad)
 231       intersection(){
 232         rotate_extrude()
 233           intersection(){
 234             mirror([1,0,0])
 235               translate([-1,0] * phone_cnr_rad)
 236               children(0);
 237             rectfromto([0,-20],[10,20]);
 238           }
 239         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 240           cube([10,10,40]);
 241       }
 242   }
 243   // top and bottom
 244   CaseBase_botflip(){
 245     translate([ phone_width - phone_cnr_rad, 0,0 ])
 246       rotate([90,0,-90])
 247       linear_extrude(height = phone_width - phone_cnr_rad*2)
 248       children(0);
 249   }
 250   // fill
 251   translate([0,0, fill_zstart])
 252     mirror([0,0, fill_downwards])
 253     linear_extrude(height = fill_th)
 254     rectfromto([+1,-1] * phone_cnr_rad,
 255                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 256 }
 257
 258 module SideButton(y,l){
 259   $button_l= l;
 260   translate([0, -y, 0])
 261     children();
 262 }
 263
 264 module Buttons(){
 265   CaseBase_rhsflip([1]) SideButton(20.6, 8.8) children(); // power
 266 }
 267
 268 module Struts(x_start, z_min, th){
 269   // if th is negative, starts at z_min and works towards -ve z
 270   // and object should then be printed other way up
 271   for (i= [1 : 1 : case_struts_count]) {
 272     translate([0,
 273                0,
 274                z_min])
 275       mirror([0,0, th<0 ? 1 : 0])
 276       translate([0,
 277                  -phone_height * i / (case_struts_count+1),
 278                  case_struts_solid_below])
 279       linear_extrude(height= abs(th)
 280                      -(case_struts_solid_below+case_struts_solid_above))
 281       rectfromto([               x_start, -0.5 * case_struts_width ],
 282                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 283   }
 284 }
 285
 286 module CaseBase(){
 287   AroundEdges(epp3[1], case_th_bottom, 1)
 288     EdgeProfile();
 289 }
 290
 291 module Case(){ ////toplevel
 292   difference(){
 293     union(){
 294       CaseBase();
 295
 296       // ledge (fixed keeper)
 297       intersection(){
 298         rotate([90, 0, 0])
 299           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 300           KeeperProfile(1);
 301
 302         // outline of the whole case, to stop it protruding
 303         translate([0,0, -25])
 304           linear_extrude(height = 50)
 305           hull()
 306           // CaseBase_rhsflip() // actually, we only care about the LH
 307           CaseBase_botflip()
 308           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 309       }
 310     }
 311
 312     // slot for keeper
 313     CaseBase_rhsflip(1)
 314       translate([0, -phone_cnr_rad, 0])
 315       rotate([90, 0, 0])
 316       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 317       minkowski(){
 318         KeeperProfile();
 319         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 320                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 321       }
 322
 323     // front camera
 324     CaseBase_rhsflip([1])
 325       mirror([0, 0, 1])
 326       linear_extrude(height = 20)
 327       mirror([0, 1, 0])
 328       rectfromto(camera_pos_tl, camera_pos_br);
 329
 330     // struts (invisible, because they're buried in the case)
 331     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 332
 333     Buttons(){
 334       mirror([1,0,0])
 335         rotate([90,0,90]) {
 336           translate([0,0,-10])
 337             linear_extrude(height= 20)
 338             ButtonPlan($button_l, 0,1);
 339           translate([0,0, -bppR[0]])
 340             linear_extrude(height= 20)
 341             ButtonPlan($button_l, 1,1);
 342         }
 343     }
 344   }
 345 }
 346
 347 module Lid(){ ////toplevel
 348   difference(){
 349     union(){
 350       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 351         LidEdgeProfile();
 352
 353       // button covers
 354       Buttons(){
 355         intersection(){
 356           rotate([90,0,90])
 357             translate([0,0,-10])
 358             linear_extrude(height= 20)
 359             ButtonPlan($button_l, 1,0);
 360           rotate([90,0,0])
 361              translate([0,0,-100])
 362             linear_extrude(height= 200)
 363             ButtonCoverProfile();
 364         }
 365       }
 366     }
 367     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 368   }
 369 }
 370
 371 module TestLength(){ ////toplevel
 372   intersection(){
 373     Case();
 374     translate([-30, -200, -20])
 375     cube([30 + 15, 250, 40]);
 376   }
 377 }
 378
 379 module TestSelectWidth(){
 380   translate([-30, -(phone_height - 25), -20])
 381     mirror([0, 1, 0])
 382     cube([200, 50, 40]);
 383 }
 384
 385 module TestWidth(){ ////toplevel
 386   intersection(){
 387     Case();
 388     TestSelectWidth();
 389   }
 390 }
 391
 392 module TestLidWidthPrint(){ ////toplevel
 393   rotate([0,180.0]) TestLidWidth();
 394 }
 395
 396 module TestSelectCamera(){
 397   CaseBase_rhsflip(1)
 398     translate([0,0,-25])
 399     linear_extrude(height = 50)
 400     mirror([0, 1, 0])
 401     rectfromto([-20, -20],
 402                camera_pos_br + [ 5, 5 ]);
 403 }
 404
 405 module TestCamera(){ ////toplevel
 406   intersection(){
 407     Case();
 408     TestSelectCamera();
 409   }
 410 }
 411
 412 module TestLidByCamera(){ ////toplevel
 413   intersection(){
 414     Lid();
 415     TestSelectCamera();
 416   }
 417 }
 418
 419 module TestLidByCameraPrint(){ ////toplevel
 420   rotate([180,0,0]) TestLidByCamera();
 421 }
 422
 423 module DemoByCamera(){ ////toplevel
 424   color("blue") TestLidByCamera();
 425   color("red")  TestCamera();
 426 }
 427
 428 module OneKeeper(){ ////toplevel
 429   translate([0, -phone_cnr_rad, 0])
 430     rotate([90, 0, 0])
 431     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 432     KeeperProfile();
 433 }
 434
 435 module OneKeeperPrint(){ ////toplevel
 436   rotate([0,180,0])
 437     OneKeeper();
 438 }
 439
 440 module Keeper(){ ////toplevel
 441   CaseBase_rhsflip()
 442     OneKeeper();
 443 }
 444
 445 module ButtonPlanForDemo(z, deep, cut){
 446   translate([0,0,z])
 447     ButtonPlan(8, deep, cut);
 448 }
 449
 450 module DemoProfiles(){ ////toplevel
 451   LidEdgeProfile();
 452   %EdgeProfile();
 453   KeeperProfile();
 454   translate([0,0,-1]) color("black") KeeperProfile(1);
 455
 456   translate([20,0]) {
 457     LidEdgeProfile();
 458     %EdgeProfile();
 459
 460     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 461
 462     color("blue") ButtonCoverProfile();
 463     color("red") {
 464       rectfromto(bppQ, demopoint_QR);
 465       rectfromto(bppR, demopoint_QR);
 466     }
 467   }
 468
 469   translate([-20,0]) {
 470     color("black") ButtonPlanForDemo(-2, 0,1);
 471     color("red" )  ButtonPlanForDemo(-4, 1,1);
 472     color("blue")  ButtonPlanForDemo(-6, 1,0);
 473   }
 474 }
 475
 476 //EdgeProfile();
 477 //KeeperProfile();
 478 //CaseBase();
 479 //%Case();
 480 //Keeper();
 481 //LidEdgeProfile();
 482 //KeeperProfile();
 483 //DemoProfiles();