fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 thumbrecess_depth = 1.3;
 256
 257 catch_slop = -0.75;
 258
 259 catch_len = 4.5;
 260 catch_width = 15;
 261 catch_thickness = 1.3;
 262 catch_side_gap = 0.75; // each side
 263
 264 catch_depth = 0.75;
 265 catch_height = 0.35;
 266 catch_finger_height = 1.5;
 267 catch_finger_depth = 2.5;
 268 catch_catch_slope = 2.00;
 269 catch_close_slope = 3.00;
 270
 271 catch_topcurve_r = 5.0;
 272
 273 prop_recess_under = 0.50;
 274 prop_recess_slop = 0.200; // each side
 275 prop_end_dia = 0.5;
 276 prop_main_th = 3;
 277 prop_taper_len = 6;
 278 prop_main_width = 4;
 279 prop_side_gap = 0.75; // each side
 280 prop_lidrecess_behind = 0.75;
 281 prop_caserecess_behind = 0.75;
 282 prop_caserecess_taper = 0.45; // one side only
 283 prop_prop_gap = 0.5;
 284 prop_prong_heel_slope = 0.5;
 285
 286 lid_fold_clearance_antislop = 0.5;
 287
 288 // ---------- calculated ----------
 289
 290 phone_width =  (phone + bumper*2)[0];
 291 phone_height = (phone + bumper*2)[1];
 292
 293 inside_br = [phone_width, -phone_height];
 294
 295 prop_prong_h = prop_main_th;
 296
 297 //echo(camera_pos_tl + bumper,
 298 //     camera_pos_br + bumper);
 299
 300 // ----- could be changed -----
 301 lid_buttoncover_gap = lid_gap_x;
 302 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 303
 304 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 305
 306 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 307
 308 //prop_nose_len = case_th_lid - prop_recess_under;
 309 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 310 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 311
 312
 313 //lid_lip_overlap_width xxx bad name = ;
 314 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 315
 316 epp0 = [0,0];
 317 epp1 = [0, -phone_edge_thick];
 318 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 319 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 320 epp3 = epp2i + [10, 0];
 321 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 322 epp4 = epp5 + [-1,0] * case_th_side;
 323
 324 kppe = [0,0];
 325 kppd = kppe + [1,0] * keeper_inner_width;
 326 kppc = kppd + [0,1] * keeper_th_z;
 327 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 328 kppf = kppe - [0,1] * keeper_inner_height;
 329 kppa = [ kppb[0], kppf[1] ];
 330
 331 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 332 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 333
 334 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 335 // exact x posn not very important; must extend past end of keeper
 336
 337 lpp15 = [ lpp14[0],
 338           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 339           + lid_screen_gap_extra ];
 340 // ^ beam theory says to maximise force before contact,
 341 //   the gap below the `beam' (the lid) must be 1/3
 342 //   the thickness (ie the lid thickness) if the beam
 343 //   is solid, or 1/2 if it has a top and bottom only.
 344 //   ours is mostly solid.
 345
 346 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 347              case_th_lip);
 348
 349 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 350 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 351
 352 case_bottom_z = epp2o[1] - case_th_bottom;
 353
 354 // button profile
 355 bppM = epp4 + [0,5];
 356 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 357 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 358 bppS = [ epp1[0], bppR[1] ];
 359 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 360 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 361 bppO = [ bppN[0], bppP[1] ];
 362 bppL = lpp10 + [5,0];
 363 bppK = [ bppL[0], bppN[1] ];
 364 bppJ = [ bppN[0], bppL[1] ];
 365 bppU = [ bppJ[0], lpp12[1] ];
 366 bppV = lpp11;
 367 bppW = lpp10;
 368
 369 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 370
 371 // notification led aperture
 372
 373 nla_r0 = led_aperture/2;
 374 nla_r1 = nla_r0 + led_window_ledge;
 375 nla_r2 = nla_r1 + multicolour_gap;
 376 nla_t =
 377   led_window_style >= 3 ? initial_layer_thick :
 378   led_window_style >= 2 ? led_window_ledge : 0;
 379
 380
 381 // hinge plan
 382 hp_rn = hingescrew_nut_access_dia/2;
 383 hp_r2_min = hp_rn + lever_cover_th;
 384 hp_rs = hingescrew_shaft_dia/2;
 385 hp_r1_min = hp_rs + hingemount_th;
 386
 387 hp_r1 = max(hp_r1_min, hp_r2_min);
 388 hp_r2 = hp_r1;
 389
 390 hppU = lpp13;
 391 hppS = epp2o + [0,-1] * case_th_bottom;
 392 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 393
 394 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 395          0.5 * (hppU + hppS)[1] ];
 396 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 397 hppB = hppT + [0,-1] * hp_k;
 398
 399 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 400 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 401 hppE = [ hppE_x, hppE_y ];
 402
 403 // hinge elevation x coords
 404
 405 hex20 = max(epp2o[0],
 406             phone_cnr_rad,
 407             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 408 hex21 = hex20 + hingemount_wd;
 409 hex22 = hex21 + hinge_x_gap;
 410 hex27 = hex20 + hingescrew_shaft_len;
 411 hex24 = hex27 + hinge_x_postscrew_gap;
 412 hex23 = hex27 - (hingescrew_nut_thick*2
 413                  + hingescrew_fasteners_extra_thick);
 414 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 415
 416 echo(hex20, hex21, hex22, hex23, hex24);
 417 //  6, 10.8725, 10.9975, 13.74, 18.75
 418 module chk(act,exp) {
 419   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 420   else echo("ok", act);
 421 }
 422 chk(hex20, 6);
 423 chk(hex21, 10.8725);
 424 chk(hex22, 10.9975);
 425 chk(hex23, 13.74);
 426 chk(hex24, 18.75);
 427
 428 lid_fold_clearance_skew =
 429   (lpp10[1] - hppB[1]) /
 430   (lpp10[0] - hppB[0]);
 431
 432 echo("SK",lid_fold_clearance_skew);
 433
 434 // thumb recess (used to be "catch" hence cpp*
 435
 436 cppA = epp4 + [thumbrecess_depth, 0];
 437 cppB = [ cppA[0], epp1[1] ];
 438
 439 // catch
 440
 441 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 442 cppP = [ epp4[0], cppJ[1] ];
 443
 444 cppS = cppJ + [0,-1] * catch_len;
 445 cppD = [ cppA[0], cppS[1] + catch_slop ];
 446 cppC = [ cppB[0], cppD[1] ];
 447 cppT = cppS + [1, -catch_catch_slope] * catch_depth;
 448 cppU = cppT + [0,-1] * catch_height;
 449 cppV = [ cppS[0], cppU[1] - catch_depth * catch_close_slope ];
 450
 451 cppR = 0.5*(cppP + cppJ);
 452
 453 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 454 cppQ = [ cppR[0],
 455          cppV[1] - (catch_finger_height - cp_rQ) ];
 456 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 457
 458 // lanyard
 459
 460 ly_r = lanyard_half_dia / 2;
 461 ly_rc = ly_r * 2;
 462
 463 ly_theta = -atan2vector(epp2i - epp1);
 464 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 465
 466 max_case_bottom_edge_thickness =
 467   case_th_bottom
 468   + sin(ly_theta) * (epp2i-epp2o)[0];
 469
 470 ly_q_z = -(ly_rc + ly_r);
 471 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 472
 473 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 474
 475 // prop recess in case
 476
 477 prop_x_pos = phone_width/2;
 478
 479 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 480
 481 prc_r1 = prop_end_dia/2;
 482 prc_r3 = prc_r1 + prop_recess_slop;
 483
 484 prcp2 = [ epp4[0] + prop_buildout_less,
 485           case_bottom_z ];
 486
 487 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 488
 489 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 490           epp2i[1] - prc_r3 - prop_recess_under];
 491
 492 // prop recess in lid
 493
 494 prl_r10 = prop_end_dia/2;
 495 prl_r10o = prl_r10 + prop_recess_slop;
 496
 497 prlp10 = lpp10 + [1,1] * prl_r10o
 498   + [1,0] * prop_lidrecess_behind
 499   + [0,1] * prop_recess_under;
 500
 501 // prop
 502
 503 $prpp10 = [0,0];
 504 $prpp11 = [0, prop_taper_len];
 505
 506 $prp_r10 = prl_r10;
 507
 508 // ---------- modules ----------
 509
 510 module AdhocMultiprintFrame(phase, z0, zs) {
 511   // from z0 to z0 + zs*layer
 512   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 513   xextra = extra + -epp4[0];
 514   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 515   yextra = extra + -epp4[0];
 516   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 517   p0 = [ xrange[0], yrange[0] ];
 518   p1 = [ xrange[1], yrange[1] ];
 519   echo(p0, p1);
 520   translate([0,0, z0])
 521     mirror([0,0, zs<0 ? 1 : 0])
 522     linear_extrude(height= initial_layer_thick)
 523     difference(){
 524       rectfromto(p0 - [1,1] * initial_layer_width,
 525                  p1 + [1,1] * initial_layer_width);
 526       rectfromto(p0, p1);
 527     }
 528 }
 529
 530 module KeeperProfile(slant=0){
 531   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 532   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 533 }
 534
 535 module EdgeProfile(){
 536   difference(){
 537     hull(){
 538       translate(epp3) square(case_th_bottom*2, center=true);
 539       circleat(epp2o, r=case_th_bottom);
 540       circleat(epp1, r=case_th_side);
 541       rectfromto(epp0, epp4);
 542     }
 543     polygon([ epp5 + [0,10],
 544               epp1,
 545               epp2i,
 546               epp3 + [10,0] ]);
 547   }
 548 }
 549
 550 module LanyardLanyardProfile(entry=false){
 551   hull(){
 552     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 553       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 554         circle(r= lanyard_half_dia/2);
 555   }
 556 }
 557
 558 module LanyardCurveChannelProfile(){
 559   translate([0, -ly_r])
 560     LanyardLanyardProfile();
 561 }
 562
 563 module LanyardEntryChannelProfile(){
 564   LanyardLanyardProfile(true);
 565 }
 566
 567 module LanyardMainChannelProfile(){
 568   LanyardCurveChannelProfile();
 569   difference(){
 570     square(center=true, ly_r * [6, 2]);
 571     for (xs=[-1,+1])
 572       translate(ly_r * [3 * xs, -1])
 573         circle(r = ly_r);
 574   }
 575 }
 576
 577 module LanyardEntryOuterProfile(){
 578   circleat([ly_re + ly_r, 0], ly_re);
 579 }
 580
 581 module LanyardEntry(){
 582   q_z = ly_q_z;
 583   oec_y = ly_oec_y;
 584
 585   d_x = -ly_rc;
 586
 587   translate([d_x, 0, q_z]) {
 588     intersection(){
 589       rotate([90,0,0])
 590         rotate_extrude(convexity=10)
 591         rotate(90)
 592         translate([0, -q_z])
 593         LanyardCurveChannelProfile();
 594       translate([0,-10,0])
 595         cube([20,20,20]);
 596     }
 597   }
 598
 599   mirror([0,0,1])
 600     translate([0,0,-1])
 601     linear_extrude(height=20)
 602     rotate(-90)
 603     LanyardEntryChannelProfile();
 604
 605   translate([0, ly_r*2, 0])
 606     rotate([90,0,0])
 607     linear_extrude(height = ly_r*4){
 608     difference(){
 609       rectfromto([d_x, q_z], [ly_r, 0]);
 610       circleat([d_x, q_z], ly_rc);
 611     }
 612   }
 613
 614   translate([0,0,q_z]){
 615     for (my=[0,1])
 616       mirror([0,my,0]){
 617         translate([0, oec_y, 0]){
 618           difference(){
 619             translate(ly_re * [-1,0,-2])
 620               cube(ly_re * [2,1,2]);
 621             rotate_extrude(convexity=10)
 622               LanyardEntryOuterProfile();
 623           }
 624         }
 625       }
 626     difference(){
 627       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 628         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 629       for (mx=[0,1])
 630         mirror([mx,0,0])
 631           rotate([90,0,0])
 632           translate([0,0,-10])
 633           linear_extrude(height=20)
 634           LanyardEntryOuterProfile();
 635     }
 636   }
 637 }
 638
 639 module LanyardCutout(l){
 640   rotate([0,-90,0])
 641     linear_extrude(height=l)
 642     rotate(-90)
 643     LanyardMainChannelProfile();
 644
 645   for (ee=[0,1]){
 646     translate(ee * l * [-1,0])
 647       mirror([ee,0,0])
 648       LanyardEntry();
 649   }
 650 }
 651
 652 module LidEdgeProfile(){
 653   polygon([ lpp10,
 654             lpp11,
 655             lpp12,
 656             lpp13,
 657             lpp13 + [10, 0],
 658             lpp15 + [10, 0],
 659             lpp15,
 660             lpp14,
 661             ]);
 662   intersection(){
 663     circleat(lpp12, r=lp_r12);
 664     rectfromto( lpp12 + [-10,   0],
 665                 lpp12 + [+10, +10] );
 666   }
 667 }
 668
 669 module LidEdgeFoldClearanceProfile(){
 670   translate([-lid_fold_clearance_antislop, 0])
 671     polygon([ lpp10,
 672               lpp11,
 673               lpp11 + [-20,  0],
 674               lpp11 + [-20, 20],
 675               lpp11 + [+20, 20],
 676               lpp10 + [+20,  0] ]);
 677 }
 678
 679 module ButtonCoverProfile(){
 680   intersection(){
 681     polygon(concat([ bppM, bppP, bppO, bppJ ],
 682                    (enable_support && !$button_suppress_over_keeper
 683                     ? [ bppU, bppV, bppW ] : []),
 684                    [ bppL, bppK ]));
 685     hull(){
 686       EdgeProfile();
 687       LidEdgeProfile();
 688     }
 689   }
 690 }
 691
 692 module ButtonPlan(l, deep, cut){
 693   epsilon =
 694     (cut  ? 0 : lid_buttoncover_gap);
 695
 696   delta =
 697     (deep ? lid_buttoncover_overlap : 0);
 698
 699   C = [0,0]; // by definition
 700   T = [ 0, epp4[1] ];
 701   G = T + [0,10];
 702
 703   B0 = C + [0,-1] * button_cutout_depth;
 704   B1 = B0 + [0,1] * epsilon;
 705
 706   r0 = 0.5 * (T[1] - B0[1]);
 707   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 708   H = A + [0,-1] * delta;
 709
 710   D = A + [-2,0] * r0;
 711   F = D + [0,10];
 712
 713   E0 = 0.5 * (D + A);
 714   E1 = E0 + [1,0] * epsilon;
 715
 716   I0 = [ E0[0], H[1] ];
 717   I1 = [ E1[0], H[1] ];
 718
 719   hull(){
 720     for (m=[0,1]) mirror([m,0])
 721       circleat(H, r0 - epsilon);
 722   }
 723   for (m=[0,1]) mirror([m,0]) {
 724     difference(){
 725       polygon([ E1,
 726                 I1,
 727                 H,
 728                 B1,
 729                 G,
 730                 F,
 731                 D
 732                 ]);
 733       circleat(D, r0 + epsilon);
 734     }
 735   }
 736 }
 737
 738 module ButtonCoverReinf(){ ////toplevel
 739   minkowski(){
 740     rotate([90,0,0])
 741       linear_extrude(height=0.01)
 742       intersection(){
 743         ButtonCoverProfile();
 744         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 745           square([100,100]);
 746     }
 747     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 748       circle(r= lid_buttoncover_reinf);
 749       translate([-20,0]) square(40, center=true);
 750     }
 751   }
 752 }
 753
 754 module CatchCutProfile(){
 755   difference(){
 756     polygon([ cppA + [-10,0],
 757               cppB + [-10,0],
 758               cppB,
 759               cppA ]);
 760     circleat(epp1, r=case_th_side);
 761   }
 762 }
 763
 764 module Flip_rhs(yn=[0,1]) {
 765   for ($rhsflip=yn) {
 766     translate([phone_width/2, 0, 0])
 767       mirror([$rhsflip,0,0])
 768       translate([-phone_width/2, 0, 0])
 769       children();
 770   }
 771 }
 772
 773 module Flip_bot(yn=[0,1]) {
 774   for ($botflip=yn) {
 775     translate([0, -phone_height/2, 0])
 776       mirror([0, $botflip, 0])
 777       translate([0, phone_height/2, 0])
 778       children();
 779   }
 780 }
 781
 782 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 783   // sides
 784   Flip_rhs(){
 785     translate([0, -phone_cnr_rad, 0])
 786       rotate([90,0,0])
 787       linear_extrude(height = phone_height - phone_cnr_rad*2)
 788       children(0);
 789   }
 790   // corners
 791   Flip_rhs() Flip_bot() {
 792     translate([+1,-1] * phone_cnr_rad)
 793       intersection(){
 794         rotate_extrude()
 795           intersection(){
 796             mirror([1,0,0])
 797               translate([-1,0] * phone_cnr_rad)
 798               children(0);
 799             rectfromto([0,-20],[10,20]);
 800           }
 801         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 802           cube([10,10,40]);
 803       }
 804   }
 805   // top and bottom
 806   Flip_bot(){
 807     translate([ phone_width - phone_cnr_rad, 0,0 ])
 808       rotate([90,0,-90])
 809       linear_extrude(height = phone_width - phone_cnr_rad*2)
 810       children(0);
 811   }
 812   // fill
 813   translate([0,0, fill_zstart])
 814     mirror([0,0, fill_downwards])
 815     linear_extrude(height = fill_th)
 816     rectfromto([+1,-1] * phone_cnr_rad,
 817                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 818 }
 819
 820 module CaseAperture(pos, dia, $fn) {
 821   theta = 180/$fn;
 822   translate([ pos[0] + bumper[0],
 823               -epp2i[0],
 824               -pos[1] ])
 825     rotate([-90, theta, 0])
 826     cylinder(r = dia/2 / cos(theta),
 827              h = 60);
 828 }
 829
 830 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 831   // y_ref_sign:
 832   //   +1  measured from top    of actual phone to top    of button
 833   //   -1  measured from bottom of actual phone to bottom of button
 834   //    0  y is centre of button in coordinate system
 835   $button_l= l;
 836   $button_suppress_over_keeper= suppress_over_keeper;
 837   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 838           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 839           y;
 840   //echo(eff_y);
 841   translate([0, eff_y, 0])
 842     children();
 843 }
 844
 845 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 846   $button_leg_only = true;
 847   SideButton(y, y_ref_sign, l) children();
 848 }
 849
 850 module Buttons(){
 851   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 852   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 853   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 854   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 855 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 856 }
 857
 858 module Struts(x_start, z_min, th){
 859   // if th is negative, starts at z_min and works towards -ve z
 860   // and object should then be printed other way up
 861   for (i= [1 : 1 : case_struts_count]) {
 862     translate([0,
 863                0,
 864                z_min])
 865       mirror([0,0, th<0 ? 1 : 0])
 866       translate([0,
 867                  -phone_height * i / (case_struts_count+1),
 868                  case_struts_solid_below])
 869       linear_extrude(height= abs(th)
 870                      -(case_struts_solid_below+case_struts_solid_above))
 871       rectfromto([               x_start, -0.5 * case_struts_width ],
 872                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 873   }
 874 }
 875
 876 module OrdinaryRearAperture(rhs,bot, pos){
 877   Flip_rhs(rhs) Flip_bot(bot)
 878     linextr(-20, 20)
 879     mirror([0,1])
 880     translate(pos + bumper)
 881     children();
 882 }
 883
 884 module MicroUSB(){
 885   Flip_bot(1){
 886     rotate([90,0,0])
 887       mirror([0,0,1])
 888       linextr(-epp2i[0], 60)
 889       translate([0.5 * phone_width, 0, 0])
 890       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 891                  [+microusb_width/2, epp0[1] + -microusb_above]);
 892   }
 893 }
 894
 895 module OrdinaryRearApertures(){
 896   // rear speaker
 897   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 898     rectfromto(-rearspeaker_gap,
 899                rearspeaker_size + rearspeaker_gap);
 900
 901   // finger hole to remove phone
 902   if (len(fingerpushhole_dias))
 903     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 904                                 phone[1]/2 ])
 905     scale(fingerpushhole_dias)
 906     circle(r= 0.5 );
 907 }
 908
 909 module RearCameraAperture(){
 910   Flip_rhs(1)
 911     mirror([0, 0, 1])
 912     linear_extrude(height = 20)
 913     mirror([0, 1, 0])
 914     translate(bumper)
 915     rectfromto(camera_pos_tl, camera_pos_br);
 916 }
 917
 918 module HingeLidProfile(){
 919   hull(){
 920     circleat(hppT, hp_r1);
 921     circleat(lpp12, lp_r12);
 922     polygon([lpp10,
 923              lpp13 + [2,0],
 924              lpp12,
 925              hppT]);
 926   }
 927 }
 928
 929 module HingeBaseProfile(){
 930   difference(){
 931     hull(){
 932       circleat(hppB, hp_r1);
 933       circleat(hppE, hp_r1);
 934       circleat(epp2o, case_th_bottom);
 935       circleat(hppB + [10,0], hp_r1);
 936     }
 937     polygon([epp5, epp1, epp2i, epp3, bppL]);
 938   }
 939 }
 940
 941 module HingeLeverOuterProfile(){
 942   hull(){
 943     circleat(hppT, hp_r2);
 944     circleat(hppB, hp_r2);
 945   }
 946 }
 947
 948 module HingeLeverInnerProfile(){
 949   for (s = [-1,+1]) {
 950     c = s > 0 ? hppT : hppB;
 951     translate(c)
 952       mirror([0,0,s>0])
 953       rotate(s<0 ? -40 : 0)
 954       hull()
 955       for (x=[-20,20])
 956         for (y=[0, s * 10])
 957           translate([x,y])
 958             circle(hp_rn);
 959   }
 960 }
 961
 962 module HingeLeverNutProfile(){
 963   for (c= [hppB, hppT]) {
 964     translate(c)
 965       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 966   }
 967 }
 968
 969 module Flip_hinge(doflip=1){
 970   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 971   translate(hinge_origin)
 972     rotate([doflip*180,0,0])
 973     translate(-hinge_origin)
 974     children();
 975 }
 976
 977 module HingePortion(x0,x1){
 978   Flip_rhs() Flip_bot(1)
 979     translate([x0,0,0])
 980     mirror([1,0,0])
 981     rotate([90,0,-90])
 982     linear_extrude(height=x1-x0)
 983     children();
 984 }
 985
 986 module CatchPortion(xwidth, ztop){
 987   width = catch_width + xwidth;
 988   w = width + catch_topcurve_r*2 + 1;
 989   translate([phone_width/2, 0,0]){
 990     difference(){
 991       rotate([90,0,-90])
 992         linextr(-w/2, w/2)
 993         children(0);
 994       translate([0, 50, 0])
 995         rotate([90,0,0])
 996         linear_extrude(height=100){
 997         for (m=[0,1]) mirror([m,0,0]) {
 998           hull(){
 999             translate([w/2, ztop - catch_topcurve_r])
1000               circle(catch_topcurve_r);
1001             translate([w/2, -50])
1002               square(catch_topcurve_r*2, center=true);
1003           }
1004         }
1005       }
1006     }
1007   }
1008 }
1009
1010 module CaseBase(){
1011   AroundEdges(epp3[1], case_th_bottom, 1)
1012     EdgeProfile();
1013 }
1014
1015 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1016
1017 module PropProfileAssignments(gamma){
1018   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1019   x = prop_x(gamma);
1020   p = phone_height + prlp10[0] - hppB[0];
1021   b = p + x;
1022
1023   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1024   a = q + x;
1025   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1026   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1027
1028   $prp_theta = 90 - $prp_alpha;
1029   beta = 180 - $prp_alpha - gamma;
1030   psi = 90 - beta;
1031
1032   //echo("abc", a,b,c);
1033
1034   v1 = [ [ cos(psi), -sin(psi) ],    // x
1035          [ sin(psi),  cos(psi) ] ];  // y
1036
1037   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1038
1039   $prp_r1 = prc_r1;
1040   $prp_r11 = prop_main_th/2;
1041
1042   $prpp1 = $prpp7 + [1,0] *
1043     // this is approximate, but will do
1044     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1045   $prpp3 = $prpp1 +
1046     v1[0] * -$prp_r1 +
1047     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1048   $prpp12 = $prpp3 + v1[0] *
1049     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1050   $prp_r8 = prop_main_th;
1051   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1052   $prp_r5 = $prp_r8;
1053   $prpp5 = [ $prpp12[0] - $prp_r5,
1054             $prpp3[1] - prop_prong_h + $prp_r5 ];
1055   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1056          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1057   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1058   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1059
1060   children();
1061 }
1062
1063 module PropProfile(gamma, cut=0, rot=0){
1064   PropProfileAssignments(gamma){
1065
1066     //#circleat($prpp3,1);
1067     //#circleat($prpp12,1);
1068
1069     if (!cut) {
1070       hull(){
1071         translate($prpp8)
1072           intersection(){
1073             circle($prp_r8);
1074             polygon([[-20,-0], [20,20], [0,0]]);
1075           }
1076         rectfromto($prpp6, $prpp9);
1077         translate($prpp5) intersection(){
1078           circle($prp_r5);
1079           polygon([[-10,-10], [0,0], [10,0]]);
1080         }
1081         rectfromto($prpp12 + [0,-0.1], $prpp3);
1082       }
1083       hull(){
1084         circleat($prpp1, $prp_r1);
1085         rectfromto($prpp12 + [0,-0.1], $prpp3);
1086       }
1087     }
1088     // main shaft
1089     rotate([0,0, rot*-$prp_theta]){
1090       hull(){
1091         extra = cut ? prop_recess_slop : 0;
1092         rectfromto($prpp6, $prpp9);
1093         circleat($prpp11, $prp_r11 + extra);
1094         circleat($prpp10, $prp_r10 + extra);
1095       }
1096     }
1097   }
1098 }
1099
1100 module PropAggregateProfile(){
1101   for (angle = prop_angles)
1102     PropProfile(angle, 0,0);
1103 }
1104
1105 module Prop(){ ////toplevel
1106   hw = prop_main_width/2;
1107   linextr(-hw, +hw)
1108     PropAggregateProfile();
1109 }
1110
1111 module Case(){ ////toplevel
1112   difference(){
1113     union(){
1114       CaseBase();
1115
1116       // ledge (fixed keeper)
1117       Flip_rhs(1-keeper_side) intersection(){
1118         rotate([90, 0, 0])
1119           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1120           KeeperProfile(1);
1121
1122         // outline of the whole case, to stop it protruding
1123         translate([0,0, -25])
1124           linear_extrude(height = 50)
1125           hull()
1126           Flip_bot()
1127           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1128       }
1129
1130       // hinge
1131       HingePortion(hex20, hex21) HingeBaseProfile();
1132
1133       // buildout for prop recess
1134       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1135         linextr(case_bottom_z, epp2i[1])
1136         hull() {
1137           for (dxs = [-1,+1])
1138             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1139                        -epp2o[0] ],
1140                      r = epp2o[0] - prcp2[0]);
1141         }
1142     }
1143
1144     // slot for keeper
1145     Flip_rhs(keeper_side)
1146       translate([0, -phone_cnr_rad, 0])
1147       rotate([90, 0, 0])
1148       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1149       minkowski(){
1150         KeeperProfile();
1151         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1152                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1153       }
1154
1155     // front camera
1156     RearCameraAperture();
1157
1158     // struts (invisible, because they're buried in the case)
1159     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1160
1161     Buttons(){
1162       mirror([1,0,0])
1163         rotate([90,0,90]) {
1164           if (!($button_leg_only && enable_support))
1165           intersection(){
1166             translate([0,0,-10])
1167               linear_extrude(height= 20)
1168               ButtonPlan($button_l, 0,1);
1169             if ($button_leg_only)
1170               rotate([-90,90,0])
1171                 translate([phone_width/2, -400, kppe[1]])
1172                 mirror([1-abs($rhsflip - keeper_side),0,0])
1173                 cube([400, 800, 50]);
1174             if (enable_support && !$button_suppress_over_keeper)
1175               rotate([-90,90,0])
1176               translate([-400, -400, kppd[1]])
1177                 mirror([0,0,1])
1178                 cube([800,800,100]);
1179           }
1180           translate([0,0, -bppR[0]])
1181             linear_extrude(height= 20)
1182             ButtonPlan($button_l, 1,1);
1183         }
1184
1185     }
1186
1187     // apertures along top edge
1188     CaseAperture(jack_pos, jack_dia, 8);
1189     Flip_rhs(1)
1190       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1191
1192     OrdinaryRearApertures();
1193
1194     MicroUSB();
1195
1196     // gaps for the lid's hinge arms
1197     HingePortion(hex20 - hinge_x_arms_gap,
1198                  hex21 + hinge_x_arms_gap)
1199       minkowski(){
1200         HingeLidProfile();
1201         circle(r= hinge_r_arms_gap, $fn= 8);
1202       }
1203
1204     // screw holes in the hinge arms
1205     HingeScrews();
1206
1207     // catch striker
1208     CatchPortion(catch_side_gap*2, epp4[1])
1209       CatchCutProfile();
1210
1211     // lanyard
1212     Flip_bot(1)
1213       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1214       rotate([0, ly_theta, 0])
1215       rotate([0,0,90])
1216       LanyardCutout(lanyard_channel_len);
1217
1218     // prop recess
1219     Flip_rhs(1)
1220       translate([prop_x_pos,0,0])
1221       mirror([0,1,0])
1222       rotate([90,0,90])
1223       linextr(-prop_recess_hw, +prop_recess_hw)
1224       hull(){
1225         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1226           circleat(prcp1 + 20*d,
1227                    prc_r3);
1228       }
1229   }
1230 }
1231
1232 module LidAdhocMultiprintFrame(phase){
1233   if (led_window_style >= 3) {
1234     AdhocMultiprintFrame(phase, lpp13[1], -1);
1235   }
1236 }
1237
1238 module LidAroundEdges(){
1239   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1240     children();
1241 }
1242
1243 module Lid(){ ////toplevel
1244   skew_centre = [0, lpp11[0], lpp11[1]];
1245   difference(){
1246     union(){
1247       intersection(){
1248         LidAroundEdges()
1249           LidEdgeProfile();
1250
1251         translate(skew_centre)
1252           multmatrix([[ 1, 0, 0, 0 ],
1253                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1254                       [ 0, 0, 1, 0 ],
1255                       [ 0, 0, 0, 1 ]])
1256           translate(-skew_centre)
1257           LidAroundEdges()
1258           LidEdgeFoldClearanceProfile();
1259       }
1260
1261       // button covers
1262       Buttons(){
1263         intersection(){
1264           rotate([90,0,90])
1265             translate([0,0,-10])
1266             linear_extrude(height= 20)
1267             ButtonPlan($button_l, 1,0);
1268           union(){
1269             rotate([90,0,0])
1270               translate([0,0,-100])
1271               linear_extrude(height= 200)
1272               ButtonCoverProfile();
1273             hull()
1274               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1275                                  - lid_buttoncover_reinf))
1276                 translate([0,y,0])
1277                   ButtonCoverReinf();
1278           }
1279         }
1280       }
1281
1282       // hinge arms
1283       HingePortion(hex20, hex21) {
1284         LidEdgeProfile();
1285         HingeLidProfile();
1286       }
1287     }
1288     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1289
1290     // screw holes in the hinge arms
1291     HingeScrews();
1292
1293     // prop recess
1294     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1295       mirror([0,1,0])
1296       rotate([90,0,90])
1297       linextr(-prop_recess_hw, +prop_recess_hw)
1298       hull()
1299       for (pa = prop_angles)
1300         PropProfile(pa, 1,1);
1301
1302     // notification led aperture
1303     if (led_window_style)
1304       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1305         translate([0,0,-10])
1306           cylinder(r=nla_r0, h=20);
1307         if (led_window_style >= 2)
1308           translate([0,0, -nla_t])
1309             cylinder(r=nla_r2, height=20);
1310       }
1311
1312     }
1313
1314   LidAdhocMultiprintFrame(1);
1315 }
1316
1317 module HingeLever(){ ////toplevel
1318   difference() {
1319     // outer body, positive
1320     HingePortion(hex22, hex22 + phone_width/2)
1321       HingeLeverOuterProfile();
1322
1323     // space for the screws
1324     HingePortion(hex26, hex24)
1325       HingeLeverInnerProfile();
1326
1327     // recesses for the nuts
1328     HingePortion(hex23, hex26+1)
1329       HingeLeverNutProfile();
1330
1331     // bores for the screws
1332     HingeScrews();
1333
1334     // space for the charging cable
1335     MicroUSB();
1336     Flip_hinge() MicroUSB();
1337   }
1338 }
1339
1340 module LidWindow(){ ////toplevel
1341   translate([led_pos[0], -led_pos[1], lpp13[1]])
1342     mirror([0,0,1])
1343     cylinder(r= nla_r1, h=nla_t);
1344   LidAdhocMultiprintFrame(0);
1345 }
1346
1347 module LidWindowPrint(){ ////toplevel
1348   rotate([0,180,0])
1349     LidWindow();
1350 }
1351
1352 module DemoLidWindowSelect(){
1353   translate([led_pos[0], led_pos[1], -100]) {
1354     translate([0, -30, 0]) cube([400, 400, 200]);
1355   }
1356 }
1357
1358 module DemoLidWindow(){ ////toplevel
1359   %Lid();
1360   LidWindow();
1361   translate([0,40,0]){
1362     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1363     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1364   }
1365 }
1366
1367 module HingeLeverPrint(){ ////toplevel
1368   rotate([-90,0,0])
1369     translate([-phone_width/2, phone_height, 0])
1370     HingeLever();
1371 }
1372
1373 module TestSelectLength(){
1374   translate([-30, -200, -20])
1375     cube([30 + 15, 250, 40]);
1376 }
1377
1378 module TestLength(){ ////toplevel
1379   intersection(){
1380     Case();
1381     TestSelectLength();
1382   }
1383 }
1384
1385 module TestLengthRight(){ ////toplevel
1386   intersection(){
1387     Case();
1388     Flip_rhs(1)
1389       TestSelectLength();
1390   }
1391 }
1392
1393 module TestSelectWidth(){
1394   translate([-30, -(phone_height - 25), -20])
1395     mirror([0, 1, 0])
1396     cube([200, 50, 40]);
1397 }
1398
1399 module TestWidth(){ ////toplevel
1400   intersection(){
1401     Case();
1402     TestSelectWidth();
1403   }
1404 }
1405
1406 module TestLidWidthPrint(){ ////toplevel
1407   rotate([0,180.0]) intersection(){
1408     Lid();
1409     TestSelectWidth();
1410   }
1411 }
1412
1413 module TestSelectRearAperture(){
1414   minkowski(){
1415     union() children();
1416     translate([20, 0,0])
1417       cube([42, 2, 1], center=true);
1418   }
1419 }
1420
1421 module TestSelectCamera(){
1422   minkowski(){
1423     TestSelectRearAperture()
1424       RearCameraAperture();
1425     cube([0.1, 50, 0.1]);
1426   }
1427 }
1428
1429 module TestSelectOrdinaryRearApertures(){
1430   TestSelectRearAperture()
1431     OrdinaryRearApertures();
1432 }
1433
1434 module TestCamera(){ ////toplevel
1435   intersection(){
1436     Case();
1437     TestSelectCamera();
1438   }
1439 }
1440
1441 module TestLidByCamera(){ ////toplevel
1442   intersection(){
1443     Lid();
1444     TestSelectCamera();
1445   }
1446 }
1447
1448 module TestLidByCameraPrint(){ ////toplevel
1449   rotate([180,0,0]) TestLidByCamera();
1450 }
1451
1452 module DemoByCamera(){ ////toplevel
1453   color("blue") TestLidByCamera();
1454   color("red")  TestCamera();
1455 }
1456
1457 module OneKeeper(){ ////toplevel
1458   translate([0, -phone_cnr_rad, 0])
1459     rotate([90, 0, 0])
1460     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1461     KeeperProfile();
1462 }
1463
1464 module OneKeeperPrint(){ ////toplevel
1465   rotate([0,180,0])
1466     OneKeeper();
1467 }
1468
1469 module LidPrint(){ ////toplevel
1470   rotate([0,180,0])
1471     Lid();
1472 }
1473
1474 module TestSelectFrame(){
1475   include = [1,-1] * (epp2i[0] + 4);
1476
1477   difference(){
1478     cube(1000, center=true);
1479     translate([0,0, -100])
1480       linear_extrude(height=200)
1481       rectfromto(include,  inside_br - include);
1482   }
1483 }
1484
1485 module TestSelectLidFrame(){
1486   TestSelectFrame();
1487   translate([led_pos[0], -led_pos[1], -50])
1488     cylinder(r= nla_r2+3, h=100);
1489 }
1490
1491 module TestFrameCase(){ ////toplevel
1492   intersection(){
1493     Case();
1494     union(){
1495       TestSelectFrame();
1496       TestSelectCamera();
1497       TestSelectOrdinaryRearApertures();
1498     }
1499   }
1500 }
1501
1502 module TestSelectTopApertures(){
1503   translate([-100, -35, -100])
1504     cube([400, 100, 200]);
1505   LidAdhocMultiprintFrame(0);
1506   LidAdhocMultiprintFrame(1);
1507 }
1508
1509 module TestTopApertures(){ ////toplevel
1510   intersection(){
1511     Case();
1512     TestSelectFrame();
1513     TestSelectTopApertures();
1514   }
1515 }
1516
1517 module TestLidTopAperturesPrint(){ ////toplevel
1518   rotate([0,180,0]) intersection(){
1519     Lid();
1520     TestSelectLidFrame();
1521     TestSelectTopApertures();
1522   }
1523 }
1524
1525 module TestLidWindowTopAperturesPrint(){ ////toplevel
1526   rotate([0,180,0]) intersection(){
1527     LidWindow();
1528     TestSelectTopApertures();
1529   }
1530 }
1531
1532 module TestFrameLidPrint(){ ////toplevel
1533   rotate([0,180,0]) intersection(){
1534     Lid();
1535     TestSelectLidFrame();
1536   }
1537 }
1538
1539 module ButtonPlanForDemo(z, deep, cut){
1540   translate([0,0,z])
1541     ButtonPlan(8, deep, cut);
1542 }
1543
1544 module HingeScrews(){
1545   Flip_rhs() Flip_bot(1){
1546     for (c= [ hppT, hppB ])
1547       translate([ hex20,
1548                   -c[0],
1549                   c[1] ]){
1550         rotate([0,90,0])
1551           translate([0,0,-.2])
1552           cylinder( r= hingescrew_shaft_dia/2,
1553                     h = hingescrew_shaft_len+0.2 );
1554         rotate([0,-90,0])
1555           translate([0,0,+.1])
1556           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1557       }
1558   }
1559 }
1560
1561 module DemoPropAngleSelect(c){
1562   color(c) difference(){
1563     union(){ children(); }
1564     translate([ prop_x_pos, -400, -200 ])
1565       cube([ 400,800,400 ]);
1566   }
1567 }
1568
1569 module DemoPropAngle(ang){
1570   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1571   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1572
1573   translate(hL)
1574     rotate([ang/2,0,0])
1575     translate(-hL)
1576     translate(hC)
1577     rotate([ang/2,0,0])
1578     translate(-hC) {
1579       DemoPropAngleSelect("red") Case();
1580
1581       color("orange")
1582         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1583         PropProfileAssignments(ang) {
1584           echo($prpp1);
1585           rotate([-$prp_theta, 0, 0])
1586           translate([0, $prpp1[0], -$prpp1[1]])
1587           rotate([90,0,-90])
1588           Prop();
1589         }
1590     }
1591
1592   translate([0,0, -hp_k*2])
1593     DemoPropAngleSelect("blue")
1594     Lid();
1595 }
1596
1597 module DemoPropAngles(){ ////toplevel
1598   for (i=[0 : len(prop_angles)-1])
1599     translate(i * [0, -100, 100])
1600     DemoPropAngle(prop_angles[i]);
1601 }
1602
1603 module DemoHingeAngle(ang1,ang2){
1604   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1605   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1606
1607   translate(hL)
1608     rotate([ang2,0,0])
1609     translate(-hL)
1610     translate(hC)
1611     rotate([ang1,0,0])
1612     translate(-hC) {
1613       color("red") Lid();
1614     }
1615
1616   color("blue") intersection(){
1617     Case();
1618     union(){
1619       translate([bppJ[0], -400, -200])
1620         mirror([1,0,0])
1621         cube([400, 800, 400]);
1622       translate([10, -400, -200])
1623         cube([10, 800, 400]);
1624     }
1625   }
1626 }
1627
1628 module DemoHingeAngles(){ ////toplevel
1629   angles = [ 0, 4, 8, 12 ];
1630   echo("angles",angles);
1631   for (i=[0 : len(angles)-1]) {
1632     translate(i * [0, 0, 30]) {
1633       DemoHingeAngle(0,angles[i]);
1634       translate([0, 200, 0])
1635         DemoHingeAngle(angles[i],0);
1636     }
1637   }
1638 }
1639
1640 module DemoSelectAdhocLeftRight(right=0) {
1641   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1642     mirror([1-right, 0,0])
1643     cube([400, 800, 200]);
1644 }
1645
1646 module DemoLeft(){ ////toplevel
1647   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1648   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1649 }
1650
1651 module DemoFrame(){ ////toplevel
1652   color("red") TestFrameCase();
1653   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1654   color("black") HingeScrews();
1655   %HingeLever();
1656 }
1657
1658 module DemoLanyardCutout(){ ////toplevel
1659   LanyardCutout(25);
1660 }
1661
1662 module DemoHingedFrame(){ ///toplevel
1663   color("red") TestFrameCase();
1664   translate([0,0, -2*hp_k])
1665   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1666
1667   Flip_hinge(){
1668     color("orange") HingeLever();
1669     color("black") HingeScrews();
1670   }
1671 }
1672
1673 module DemoHinge(){ ////toplevel
1674   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1675     DemoFrame();
1676     translate([0,0, -hp_k*3])
1677       DemoHingedFrame();
1678   }
1679 }
1680
1681 module DemoProfiles(){ ////toplevel
1682   LidEdgeProfile();
1683   %EdgeProfile();
1684   KeeperProfile();
1685   translate([0,0,-1]) color("black") KeeperProfile(1);
1686   translate(ly_o){
1687     rotate(-ly_theta){
1688       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1689       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1690       translate([0, ly_q_z]){
1691         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1692         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1693       }
1694     }
1695   }
1696   translate([0,0,-5]) color("white") translate(epp2i)
1697     rotate(-ly_theta)
1698     rectfromto([-15, 0],
1699                [+15, -max_case_bottom_edge_thickness]);
1700
1701   translate([0,20]) {
1702     LanyardMainChannelProfile();
1703     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1704     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1705   }
1706
1707   translate([20,0]) {
1708     LidEdgeProfile();
1709     %EdgeProfile();
1710
1711     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1712
1713     color("blue") ButtonCoverProfile();
1714     color("red") {
1715       rectfromto(bppQ, demopoint_QR);
1716       rectfromto(bppR, demopoint_QR);
1717     }
1718   }
1719
1720   translate([-20,0]) {
1721     color("black") ButtonPlanForDemo(-2, 0,1);
1722     color("red" )  ButtonPlanForDemo(-4, 1,1);
1723     color("blue")  ButtonPlanForDemo(-6, 1,0);
1724   }
1725
1726   translate([0, -30]) {
1727     %LidEdgeProfile();
1728     %EdgeProfile();
1729     color("blue") HingeLidProfile();
1730     color("red")  HingeBaseProfile();
1731     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1732   }
1733
1734   for (f=[0,1]) {
1735     translate([-30, -60 + 30*f]) {
1736       translate([0,0,-4]) EdgeProfile();
1737       %translate([0,0,-10]) HingeBaseProfile();
1738       translate([0,-2] * f * hp_k) {
1739         translate([0,0,-4]) LidEdgeProfile();
1740         %translate([0,0,-10]) %HingeLidProfile();
1741       }
1742       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1743         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1744         translate([0,0,0]) color("red") difference(){
1745           HingeLeverOuterProfile();
1746           HingeLeverInnerProfile();
1747         }
1748         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1749       }
1750     }
1751   }
1752
1753   translate([20,-30]) {
1754     %EdgeProfile();
1755     %LidEdgeProfile();
1756     //translate([0,0,1]) CatchCutProfile();
1757     translate([0,0,+1]) color("red")
1758       difference(){ EdgeProfile(); CatchCutProfile(); }
1759   }
1760
1761   translate([40,-30]) {
1762     difference(){
1763       LidEdgeProfile();
1764       translate(prlp10)
1765         PropProfile(10, 1, 0);
1766     }
1767     translate(prlp10)
1768       PropProfile(15, 0);
1769   }
1770   translate([60,-30]) {
1771     PropAggregateProfile();
1772   }
1773 }
1774
1775 //EdgeProfile();
1776 //KeeperProfile();
1777 //CaseBase();
1778 //%Case();
1779 //Keeper();
1780 //LidEdgeProfile();
1781 //KeeperProfile();
1782 //DemoProfiles();
1783 //PropRecess();