fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 lanyard_half_dia = 1.0;
 171
 172 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 173 rearspeaker_size   = [  3.76,  7.36 ];
 174
 175 microusb_above = 3.27 - 0.25;
 176 microusb_below = 0.0;
 177 microusb_width = 16.12 + 1.25;
 178
 179 case_th_bottom = 2.5;
 180 case_th_lid = 3.0;
 181 case_th_side = 2.3;
 182 case_th_lip = 1.2;
 183
 184 lid_screen_gap_extra = .66;
 185
 186 case_struts_count = 6;
 187 case_struts_solid_below = 1.00;
 188 case_struts_solid_above = 0.75;
 189 case_struts_width = 0.10;
 190
 191 keeper_th_z = 0.75;
 192 keeper_th_x = 0.75;
 193 keeper_inner_width = 2.75;
 194 keeper_inner_height = 2.75;
 195 keeper_slant_slope = 2; // larger means steeper
 196
 197 keeper_gap_z_top = 0.25;
 198 keeper_gap_z_bot = 0.75;
 199 keeper_gap_x     = 0.25;
 200 keeper_gap_x_holes = 0.75;
 201
 202 keeper_side = 0; // 0 = lhs; 1 = rhs
 203
 204 case_lip = 1.25;
 205
 206 lid_gap_x = 0.25;
 207 lid_gap_z = 0.25;
 208 lid_lip = 1.75;
 209 lid_edgepart_width = 5.0;
 210 lid_buttoncover_thick = 1.3;
 211
 212 catch_slop = 0.50;
 213
 214 foldover_gap = 0.50;
 215 foldover_lever_gap = 0.50;
 216
 217 // properties of the hinge fasteners
 218 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 219 hingescrew_shaft_len = 12;
 220 hingescrew_fasteners_extra_thick = 0.40;
 221 // ^ amount of thread protruding if everything was completely nominal
 222 //   and we are using two nuts
 223 hingescrew_nut_access_dia = 4.72 + 0.50;
 224 // ^ washer is 4.72 dia
 225 //   also, want to get pliers or tiny spanner in to do up locknut
 226 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 227 hingescrew_nut_thick = 1.93;
 228 hingescrew_head_th = 1.38 + 0.75;
 229 hingescrew_head_dia = 3.92;
 230
 231 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 232
 233 lever_cover_th = 0.75;
 234 hingemount_th = 2.5;
 235 hingemount_wd = 4.8725;
 236
 237 $fa = 5;
 238 $fs = 0.1;
 239
 240 button_l_fudge = 4.4;
 241 buttonishleg_default_l_is_fudge = 10;
 242
 243 hinge_base_slope = 1.5; // bigger is steeper
 244
 245 strut_min_at_end = 1.5;
 246
 247 hinge_x_gap = 0.125;
 248 hinge_x_postscrew_gap = 0.75;
 249 hinge_x_arms_gap = 0.35;
 250 hinge_r_arms_gap = 0.55;
 251
 252 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 253
 254 catch_len = 7.5;
 255 catch_width = 15;
 256 catch_thickness = 1.0;
 257 catch_side_gap = 0.75; // each side
 258
 259 catch_depth = 0.75;
 260 catch_height = 0.35;
 261 catch_finger_height = 1.5;
 262 catch_finger_depth = 2.5;
 263
 264 catch_topcurve_r = 5.0;
 265
 266 prop_recess_under = 0.50;
 267 prop_recess_slop = 0.200; // each side
 268 prop_end_dia = 0.5;
 269 prop_main_th = 3;
 270 prop_taper_len = 6;
 271 prop_main_width = 4;
 272 prop_side_gap = 0.75; // each side
 273 prop_lidrecess_behind = 0.75;
 274 prop_caserecess_behind = 0.75;
 275 prop_caserecess_taper = 0.45; // one side only
 276 prop_prop_gap = 0.5;
 277 prop_prong_heel_slope = 0.5;
 278
 279 lid_fold_clearance_antislop = 0.5;
 280
 281 // ---------- calculated ----------
 282
 283 phone_width =  (phone + bumper*2)[0];
 284 phone_height = (phone + bumper*2)[1];
 285
 286 inside_br = [phone_width, -phone_height];
 287
 288 prop_prong_h = prop_main_th;
 289
 290 //echo(camera_pos_tl + bumper,
 291 //     camera_pos_br + bumper);
 292
 293 // ----- could be changed -----
 294 lid_buttoncover_gap = lid_gap_x;
 295 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 296
 297 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 298
 299 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 300
 301 //prop_nose_len = case_th_lid - prop_recess_under;
 302 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 303 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 304
 305
 306 //lid_lip_overlap_width xxx bad name = ;
 307 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 308
 309 epp0 = [0,0];
 310 epp1 = [0, -phone_edge_thick];
 311 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 312 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 313 epp3 = epp2i + [10, 0];
 314 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 315 epp4 = epp5 + [-1,0] * case_th_side;
 316
 317 kppe = [0,0];
 318 kppd = kppe + [1,0] * keeper_inner_width;
 319 kppc = kppd + [0,1] * keeper_th_z;
 320 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 321 kppf = kppe - [0,1] * keeper_inner_height;
 322 kppa = [ kppb[0], kppf[1] ];
 323
 324 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 325 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 326
 327 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 328 // exact x posn not very important; must extend past end of keeper
 329
 330 lpp15 = [ lpp14[0],
 331           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 332           + lid_screen_gap_extra ];
 333 // ^ beam theory says to maximise force before contact,
 334 //   the gap below the `beam' (the lid) must be 1/3
 335 //   the thickness (ie the lid thickness) if the beam
 336 //   is solid, or 1/2 if it has a top and bottom only.
 337 //   ours is mostly solid.
 338
 339 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 340              case_th_lip);
 341
 342 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 343 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 344
 345 case_bottom_z = epp2o[1] - case_th_bottom;
 346
 347 // button profile
 348 bppM = epp4 + [0,5];
 349 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 350 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 351 bppS = [ epp1[0], bppR[1] ];
 352 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 353 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 354 bppO = [ bppN[0], bppP[1] ];
 355 bppL = lpp10 + [5,0];
 356 bppK = [ bppL[0], bppN[1] ];
 357 bppJ = [ bppN[0], bppL[1] ];
 358 bppU = [ bppJ[0], lpp12[1] ];
 359 bppV = lpp11;
 360 bppW = lpp10;
 361
 362 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 363
 364 // notification led aperture
 365
 366 nla_r0 = led_aperture/2;
 367 nla_r1 = nla_r0 + led_window_ledge;
 368 nla_r2 = nla_r1 + multicolour_gap;
 369 nla_t =
 370   led_window_style >= 3 ? initial_layer_thick :
 371   led_window_style >= 2 ? led_window_ledge : 0;
 372
 373
 374 // hinge plan
 375 hp_rn = hingescrew_nut_access_dia/2;
 376 hp_r2_min = hp_rn + lever_cover_th;
 377 hp_rs = hingescrew_shaft_dia/2;
 378 hp_r1_min = hp_rs + hingemount_th;
 379
 380 hp_r1 = max(hp_r1_min, hp_r2_min);
 381 hp_r2 = hp_r1;
 382
 383 hppU = lpp13;
 384 hppS = epp2o + [0,-1] * case_th_bottom;
 385 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 386
 387 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 388          0.5 * (hppU + hppS)[1] ];
 389 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 390 hppB = hppT + [0,-1] * hp_k;
 391
 392 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 393 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 394 hppE = [ hppE_x, hppE_y ];
 395
 396 // hinge elevation x coords
 397
 398 hex20 = max(epp2o[0],
 399             phone_cnr_rad,
 400             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 401 hex21 = hex20 + hingemount_wd;
 402 hex22 = hex21 + hinge_x_gap;
 403 hex27 = hex20 + hingescrew_shaft_len;
 404 hex24 = hex27 + hinge_x_postscrew_gap;
 405 hex23 = hex27 - (hingescrew_nut_thick*2
 406                  + hingescrew_fasteners_extra_thick);
 407 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 408
 409 echo(hex20, hex21, hex22, hex23, hex24);
 410 //  6, 10.8725, 10.9975, 13.74, 18.75
 411 module chk(act,exp) {
 412   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 413   else echo("ok", act);
 414 }
 415 chk(hex20, 6);
 416 chk(hex21, 10.8725);
 417 chk(hex22, 10.9975);
 418 chk(hex23, 13.74);
 419 chk(hex24, 18.75);
 420
 421 lid_fold_clearance_skew =
 422   (lpp10[1] - hppB[1]) /
 423   (lpp10[0] - hppB[0]);
 424
 425 echo("SK",lid_fold_clearance_skew);
 426
 427 // catch
 428
 429 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 430 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 431 cppB = [ epp0[0], cppA[1] ];
 432 cppP = [ epp4[0], cppJ[1] ];
 433
 434 cppS = cppJ + [0,-1] * catch_len;
 435 cppD = [ cppA[0], cppS[1] + catch_slop ];
 436 cppC = [ cppB[0], cppD[1] ];
 437 cppT = cppS + [1,0] * catch_depth;
 438 cppU = cppT + [0,-1] * catch_height;
 439 cppV = [ cppS[0], cppU[1] - catch_depth ];
 440
 441 cppR = 0.5*(cppP + cppJ);
 442
 443 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 444 cppQ = [ cppR[0],
 445          cppV[1] - (catch_finger_height - cp_rQ) ];
 446 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 447
 448 // prop recess in case
 449
 450 prop_x_pos = phone_width/2;
 451
 452 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 453
 454 prc_r1 = prop_end_dia/2;
 455 prc_r3 = prc_r1 + prop_recess_slop;
 456
 457 prcp2 = [ epp4[0] + prop_buildout_less,
 458           case_bottom_z ];
 459
 460 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 461
 462 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 463           epp2i[1] - prc_r3 - prop_recess_under];
 464
 465 // prop recess in lid
 466
 467 prl_r10 = prop_end_dia/2;
 468 prl_r10o = prl_r10 + prop_recess_slop;
 469
 470 prlp10 = lpp10 + [1,1] * prl_r10o
 471   + [1,0] * prop_lidrecess_behind
 472   + [0,1] * prop_recess_under;
 473
 474 // prop
 475
 476 $prpp10 = [0,0];
 477 $prpp11 = [0, prop_taper_len];
 478
 479 $prp_r10 = prl_r10;
 480
 481 // ---------- modules ----------
 482
 483 module AdhocMultiprintFrame(phase, z0, zs) {
 484   // from z0 to z0 + zs*layer
 485   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 486   xextra = extra + -epp4[0];
 487   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 488   yextra = extra + -epp4[0];
 489   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 490   p0 = [ xrange[0], yrange[0] ];
 491   p1 = [ xrange[1], yrange[1] ];
 492   echo(p0, p1);
 493   translate([0,0, z0])
 494     mirror([0,0, zs<0 ? 1 : 0])
 495     linear_extrude(height= initial_layer_thick)
 496     difference(){
 497       rectfromto(p0 - [1,1] * initial_layer_width,
 498                  p1 + [1,1] * initial_layer_width);
 499       rectfromto(p0, p1);
 500     }
 501 }
 502
 503 module KeeperProfile(slant=0){
 504   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 505   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 506 }
 507
 508 module EdgeProfile(){
 509   difference(){
 510     hull(){
 511       translate(epp3) square(case_th_bottom*2, center=true);
 512       circleat(epp2o, r=case_th_bottom);
 513       circleat(epp1, r=case_th_side);
 514       rectfromto(epp0, epp4);
 515     }
 516     polygon([ epp5 + [0,10],
 517               epp1,
 518               epp2i,
 519               epp3 + [10,0] ]);
 520   }
 521 }
 522
 523 module LanyardLanyardProfile(){
 524   hull(){
 525     for (xs=[-1,+1])
 526       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 527         circle(r= lanyard_half_dia/2);
 528   }
 529 }
 530
 531 module LidEdgeProfile(){
 532   polygon([ lpp10,
 533             lpp11,
 534             lpp12,
 535             lpp13,
 536             lpp13 + [10, 0],
 537             lpp15 + [10, 0],
 538             lpp15,
 539             lpp14,
 540             ]);
 541   intersection(){
 542     circleat(lpp12, r=lp_r12);
 543     rectfromto( lpp12 + [-10,   0],
 544                 lpp12 + [+10, +10] );
 545   }
 546 }
 547
 548 module LidEdgeFoldClearanceProfile(){
 549   translate([-lid_fold_clearance_antislop, 0])
 550     polygon([ lpp10,
 551               lpp11,
 552               lpp11 + [-20,  0],
 553               lpp11 + [-20, 20],
 554               lpp11 + [+20, 20],
 555               lpp10 + [+20,  0] ]);
 556 }
 557
 558 module ButtonCoverProfile(){
 559   intersection(){
 560     polygon(concat([ bppM, bppP, bppO, bppJ ],
 561                    (enable_support && !$button_suppress_over_keeper
 562                     ? [ bppU, bppV, bppW ] : []),
 563                    [ bppL, bppK ]));
 564     hull(){
 565       EdgeProfile();
 566       LidEdgeProfile();
 567     }
 568   }
 569 }
 570
 571 module ButtonPlan(l, deep, cut){
 572   epsilon =
 573     (cut  ? 0 : lid_buttoncover_gap);
 574
 575   delta =
 576     (deep ? lid_buttoncover_overlap : 0);
 577
 578   C = [0,0]; // by definition
 579   T = [ 0, epp4[1] ];
 580   G = T + [0,10];
 581
 582   B0 = C + [0,-1] * button_cutout_depth;
 583   B1 = B0 + [0,1] * epsilon;
 584
 585   r0 = 0.5 * (T[1] - B0[1]);
 586   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 587   H = A + [0,-1] * delta;
 588
 589   D = A + [-2,0] * r0;
 590   F = D + [0,10];
 591
 592   E0 = 0.5 * (D + A);
 593   E1 = E0 + [1,0] * epsilon;
 594
 595   I0 = [ E0[0], H[1] ];
 596   I1 = [ E1[0], H[1] ];
 597
 598   hull(){
 599     for (m=[0,1]) mirror([m,0])
 600       circleat(H, r0 - epsilon);
 601   }
 602   for (m=[0,1]) mirror([m,0]) {
 603     difference(){
 604       polygon([ E1,
 605                 I1,
 606                 H,
 607                 B1,
 608                 G,
 609                 F,
 610                 D
 611                 ]);
 612       circleat(D, r0 + epsilon);
 613     }
 614   }
 615 }
 616
 617 module CatchCatchProfile(){
 618   hull(){
 619     for (c=[ cppR, cppQ ])
 620       circleat(c, cp_rQ);
 621   }
 622   hull(){
 623     circleat(lpp12, lp_r12);
 624     circleat(lpp12 + [5,0], lp_r12);
 625     rectfromto(cppP, cppP + [5,0.1]);
 626   }
 627   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 628 }
 629
 630 module CatchCutProfile(){
 631   polygon([ cppB,
 632             cppA,
 633             cppD,
 634             cppF,
 635             cppF + [0,-10],
 636             cppF + [-10,-10],
 637             lpp12 + [-10,0],
 638             lpp12 + [10,0]
 639             ]);
 640 }
 641
 642 module Flip_rhs(yn=[0,1]) {
 643   for ($rhsflip=yn) {
 644     translate([phone_width/2, 0, 0])
 645       mirror([$rhsflip,0,0])
 646       translate([-phone_width/2, 0, 0])
 647       children();
 648   }
 649 }
 650
 651 module Flip_bot(yn=[0,1]) {
 652   for ($botflip=yn) {
 653     translate([0, -phone_height/2, 0])
 654       mirror([0, $botflip, 0])
 655       translate([0, phone_height/2, 0])
 656       children();
 657   }
 658 }
 659
 660 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 661   // sides
 662   Flip_rhs(){
 663     translate([0, -phone_cnr_rad, 0])
 664       rotate([90,0,0])
 665       linear_extrude(height = phone_height - phone_cnr_rad*2)
 666       children(0);
 667   }
 668   // corners
 669   Flip_rhs() Flip_bot() {
 670     translate([+1,-1] * phone_cnr_rad)
 671       intersection(){
 672         rotate_extrude()
 673           intersection(){
 674             mirror([1,0,0])
 675               translate([-1,0] * phone_cnr_rad)
 676               children(0);
 677             rectfromto([0,-20],[10,20]);
 678           }
 679         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 680           cube([10,10,40]);
 681       }
 682   }
 683   // top and bottom
 684   Flip_bot(){
 685     translate([ phone_width - phone_cnr_rad, 0,0 ])
 686       rotate([90,0,-90])
 687       linear_extrude(height = phone_width - phone_cnr_rad*2)
 688       children(0);
 689   }
 690   // fill
 691   translate([0,0, fill_zstart])
 692     mirror([0,0, fill_downwards])
 693     linear_extrude(height = fill_th)
 694     rectfromto([+1,-1] * phone_cnr_rad,
 695                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 696 }
 697
 698 module CaseAperture(pos, dia, $fn) {
 699   theta = 180/$fn;
 700   translate([ pos[0] + bumper[0],
 701               -epp2i[0],
 702               -pos[1] ])
 703     rotate([-90, theta, 0])
 704     cylinder(r = dia/2 / cos(theta),
 705              h = 60);
 706 }
 707
 708 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 709   // y_ref_sign:
 710   //   +1  measured from top    of actual phone to top    of button
 711   //   -1  measured from bottom of actual phone to bottom of button
 712   //    0  y is centre of button in coordinate system
 713   $button_l= l;
 714   $button_suppress_over_keeper= suppress_over_keeper;
 715   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 716           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 717           y;
 718   //echo(eff_y);
 719   translate([0, eff_y, 0])
 720     children();
 721 }
 722
 723 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 724   $button_leg_only = true;
 725   SideButton(y, y_ref_sign, l) children();
 726 }
 727
 728 module Buttons(){
 729   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 730   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 731   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 732   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 733 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 734 }
 735
 736 module Struts(x_start, z_min, th){
 737   // if th is negative, starts at z_min and works towards -ve z
 738   // and object should then be printed other way up
 739   for (i= [1 : 1 : case_struts_count]) {
 740     translate([0,
 741                0,
 742                z_min])
 743       mirror([0,0, th<0 ? 1 : 0])
 744       translate([0,
 745                  -phone_height * i / (case_struts_count+1),
 746                  case_struts_solid_below])
 747       linear_extrude(height= abs(th)
 748                      -(case_struts_solid_below+case_struts_solid_above))
 749       rectfromto([               x_start, -0.5 * case_struts_width ],
 750                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 751   }
 752 }
 753
 754 module OrdinaryRearAperture(rhs,bot, pos){
 755   Flip_rhs(rhs) Flip_bot(bot)
 756     linextr(-20, 20)
 757     mirror([0,1])
 758     translate(pos + bumper)
 759     children();
 760 }
 761
 762 module MicroUSB(){
 763   Flip_bot(1){
 764     rotate([90,0,0])
 765       mirror([0,0,1])
 766       linextr(-epp2i[0], 60)
 767       translate([0.5 * phone_width, 0, 0])
 768       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 769                  [+microusb_width/2, epp0[1] + -microusb_above]);
 770   }
 771 }
 772
 773 module OrdinaryRearApertures(){
 774   // rear speaker
 775   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 776     rectfromto(-rearspeaker_gap,
 777                rearspeaker_size + rearspeaker_gap);
 778
 779   // finger hole to remove phone
 780   if (len(fingerpushhole_dias))
 781     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 782                                 phone[1]/2 ])
 783     scale(fingerpushhole_dias)
 784     circle(r= 0.5 );
 785 }
 786
 787 module RearCameraAperture(){
 788   Flip_rhs(1)
 789     mirror([0, 0, 1])
 790     linear_extrude(height = 20)
 791     mirror([0, 1, 0])
 792     translate(bumper)
 793     rectfromto(camera_pos_tl, camera_pos_br);
 794 }
 795
 796 module HingeLidProfile(){
 797   hull(){
 798     circleat(hppT, hp_r1);
 799     circleat(lpp12, lp_r12);
 800     polygon([lpp10,
 801              lpp13 + [2,0],
 802              lpp12,
 803              hppT]);
 804   }
 805 }
 806
 807 module HingeBaseProfile(){
 808   difference(){
 809     hull(){
 810       circleat(hppB, hp_r1);
 811       circleat(hppE, hp_r1);
 812       circleat(epp2o, case_th_bottom);
 813       circleat(hppB + [10,0], hp_r1);
 814     }
 815     polygon([epp5, epp1, epp2i, epp3, bppL]);
 816   }
 817 }
 818
 819 module HingeLeverOuterProfile(){
 820   hull(){
 821     circleat(hppT, hp_r2);
 822     circleat(hppB, hp_r2);
 823   }
 824 }
 825
 826 module HingeLeverInnerProfile(){
 827   for (s = [-1,+1]) {
 828     c = s > 0 ? hppT : hppB;
 829     translate(c)
 830       mirror([0,0,s>0])
 831       rotate(s<0 ? -40 : 0)
 832       hull()
 833       for (x=[-20,20])
 834         for (y=[0, s * 10])
 835           translate([x,y])
 836             circle(hp_rn);
 837   }
 838 }
 839
 840 module HingeLeverNutProfile(){
 841   for (c= [hppB, hppT]) {
 842     translate(c)
 843       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 844   }
 845 }
 846
 847 module Flip_hinge(doflip=1){
 848   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 849   translate(hinge_origin)
 850     rotate([doflip*180,0,0])
 851     translate(-hinge_origin)
 852     children();
 853 }
 854
 855 module HingePortion(x0,x1){
 856   Flip_rhs() Flip_bot(1)
 857     translate([x0,0,0])
 858     mirror([1,0,0])
 859     rotate([90,0,-90])
 860     linear_extrude(height=x1-x0)
 861     children();
 862 }
 863
 864 module CatchPortion(xwidth, ztop){
 865   width = catch_width + xwidth;
 866   w = width + catch_topcurve_r*2 + 1;
 867   translate([phone_width/2, 0,0]){
 868     difference(){
 869       rotate([90,0,-90])
 870         linextr(-w/2, w/2)
 871         children(0);
 872       translate([0, 50, 0])
 873         rotate([90,0,0])
 874         linear_extrude(height=100){
 875         for (m=[0,1]) mirror([m,0,0]) {
 876           hull(){
 877             translate([w/2, ztop - catch_topcurve_r])
 878               circle(catch_topcurve_r);
 879             translate([w/2, -50])
 880               square(catch_topcurve_r*2, center=true);
 881           }
 882         }
 883       }
 884     }
 885   }
 886 }
 887
 888 module CaseBase(){
 889   AroundEdges(epp3[1], case_th_bottom, 1)
 890     EdgeProfile();
 891 }
 892
 893 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 894
 895 module PropProfileAssignments(gamma){
 896   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 897   x = prop_x(gamma);
 898   p = phone_height + prlp10[0] - hppB[0];
 899   b = p + x;
 900
 901   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 902   a = q + x;
 903   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 904   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 905
 906   $prp_theta = 90 - $prp_alpha;
 907   beta = 180 - $prp_alpha - gamma;
 908   psi = 90 - beta;
 909
 910   //echo("abc", a,b,c);
 911
 912   v1 = [ [ cos(psi), -sin(psi) ],    // x
 913          [ sin(psi),  cos(psi) ] ];  // y
 914
 915   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 916
 917   $prp_r1 = prc_r1;
 918   $prp_r11 = prop_main_th/2;
 919
 920   $prpp1 = $prpp7 + [1,0] *
 921     // this is approximate, but will do
 922     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 923   $prpp3 = $prpp1 +
 924     v1[0] * -$prp_r1 +
 925     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 926   $prpp12 = $prpp3 + v1[0] *
 927     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 928   $prp_r8 = prop_main_th;
 929   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 930   $prp_r5 = $prp_r8;
 931   $prpp5 = [ $prpp12[0] - $prp_r5,
 932             $prpp3[1] - prop_prong_h + $prp_r5 ];
 933   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 934          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 935   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 936   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 937
 938   children();
 939 }
 940
 941 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 942   PropProfileAssignments(gamma){
 943
 944     //#circleat($prpp3,1);
 945     //#circleat($prpp12,1);
 946
 947     if (!cut) {
 948       hull(){
 949         translate($prpp8)
 950           intersection(){
 951             circle($prp_r8);
 952             polygon([[-20,-0], [20,20], [0,0]]);
 953           }
 954         rectfromto($prpp6, $prpp9);
 955         translate($prpp5) intersection(){
 956           circle($prp_r5);
 957           polygon([[-10,-10], [0,0], [10,0]]);
 958         }
 959         rectfromto($prpp12 + [0,-0.1], $prpp3);
 960       }
 961       hull(){
 962         circleat($prpp1, $prp_r1);
 963         rectfromto($prpp12 + [0,-0.1], $prpp3);
 964       }
 965     }
 966     // main shaft
 967     rotate([0,0, rot*-$prp_theta]){
 968       hull(){
 969         extra = cut ? prop_recess_slop : 0;
 970         rectfromto($prpp6, $prpp9);
 971         circleat($prpp11, $prp_r11 + extra);
 972         circleat($prpp10, $prp_r10 + extra);
 973       }
 974     }
 975   }
 976 }
 977
 978 module PropAggregateProfile(){
 979   for (angle = prop_angles)
 980     PropProfile(angle, 0,0);
 981 }
 982
 983 module Prop(){ ////toplevel
 984   hw = prop_main_width/2;
 985   linextr(-hw, +hw)
 986     PropAggregateProfile();
 987 }
 988
 989 module Case(){ ////toplevel
 990   difference(){
 991     union(){
 992       CaseBase();
 993
 994       // ledge (fixed keeper)
 995       Flip_rhs(1-keeper_side) intersection(){
 996         rotate([90, 0, 0])
 997           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 998           KeeperProfile(1);
 999
1000         // outline of the whole case, to stop it protruding
1001         translate([0,0, -25])
1002           linear_extrude(height = 50)
1003           hull()
1004           Flip_bot()
1005           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1006       }
1007
1008       // hinge
1009       HingePortion(hex20, hex21) HingeBaseProfile();
1010
1011       // buildout for prop recess
1012       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1013         linextr(case_bottom_z, epp2i[1])
1014         hull() {
1015           for (dxs = [-1,+1])
1016             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1017                        -epp2o[0] ],
1018                      r = epp2o[0] - prcp2[0]);
1019         }
1020     }
1021
1022     // slot for keeper
1023     Flip_rhs(keeper_side)
1024       translate([0, -phone_cnr_rad, 0])
1025       rotate([90, 0, 0])
1026       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1027       minkowski(){
1028         KeeperProfile();
1029         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1030                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1031       }
1032
1033     // front camera
1034     RearCameraAperture();
1035
1036     // struts (invisible, because they're buried in the case)
1037     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1038
1039     Buttons(){
1040       mirror([1,0,0])
1041         rotate([90,0,90]) {
1042           if (!($button_leg_only && enable_support))
1043           intersection(){
1044             translate([0,0,-10])
1045               linear_extrude(height= 20)
1046               ButtonPlan($button_l, 0,1);
1047             if ($button_leg_only)
1048               rotate([-90,90,0])
1049                 translate([phone_width/2, -400, kppe[1]])
1050                 mirror([1-abs($rhsflip - keeper_side),0,0])
1051                 cube([400, 800, 50]);
1052             if (enable_support && !$button_suppress_over_keeper)
1053               rotate([-90,90,0])
1054               translate([-400, -400, kppd[1]])
1055                 mirror([0,0,1])
1056                 cube([800,800,100]);
1057           }
1058           translate([0,0, -bppR[0]])
1059             linear_extrude(height= 20)
1060             ButtonPlan($button_l, 1,1);
1061         }
1062
1063     }
1064
1065     // apertures along top edge
1066     CaseAperture(jack_pos, jack_dia, 8);
1067     Flip_rhs(1)
1068       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1069
1070     OrdinaryRearApertures();
1071
1072     MicroUSB();
1073
1074     // gaps for the lid's hinge arms
1075     HingePortion(hex20 - hinge_x_arms_gap,
1076                  hex21 + hinge_x_arms_gap)
1077       minkowski(){
1078         HingeLidProfile();
1079         circle(r= hinge_r_arms_gap, $fn= 8);
1080       }
1081
1082     // screw holes in the hinge arms
1083     HingeScrews();
1084
1085     // catch striker
1086     CatchPortion(catch_side_gap*2, epp4[1])
1087       CatchCutProfile();
1088
1089     // prop recess
1090     Flip_rhs(1)
1091       translate([prop_x_pos,0,0])
1092       mirror([0,1,0])
1093       rotate([90,0,90])
1094       linextr(-prop_recess_hw, +prop_recess_hw)
1095       hull(){
1096         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1097           circleat(prcp1 + 20*d,
1098                    prc_r3);
1099       }
1100   }
1101 }
1102
1103 module LidAdhocMultiprintFrame(phase){
1104   if (led_window_style >= 3) {
1105     AdhocMultiprintFrame(phase, lpp13[1], -1);
1106   }
1107 }
1108
1109 module LidAroundEdges(){
1110   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1111     children();
1112 }
1113
1114 module Lid(){ ////toplevel
1115   skew_centre = [0, lpp11[0], lpp11[1]];
1116   difference(){
1117     union(){
1118       intersection(){
1119         LidAroundEdges()
1120           LidEdgeProfile();
1121
1122         translate(skew_centre)
1123           multmatrix([[ 1, 0, 0, 0 ],
1124                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1125                       [ 0, 0, 1, 0 ],
1126                       [ 0, 0, 0, 1 ]])
1127           translate(-skew_centre)
1128           LidAroundEdges()
1129           LidEdgeFoldClearanceProfile();
1130       }
1131
1132       // button covers
1133       Buttons(){
1134         intersection(){
1135           rotate([90,0,90])
1136             translate([0,0,-10])
1137             linear_extrude(height= 20)
1138             ButtonPlan($button_l, 1,0);
1139           rotate([90,0,0])
1140              translate([0,0,-100])
1141             linear_extrude(height= 200)
1142             ButtonCoverProfile();
1143         }
1144       }
1145
1146       // hinge arms
1147       HingePortion(hex20, hex21) {
1148         LidEdgeProfile();
1149         HingeLidProfile();
1150       }
1151
1152       // catch
1153       CatchPortion(0, lpp12[1])
1154         CatchCatchProfile();
1155     }
1156     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1157
1158     // screw holes in the hinge arms
1159     HingeScrews();
1160
1161     // prop recess
1162     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1163       mirror([0,1,0])
1164       rotate([90,0,90])
1165       linextr(-prop_recess_hw, +prop_recess_hw)
1166       hull()
1167       for (pa = prop_angles)
1168         PropProfile(pa, 1,1);
1169
1170     // notification led aperture
1171     if (led_window_style)
1172       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1173         translate([0,0,-10])
1174           cylinder(r=nla_r0, h=20);
1175         if (led_window_style >= 2)
1176           translate([0,0, -nla_t])
1177             cylinder(r=nla_r2, height=20);
1178       }
1179
1180     }
1181
1182   LidAdhocMultiprintFrame(1);
1183 }
1184
1185 module HingeLever(){ ////toplevel
1186   difference() {
1187     // outer body, positive
1188     HingePortion(hex22, hex22 + phone_width/2)
1189       HingeLeverOuterProfile();
1190
1191     // space for the screws
1192     HingePortion(hex26, hex24)
1193       HingeLeverInnerProfile();
1194
1195     // recesses for the nuts
1196     HingePortion(hex23, hex26+1)
1197       HingeLeverNutProfile();
1198
1199     // bores for the screws
1200     HingeScrews();
1201
1202     // space for the charging cable
1203     MicroUSB();
1204     Flip_hinge() MicroUSB();
1205   }
1206 }
1207
1208 module LidWindow(){ ////toplevel
1209   translate([led_pos[0], -led_pos[1], lpp13[1]])
1210     mirror([0,0,1])
1211     cylinder(r= nla_r1, h=nla_t);
1212   LidAdhocMultiprintFrame(0);
1213 }
1214
1215 module LidWindowPrint(){ ////toplevel
1216   rotate([0,180,0])
1217     LidWindow();
1218 }
1219
1220 module DemoLidWindowSelect(){
1221   translate([led_pos[0], led_pos[1], -100]) {
1222     translate([0, -30, 0]) cube([400, 400, 200]);
1223   }
1224 }
1225
1226 module DemoLidWindow(){ ////toplevel
1227   %Lid();
1228   LidWindow();
1229   translate([0,40,0]){
1230     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1231     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1232   }
1233 }
1234
1235 module HingeLeverPrint(){ ////toplevel
1236   rotate([-90,0,0])
1237     translate([-phone_width/2, phone_height, 0])
1238     HingeLever();
1239 }
1240
1241 module TestSelectLength(){
1242   translate([-30, -200, -20])
1243     cube([30 + 15, 250, 40]);
1244 }
1245
1246 module TestLength(){ ////toplevel
1247   intersection(){
1248     Case();
1249     TestSelectLength();
1250   }
1251 }
1252
1253 module TestLengthRight(){ ////toplevel
1254   intersection(){
1255     Case();
1256     Flip_rhs(1)
1257       TestSelectLength();
1258   }
1259 }
1260
1261 module TestSelectWidth(){
1262   translate([-30, -(phone_height - 25), -20])
1263     mirror([0, 1, 0])
1264     cube([200, 50, 40]);
1265 }
1266
1267 module TestWidth(){ ////toplevel
1268   intersection(){
1269     Case();
1270     TestSelectWidth();
1271   }
1272 }
1273
1274 module TestLidWidthPrint(){ ////toplevel
1275   rotate([0,180.0]) intersection(){
1276     Lid();
1277     TestSelectWidth();
1278   }
1279 }
1280
1281 module TestSelectRearAperture(){
1282   minkowski(){
1283     union() children();
1284     translate([20, 0,0])
1285       cube([42, 2, 1], center=true);
1286   }
1287 }
1288
1289 module TestSelectCamera(){
1290   minkowski(){
1291     TestSelectRearAperture()
1292       RearCameraAperture();
1293     cube([0.1, 50, 0.1]);
1294   }
1295 }
1296
1297 module TestSelectOrdinaryRearApertures(){
1298   TestSelectRearAperture()
1299     OrdinaryRearApertures();
1300 }
1301
1302 module TestCamera(){ ////toplevel
1303   intersection(){
1304     Case();
1305     TestSelectCamera();
1306   }
1307 }
1308
1309 module TestLidByCamera(){ ////toplevel
1310   intersection(){
1311     Lid();
1312     TestSelectCamera();
1313   }
1314 }
1315
1316 module TestLidByCameraPrint(){ ////toplevel
1317   rotate([180,0,0]) TestLidByCamera();
1318 }
1319
1320 module DemoByCamera(){ ////toplevel
1321   color("blue") TestLidByCamera();
1322   color("red")  TestCamera();
1323 }
1324
1325 module OneKeeper(){ ////toplevel
1326   translate([0, -phone_cnr_rad, 0])
1327     rotate([90, 0, 0])
1328     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1329     KeeperProfile();
1330 }
1331
1332 module OneKeeperPrint(){ ////toplevel
1333   rotate([0,180,0])
1334     OneKeeper();
1335 }
1336
1337 module LidPrint(){ ////toplevel
1338   rotate([0,180,0])
1339     Lid();
1340 }
1341
1342 module TestSelectFrame(){
1343   include = [1,-1] * (epp2i[0] + 4);
1344
1345   difference(){
1346     cube(1000, center=true);
1347     translate([0,0, -100])
1348       linear_extrude(height=200)
1349       rectfromto(include,  inside_br - include);
1350   }
1351 }
1352
1353 module TestSelectLidFrame(){
1354   TestSelectFrame();
1355   translate([led_pos[0], -led_pos[1], -50])
1356     cylinder(r= nla_r2+3, h=100);
1357 }
1358
1359 module TestFrameCase(){ ////toplevel
1360   intersection(){
1361     Case();
1362     union(){
1363       TestSelectFrame();
1364       TestSelectCamera();
1365       TestSelectOrdinaryRearApertures();
1366     }
1367   }
1368 }
1369
1370 module TestSelectTopApertures(){
1371   translate([-100, -35, -100])
1372     cube([400, 100, 200]);
1373   LidAdhocMultiprintFrame(0);
1374   LidAdhocMultiprintFrame(1);
1375 }
1376
1377 module TestTopApertures(){ ////toplevel
1378   intersection(){
1379     Case();
1380     TestSelectFrame();
1381     TestSelectTopApertures();
1382   }
1383 }
1384
1385 module TestLidTopAperturesPrint(){ ////toplevel
1386   rotate([0,180,0]) intersection(){
1387     Lid();
1388     TestSelectLidFrame();
1389     TestSelectTopApertures();
1390   }
1391 }
1392
1393 module TestLidWindowTopAperturesPrint(){ ////toplevel
1394   rotate([0,180,0]) intersection(){
1395     LidWindow();
1396     TestSelectTopApertures();
1397   }
1398 }
1399
1400 module TestFrameLidPrint(){ ////toplevel
1401   rotate([0,180,0]) intersection(){
1402     Lid();
1403     TestSelectLidFrame();
1404   }
1405 }
1406
1407 module ButtonPlanForDemo(z, deep, cut){
1408   translate([0,0,z])
1409     ButtonPlan(8, deep, cut);
1410 }
1411
1412 module HingeScrews(){
1413   Flip_rhs() Flip_bot(1){
1414     for (c= [ hppT, hppB ])
1415       translate([ hex20,
1416                   -c[0],
1417                   c[1] ]){
1418         rotate([0,90,0])
1419           translate([0,0,-.2])
1420           cylinder( r= hingescrew_shaft_dia/2,
1421                     h = hingescrew_shaft_len+0.2 );
1422         rotate([0,-90,0])
1423           translate([0,0,+.1])
1424           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1425       }
1426   }
1427 }
1428
1429 module DemoPropAngleSelect(c){
1430   color(c) difference(){
1431     union(){ children(); }
1432     translate([ prop_x_pos, -400, -200 ])
1433       cube([ 400,800,400 ]);
1434   }
1435 }
1436
1437 module DemoPropAngle(ang){
1438   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1439   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1440
1441   translate(hL)
1442     rotate([ang/2,0,0])
1443     translate(-hL)
1444     translate(hC)
1445     rotate([ang/2,0,0])
1446     translate(-hC) {
1447       DemoPropAngleSelect("red") Case();
1448
1449       color("orange")
1450         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1451         PropProfileAssignments(ang) {
1452           echo($prpp1);
1453           rotate([-$prp_theta, 0, 0])
1454           translate([0, $prpp1[0], -$prpp1[1]])
1455           rotate([90,0,-90])
1456           Prop();
1457         }
1458     }
1459
1460   translate([0,0, -hp_k*2])
1461     DemoPropAngleSelect("blue")
1462     Lid();
1463 }
1464
1465 module DemoPropAngles(){ ////toplevel
1466   for (i=[0 : len(prop_angles)-1])
1467     translate(i * [0, -100, 100])
1468     DemoPropAngle(prop_angles[i]);
1469 }
1470
1471 module DemoHingeAngle(ang1,ang2){
1472   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1473   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1474
1475   translate(hL)
1476     rotate([ang2,0,0])
1477     translate(-hL)
1478     translate(hC)
1479     rotate([ang1,0,0])
1480     translate(-hC) {
1481       color("red") Lid();
1482     }
1483
1484   color("blue") intersection(){
1485     Case();
1486     union(){
1487       translate([bppJ[0], -400, -200])
1488         mirror([1,0,0])
1489         cube([400, 800, 400]);
1490       translate([10, -400, -200])
1491         cube([10, 800, 400]);
1492     }
1493   }
1494 }
1495
1496 module DemoHingeAngles(){ ////toplevel
1497   angles = [ 0, 4, 8, 12 ];
1498   echo("angles",angles);
1499   for (i=[0 : len(angles)-1]) {
1500     translate(i * [0, 0, 30]) {
1501       DemoHingeAngle(0,angles[i]);
1502       translate([0, 200, 0])
1503         DemoHingeAngle(angles[i],0);
1504     }
1505   }
1506 }
1507
1508 module DemoSelectAdhocLeftRight(right=0) {
1509   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1510     mirror([1-right, 0,0])
1511     cube([400, 800, 200]);
1512 }
1513
1514 module DemoLeft(){ ////toplevel
1515   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1516   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1517 }
1518
1519 module DemoFrame(){ ////toplevel
1520   color("red") TestFrameCase();
1521   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1522   color("black") HingeScrews();
1523   %HingeLever();
1524 }
1525
1526 module DemoHingedFrame(){ ///toplevel
1527   color("red") TestFrameCase();
1528   translate([0,0, -2*hp_k])
1529   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1530
1531   Flip_hinge(){
1532     color("orange") HingeLever();
1533     color("black") HingeScrews();
1534   }
1535 }
1536
1537 module DemoHinge(){ ////toplevel
1538   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1539     DemoFrame();
1540     translate([0,0, -hp_k*3])
1541       DemoHingedFrame();
1542   }
1543 }
1544
1545 module DemoProfiles(){ ////toplevel
1546   LidEdgeProfile();
1547   %EdgeProfile();
1548   KeeperProfile();
1549   translate([0,0,-1]) color("black") KeeperProfile(1);
1550   color("purple") LanyardLanyardProfile();
1551
1552   translate([20,0]) {
1553     LidEdgeProfile();
1554     %EdgeProfile();
1555
1556     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1557
1558     color("blue") ButtonCoverProfile();
1559     color("red") {
1560       rectfromto(bppQ, demopoint_QR);
1561       rectfromto(bppR, demopoint_QR);
1562     }
1563   }
1564
1565   translate([-20,0]) {
1566     color("black") ButtonPlanForDemo(-2, 0,1);
1567     color("red" )  ButtonPlanForDemo(-4, 1,1);
1568     color("blue")  ButtonPlanForDemo(-6, 1,0);
1569   }
1570
1571   translate([0, -30]) {
1572     %LidEdgeProfile();
1573     %EdgeProfile();
1574     color("blue") HingeLidProfile();
1575     color("red")  HingeBaseProfile();
1576     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1577   }
1578
1579   for (f=[0,1]) {
1580     translate([-30, -60 + 30*f]) {
1581       translate([0,0,-4]) EdgeProfile();
1582       %translate([0,0,-10]) HingeBaseProfile();
1583       translate([0,-2] * f * hp_k) {
1584         translate([0,0,-4]) LidEdgeProfile();
1585         %translate([0,0,-10]) %HingeLidProfile();
1586       }
1587       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1588         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1589         translate([0,0,0]) color("red") difference(){
1590           HingeLeverOuterProfile();
1591           HingeLeverInnerProfile();
1592         }
1593         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1594       }
1595     }
1596   }
1597
1598   translate([20,-30]) {
1599     %EdgeProfile();
1600     %LidEdgeProfile();
1601     //translate([0,0,1]) CatchCutProfile();
1602     color("blue") CatchCatchProfile();
1603     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1604   }
1605
1606   translate([40,-30]) {
1607     difference(){
1608       LidEdgeProfile();
1609       translate(prlp10)
1610         PropProfile(10, 1, 0);
1611     }
1612     translate(prlp10)
1613       PropProfile(15, 0);
1614   }
1615   translate([60,-30]) {
1616     PropAggregateProfile();
1617   }
1618 }
1619
1620 //EdgeProfile();
1621 //KeeperProfile();
1622 //CaseBase();
1623 //%Case();
1624 //Keeper();
1625 //LidEdgeProfile();
1626 //KeeperProfile();
1627 //DemoProfiles();
1628 //PropRecess();