fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172
 173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 174 rearspeaker_size   = [  3.76,  7.36 ];
 175
 176 microusb_above = 3.27 - 0.25;
 177 microusb_below = 0.0;
 178 microusb_width = 16.12 + 1.25;
 179
 180 case_th_bottom = 2.5;
 181 case_th_lid = 3.0;
 182 case_th_side = 2.3;
 183 case_th_lip = 1.2;
 184
 185 lid_screen_gap_extra = .66;
 186
 187 case_struts_count = 6;
 188 case_struts_solid_below = 1.00;
 189 case_struts_solid_above = 0.75;
 190 case_struts_width = 0.10;
 191
 192 keeper_th_z = 0.75;
 193 keeper_th_x = 0.75;
 194 keeper_inner_width = 2.75;
 195 keeper_inner_height = 2.75;
 196 keeper_slant_slope = 2; // larger means steeper
 197
 198 keeper_gap_z_top = 0.25;
 199 keeper_gap_z_bot = 0.75;
 200 keeper_gap_x     = 0.25;
 201 keeper_gap_x_holes = 0.75;
 202
 203 keeper_side = 0; // 0 = lhs; 1 = rhs
 204
 205 case_lip = 1.25;
 206
 207 lid_gap_x = 0.25;
 208 lid_gap_z = 0.25;
 209 lid_lip = 1.75;
 210 lid_edgepart_width = 5.0;
 211 lid_buttoncover_thick = 1.3;
 212
 213 catch_slop = 0.50;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_len = 7.5;
 256 catch_width = 15;
 257 catch_thickness = 1.0;
 258 catch_side_gap = 0.75; // each side
 259
 260 catch_depth = 0.75;
 261 catch_height = 0.35;
 262 catch_finger_height = 1.5;
 263 catch_finger_depth = 2.5;
 264
 265 catch_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 // ---------- calculated ----------
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // catch
 429
 430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 432 cppB = [ epp0[0], cppA[1] ];
 433 cppP = [ epp4[0], cppJ[1] ];
 434
 435 cppS = cppJ + [0,-1] * catch_len;
 436 cppD = [ cppA[0], cppS[1] + catch_slop ];
 437 cppC = [ cppB[0], cppD[1] ];
 438 cppT = cppS + [1,0] * catch_depth;
 439 cppU = cppT + [0,-1] * catch_height;
 440 cppV = [ cppS[0], cppU[1] - catch_depth ];
 441
 442 cppR = 0.5*(cppP + cppJ);
 443
 444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 445 cppQ = [ cppR[0],
 446          cppV[1] - (catch_finger_height - cp_rQ) ];
 447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 448
 449 // lanyard
 450
 451 ly_r = lanyard_half_dia / 2;
 452 ly_rc = ly_r * 2;
 453
 454 // prop recess in case
 455
 456 prop_x_pos = phone_width/2;
 457
 458 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 459
 460 prc_r1 = prop_end_dia/2;
 461 prc_r3 = prc_r1 + prop_recess_slop;
 462
 463 prcp2 = [ epp4[0] + prop_buildout_less,
 464           case_bottom_z ];
 465
 466 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 467
 468 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 469           epp2i[1] - prc_r3 - prop_recess_under];
 470
 471 // prop recess in lid
 472
 473 prl_r10 = prop_end_dia/2;
 474 prl_r10o = prl_r10 + prop_recess_slop;
 475
 476 prlp10 = lpp10 + [1,1] * prl_r10o
 477   + [1,0] * prop_lidrecess_behind
 478   + [0,1] * prop_recess_under;
 479
 480 // prop
 481
 482 $prpp10 = [0,0];
 483 $prpp11 = [0, prop_taper_len];
 484
 485 $prp_r10 = prl_r10;
 486
 487 // ---------- modules ----------
 488
 489 module AdhocMultiprintFrame(phase, z0, zs) {
 490   // from z0 to z0 + zs*layer
 491   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 492   xextra = extra + -epp4[0];
 493   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 494   yextra = extra + -epp4[0];
 495   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 496   p0 = [ xrange[0], yrange[0] ];
 497   p1 = [ xrange[1], yrange[1] ];
 498   echo(p0, p1);
 499   translate([0,0, z0])
 500     mirror([0,0, zs<0 ? 1 : 0])
 501     linear_extrude(height= initial_layer_thick)
 502     difference(){
 503       rectfromto(p0 - [1,1] * initial_layer_width,
 504                  p1 + [1,1] * initial_layer_width);
 505       rectfromto(p0, p1);
 506     }
 507 }
 508
 509 module KeeperProfile(slant=0){
 510   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 511   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 512 }
 513
 514 module EdgeProfile(){
 515   difference(){
 516     hull(){
 517       translate(epp3) square(case_th_bottom*2, center=true);
 518       circleat(epp2o, r=case_th_bottom);
 519       circleat(epp1, r=case_th_side);
 520       rectfromto(epp0, epp4);
 521     }
 522     polygon([ epp5 + [0,10],
 523               epp1,
 524               epp2i,
 525               epp3 + [10,0] ]);
 526   }
 527 }
 528
 529 module LanyardLanyardProfile(entry=false){
 530   hull(){
 531     for (xs=[-1,+1] * (entry ? 2 : 1))
 532       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 533         circle(r= lanyard_half_dia/2);
 534   }
 535 }
 536
 537 module LanyardCurveChannelProfile(){
 538   translate([0, -ly_r])
 539     LanyardLanyardProfile();
 540 }
 541
 542 module LanyardEntryChannelProfile(){
 543   LanyardLanyardProfile(true);
 544 }
 545
 546 module LanyardMainChannelProfile(){
 547   LanyardCurveChannelProfile();
 548   difference(){
 549     square(center=true, ly_r * [6, 2]);
 550     for (xs=[-1,+1])
 551       translate(ly_r * [3 * xs, -1])
 552         circle(r = ly_r);
 553   }
 554 }
 555
 556 module LanyardEntry(){
 557   q_z = -(ly_rc + ly_r);
 558   d_x = -ly_rc;
 559
 560   translate([d_x, 0, q_z]) {
 561     intersection(){
 562       rotate([90,0,0])
 563         rotate_extrude(convexity=10)
 564         rotate(90)
 565         translate([0, -q_z])
 566         LanyardCurveChannelProfile();
 567       translate([0,-10,0])
 568         cube([20,20,20]);
 569     }
 570   }
 571
 572   mirror([0,0,1])
 573     linear_extrude(height=20)
 574     rotate(90)
 575     LanyardEntryChannelProfile();
 576 }
 577
 578 module LanyardCutout(l){
 579   for (ee=[0,1]){
 580     translate(ee * l * [-1,0])
 581       mirror([ee,0,0])
 582       LanyardEntry();
 583   }
 584 }
 585
 586 module LidEdgeProfile(){
 587   polygon([ lpp10,
 588             lpp11,
 589             lpp12,
 590             lpp13,
 591             lpp13 + [10, 0],
 592             lpp15 + [10, 0],
 593             lpp15,
 594             lpp14,
 595             ]);
 596   intersection(){
 597     circleat(lpp12, r=lp_r12);
 598     rectfromto( lpp12 + [-10,   0],
 599                 lpp12 + [+10, +10] );
 600   }
 601 }
 602
 603 module LidEdgeFoldClearanceProfile(){
 604   translate([-lid_fold_clearance_antislop, 0])
 605     polygon([ lpp10,
 606               lpp11,
 607               lpp11 + [-20,  0],
 608               lpp11 + [-20, 20],
 609               lpp11 + [+20, 20],
 610               lpp10 + [+20,  0] ]);
 611 }
 612
 613 module ButtonCoverProfile(){
 614   intersection(){
 615     polygon(concat([ bppM, bppP, bppO, bppJ ],
 616                    (enable_support && !$button_suppress_over_keeper
 617                     ? [ bppU, bppV, bppW ] : []),
 618                    [ bppL, bppK ]));
 619     hull(){
 620       EdgeProfile();
 621       LidEdgeProfile();
 622     }
 623   }
 624 }
 625
 626 module ButtonPlan(l, deep, cut){
 627   epsilon =
 628     (cut  ? 0 : lid_buttoncover_gap);
 629
 630   delta =
 631     (deep ? lid_buttoncover_overlap : 0);
 632
 633   C = [0,0]; // by definition
 634   T = [ 0, epp4[1] ];
 635   G = T + [0,10];
 636
 637   B0 = C + [0,-1] * button_cutout_depth;
 638   B1 = B0 + [0,1] * epsilon;
 639
 640   r0 = 0.5 * (T[1] - B0[1]);
 641   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 642   H = A + [0,-1] * delta;
 643
 644   D = A + [-2,0] * r0;
 645   F = D + [0,10];
 646
 647   E0 = 0.5 * (D + A);
 648   E1 = E0 + [1,0] * epsilon;
 649
 650   I0 = [ E0[0], H[1] ];
 651   I1 = [ E1[0], H[1] ];
 652
 653   hull(){
 654     for (m=[0,1]) mirror([m,0])
 655       circleat(H, r0 - epsilon);
 656   }
 657   for (m=[0,1]) mirror([m,0]) {
 658     difference(){
 659       polygon([ E1,
 660                 I1,
 661                 H,
 662                 B1,
 663                 G,
 664                 F,
 665                 D
 666                 ]);
 667       circleat(D, r0 + epsilon);
 668     }
 669   }
 670 }
 671
 672 module CatchCatchProfile(){
 673   hull(){
 674     for (c=[ cppR, cppQ ])
 675       circleat(c, cp_rQ);
 676   }
 677   hull(){
 678     circleat(lpp12, lp_r12);
 679     circleat(lpp12 + [5,0], lp_r12);
 680     rectfromto(cppP, cppP + [5,0.1]);
 681   }
 682   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 683 }
 684
 685 module CatchCutProfile(){
 686   polygon([ cppB,
 687             cppA,
 688             cppD,
 689             cppF,
 690             cppF + [0,-10],
 691             cppF + [-10,-10],
 692             lpp12 + [-10,0],
 693             lpp12 + [10,0]
 694             ]);
 695 }
 696
 697 module Flip_rhs(yn=[0,1]) {
 698   for ($rhsflip=yn) {
 699     translate([phone_width/2, 0, 0])
 700       mirror([$rhsflip,0,0])
 701       translate([-phone_width/2, 0, 0])
 702       children();
 703   }
 704 }
 705
 706 module Flip_bot(yn=[0,1]) {
 707   for ($botflip=yn) {
 708     translate([0, -phone_height/2, 0])
 709       mirror([0, $botflip, 0])
 710       translate([0, phone_height/2, 0])
 711       children();
 712   }
 713 }
 714
 715 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 716   // sides
 717   Flip_rhs(){
 718     translate([0, -phone_cnr_rad, 0])
 719       rotate([90,0,0])
 720       linear_extrude(height = phone_height - phone_cnr_rad*2)
 721       children(0);
 722   }
 723   // corners
 724   Flip_rhs() Flip_bot() {
 725     translate([+1,-1] * phone_cnr_rad)
 726       intersection(){
 727         rotate_extrude()
 728           intersection(){
 729             mirror([1,0,0])
 730               translate([-1,0] * phone_cnr_rad)
 731               children(0);
 732             rectfromto([0,-20],[10,20]);
 733           }
 734         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 735           cube([10,10,40]);
 736       }
 737   }
 738   // top and bottom
 739   Flip_bot(){
 740     translate([ phone_width - phone_cnr_rad, 0,0 ])
 741       rotate([90,0,-90])
 742       linear_extrude(height = phone_width - phone_cnr_rad*2)
 743       children(0);
 744   }
 745   // fill
 746   translate([0,0, fill_zstart])
 747     mirror([0,0, fill_downwards])
 748     linear_extrude(height = fill_th)
 749     rectfromto([+1,-1] * phone_cnr_rad,
 750                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 751 }
 752
 753 module CaseAperture(pos, dia, $fn) {
 754   theta = 180/$fn;
 755   translate([ pos[0] + bumper[0],
 756               -epp2i[0],
 757               -pos[1] ])
 758     rotate([-90, theta, 0])
 759     cylinder(r = dia/2 / cos(theta),
 760              h = 60);
 761 }
 762
 763 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 764   // y_ref_sign:
 765   //   +1  measured from top    of actual phone to top    of button
 766   //   -1  measured from bottom of actual phone to bottom of button
 767   //    0  y is centre of button in coordinate system
 768   $button_l= l;
 769   $button_suppress_over_keeper= suppress_over_keeper;
 770   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 771           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 772           y;
 773   //echo(eff_y);
 774   translate([0, eff_y, 0])
 775     children();
 776 }
 777
 778 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 779   $button_leg_only = true;
 780   SideButton(y, y_ref_sign, l) children();
 781 }
 782
 783 module Buttons(){
 784   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 785   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 786   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 787   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 788 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 789 }
 790
 791 module Struts(x_start, z_min, th){
 792   // if th is negative, starts at z_min and works towards -ve z
 793   // and object should then be printed other way up
 794   for (i= [1 : 1 : case_struts_count]) {
 795     translate([0,
 796                0,
 797                z_min])
 798       mirror([0,0, th<0 ? 1 : 0])
 799       translate([0,
 800                  -phone_height * i / (case_struts_count+1),
 801                  case_struts_solid_below])
 802       linear_extrude(height= abs(th)
 803                      -(case_struts_solid_below+case_struts_solid_above))
 804       rectfromto([               x_start, -0.5 * case_struts_width ],
 805                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 806   }
 807 }
 808
 809 module OrdinaryRearAperture(rhs,bot, pos){
 810   Flip_rhs(rhs) Flip_bot(bot)
 811     linextr(-20, 20)
 812     mirror([0,1])
 813     translate(pos + bumper)
 814     children();
 815 }
 816
 817 module MicroUSB(){
 818   Flip_bot(1){
 819     rotate([90,0,0])
 820       mirror([0,0,1])
 821       linextr(-epp2i[0], 60)
 822       translate([0.5 * phone_width, 0, 0])
 823       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 824                  [+microusb_width/2, epp0[1] + -microusb_above]);
 825   }
 826 }
 827
 828 module OrdinaryRearApertures(){
 829   // rear speaker
 830   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 831     rectfromto(-rearspeaker_gap,
 832                rearspeaker_size + rearspeaker_gap);
 833
 834   // finger hole to remove phone
 835   if (len(fingerpushhole_dias))
 836     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 837                                 phone[1]/2 ])
 838     scale(fingerpushhole_dias)
 839     circle(r= 0.5 );
 840 }
 841
 842 module RearCameraAperture(){
 843   Flip_rhs(1)
 844     mirror([0, 0, 1])
 845     linear_extrude(height = 20)
 846     mirror([0, 1, 0])
 847     translate(bumper)
 848     rectfromto(camera_pos_tl, camera_pos_br);
 849 }
 850
 851 module HingeLidProfile(){
 852   hull(){
 853     circleat(hppT, hp_r1);
 854     circleat(lpp12, lp_r12);
 855     polygon([lpp10,
 856              lpp13 + [2,0],
 857              lpp12,
 858              hppT]);
 859   }
 860 }
 861
 862 module HingeBaseProfile(){
 863   difference(){
 864     hull(){
 865       circleat(hppB, hp_r1);
 866       circleat(hppE, hp_r1);
 867       circleat(epp2o, case_th_bottom);
 868       circleat(hppB + [10,0], hp_r1);
 869     }
 870     polygon([epp5, epp1, epp2i, epp3, bppL]);
 871   }
 872 }
 873
 874 module HingeLeverOuterProfile(){
 875   hull(){
 876     circleat(hppT, hp_r2);
 877     circleat(hppB, hp_r2);
 878   }
 879 }
 880
 881 module HingeLeverInnerProfile(){
 882   for (s = [-1,+1]) {
 883     c = s > 0 ? hppT : hppB;
 884     translate(c)
 885       mirror([0,0,s>0])
 886       rotate(s<0 ? -40 : 0)
 887       hull()
 888       for (x=[-20,20])
 889         for (y=[0, s * 10])
 890           translate([x,y])
 891             circle(hp_rn);
 892   }
 893 }
 894
 895 module HingeLeverNutProfile(){
 896   for (c= [hppB, hppT]) {
 897     translate(c)
 898       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 899   }
 900 }
 901
 902 module Flip_hinge(doflip=1){
 903   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 904   translate(hinge_origin)
 905     rotate([doflip*180,0,0])
 906     translate(-hinge_origin)
 907     children();
 908 }
 909
 910 module HingePortion(x0,x1){
 911   Flip_rhs() Flip_bot(1)
 912     translate([x0,0,0])
 913     mirror([1,0,0])
 914     rotate([90,0,-90])
 915     linear_extrude(height=x1-x0)
 916     children();
 917 }
 918
 919 module CatchPortion(xwidth, ztop){
 920   width = catch_width + xwidth;
 921   w = width + catch_topcurve_r*2 + 1;
 922   translate([phone_width/2, 0,0]){
 923     difference(){
 924       rotate([90,0,-90])
 925         linextr(-w/2, w/2)
 926         children(0);
 927       translate([0, 50, 0])
 928         rotate([90,0,0])
 929         linear_extrude(height=100){
 930         for (m=[0,1]) mirror([m,0,0]) {
 931           hull(){
 932             translate([w/2, ztop - catch_topcurve_r])
 933               circle(catch_topcurve_r);
 934             translate([w/2, -50])
 935               square(catch_topcurve_r*2, center=true);
 936           }
 937         }
 938       }
 939     }
 940   }
 941 }
 942
 943 module CaseBase(){
 944   AroundEdges(epp3[1], case_th_bottom, 1)
 945     EdgeProfile();
 946 }
 947
 948 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 949
 950 module PropProfileAssignments(gamma){
 951   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 952   x = prop_x(gamma);
 953   p = phone_height + prlp10[0] - hppB[0];
 954   b = p + x;
 955
 956   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 957   a = q + x;
 958   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 959   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 960
 961   $prp_theta = 90 - $prp_alpha;
 962   beta = 180 - $prp_alpha - gamma;
 963   psi = 90 - beta;
 964
 965   //echo("abc", a,b,c);
 966
 967   v1 = [ [ cos(psi), -sin(psi) ],    // x
 968          [ sin(psi),  cos(psi) ] ];  // y
 969
 970   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 971
 972   $prp_r1 = prc_r1;
 973   $prp_r11 = prop_main_th/2;
 974
 975   $prpp1 = $prpp7 + [1,0] *
 976     // this is approximate, but will do
 977     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 978   $prpp3 = $prpp1 +
 979     v1[0] * -$prp_r1 +
 980     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 981   $prpp12 = $prpp3 + v1[0] *
 982     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 983   $prp_r8 = prop_main_th;
 984   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 985   $prp_r5 = $prp_r8;
 986   $prpp5 = [ $prpp12[0] - $prp_r5,
 987             $prpp3[1] - prop_prong_h + $prp_r5 ];
 988   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 989          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 990   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 991   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 992
 993   children();
 994 }
 995
 996 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 997   PropProfileAssignments(gamma){
 998
 999     //#circleat($prpp3,1);
1000     //#circleat($prpp12,1);
1001
1002     if (!cut) {
1003       hull(){
1004         translate($prpp8)
1005           intersection(){
1006             circle($prp_r8);
1007             polygon([[-20,-0], [20,20], [0,0]]);
1008           }
1009         rectfromto($prpp6, $prpp9);
1010         translate($prpp5) intersection(){
1011           circle($prp_r5);
1012           polygon([[-10,-10], [0,0], [10,0]]);
1013         }
1014         rectfromto($prpp12 + [0,-0.1], $prpp3);
1015       }
1016       hull(){
1017         circleat($prpp1, $prp_r1);
1018         rectfromto($prpp12 + [0,-0.1], $prpp3);
1019       }
1020     }
1021     // main shaft
1022     rotate([0,0, rot*-$prp_theta]){
1023       hull(){
1024         extra = cut ? prop_recess_slop : 0;
1025         rectfromto($prpp6, $prpp9);
1026         circleat($prpp11, $prp_r11 + extra);
1027         circleat($prpp10, $prp_r10 + extra);
1028       }
1029     }
1030   }
1031 }
1032
1033 module PropAggregateProfile(){
1034   for (angle = prop_angles)
1035     PropProfile(angle, 0,0);
1036 }
1037
1038 module Prop(){ ////toplevel
1039   hw = prop_main_width/2;
1040   linextr(-hw, +hw)
1041     PropAggregateProfile();
1042 }
1043
1044 module Case(){ ////toplevel
1045   difference(){
1046     union(){
1047       CaseBase();
1048
1049       // ledge (fixed keeper)
1050       Flip_rhs(1-keeper_side) intersection(){
1051         rotate([90, 0, 0])
1052           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1053           KeeperProfile(1);
1054
1055         // outline of the whole case, to stop it protruding
1056         translate([0,0, -25])
1057           linear_extrude(height = 50)
1058           hull()
1059           Flip_bot()
1060           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1061       }
1062
1063       // hinge
1064       HingePortion(hex20, hex21) HingeBaseProfile();
1065
1066       // buildout for prop recess
1067       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1068         linextr(case_bottom_z, epp2i[1])
1069         hull() {
1070           for (dxs = [-1,+1])
1071             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1072                        -epp2o[0] ],
1073                      r = epp2o[0] - prcp2[0]);
1074         }
1075     }
1076
1077     // slot for keeper
1078     Flip_rhs(keeper_side)
1079       translate([0, -phone_cnr_rad, 0])
1080       rotate([90, 0, 0])
1081       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1082       minkowski(){
1083         KeeperProfile();
1084         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1085                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1086       }
1087
1088     // front camera
1089     RearCameraAperture();
1090
1091     // struts (invisible, because they're buried in the case)
1092     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1093
1094     Buttons(){
1095       mirror([1,0,0])
1096         rotate([90,0,90]) {
1097           if (!($button_leg_only && enable_support))
1098           intersection(){
1099             translate([0,0,-10])
1100               linear_extrude(height= 20)
1101               ButtonPlan($button_l, 0,1);
1102             if ($button_leg_only)
1103               rotate([-90,90,0])
1104                 translate([phone_width/2, -400, kppe[1]])
1105                 mirror([1-abs($rhsflip - keeper_side),0,0])
1106                 cube([400, 800, 50]);
1107             if (enable_support && !$button_suppress_over_keeper)
1108               rotate([-90,90,0])
1109               translate([-400, -400, kppd[1]])
1110                 mirror([0,0,1])
1111                 cube([800,800,100]);
1112           }
1113           translate([0,0, -bppR[0]])
1114             linear_extrude(height= 20)
1115             ButtonPlan($button_l, 1,1);
1116         }
1117
1118     }
1119
1120     // apertures along top edge
1121     CaseAperture(jack_pos, jack_dia, 8);
1122     Flip_rhs(1)
1123       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1124
1125     OrdinaryRearApertures();
1126
1127     MicroUSB();
1128
1129     // gaps for the lid's hinge arms
1130     HingePortion(hex20 - hinge_x_arms_gap,
1131                  hex21 + hinge_x_arms_gap)
1132       minkowski(){
1133         HingeLidProfile();
1134         circle(r= hinge_r_arms_gap, $fn= 8);
1135       }
1136
1137     // screw holes in the hinge arms
1138     HingeScrews();
1139
1140     // catch striker
1141     CatchPortion(catch_side_gap*2, epp4[1])
1142       CatchCutProfile();
1143
1144     // prop recess
1145     Flip_rhs(1)
1146       translate([prop_x_pos,0,0])
1147       mirror([0,1,0])
1148       rotate([90,0,90])
1149       linextr(-prop_recess_hw, +prop_recess_hw)
1150       hull(){
1151         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1152           circleat(prcp1 + 20*d,
1153                    prc_r3);
1154       }
1155   }
1156 }
1157
1158 module LidAdhocMultiprintFrame(phase){
1159   if (led_window_style >= 3) {
1160     AdhocMultiprintFrame(phase, lpp13[1], -1);
1161   }
1162 }
1163
1164 module LidAroundEdges(){
1165   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1166     children();
1167 }
1168
1169 module Lid(){ ////toplevel
1170   skew_centre = [0, lpp11[0], lpp11[1]];
1171   difference(){
1172     union(){
1173       intersection(){
1174         LidAroundEdges()
1175           LidEdgeProfile();
1176
1177         translate(skew_centre)
1178           multmatrix([[ 1, 0, 0, 0 ],
1179                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1180                       [ 0, 0, 1, 0 ],
1181                       [ 0, 0, 0, 1 ]])
1182           translate(-skew_centre)
1183           LidAroundEdges()
1184           LidEdgeFoldClearanceProfile();
1185       }
1186
1187       // button covers
1188       Buttons(){
1189         intersection(){
1190           rotate([90,0,90])
1191             translate([0,0,-10])
1192             linear_extrude(height= 20)
1193             ButtonPlan($button_l, 1,0);
1194           rotate([90,0,0])
1195              translate([0,0,-100])
1196             linear_extrude(height= 200)
1197             ButtonCoverProfile();
1198         }
1199       }
1200
1201       // hinge arms
1202       HingePortion(hex20, hex21) {
1203         LidEdgeProfile();
1204         HingeLidProfile();
1205       }
1206
1207       // catch
1208       CatchPortion(0, lpp12[1])
1209         CatchCatchProfile();
1210     }
1211     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1212
1213     // screw holes in the hinge arms
1214     HingeScrews();
1215
1216     // prop recess
1217     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1218       mirror([0,1,0])
1219       rotate([90,0,90])
1220       linextr(-prop_recess_hw, +prop_recess_hw)
1221       hull()
1222       for (pa = prop_angles)
1223         PropProfile(pa, 1,1);
1224
1225     // notification led aperture
1226     if (led_window_style)
1227       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1228         translate([0,0,-10])
1229           cylinder(r=nla_r0, h=20);
1230         if (led_window_style >= 2)
1231           translate([0,0, -nla_t])
1232             cylinder(r=nla_r2, height=20);
1233       }
1234
1235     }
1236
1237   LidAdhocMultiprintFrame(1);
1238 }
1239
1240 module HingeLever(){ ////toplevel
1241   difference() {
1242     // outer body, positive
1243     HingePortion(hex22, hex22 + phone_width/2)
1244       HingeLeverOuterProfile();
1245
1246     // space for the screws
1247     HingePortion(hex26, hex24)
1248       HingeLeverInnerProfile();
1249
1250     // recesses for the nuts
1251     HingePortion(hex23, hex26+1)
1252       HingeLeverNutProfile();
1253
1254     // bores for the screws
1255     HingeScrews();
1256
1257     // space for the charging cable
1258     MicroUSB();
1259     Flip_hinge() MicroUSB();
1260   }
1261 }
1262
1263 module LidWindow(){ ////toplevel
1264   translate([led_pos[0], -led_pos[1], lpp13[1]])
1265     mirror([0,0,1])
1266     cylinder(r= nla_r1, h=nla_t);
1267   LidAdhocMultiprintFrame(0);
1268 }
1269
1270 module LidWindowPrint(){ ////toplevel
1271   rotate([0,180,0])
1272     LidWindow();
1273 }
1274
1275 module DemoLidWindowSelect(){
1276   translate([led_pos[0], led_pos[1], -100]) {
1277     translate([0, -30, 0]) cube([400, 400, 200]);
1278   }
1279 }
1280
1281 module DemoLidWindow(){ ////toplevel
1282   %Lid();
1283   LidWindow();
1284   translate([0,40,0]){
1285     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1286     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1287   }
1288 }
1289
1290 module HingeLeverPrint(){ ////toplevel
1291   rotate([-90,0,0])
1292     translate([-phone_width/2, phone_height, 0])
1293     HingeLever();
1294 }
1295
1296 module TestSelectLength(){
1297   translate([-30, -200, -20])
1298     cube([30 + 15, 250, 40]);
1299 }
1300
1301 module TestLength(){ ////toplevel
1302   intersection(){
1303     Case();
1304     TestSelectLength();
1305   }
1306 }
1307
1308 module TestLengthRight(){ ////toplevel
1309   intersection(){
1310     Case();
1311     Flip_rhs(1)
1312       TestSelectLength();
1313   }
1314 }
1315
1316 module TestSelectWidth(){
1317   translate([-30, -(phone_height - 25), -20])
1318     mirror([0, 1, 0])
1319     cube([200, 50, 40]);
1320 }
1321
1322 module TestWidth(){ ////toplevel
1323   intersection(){
1324     Case();
1325     TestSelectWidth();
1326   }
1327 }
1328
1329 module TestLidWidthPrint(){ ////toplevel
1330   rotate([0,180.0]) intersection(){
1331     Lid();
1332     TestSelectWidth();
1333   }
1334 }
1335
1336 module TestSelectRearAperture(){
1337   minkowski(){
1338     union() children();
1339     translate([20, 0,0])
1340       cube([42, 2, 1], center=true);
1341   }
1342 }
1343
1344 module TestSelectCamera(){
1345   minkowski(){
1346     TestSelectRearAperture()
1347       RearCameraAperture();
1348     cube([0.1, 50, 0.1]);
1349   }
1350 }
1351
1352 module TestSelectOrdinaryRearApertures(){
1353   TestSelectRearAperture()
1354     OrdinaryRearApertures();
1355 }
1356
1357 module TestCamera(){ ////toplevel
1358   intersection(){
1359     Case();
1360     TestSelectCamera();
1361   }
1362 }
1363
1364 module TestLidByCamera(){ ////toplevel
1365   intersection(){
1366     Lid();
1367     TestSelectCamera();
1368   }
1369 }
1370
1371 module TestLidByCameraPrint(){ ////toplevel
1372   rotate([180,0,0]) TestLidByCamera();
1373 }
1374
1375 module DemoByCamera(){ ////toplevel
1376   color("blue") TestLidByCamera();
1377   color("red")  TestCamera();
1378 }
1379
1380 module OneKeeper(){ ////toplevel
1381   translate([0, -phone_cnr_rad, 0])
1382     rotate([90, 0, 0])
1383     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1384     KeeperProfile();
1385 }
1386
1387 module OneKeeperPrint(){ ////toplevel
1388   rotate([0,180,0])
1389     OneKeeper();
1390 }
1391
1392 module LidPrint(){ ////toplevel
1393   rotate([0,180,0])
1394     Lid();
1395 }
1396
1397 module TestSelectFrame(){
1398   include = [1,-1] * (epp2i[0] + 4);
1399
1400   difference(){
1401     cube(1000, center=true);
1402     translate([0,0, -100])
1403       linear_extrude(height=200)
1404       rectfromto(include,  inside_br - include);
1405   }
1406 }
1407
1408 module TestSelectLidFrame(){
1409   TestSelectFrame();
1410   translate([led_pos[0], -led_pos[1], -50])
1411     cylinder(r= nla_r2+3, h=100);
1412 }
1413
1414 module TestFrameCase(){ ////toplevel
1415   intersection(){
1416     Case();
1417     union(){
1418       TestSelectFrame();
1419       TestSelectCamera();
1420       TestSelectOrdinaryRearApertures();
1421     }
1422   }
1423 }
1424
1425 module TestSelectTopApertures(){
1426   translate([-100, -35, -100])
1427     cube([400, 100, 200]);
1428   LidAdhocMultiprintFrame(0);
1429   LidAdhocMultiprintFrame(1);
1430 }
1431
1432 module TestTopApertures(){ ////toplevel
1433   intersection(){
1434     Case();
1435     TestSelectFrame();
1436     TestSelectTopApertures();
1437   }
1438 }
1439
1440 module TestLidTopAperturesPrint(){ ////toplevel
1441   rotate([0,180,0]) intersection(){
1442     Lid();
1443     TestSelectLidFrame();
1444     TestSelectTopApertures();
1445   }
1446 }
1447
1448 module TestLidWindowTopAperturesPrint(){ ////toplevel
1449   rotate([0,180,0]) intersection(){
1450     LidWindow();
1451     TestSelectTopApertures();
1452   }
1453 }
1454
1455 module TestFrameLidPrint(){ ////toplevel
1456   rotate([0,180,0]) intersection(){
1457     Lid();
1458     TestSelectLidFrame();
1459   }
1460 }
1461
1462 module ButtonPlanForDemo(z, deep, cut){
1463   translate([0,0,z])
1464     ButtonPlan(8, deep, cut);
1465 }
1466
1467 module HingeScrews(){
1468   Flip_rhs() Flip_bot(1){
1469     for (c= [ hppT, hppB ])
1470       translate([ hex20,
1471                   -c[0],
1472                   c[1] ]){
1473         rotate([0,90,0])
1474           translate([0,0,-.2])
1475           cylinder( r= hingescrew_shaft_dia/2,
1476                     h = hingescrew_shaft_len+0.2 );
1477         rotate([0,-90,0])
1478           translate([0,0,+.1])
1479           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1480       }
1481   }
1482 }
1483
1484 module DemoPropAngleSelect(c){
1485   color(c) difference(){
1486     union(){ children(); }
1487     translate([ prop_x_pos, -400, -200 ])
1488       cube([ 400,800,400 ]);
1489   }
1490 }
1491
1492 module DemoPropAngle(ang){
1493   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1494   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1495
1496   translate(hL)
1497     rotate([ang/2,0,0])
1498     translate(-hL)
1499     translate(hC)
1500     rotate([ang/2,0,0])
1501     translate(-hC) {
1502       DemoPropAngleSelect("red") Case();
1503
1504       color("orange")
1505         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1506         PropProfileAssignments(ang) {
1507           echo($prpp1);
1508           rotate([-$prp_theta, 0, 0])
1509           translate([0, $prpp1[0], -$prpp1[1]])
1510           rotate([90,0,-90])
1511           Prop();
1512         }
1513     }
1514
1515   translate([0,0, -hp_k*2])
1516     DemoPropAngleSelect("blue")
1517     Lid();
1518 }
1519
1520 module DemoPropAngles(){ ////toplevel
1521   for (i=[0 : len(prop_angles)-1])
1522     translate(i * [0, -100, 100])
1523     DemoPropAngle(prop_angles[i]);
1524 }
1525
1526 module DemoHingeAngle(ang1,ang2){
1527   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1528   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1529
1530   translate(hL)
1531     rotate([ang2,0,0])
1532     translate(-hL)
1533     translate(hC)
1534     rotate([ang1,0,0])
1535     translate(-hC) {
1536       color("red") Lid();
1537     }
1538
1539   color("blue") intersection(){
1540     Case();
1541     union(){
1542       translate([bppJ[0], -400, -200])
1543         mirror([1,0,0])
1544         cube([400, 800, 400]);
1545       translate([10, -400, -200])
1546         cube([10, 800, 400]);
1547     }
1548   }
1549 }
1550
1551 module DemoHingeAngles(){ ////toplevel
1552   angles = [ 0, 4, 8, 12 ];
1553   echo("angles",angles);
1554   for (i=[0 : len(angles)-1]) {
1555     translate(i * [0, 0, 30]) {
1556       DemoHingeAngle(0,angles[i]);
1557       translate([0, 200, 0])
1558         DemoHingeAngle(angles[i],0);
1559     }
1560   }
1561 }
1562
1563 module DemoSelectAdhocLeftRight(right=0) {
1564   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1565     mirror([1-right, 0,0])
1566     cube([400, 800, 200]);
1567 }
1568
1569 module DemoLeft(){ ////toplevel
1570   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1571   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1572 }
1573
1574 module DemoFrame(){ ////toplevel
1575   color("red") TestFrameCase();
1576   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1577   color("black") HingeScrews();
1578   %HingeLever();
1579 }
1580
1581 module DemoLanyardCutout(){ ////toplevel
1582   LanyardCutout(25);
1583 }
1584
1585 module DemoHingedFrame(){ ///toplevel
1586   color("red") TestFrameCase();
1587   translate([0,0, -2*hp_k])
1588   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1589
1590   Flip_hinge(){
1591     color("orange") HingeLever();
1592     color("black") HingeScrews();
1593   }
1594 }
1595
1596 module DemoHinge(){ ////toplevel
1597   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1598     DemoFrame();
1599     translate([0,0, -hp_k*3])
1600       DemoHingedFrame();
1601   }
1602 }
1603
1604 module DemoProfiles(){ ////toplevel
1605   LidEdgeProfile();
1606   %EdgeProfile();
1607   KeeperProfile();
1608   translate([0,0,-1]) color("black") KeeperProfile(1);
1609   color("purple") translate(epp2i)
1610     rotate(atan2vector(epp2i - epp1)) {
1611     translate(lanyard_half_dia * 0.5 * [-3,-1])
1612       LanyardLanyardProfile();
1613     translate(lanyard_half_dia * 0.5 * [-3,+1])
1614       translate([0,-1] * case_th_side)
1615       LanyardLanyardProfile(true);
1616   }
1617
1618   translate([0,20]) {
1619     LanyardMainChannelProfile();
1620     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1621     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1622   }
1623
1624   translate([20,0]) {
1625     LidEdgeProfile();
1626     %EdgeProfile();
1627
1628     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1629
1630     color("blue") ButtonCoverProfile();
1631     color("red") {
1632       rectfromto(bppQ, demopoint_QR);
1633       rectfromto(bppR, demopoint_QR);
1634     }
1635   }
1636
1637   translate([-20,0]) {
1638     color("black") ButtonPlanForDemo(-2, 0,1);
1639     color("red" )  ButtonPlanForDemo(-4, 1,1);
1640     color("blue")  ButtonPlanForDemo(-6, 1,0);
1641   }
1642
1643   translate([0, -30]) {
1644     %LidEdgeProfile();
1645     %EdgeProfile();
1646     color("blue") HingeLidProfile();
1647     color("red")  HingeBaseProfile();
1648     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1649   }
1650
1651   for (f=[0,1]) {
1652     translate([-30, -60 + 30*f]) {
1653       translate([0,0,-4]) EdgeProfile();
1654       %translate([0,0,-10]) HingeBaseProfile();
1655       translate([0,-2] * f * hp_k) {
1656         translate([0,0,-4]) LidEdgeProfile();
1657         %translate([0,0,-10]) %HingeLidProfile();
1658       }
1659       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1660         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1661         translate([0,0,0]) color("red") difference(){
1662           HingeLeverOuterProfile();
1663           HingeLeverInnerProfile();
1664         }
1665         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1666       }
1667     }
1668   }
1669
1670   translate([20,-30]) {
1671     %EdgeProfile();
1672     %LidEdgeProfile();
1673     //translate([0,0,1]) CatchCutProfile();
1674     color("blue") CatchCatchProfile();
1675     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1676   }
1677
1678   translate([40,-30]) {
1679     difference(){
1680       LidEdgeProfile();
1681       translate(prlp10)
1682         PropProfile(10, 1, 0);
1683     }
1684     translate(prlp10)
1685       PropProfile(15, 0);
1686   }
1687   translate([60,-30]) {
1688     PropAggregateProfile();
1689   }
1690 }
1691
1692 //EdgeProfile();
1693 //KeeperProfile();
1694 //CaseBase();
1695 //%Case();
1696 //Keeper();
1697 //LidEdgeProfile();
1698 //KeeperProfile();
1699 //DemoProfiles();
1700 //PropRecess();