fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25 noisecancelmic_dia = 1.75;
  26
  27 rearspeaker_pos_bl = [ 14.92, 18.72 ];
  28 rearspeaker_size   = [  3.76,  7.36 ];
  29
  30 case_th_bottom = 2.5;
  31 case_th_lid = 2.5;
  32 case_th_side = 2;
  33 case_th_lip = 1.2;
  34
  35 case_struts_count = 6;
  36 case_struts_solid_below = 1.00;
  37 case_struts_solid_above = 0.75;
  38 case_struts_width = 0.10;
  39
  40 keeper_th_z = 0.75;
  41 keeper_th_x = 0.75;
  42 keeper_inner_width = 2.75;
  43 keeper_inner_height = 2.75;
  44 keeper_slant_slope = 2; // larger means steeper
  45
  46 keeper_gap_z_top = 0.25;
  47 keeper_gap_z_bot = 0.75;
  48 keeper_gap_x     = 0.25;
  49 keeper_gap_x_holes = 0.75;
  50
  51 case_lip = 1.25;
  52
  53 lid_gap_x = 0.25;
  54 lid_gap_z = 0.25;
  55 lid_lip = 1.75;
  56
  57 $fa = 5;
  58 $fs = 0.1;
  59
  60 button_l_fudge = 4.4;
  61 buttonishleg_default_l_is_fudge = 10;
  62
  63 strut_min_at_end = 1.5;
  64
  65 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  66
  67 // ---------- calculated ----------
  68
  69 phone_width =  (phone + bumper*2)[0];
  70 phone_height = (phone + bumper*2)[1];
  71
  72 inside_br = [phone_width, -phone_height];
  73
  74 //echo(camera_pos_tl + bumper,
  75 //     camera_pos_br + bumper);
  76
  77 // ----- could be changed -----
  78 lid_buttoncover_gap = lid_gap_x;
  79 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  80
  81 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  82
  83 //lid_lip_overlap_width xxx bad name = ;
  84 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  85
  86 epp0 = [0,0];
  87 epp1 = [0, -phone_edge_thick];
  88 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  89 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  90 epp3 = epp2i + [10, 0];
  91 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  92 epp4 = epp5 + [-1,0] * case_th_side;
  93
  94 kppe = [0,0];
  95 kppd = kppe + [1,0] * keeper_inner_width;
  96 kppc = kppd + [0,1] * keeper_th_z;
  97 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  98 kppf = kppe - [0,1] * keeper_inner_height;
  99 kppa = [ kppb[0], kppf[1] ];
 100
 101 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 102 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 103
 104 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 105
 106 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 107 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 108
 109 // button profile
 110 bppM = epp4 + [0,5];
 111 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 112 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 113 bppS = [ epp1[0], bppR[1] ];
 114 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 115 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 116 bppO = [ bppN[0], bppP[1] ];
 117 bppL = lpp10 + [5,0];
 118 bppK = [ bppL[0], bppN[1] ];
 119 bppJ = [ bppN[0], bppL[1] ];
 120
 121 module rectfromto(a,b) {
 122   ab = b - a;
 123   translate([min(a[0], b[0]), min(a[1], b[1])])
 124     square([abs(ab[0]), abs(ab[1])]);
 125 }
 126 module circleat(c,r) { translate(c) circle(r); }
 127 module linextr(z0,z1) {
 128   translate([0,0,z0])
 129     linear_extrude(height=z1-z0)
 130     children();
 131 }
 132
 133 module KeeperProfile(slant=0){
 134   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 135   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 136 }
 137
 138 module EdgeProfile(){
 139   difference(){
 140     hull(){
 141       translate(epp3) square(case_th_bottom*2, center=true);
 142       circleat(epp2o, r=case_th_bottom);
 143       circleat(epp1, r=case_th_side);
 144       rectfromto(epp0, epp4);
 145     }
 146     polygon([ epp5 + [0,10],
 147               epp1,
 148               epp2i,
 149               epp3 + [10,0] ]);
 150   }
 151 }
 152
 153 module LidEdgeProfile(){
 154   polygon([ lpp10,
 155             lpp11,
 156             lpp12,
 157             lpp13,
 158             lpp13 + [10, 0],
 159             lpp10 + [10, 0]
 160             ]);
 161   intersection(){
 162     circleat(lpp12, r=lp_r12);
 163     rectfromto( lpp12 + [-10,   0],
 164                 lpp12 + [+10, +10] );
 165   }
 166 }
 167
 168 module ButtonCoverProfile(){
 169   intersection(){
 170     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 171     hull(){
 172       EdgeProfile();
 173       LidEdgeProfile();
 174     }
 175   }
 176 }
 177
 178 module ButtonPlan(l, deep, cut){
 179   epsilon =
 180     (cut  ? 0 : lid_buttoncover_gap);
 181
 182   delta =
 183     (deep ? lid_buttoncover_overlap : 0);
 184
 185   C = [0,0]; // by definition
 186   T = [ 0, epp4[1] ];
 187   G = T + [0,10];
 188
 189   B0 = C + [0,-1] * button_cutout_depth;
 190   B1 = B0 + [0,1] * epsilon;
 191
 192   r0 = 0.5 * (T[1] - B0[1]);
 193   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 194   H = A + [0,-1] * delta;
 195
 196   D = A + [-2,0] * r0;
 197   F = D + [0,10];
 198
 199   E0 = 0.5 * (D + A);
 200   E1 = E0 + [1,0] * epsilon;
 201
 202   I0 = [ E0[0], H[1] ];
 203   I1 = [ E1[0], H[1] ];
 204
 205   hull(){
 206     for (m=[0,1]) mirror([m,0])
 207       circleat(H, r0 - epsilon);
 208   }
 209   for (m=[0,1]) mirror([m,0]) {
 210     difference(){
 211       polygon([ E1,
 212                 I1,
 213                 H,
 214                 B1,
 215                 G,
 216                 F,
 217                 D
 218                 ]);
 219       circleat(D, r0 + epsilon);
 220     }
 221   }
 222 }
 223
 224 module CaseBase_rhsflip(yn=[0,1]) {
 225   for ($rhsflip=yn) {
 226     translate([phone_width/2, 0, 0])
 227       mirror([$rhsflip,0,0])
 228       translate([-phone_width/2, 0, 0])
 229       children();
 230   }
 231 }
 232
 233 module CaseBase_botflip(yn=[0,1]) {
 234   for ($botflip=yn) {
 235     translate([0, -phone_height/2, 0])
 236       mirror([0, $botflip, 0])
 237       translate([0, phone_height/2, 0])
 238       children();
 239   }
 240 }
 241
 242 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 243   // sides
 244   CaseBase_rhsflip(){
 245     translate([0, -phone_cnr_rad, 0])
 246       rotate([90,0,0])
 247       linear_extrude(height = phone_height - phone_cnr_rad*2)
 248       children(0);
 249   }
 250   // corners
 251   CaseBase_rhsflip() CaseBase_botflip() {
 252     translate([+1,-1] * phone_cnr_rad)
 253       intersection(){
 254         rotate_extrude()
 255           intersection(){
 256             mirror([1,0,0])
 257               translate([-1,0] * phone_cnr_rad)
 258               children(0);
 259             rectfromto([0,-20],[10,20]);
 260           }
 261         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 262           cube([10,10,40]);
 263       }
 264   }
 265   // top and bottom
 266   CaseBase_botflip(){
 267     translate([ phone_width - phone_cnr_rad, 0,0 ])
 268       rotate([90,0,-90])
 269       linear_extrude(height = phone_width - phone_cnr_rad*2)
 270       children(0);
 271   }
 272   // fill
 273   translate([0,0, fill_zstart])
 274     mirror([0,0, fill_downwards])
 275     linear_extrude(height = fill_th)
 276     rectfromto([+1,-1] * phone_cnr_rad,
 277                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 278 }
 279
 280 module CaseAperture(pos, dia, $fn) {
 281   theta = 180/$fn;
 282   translate([ pos[0] + bumper[0],
 283               -epp2i[0],
 284               -pos[1] ])
 285     rotate([-90, theta, 0])
 286     cylinder(r = dia/2 / cos(theta),
 287              h = 60);
 288 }
 289
 290 module SideButton(y, y_ref_sign, l){
 291   // y_ref_sign:
 292   //   +1  measured from top    of actual phone to top    of button
 293   //   -1  measured from bottom of actual phone to bottom of button
 294   //    0  y is centre of button in coordinate system
 295   $button_l= l;
 296   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 297           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 298           y;
 299   echo(eff_y);
 300   translate([0, eff_y, 0])
 301     children();
 302 }
 303
 304 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 305   $button_leg_only = true;
 306   SideButton(y, y_ref_sign, l) children();
 307 }
 308
 309 module Buttons(){
 310   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 311   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 312   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 313   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 314 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 315 }
 316
 317 module Struts(x_start, z_min, th){
 318   // if th is negative, starts at z_min and works towards -ve z
 319   // and object should then be printed other way up
 320   for (i= [1 : 1 : case_struts_count]) {
 321     translate([0,
 322                0,
 323                z_min])
 324       mirror([0,0, th<0 ? 1 : 0])
 325       translate([0,
 326                  -phone_height * i / (case_struts_count+1),
 327                  case_struts_solid_below])
 328       linear_extrude(height= abs(th)
 329                      -(case_struts_solid_below+case_struts_solid_above))
 330       rectfromto([               x_start, -0.5 * case_struts_width ],
 331                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 332   }
 333 }
 334
 335 module RearSpeakerAperture(){
 336   CaseBase_rhsflip([1]) CaseBase_botflip([1])
 337     linextr(-20, 20)
 338     mirror([0,1])
 339     translate(rearspeaker_pos_bl + bumper)
 340     rectfromto(-rearspeaker_gap,
 341                rearspeaker_size + rearspeaker_gap);
 342 }
 343
 344 module CaseBase(){
 345   AroundEdges(epp3[1], case_th_bottom, 1)
 346     EdgeProfile();
 347 }
 348
 349 module Case(){ ////toplevel
 350   difference(){
 351     union(){
 352       CaseBase();
 353
 354       // ledge (fixed keeper)
 355       intersection(){
 356         rotate([90, 0, 0])
 357           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 358           KeeperProfile(1);
 359
 360         // outline of the whole case, to stop it protruding
 361         translate([0,0, -25])
 362           linear_extrude(height = 50)
 363           hull()
 364           // CaseBase_rhsflip() // actually, we only care about the LH
 365           CaseBase_botflip()
 366           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 367       }
 368     }
 369
 370     // slot for keeper
 371     CaseBase_rhsflip(1)
 372       translate([0, -phone_cnr_rad, 0])
 373       rotate([90, 0, 0])
 374       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 375       minkowski(){
 376         KeeperProfile();
 377         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 378                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 379       }
 380
 381     // front camera
 382     CaseBase_rhsflip([1])
 383       mirror([0, 0, 1])
 384       linear_extrude(height = 20)
 385       mirror([0, 1, 0])
 386       translate(bumper)
 387       rectfromto(camera_pos_tl, camera_pos_br);
 388
 389     // struts (invisible, because they're buried in the case)
 390     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 391
 392     Buttons(){
 393       mirror([1,0,0])
 394         rotate([90,0,90]) {
 395           intersection(){
 396             translate([0,0,-10])
 397               linear_extrude(height= 20)
 398               ButtonPlan($button_l, 0,1);
 399             if ($button_leg_only)
 400               rotate([-90,90,0])
 401                 translate([phone_width/2, -400, kppe[1]])
 402                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 403           }
 404           translate([0,0, -bppR[0]])
 405             linear_extrude(height= 20)
 406             ButtonPlan($button_l, 1,1);
 407         }
 408     }
 409
 410     // apertures along top edge
 411     CaseAperture(jack_pos, jack_dia, 8);
 412     CaseBase_rhsflip([1])
 413       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 414
 415     RearSpeakerAperture();
 416   }
 417 }
 418
 419 module Lid(){ ////toplevel
 420   difference(){
 421     union(){
 422       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 423         LidEdgeProfile();
 424
 425       // button covers
 426       Buttons(){
 427         intersection(){
 428           rotate([90,0,90])
 429             translate([0,0,-10])
 430             linear_extrude(height= 20)
 431             ButtonPlan($button_l, 1,0);
 432           rotate([90,0,0])
 433              translate([0,0,-100])
 434             linear_extrude(height= 200)
 435             ButtonCoverProfile();
 436         }
 437       }
 438     }
 439     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 440   }
 441 }
 442
 443 module TestLength(){ ////toplevel
 444   intersection(){
 445     Case();
 446     translate([-30, -200, -20])
 447     cube([30 + 15, 250, 40]);
 448   }
 449 }
 450
 451 module TestSelectWidth(){
 452   translate([-30, -(phone_height - 25), -20])
 453     mirror([0, 1, 0])
 454     cube([200, 50, 40]);
 455 }
 456
 457 module TestWidth(){ ////toplevel
 458   intersection(){
 459     Case();
 460     TestSelectWidth();
 461   }
 462 }
 463
 464 module TestLidWidthPrint(){ ////toplevel
 465   rotate([0,180.0]) intersection(){
 466     Lid();
 467     TestSelectWidth();
 468   }
 469 }
 470
 471 module TestSelectCamera(){
 472   CaseBase_rhsflip(1)
 473     translate([0,0,-25])
 474     linear_extrude(height = 50)
 475     mirror([0, 1, 0])
 476     rectfromto([-20, -20],
 477                camera_pos_br + bumper + [ 5, 5 ]);
 478 }
 479
 480 module TestSelectRearSpeaker(){
 481   CaseBase_rhsflip(1) CaseBase_botflip([1])
 482     linextr(-20,20)
 483     mirror([0,1,0])
 484     translate(rearspeaker_pos_bl + bumper)
 485     rectfromto(-(rearspeaker_gap + [40,2]),
 486                rearspeaker_size + rearspeaker_gap + [2,2]);
 487 }
 488
 489 module TestCamera(){ ////toplevel
 490   intersection(){
 491     Case();
 492     TestSelectCamera();
 493   }
 494 }
 495
 496 module TestLidByCamera(){ ////toplevel
 497   intersection(){
 498     Lid();
 499     TestSelectCamera();
 500   }
 501 }
 502
 503 module TestLidByCameraPrint(){ ////toplevel
 504   rotate([180,0,0]) TestLidByCamera();
 505 }
 506
 507 module DemoByCamera(){ ////toplevel
 508   color("blue") TestLidByCamera();
 509   color("red")  TestCamera();
 510 }
 511
 512 module OneKeeper(){ ////toplevel
 513   translate([0, -phone_cnr_rad, 0])
 514     rotate([90, 0, 0])
 515     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 516     KeeperProfile();
 517 }
 518
 519 module OneKeeperPrint(){ ////toplevel
 520   rotate([0,180,0])
 521     OneKeeper();
 522 }
 523
 524 module LidPrint(){ ////toplevel
 525   rotate([0,180,0])
 526     Lid();
 527 }
 528
 529 module TestSelectFrame(){
 530   include = [1,-1] * (epp2i[0] + 4);
 531
 532   difference(){
 533     cube(1000, center=true);
 534     translate([0,0, -100])
 535       linear_extrude(height=200)
 536       rectfromto(include,  inside_br - include);
 537   }
 538 }
 539
 540 module TestFrameCase(){ ////toplevel
 541   intersection(){
 542     Case();
 543     union(){
 544       TestSelectFrame();
 545       TestSelectCamera();
 546       TestSelectRearSpeaker();
 547     }
 548   }
 549 }
 550
 551 module TestFrameLidPrint(){ ////toplevel
 552   rotate([0,0,180]) intersection(){
 553     Lid();
 554     TestSelectFrame();
 555   }
 556 }
 557
 558 module Keeper(){ ////toplevel
 559   CaseBase_rhsflip()
 560     OneKeeper();
 561 }
 562
 563 module ButtonPlanForDemo(z, deep, cut){
 564   translate([0,0,z])
 565     ButtonPlan(8, deep, cut);
 566 }
 567
 568 module DemoProfiles(){ ////toplevel
 569   LidEdgeProfile();
 570   %EdgeProfile();
 571   KeeperProfile();
 572   translate([0,0,-1]) color("black") KeeperProfile(1);
 573
 574   translate([20,0]) {
 575     LidEdgeProfile();
 576     %EdgeProfile();
 577
 578     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 579
 580     color("blue") ButtonCoverProfile();
 581     color("red") {
 582       rectfromto(bppQ, demopoint_QR);
 583       rectfromto(bppR, demopoint_QR);
 584     }
 585   }
 586
 587   translate([-20,0]) {
 588     color("black") ButtonPlanForDemo(-2, 0,1);
 589     color("red" )  ButtonPlanForDemo(-4, 1,1);
 590     color("blue")  ButtonPlanForDemo(-6, 1,0);
 591   }
 592 }
 593
 594 //EdgeProfile();
 595 //KeeperProfile();
 596 //CaseBase();
 597 //%Case();
 598 //Keeper();
 599 //LidEdgeProfile();
 600 //KeeperProfile();
 601 //DemoProfiles();