fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213
 214 catch_slop = 0.50;
 215
 216 foldover_gap = 0.50;
 217 foldover_lever_gap = 0.50;
 218
 219 // properties of the hinge fasteners
 220 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 221 hingescrew_shaft_len = 12;
 222 hingescrew_fasteners_extra_thick = 0.40;
 223 // ^ amount of thread protruding if everything was completely nominal
 224 //   and we are using two nuts
 225 hingescrew_nut_access_dia = 4.72 + 0.50;
 226 // ^ washer is 4.72 dia
 227 //   also, want to get pliers or tiny spanner in to do up locknut
 228 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 229 hingescrew_nut_thick = 1.93;
 230 hingescrew_head_th = 1.38 + 0.75;
 231 hingescrew_head_dia = 3.92;
 232
 233 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 234
 235 lever_cover_th = 0.75;
 236 hingemount_th = 2.5;
 237 hingemount_wd = 4.8725;
 238
 239 $fa = 5;
 240 $fs = 0.1;
 241
 242 button_l_fudge = 4.4;
 243 buttonishleg_default_l_is_fudge = 10;
 244
 245 hinge_base_slope = 1.5; // bigger is steeper
 246
 247 strut_min_at_end = 1.5;
 248
 249 hinge_x_gap = 0.125;
 250 hinge_x_postscrew_gap = 0.75;
 251 hinge_x_arms_gap = 0.35;
 252 hinge_r_arms_gap = 0.55;
 253
 254 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 255
 256 catch_len = 7.5;
 257 catch_width = 15;
 258 catch_thickness = 1.3;
 259 catch_side_gap = 0.75; // each side
 260
 261 catch_depth = 0.75;
 262 catch_height = 0.35;
 263 catch_finger_height = 1.5;
 264 catch_finger_depth = 2.5;
 265
 266 catch_topcurve_r = 5.0;
 267
 268 prop_recess_under = 0.50;
 269 prop_recess_slop = 0.200; // each side
 270 prop_end_dia = 0.5;
 271 prop_main_th = 3;
 272 prop_taper_len = 6;
 273 prop_main_width = 4;
 274 prop_side_gap = 0.75; // each side
 275 prop_lidrecess_behind = 0.75;
 276 prop_caserecess_behind = 0.75;
 277 prop_caserecess_taper = 0.45; // one side only
 278 prop_prop_gap = 0.5;
 279 prop_prong_heel_slope = 0.5;
 280
 281 lid_fold_clearance_antislop = 0.5;
 282
 283 // ---------- calculated ----------
 284
 285 phone_width =  (phone + bumper*2)[0];
 286 phone_height = (phone + bumper*2)[1];
 287
 288 inside_br = [phone_width, -phone_height];
 289
 290 prop_prong_h = prop_main_th;
 291
 292 //echo(camera_pos_tl + bumper,
 293 //     camera_pos_br + bumper);
 294
 295 // ----- could be changed -----
 296 lid_buttoncover_gap = lid_gap_x;
 297 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 298
 299 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 300
 301 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 302
 303 //prop_nose_len = case_th_lid - prop_recess_under;
 304 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 305 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 306
 307
 308 //lid_lip_overlap_width xxx bad name = ;
 309 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 310
 311 epp0 = [0,0];
 312 epp1 = [0, -phone_edge_thick];
 313 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 314 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 315 epp3 = epp2i + [10, 0];
 316 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 317 epp4 = epp5 + [-1,0] * case_th_side;
 318
 319 kppe = [0,0];
 320 kppd = kppe + [1,0] * keeper_inner_width;
 321 kppc = kppd + [0,1] * keeper_th_z;
 322 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 323 kppf = kppe - [0,1] * keeper_inner_height;
 324 kppa = [ kppb[0], kppf[1] ];
 325
 326 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 327 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 328
 329 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 330 // exact x posn not very important; must extend past end of keeper
 331
 332 lpp15 = [ lpp14[0],
 333           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 334           + lid_screen_gap_extra ];
 335 // ^ beam theory says to maximise force before contact,
 336 //   the gap below the `beam' (the lid) must be 1/3
 337 //   the thickness (ie the lid thickness) if the beam
 338 //   is solid, or 1/2 if it has a top and bottom only.
 339 //   ours is mostly solid.
 340
 341 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 342              case_th_lip);
 343
 344 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 345 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 346
 347 case_bottom_z = epp2o[1] - case_th_bottom;
 348
 349 // button profile
 350 bppM = epp4 + [0,5];
 351 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 352 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 353 bppS = [ epp1[0], bppR[1] ];
 354 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 355 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 356 bppO = [ bppN[0], bppP[1] ];
 357 bppL = lpp10 + [5,0];
 358 bppK = [ bppL[0], bppN[1] ];
 359 bppJ = [ bppN[0], bppL[1] ];
 360 bppU = [ bppJ[0], lpp12[1] ];
 361 bppV = lpp11;
 362 bppW = lpp10;
 363
 364 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 365
 366 // notification led aperture
 367
 368 nla_r0 = led_aperture/2;
 369 nla_r1 = nla_r0 + led_window_ledge;
 370 nla_r2 = nla_r1 + multicolour_gap;
 371 nla_t =
 372   led_window_style >= 3 ? initial_layer_thick :
 373   led_window_style >= 2 ? led_window_ledge : 0;
 374
 375
 376 // hinge plan
 377 hp_rn = hingescrew_nut_access_dia/2;
 378 hp_r2_min = hp_rn + lever_cover_th;
 379 hp_rs = hingescrew_shaft_dia/2;
 380 hp_r1_min = hp_rs + hingemount_th;
 381
 382 hp_r1 = max(hp_r1_min, hp_r2_min);
 383 hp_r2 = hp_r1;
 384
 385 hppU = lpp13;
 386 hppS = epp2o + [0,-1] * case_th_bottom;
 387 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 388
 389 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 390          0.5 * (hppU + hppS)[1] ];
 391 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 392 hppB = hppT + [0,-1] * hp_k;
 393
 394 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 395 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 396 hppE = [ hppE_x, hppE_y ];
 397
 398 // hinge elevation x coords
 399
 400 hex20 = max(epp2o[0],
 401             phone_cnr_rad,
 402             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 403 hex21 = hex20 + hingemount_wd;
 404 hex22 = hex21 + hinge_x_gap;
 405 hex27 = hex20 + hingescrew_shaft_len;
 406 hex24 = hex27 + hinge_x_postscrew_gap;
 407 hex23 = hex27 - (hingescrew_nut_thick*2
 408                  + hingescrew_fasteners_extra_thick);
 409 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 410
 411 echo(hex20, hex21, hex22, hex23, hex24);
 412 //  6, 10.8725, 10.9975, 13.74, 18.75
 413 module chk(act,exp) {
 414   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 415   else echo("ok", act);
 416 }
 417 chk(hex20, 6);
 418 chk(hex21, 10.8725);
 419 chk(hex22, 10.9975);
 420 chk(hex23, 13.74);
 421 chk(hex24, 18.75);
 422
 423 lid_fold_clearance_skew =
 424   (lpp10[1] - hppB[1]) /
 425   (lpp10[0] - hppB[0]);
 426
 427 echo("SK",lid_fold_clearance_skew);
 428
 429 // catch
 430
 431 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 432 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 433 cppB = [ epp0[0], cppA[1] ];
 434 cppP = [ epp4[0], cppJ[1] ];
 435
 436 cppS = cppJ + [0,-1] * catch_len;
 437 cppD = [ cppA[0], cppS[1] + catch_slop ];
 438 cppC = [ cppB[0], cppD[1] ];
 439 cppT = cppS + [1,0] * catch_depth;
 440 cppU = cppT + [0,-1] * catch_height;
 441 cppV = [ cppS[0], cppU[1] - catch_depth ];
 442
 443 cppR = 0.5*(cppP + cppJ);
 444
 445 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 446 cppQ = [ cppR[0],
 447          cppV[1] - (catch_finger_height - cp_rQ) ];
 448 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 449
 450 // lanyard
 451
 452 ly_r = lanyard_half_dia / 2;
 453 ly_rc = ly_r * 2;
 454
 455 ly_theta = -atan2vector(epp2i - epp1);
 456 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 457
 458 max_case_bottom_edge_thickness =
 459   case_th_bottom
 460   + sin(ly_theta) * (epp2i-epp2o)[0];
 461
 462 ly_q_z = -(ly_rc + ly_r);
 463 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 464
 465 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 466
 467 // prop recess in case
 468
 469 prop_x_pos = phone_width/2;
 470
 471 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 472
 473 prc_r1 = prop_end_dia/2;
 474 prc_r3 = prc_r1 + prop_recess_slop;
 475
 476 prcp2 = [ epp4[0] + prop_buildout_less,
 477           case_bottom_z ];
 478
 479 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 480
 481 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 482           epp2i[1] - prc_r3 - prop_recess_under];
 483
 484 // prop recess in lid
 485
 486 prl_r10 = prop_end_dia/2;
 487 prl_r10o = prl_r10 + prop_recess_slop;
 488
 489 prlp10 = lpp10 + [1,1] * prl_r10o
 490   + [1,0] * prop_lidrecess_behind
 491   + [0,1] * prop_recess_under;
 492
 493 // prop
 494
 495 $prpp10 = [0,0];
 496 $prpp11 = [0, prop_taper_len];
 497
 498 $prp_r10 = prl_r10;
 499
 500 // ---------- modules ----------
 501
 502 module AdhocMultiprintFrame(phase, z0, zs) {
 503   // from z0 to z0 + zs*layer
 504   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 505   xextra = extra + -epp4[0];
 506   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 507   yextra = extra + -epp4[0];
 508   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 509   p0 = [ xrange[0], yrange[0] ];
 510   p1 = [ xrange[1], yrange[1] ];
 511   echo(p0, p1);
 512   translate([0,0, z0])
 513     mirror([0,0, zs<0 ? 1 : 0])
 514     linear_extrude(height= initial_layer_thick)
 515     difference(){
 516       rectfromto(p0 - [1,1] * initial_layer_width,
 517                  p1 + [1,1] * initial_layer_width);
 518       rectfromto(p0, p1);
 519     }
 520 }
 521
 522 module KeeperProfile(slant=0){
 523   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 524   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 525 }
 526
 527 module EdgeProfile(){
 528   difference(){
 529     hull(){
 530       translate(epp3) square(case_th_bottom*2, center=true);
 531       circleat(epp2o, r=case_th_bottom);
 532       circleat(epp1, r=case_th_side);
 533       rectfromto(epp0, epp4);
 534     }
 535     polygon([ epp5 + [0,10],
 536               epp1,
 537               epp2i,
 538               epp3 + [10,0] ]);
 539   }
 540 }
 541
 542 module LanyardLanyardProfile(entry=false){
 543   hull(){
 544     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 545       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 546         circle(r= lanyard_half_dia/2);
 547   }
 548 }
 549
 550 module LanyardCurveChannelProfile(){
 551   translate([0, -ly_r])
 552     LanyardLanyardProfile();
 553 }
 554
 555 module LanyardEntryChannelProfile(){
 556   LanyardLanyardProfile(true);
 557 }
 558
 559 module LanyardMainChannelProfile(){
 560   LanyardCurveChannelProfile();
 561   difference(){
 562     square(center=true, ly_r * [6, 2]);
 563     for (xs=[-1,+1])
 564       translate(ly_r * [3 * xs, -1])
 565         circle(r = ly_r);
 566   }
 567 }
 568
 569 module LanyardEntryOuterProfile(){
 570   circleat([ly_re + ly_r, 0], ly_re);
 571 }
 572
 573 module LanyardEntry(){
 574   q_z = ly_q_z;
 575   oec_y = ly_oec_y;
 576
 577   d_x = -ly_rc;
 578
 579   translate([d_x, 0, q_z]) {
 580     intersection(){
 581       rotate([90,0,0])
 582         rotate_extrude(convexity=10)
 583         rotate(90)
 584         translate([0, -q_z])
 585         LanyardCurveChannelProfile();
 586       translate([0,-10,0])
 587         cube([20,20,20]);
 588     }
 589   }
 590
 591   mirror([0,0,1])
 592     translate([0,0,-1])
 593     linear_extrude(height=20)
 594     rotate(-90)
 595     LanyardEntryChannelProfile();
 596
 597   translate([0, ly_r*2, 0])
 598     rotate([90,0,0])
 599     linear_extrude(height = ly_r*4){
 600     difference(){
 601       rectfromto([d_x, q_z], [ly_r, 0]);
 602       circleat([d_x, q_z], ly_rc);
 603     }
 604   }
 605
 606   translate([0,0,q_z]){
 607     for (my=[0,1])
 608       mirror([0,my,0]){
 609         translate([0, oec_y, 0]){
 610           difference(){
 611             translate(ly_re * [-1,0,-2])
 612               cube(ly_re * [2,1,2]);
 613             rotate_extrude(convexity=10)
 614               LanyardEntryOuterProfile();
 615           }
 616         }
 617       }
 618     difference(){
 619       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 620         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 621       for (mx=[0,1])
 622         mirror([mx,0,0])
 623           rotate([90,0,0])
 624           translate([0,0,-10])
 625           linear_extrude(height=20)
 626           LanyardEntryOuterProfile();
 627     }
 628   }
 629 }
 630
 631 module LanyardCutout(l){
 632   rotate([0,-90,0])
 633     linear_extrude(height=l)
 634     rotate(-90)
 635     LanyardMainChannelProfile();
 636
 637   for (ee=[0,1]){
 638     translate(ee * l * [-1,0])
 639       mirror([ee,0,0])
 640       LanyardEntry();
 641   }
 642 }
 643
 644 module LidEdgeProfile(){
 645   polygon([ lpp10,
 646             lpp11,
 647             lpp12,
 648             lpp13,
 649             lpp13 + [10, 0],
 650             lpp15 + [10, 0],
 651             lpp15,
 652             lpp14,
 653             ]);
 654   intersection(){
 655     circleat(lpp12, r=lp_r12);
 656     rectfromto( lpp12 + [-10,   0],
 657                 lpp12 + [+10, +10] );
 658   }
 659 }
 660
 661 module LidEdgeFoldClearanceProfile(){
 662   translate([-lid_fold_clearance_antislop, 0])
 663     polygon([ lpp10,
 664               lpp11,
 665               lpp11 + [-20,  0],
 666               lpp11 + [-20, 20],
 667               lpp11 + [+20, 20],
 668               lpp10 + [+20,  0] ]);
 669 }
 670
 671 module ButtonCoverProfile(){
 672   intersection(){
 673     polygon(concat([ bppM, bppP, bppO, bppJ ],
 674                    (enable_support && !$button_suppress_over_keeper
 675                     ? [ bppU, bppV, bppW ] : []),
 676                    [ bppL, bppK ]));
 677     hull(){
 678       EdgeProfile();
 679       LidEdgeProfile();
 680     }
 681   }
 682 }
 683
 684 module ButtonPlan(l, deep, cut){
 685   epsilon =
 686     (cut  ? 0 : lid_buttoncover_gap);
 687
 688   delta =
 689     (deep ? lid_buttoncover_overlap : 0);
 690
 691   C = [0,0]; // by definition
 692   T = [ 0, epp4[1] ];
 693   G = T + [0,10];
 694
 695   B0 = C + [0,-1] * button_cutout_depth;
 696   B1 = B0 + [0,1] * epsilon;
 697
 698   r0 = 0.5 * (T[1] - B0[1]);
 699   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 700   H = A + [0,-1] * delta;
 701
 702   D = A + [-2,0] * r0;
 703   F = D + [0,10];
 704
 705   E0 = 0.5 * (D + A);
 706   E1 = E0 + [1,0] * epsilon;
 707
 708   I0 = [ E0[0], H[1] ];
 709   I1 = [ E1[0], H[1] ];
 710
 711   hull(){
 712     for (m=[0,1]) mirror([m,0])
 713       circleat(H, r0 - epsilon);
 714   }
 715   for (m=[0,1]) mirror([m,0]) {
 716     difference(){
 717       polygon([ E1,
 718                 I1,
 719                 H,
 720                 B1,
 721                 G,
 722                 F,
 723                 D
 724                 ]);
 725       circleat(D, r0 + epsilon);
 726     }
 727   }
 728 }
 729
 730 module CatchCatchProfile(){
 731   hull(){
 732     for (c=[ cppR, cppQ ])
 733       circleat(c, cp_rQ);
 734   }
 735   hull(){
 736     circleat(lpp12, lp_r12);
 737     circleat(lpp12 + [5,0], lp_r12);
 738     rectfromto(cppP, cppP + [5,0.1]);
 739   }
 740   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 741 }
 742
 743 module CatchCutProfile(){
 744   polygon([ cppB,
 745             cppA,
 746             cppD,
 747             cppF,
 748             cppF + [0,-10],
 749             cppF + [-10,-10],
 750             lpp12 + [-10,0],
 751             lpp12 + [10,0]
 752             ]);
 753 }
 754
 755 module Flip_rhs(yn=[0,1]) {
 756   for ($rhsflip=yn) {
 757     translate([phone_width/2, 0, 0])
 758       mirror([$rhsflip,0,0])
 759       translate([-phone_width/2, 0, 0])
 760       children();
 761   }
 762 }
 763
 764 module Flip_bot(yn=[0,1]) {
 765   for ($botflip=yn) {
 766     translate([0, -phone_height/2, 0])
 767       mirror([0, $botflip, 0])
 768       translate([0, phone_height/2, 0])
 769       children();
 770   }
 771 }
 772
 773 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 774   // sides
 775   Flip_rhs(){
 776     translate([0, -phone_cnr_rad, 0])
 777       rotate([90,0,0])
 778       linear_extrude(height = phone_height - phone_cnr_rad*2)
 779       children(0);
 780   }
 781   // corners
 782   Flip_rhs() Flip_bot() {
 783     translate([+1,-1] * phone_cnr_rad)
 784       intersection(){
 785         rotate_extrude()
 786           intersection(){
 787             mirror([1,0,0])
 788               translate([-1,0] * phone_cnr_rad)
 789               children(0);
 790             rectfromto([0,-20],[10,20]);
 791           }
 792         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 793           cube([10,10,40]);
 794       }
 795   }
 796   // top and bottom
 797   Flip_bot(){
 798     translate([ phone_width - phone_cnr_rad, 0,0 ])
 799       rotate([90,0,-90])
 800       linear_extrude(height = phone_width - phone_cnr_rad*2)
 801       children(0);
 802   }
 803   // fill
 804   translate([0,0, fill_zstart])
 805     mirror([0,0, fill_downwards])
 806     linear_extrude(height = fill_th)
 807     rectfromto([+1,-1] * phone_cnr_rad,
 808                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 809 }
 810
 811 module CaseAperture(pos, dia, $fn) {
 812   theta = 180/$fn;
 813   translate([ pos[0] + bumper[0],
 814               -epp2i[0],
 815               -pos[1] ])
 816     rotate([-90, theta, 0])
 817     cylinder(r = dia/2 / cos(theta),
 818              h = 60);
 819 }
 820
 821 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 822   // y_ref_sign:
 823   //   +1  measured from top    of actual phone to top    of button
 824   //   -1  measured from bottom of actual phone to bottom of button
 825   //    0  y is centre of button in coordinate system
 826   $button_l= l;
 827   $button_suppress_over_keeper= suppress_over_keeper;
 828   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 829           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 830           y;
 831   //echo(eff_y);
 832   translate([0, eff_y, 0])
 833     children();
 834 }
 835
 836 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 837   $button_leg_only = true;
 838   SideButton(y, y_ref_sign, l) children();
 839 }
 840
 841 module Buttons(){
 842   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 843   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 844   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 845   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 846 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 847 }
 848
 849 module Struts(x_start, z_min, th){
 850   // if th is negative, starts at z_min and works towards -ve z
 851   // and object should then be printed other way up
 852   for (i= [1 : 1 : case_struts_count]) {
 853     translate([0,
 854                0,
 855                z_min])
 856       mirror([0,0, th<0 ? 1 : 0])
 857       translate([0,
 858                  -phone_height * i / (case_struts_count+1),
 859                  case_struts_solid_below])
 860       linear_extrude(height= abs(th)
 861                      -(case_struts_solid_below+case_struts_solid_above))
 862       rectfromto([               x_start, -0.5 * case_struts_width ],
 863                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 864   }
 865 }
 866
 867 module OrdinaryRearAperture(rhs,bot, pos){
 868   Flip_rhs(rhs) Flip_bot(bot)
 869     linextr(-20, 20)
 870     mirror([0,1])
 871     translate(pos + bumper)
 872     children();
 873 }
 874
 875 module MicroUSB(){
 876   Flip_bot(1){
 877     rotate([90,0,0])
 878       mirror([0,0,1])
 879       linextr(-epp2i[0], 60)
 880       translate([0.5 * phone_width, 0, 0])
 881       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 882                  [+microusb_width/2, epp0[1] + -microusb_above]);
 883   }
 884 }
 885
 886 module OrdinaryRearApertures(){
 887   // rear speaker
 888   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 889     rectfromto(-rearspeaker_gap,
 890                rearspeaker_size + rearspeaker_gap);
 891
 892   // finger hole to remove phone
 893   if (len(fingerpushhole_dias))
 894     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 895                                 phone[1]/2 ])
 896     scale(fingerpushhole_dias)
 897     circle(r= 0.5 );
 898 }
 899
 900 module RearCameraAperture(){
 901   Flip_rhs(1)
 902     mirror([0, 0, 1])
 903     linear_extrude(height = 20)
 904     mirror([0, 1, 0])
 905     translate(bumper)
 906     rectfromto(camera_pos_tl, camera_pos_br);
 907 }
 908
 909 module HingeLidProfile(){
 910   hull(){
 911     circleat(hppT, hp_r1);
 912     circleat(lpp12, lp_r12);
 913     polygon([lpp10,
 914              lpp13 + [2,0],
 915              lpp12,
 916              hppT]);
 917   }
 918 }
 919
 920 module HingeBaseProfile(){
 921   difference(){
 922     hull(){
 923       circleat(hppB, hp_r1);
 924       circleat(hppE, hp_r1);
 925       circleat(epp2o, case_th_bottom);
 926       circleat(hppB + [10,0], hp_r1);
 927     }
 928     polygon([epp5, epp1, epp2i, epp3, bppL]);
 929   }
 930 }
 931
 932 module HingeLeverOuterProfile(){
 933   hull(){
 934     circleat(hppT, hp_r2);
 935     circleat(hppB, hp_r2);
 936   }
 937 }
 938
 939 module HingeLeverInnerProfile(){
 940   for (s = [-1,+1]) {
 941     c = s > 0 ? hppT : hppB;
 942     translate(c)
 943       mirror([0,0,s>0])
 944       rotate(s<0 ? -40 : 0)
 945       hull()
 946       for (x=[-20,20])
 947         for (y=[0, s * 10])
 948           translate([x,y])
 949             circle(hp_rn);
 950   }
 951 }
 952
 953 module HingeLeverNutProfile(){
 954   for (c= [hppB, hppT]) {
 955     translate(c)
 956       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 957   }
 958 }
 959
 960 module Flip_hinge(doflip=1){
 961   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 962   translate(hinge_origin)
 963     rotate([doflip*180,0,0])
 964     translate(-hinge_origin)
 965     children();
 966 }
 967
 968 module HingePortion(x0,x1){
 969   Flip_rhs() Flip_bot(1)
 970     translate([x0,0,0])
 971     mirror([1,0,0])
 972     rotate([90,0,-90])
 973     linear_extrude(height=x1-x0)
 974     children();
 975 }
 976
 977 module CatchPortion(xwidth, ztop){
 978   width = catch_width + xwidth;
 979   w = width + catch_topcurve_r*2 + 1;
 980   translate([phone_width/2, 0,0]){
 981     difference(){
 982       rotate([90,0,-90])
 983         linextr(-w/2, w/2)
 984         children(0);
 985       translate([0, 50, 0])
 986         rotate([90,0,0])
 987         linear_extrude(height=100){
 988         for (m=[0,1]) mirror([m,0,0]) {
 989           hull(){
 990             translate([w/2, ztop - catch_topcurve_r])
 991               circle(catch_topcurve_r);
 992             translate([w/2, -50])
 993               square(catch_topcurve_r*2, center=true);
 994           }
 995         }
 996       }
 997     }
 998   }
 999 }
1000
1001 module CaseBase(){
1002   AroundEdges(epp3[1], case_th_bottom, 1)
1003     EdgeProfile();
1004 }
1005
1006 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1007
1008 module PropProfileAssignments(gamma){
1009   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1010   x = prop_x(gamma);
1011   p = phone_height + prlp10[0] - hppB[0];
1012   b = p + x;
1013
1014   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1015   a = q + x;
1016   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1017   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1018
1019   $prp_theta = 90 - $prp_alpha;
1020   beta = 180 - $prp_alpha - gamma;
1021   psi = 90 - beta;
1022
1023   //echo("abc", a,b,c);
1024
1025   v1 = [ [ cos(psi), -sin(psi) ],    // x
1026          [ sin(psi),  cos(psi) ] ];  // y
1027
1028   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1029
1030   $prp_r1 = prc_r1;
1031   $prp_r11 = prop_main_th/2;
1032
1033   $prpp1 = $prpp7 + [1,0] *
1034     // this is approximate, but will do
1035     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1036   $prpp3 = $prpp1 +
1037     v1[0] * -$prp_r1 +
1038     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1039   $prpp12 = $prpp3 + v1[0] *
1040     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1041   $prp_r8 = prop_main_th;
1042   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1043   $prp_r5 = $prp_r8;
1044   $prpp5 = [ $prpp12[0] - $prp_r5,
1045             $prpp3[1] - prop_prong_h + $prp_r5 ];
1046   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1047          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1048   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1049   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1050
1051   children();
1052 }
1053
1054 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
1055   PropProfileAssignments(gamma){
1056
1057     //#circleat($prpp3,1);
1058     //#circleat($prpp12,1);
1059
1060     if (!cut) {
1061       hull(){
1062         translate($prpp8)
1063           intersection(){
1064             circle($prp_r8);
1065             polygon([[-20,-0], [20,20], [0,0]]);
1066           }
1067         rectfromto($prpp6, $prpp9);
1068         translate($prpp5) intersection(){
1069           circle($prp_r5);
1070           polygon([[-10,-10], [0,0], [10,0]]);
1071         }
1072         rectfromto($prpp12 + [0,-0.1], $prpp3);
1073       }
1074       hull(){
1075         circleat($prpp1, $prp_r1);
1076         rectfromto($prpp12 + [0,-0.1], $prpp3);
1077       }
1078     }
1079     // main shaft
1080     rotate([0,0, rot*-$prp_theta]){
1081       hull(){
1082         extra = cut ? prop_recess_slop : 0;
1083         rectfromto($prpp6, $prpp9);
1084         circleat($prpp11, $prp_r11 + extra);
1085         circleat($prpp10, $prp_r10 + extra);
1086       }
1087     }
1088   }
1089 }
1090
1091 module PropAggregateProfile(){
1092   for (angle = prop_angles)
1093     PropProfile(angle, 0,0);
1094 }
1095
1096 module Prop(){ ////toplevel
1097   hw = prop_main_width/2;
1098   linextr(-hw, +hw)
1099     PropAggregateProfile();
1100 }
1101
1102 module Case(){ ////toplevel
1103   difference(){
1104     union(){
1105       CaseBase();
1106
1107       // ledge (fixed keeper)
1108       Flip_rhs(1-keeper_side) intersection(){
1109         rotate([90, 0, 0])
1110           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1111           KeeperProfile(1);
1112
1113         // outline of the whole case, to stop it protruding
1114         translate([0,0, -25])
1115           linear_extrude(height = 50)
1116           hull()
1117           Flip_bot()
1118           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1119       }
1120
1121       // hinge
1122       HingePortion(hex20, hex21) HingeBaseProfile();
1123
1124       // buildout for prop recess
1125       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1126         linextr(case_bottom_z, epp2i[1])
1127         hull() {
1128           for (dxs = [-1,+1])
1129             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1130                        -epp2o[0] ],
1131                      r = epp2o[0] - prcp2[0]);
1132         }
1133     }
1134
1135     // slot for keeper
1136     Flip_rhs(keeper_side)
1137       translate([0, -phone_cnr_rad, 0])
1138       rotate([90, 0, 0])
1139       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1140       minkowski(){
1141         KeeperProfile();
1142         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1143                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1144       }
1145
1146     // front camera
1147     RearCameraAperture();
1148
1149     // struts (invisible, because they're buried in the case)
1150     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1151
1152     Buttons(){
1153       mirror([1,0,0])
1154         rotate([90,0,90]) {
1155           if (!($button_leg_only && enable_support))
1156           intersection(){
1157             translate([0,0,-10])
1158               linear_extrude(height= 20)
1159               ButtonPlan($button_l, 0,1);
1160             if ($button_leg_only)
1161               rotate([-90,90,0])
1162                 translate([phone_width/2, -400, kppe[1]])
1163                 mirror([1-abs($rhsflip - keeper_side),0,0])
1164                 cube([400, 800, 50]);
1165             if (enable_support && !$button_suppress_over_keeper)
1166               rotate([-90,90,0])
1167               translate([-400, -400, kppd[1]])
1168                 mirror([0,0,1])
1169                 cube([800,800,100]);
1170           }
1171           translate([0,0, -bppR[0]])
1172             linear_extrude(height= 20)
1173             ButtonPlan($button_l, 1,1);
1174         }
1175
1176     }
1177
1178     // apertures along top edge
1179     CaseAperture(jack_pos, jack_dia, 8);
1180     Flip_rhs(1)
1181       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1182
1183     OrdinaryRearApertures();
1184
1185     MicroUSB();
1186
1187     // gaps for the lid's hinge arms
1188     HingePortion(hex20 - hinge_x_arms_gap,
1189                  hex21 + hinge_x_arms_gap)
1190       minkowski(){
1191         HingeLidProfile();
1192         circle(r= hinge_r_arms_gap, $fn= 8);
1193       }
1194
1195     // screw holes in the hinge arms
1196     HingeScrews();
1197
1198     // catch striker
1199     CatchPortion(catch_side_gap*2, epp4[1])
1200       CatchCutProfile();
1201
1202     // lanyard
1203     Flip_bot(1)
1204       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1205       rotate([0, ly_theta, 0])
1206       rotate([0,0,90])
1207       LanyardCutout(lanyard_channel_len);
1208
1209     // prop recess
1210     Flip_rhs(1)
1211       translate([prop_x_pos,0,0])
1212       mirror([0,1,0])
1213       rotate([90,0,90])
1214       linextr(-prop_recess_hw, +prop_recess_hw)
1215       hull(){
1216         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1217           circleat(prcp1 + 20*d,
1218                    prc_r3);
1219       }
1220   }
1221 }
1222
1223 module LidAdhocMultiprintFrame(phase){
1224   if (led_window_style >= 3) {
1225     AdhocMultiprintFrame(phase, lpp13[1], -1);
1226   }
1227 }
1228
1229 module LidAroundEdges(){
1230   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1231     children();
1232 }
1233
1234 module Lid(){ ////toplevel
1235   skew_centre = [0, lpp11[0], lpp11[1]];
1236   difference(){
1237     union(){
1238       intersection(){
1239         LidAroundEdges()
1240           LidEdgeProfile();
1241
1242         translate(skew_centre)
1243           multmatrix([[ 1, 0, 0, 0 ],
1244                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1245                       [ 0, 0, 1, 0 ],
1246                       [ 0, 0, 0, 1 ]])
1247           translate(-skew_centre)
1248           LidAroundEdges()
1249           LidEdgeFoldClearanceProfile();
1250       }
1251
1252       // button covers
1253       Buttons(){
1254         intersection(){
1255           rotate([90,0,90])
1256             translate([0,0,-10])
1257             linear_extrude(height= 20)
1258             ButtonPlan($button_l, 1,0);
1259           rotate([90,0,0])
1260              translate([0,0,-100])
1261             linear_extrude(height= 200)
1262             ButtonCoverProfile();
1263         }
1264       }
1265
1266       // hinge arms
1267       HingePortion(hex20, hex21) {
1268         LidEdgeProfile();
1269         HingeLidProfile();
1270       }
1271
1272       // catch
1273       CatchPortion(0, lpp12[1])
1274         CatchCatchProfile();
1275     }
1276     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1277
1278     // screw holes in the hinge arms
1279     HingeScrews();
1280
1281     // prop recess
1282     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1283       mirror([0,1,0])
1284       rotate([90,0,90])
1285       linextr(-prop_recess_hw, +prop_recess_hw)
1286       hull()
1287       for (pa = prop_angles)
1288         PropProfile(pa, 1,1);
1289
1290     // notification led aperture
1291     if (led_window_style)
1292       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1293         translate([0,0,-10])
1294           cylinder(r=nla_r0, h=20);
1295         if (led_window_style >= 2)
1296           translate([0,0, -nla_t])
1297             cylinder(r=nla_r2, height=20);
1298       }
1299
1300     }
1301
1302   LidAdhocMultiprintFrame(1);
1303 }
1304
1305 module HingeLever(){ ////toplevel
1306   difference() {
1307     // outer body, positive
1308     HingePortion(hex22, hex22 + phone_width/2)
1309       HingeLeverOuterProfile();
1310
1311     // space for the screws
1312     HingePortion(hex26, hex24)
1313       HingeLeverInnerProfile();
1314
1315     // recesses for the nuts
1316     HingePortion(hex23, hex26+1)
1317       HingeLeverNutProfile();
1318
1319     // bores for the screws
1320     HingeScrews();
1321
1322     // space for the charging cable
1323     MicroUSB();
1324     Flip_hinge() MicroUSB();
1325   }
1326 }
1327
1328 module LidWindow(){ ////toplevel
1329   translate([led_pos[0], -led_pos[1], lpp13[1]])
1330     mirror([0,0,1])
1331     cylinder(r= nla_r1, h=nla_t);
1332   LidAdhocMultiprintFrame(0);
1333 }
1334
1335 module LidWindowPrint(){ ////toplevel
1336   rotate([0,180,0])
1337     LidWindow();
1338 }
1339
1340 module DemoLidWindowSelect(){
1341   translate([led_pos[0], led_pos[1], -100]) {
1342     translate([0, -30, 0]) cube([400, 400, 200]);
1343   }
1344 }
1345
1346 module DemoLidWindow(){ ////toplevel
1347   %Lid();
1348   LidWindow();
1349   translate([0,40,0]){
1350     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1351     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1352   }
1353 }
1354
1355 module HingeLeverPrint(){ ////toplevel
1356   rotate([-90,0,0])
1357     translate([-phone_width/2, phone_height, 0])
1358     HingeLever();
1359 }
1360
1361 module TestSelectLength(){
1362   translate([-30, -200, -20])
1363     cube([30 + 15, 250, 40]);
1364 }
1365
1366 module TestLength(){ ////toplevel
1367   intersection(){
1368     Case();
1369     TestSelectLength();
1370   }
1371 }
1372
1373 module TestLengthRight(){ ////toplevel
1374   intersection(){
1375     Case();
1376     Flip_rhs(1)
1377       TestSelectLength();
1378   }
1379 }
1380
1381 module TestSelectWidth(){
1382   translate([-30, -(phone_height - 25), -20])
1383     mirror([0, 1, 0])
1384     cube([200, 50, 40]);
1385 }
1386
1387 module TestWidth(){ ////toplevel
1388   intersection(){
1389     Case();
1390     TestSelectWidth();
1391   }
1392 }
1393
1394 module TestLidWidthPrint(){ ////toplevel
1395   rotate([0,180.0]) intersection(){
1396     Lid();
1397     TestSelectWidth();
1398   }
1399 }
1400
1401 module TestSelectRearAperture(){
1402   minkowski(){
1403     union() children();
1404     translate([20, 0,0])
1405       cube([42, 2, 1], center=true);
1406   }
1407 }
1408
1409 module TestSelectCamera(){
1410   minkowski(){
1411     TestSelectRearAperture()
1412       RearCameraAperture();
1413     cube([0.1, 50, 0.1]);
1414   }
1415 }
1416
1417 module TestSelectOrdinaryRearApertures(){
1418   TestSelectRearAperture()
1419     OrdinaryRearApertures();
1420 }
1421
1422 module TestCamera(){ ////toplevel
1423   intersection(){
1424     Case();
1425     TestSelectCamera();
1426   }
1427 }
1428
1429 module TestLidByCamera(){ ////toplevel
1430   intersection(){
1431     Lid();
1432     TestSelectCamera();
1433   }
1434 }
1435
1436 module TestLidByCameraPrint(){ ////toplevel
1437   rotate([180,0,0]) TestLidByCamera();
1438 }
1439
1440 module DemoByCamera(){ ////toplevel
1441   color("blue") TestLidByCamera();
1442   color("red")  TestCamera();
1443 }
1444
1445 module OneKeeper(){ ////toplevel
1446   translate([0, -phone_cnr_rad, 0])
1447     rotate([90, 0, 0])
1448     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1449     KeeperProfile();
1450 }
1451
1452 module OneKeeperPrint(){ ////toplevel
1453   rotate([0,180,0])
1454     OneKeeper();
1455 }
1456
1457 module LidPrint(){ ////toplevel
1458   rotate([0,180,0])
1459     Lid();
1460 }
1461
1462 module TestSelectFrame(){
1463   include = [1,-1] * (epp2i[0] + 4);
1464
1465   difference(){
1466     cube(1000, center=true);
1467     translate([0,0, -100])
1468       linear_extrude(height=200)
1469       rectfromto(include,  inside_br - include);
1470   }
1471 }
1472
1473 module TestSelectLidFrame(){
1474   TestSelectFrame();
1475   translate([led_pos[0], -led_pos[1], -50])
1476     cylinder(r= nla_r2+3, h=100);
1477 }
1478
1479 module TestFrameCase(){ ////toplevel
1480   intersection(){
1481     Case();
1482     union(){
1483       TestSelectFrame();
1484       TestSelectCamera();
1485       TestSelectOrdinaryRearApertures();
1486     }
1487   }
1488 }
1489
1490 module TestSelectTopApertures(){
1491   translate([-100, -35, -100])
1492     cube([400, 100, 200]);
1493   LidAdhocMultiprintFrame(0);
1494   LidAdhocMultiprintFrame(1);
1495 }
1496
1497 module TestTopApertures(){ ////toplevel
1498   intersection(){
1499     Case();
1500     TestSelectFrame();
1501     TestSelectTopApertures();
1502   }
1503 }
1504
1505 module TestLidTopAperturesPrint(){ ////toplevel
1506   rotate([0,180,0]) intersection(){
1507     Lid();
1508     TestSelectLidFrame();
1509     TestSelectTopApertures();
1510   }
1511 }
1512
1513 module TestLidWindowTopAperturesPrint(){ ////toplevel
1514   rotate([0,180,0]) intersection(){
1515     LidWindow();
1516     TestSelectTopApertures();
1517   }
1518 }
1519
1520 module TestFrameLidPrint(){ ////toplevel
1521   rotate([0,180,0]) intersection(){
1522     Lid();
1523     TestSelectLidFrame();
1524   }
1525 }
1526
1527 module ButtonPlanForDemo(z, deep, cut){
1528   translate([0,0,z])
1529     ButtonPlan(8, deep, cut);
1530 }
1531
1532 module HingeScrews(){
1533   Flip_rhs() Flip_bot(1){
1534     for (c= [ hppT, hppB ])
1535       translate([ hex20,
1536                   -c[0],
1537                   c[1] ]){
1538         rotate([0,90,0])
1539           translate([0,0,-.2])
1540           cylinder( r= hingescrew_shaft_dia/2,
1541                     h = hingescrew_shaft_len+0.2 );
1542         rotate([0,-90,0])
1543           translate([0,0,+.1])
1544           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1545       }
1546   }
1547 }
1548
1549 module DemoPropAngleSelect(c){
1550   color(c) difference(){
1551     union(){ children(); }
1552     translate([ prop_x_pos, -400, -200 ])
1553       cube([ 400,800,400 ]);
1554   }
1555 }
1556
1557 module DemoPropAngle(ang){
1558   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1559   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1560
1561   translate(hL)
1562     rotate([ang/2,0,0])
1563     translate(-hL)
1564     translate(hC)
1565     rotate([ang/2,0,0])
1566     translate(-hC) {
1567       DemoPropAngleSelect("red") Case();
1568
1569       color("orange")
1570         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1571         PropProfileAssignments(ang) {
1572           echo($prpp1);
1573           rotate([-$prp_theta, 0, 0])
1574           translate([0, $prpp1[0], -$prpp1[1]])
1575           rotate([90,0,-90])
1576           Prop();
1577         }
1578     }
1579
1580   translate([0,0, -hp_k*2])
1581     DemoPropAngleSelect("blue")
1582     Lid();
1583 }
1584
1585 module DemoPropAngles(){ ////toplevel
1586   for (i=[0 : len(prop_angles)-1])
1587     translate(i * [0, -100, 100])
1588     DemoPropAngle(prop_angles[i]);
1589 }
1590
1591 module DemoHingeAngle(ang1,ang2){
1592   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1593   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1594
1595   translate(hL)
1596     rotate([ang2,0,0])
1597     translate(-hL)
1598     translate(hC)
1599     rotate([ang1,0,0])
1600     translate(-hC) {
1601       color("red") Lid();
1602     }
1603
1604   color("blue") intersection(){
1605     Case();
1606     union(){
1607       translate([bppJ[0], -400, -200])
1608         mirror([1,0,0])
1609         cube([400, 800, 400]);
1610       translate([10, -400, -200])
1611         cube([10, 800, 400]);
1612     }
1613   }
1614 }
1615
1616 module DemoHingeAngles(){ ////toplevel
1617   angles = [ 0, 4, 8, 12 ];
1618   echo("angles",angles);
1619   for (i=[0 : len(angles)-1]) {
1620     translate(i * [0, 0, 30]) {
1621       DemoHingeAngle(0,angles[i]);
1622       translate([0, 200, 0])
1623         DemoHingeAngle(angles[i],0);
1624     }
1625   }
1626 }
1627
1628 module DemoSelectAdhocLeftRight(right=0) {
1629   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1630     mirror([1-right, 0,0])
1631     cube([400, 800, 200]);
1632 }
1633
1634 module DemoLeft(){ ////toplevel
1635   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1636   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1637 }
1638
1639 module DemoFrame(){ ////toplevel
1640   color("red") TestFrameCase();
1641   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1642   color("black") HingeScrews();
1643   %HingeLever();
1644 }
1645
1646 module DemoLanyardCutout(){ ////toplevel
1647   LanyardCutout(25);
1648 }
1649
1650 module DemoHingedFrame(){ ///toplevel
1651   color("red") TestFrameCase();
1652   translate([0,0, -2*hp_k])
1653   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1654
1655   Flip_hinge(){
1656     color("orange") HingeLever();
1657     color("black") HingeScrews();
1658   }
1659 }
1660
1661 module DemoHinge(){ ////toplevel
1662   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1663     DemoFrame();
1664     translate([0,0, -hp_k*3])
1665       DemoHingedFrame();
1666   }
1667 }
1668
1669 module DemoProfiles(){ ////toplevel
1670   LidEdgeProfile();
1671   %EdgeProfile();
1672   KeeperProfile();
1673   translate([0,0,-1]) color("black") KeeperProfile(1);
1674   translate(ly_o){
1675     rotate(-ly_theta){
1676       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1677       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1678       translate([0, ly_q_z]){
1679         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1680         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1681       }
1682     }
1683   }
1684   translate([0,0,-5]) color("white") translate(epp2i)
1685     rotate(-ly_theta)
1686     rectfromto([-15, 0],
1687                [+15, -max_case_bottom_edge_thickness]);
1688
1689   translate([0,20]) {
1690     LanyardMainChannelProfile();
1691     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1692     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1693   }
1694
1695   translate([20,0]) {
1696     LidEdgeProfile();
1697     %EdgeProfile();
1698
1699     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1700
1701     color("blue") ButtonCoverProfile();
1702     color("red") {
1703       rectfromto(bppQ, demopoint_QR);
1704       rectfromto(bppR, demopoint_QR);
1705     }
1706   }
1707
1708   translate([-20,0]) {
1709     color("black") ButtonPlanForDemo(-2, 0,1);
1710     color("red" )  ButtonPlanForDemo(-4, 1,1);
1711     color("blue")  ButtonPlanForDemo(-6, 1,0);
1712   }
1713
1714   translate([0, -30]) {
1715     %LidEdgeProfile();
1716     %EdgeProfile();
1717     color("blue") HingeLidProfile();
1718     color("red")  HingeBaseProfile();
1719     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1720   }
1721
1722   for (f=[0,1]) {
1723     translate([-30, -60 + 30*f]) {
1724       translate([0,0,-4]) EdgeProfile();
1725       %translate([0,0,-10]) HingeBaseProfile();
1726       translate([0,-2] * f * hp_k) {
1727         translate([0,0,-4]) LidEdgeProfile();
1728         %translate([0,0,-10]) %HingeLidProfile();
1729       }
1730       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1731         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1732         translate([0,0,0]) color("red") difference(){
1733           HingeLeverOuterProfile();
1734           HingeLeverInnerProfile();
1735         }
1736         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1737       }
1738     }
1739   }
1740
1741   translate([20,-30]) {
1742     %EdgeProfile();
1743     %LidEdgeProfile();
1744     //translate([0,0,1]) CatchCutProfile();
1745     color("blue") CatchCatchProfile();
1746     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1747   }
1748
1749   translate([40,-30]) {
1750     difference(){
1751       LidEdgeProfile();
1752       translate(prlp10)
1753         PropProfile(10, 1, 0);
1754     }
1755     translate(prlp10)
1756       PropProfile(15, 0);
1757   }
1758   translate([60,-30]) {
1759     PropAggregateProfile();
1760   }
1761 }
1762
1763 //EdgeProfile();
1764 //KeeperProfile();
1765 //CaseBase();
1766 //%Case();
1767 //Keeper();
1768 //LidEdgeProfile();
1769 //KeeperProfile();
1770 //DemoProfiles();
1771 //PropRecess();