chiark / gitweb /
bc0cef0062460d5c596fed1c65c6c4d6709b1c17
[reprap-play.git] / fairphone-case.scad
1 // -*- C -*-
2
3 // Hard case for Fairphone 2
4 //
5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
6 //  See below for full licensing and disclaimer.
7 //
8 // Instructions
9 //
10 //  1. You will want to git clone this repository.
11 //
12 //  2. Decide about the notification LED aperture. See the variable
13 //     led_window_style, below.  The default here is "ad-hoc
14 //     multi-colour", which can produces a translucent (clear-ish)
15 //     window set into the lid, even on a single-nozzle printer.
16 //     See "Ad-hoc multi-colour", below.
17 //
18 //  3. use "make" to generate the necessary files:
19 //
20 //     make -j8 fairphone-case.auto.scads `for f in   \
21 //        HingePrint        \
22 //        LidWindowPrint    \
23 //        LidPrint          \
24 //        OneKeeperPrint    \
25 //        Case              \
26 //     ; do echo fairphone-case,$f.auto.stl; done`
27 //
28 //  4. Print them.  Case and OneKeeperPrint should probably be
29 //     the same colour.
30 //
31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
32 //     multi-colour:
33 //        i.   Set up for clear filament
34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
35 //             It won't take long.  As soon as it finishes, tell
36 //             your printer to warm up (so that in fact it does
37 //             not cool down).
38 //        iii. Leaving the output so far on the printbed, reload
39 //             your printer with the main lid colour.
40 //        iv.  Print LidPrint.  You can let this go unattended.
41 //
42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
43 //     and 8x M2 full nuts.
44 //
45 //     Make sure you get the hinge the right way round.  If you're not
46 //     sure, run
47 //         openscad fairphone-case,DemoHinge.auto.scad
48 //     to see an assembly diagram.
49 //
50 //     The nuts recess into the hinge.  You will want very fine
51 //     pliers.  As you screw each screw in, add the second nut when
52 //     the screw thread emerges from the first - this will be a
53 //     locknut.  Screw each screw to an appropriate tightness for the
54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
55 //     that makes closing the case work better.
56 //
57 //     When you have the stiffness right, tighten the locknuts onto
58 //     each first nut.
59 //
60 //  6. In use:
61 // 
62 //      - To put the phone in, drop its RH side into the RH side of
63 //        the case.  Then feed the keeper through the small hole.
64 //        Feed it right through.
65 //
66 //      - The optional prop can be used to prop the phone up (in
67 //        portrait orientation only right now).  See
68 //            openscad fairphone-case,DemoPropAngles.auto.scad
69 //
70 // Ad-hoc multi-colour
71 //     
72 //  This file is set up to let you make a translucent window using a
73 //  single-extruder printer, using a "two print run" technique.  This
74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
75 //  Cura.  If you are using a different printer, you may need to
76 //  adjust the parameters or try a different technique.  In particular,
77 //      initial_layer_thick
78 //         set so that the window is one layer thick
79 //      initial_layer_width
80 //         set so that the slicer draws a rectangle around the whole
81 //         object, rather than putting a "skirt" or anything inside
82 //
83 //  If you have a dual-extruder printer, you can set led_window_style
84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
85 //
86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
87 //
88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
90 //
91 // Other phones
92 //
93 //  It might well be possible to adapt this file for other phones.
94 //  If you do, let me know how you get on.
95 //
96 //
97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
98 //
99 //   Copyright (C)2018 Ian Jackson.
100 //
101 //    This program for generating a 3D model is free software: you can
102 //    redistribute it and/or modify it under the terms of the GNU
103 //    General Public License as published by the Free Software
104 //    Foundation, either version 3 of the License, or (at your option)
105 //    any later version.
106 //
107 //    This program is distributed in the hope that it will be useful,
108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
110 //    GNU General Public License for more details.
111 //
112 //    You should have received a copy of the GNU General Public
113 //    License along with this program.  If not, see
114 //    <http://www.gnu.org/licenses/>.
115 //
116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
118 //  this case will meet your needs.
119
120 include <utils.scad>
121 include <funcs.scad>
122
123 phone = [ 75.0, 145.0 ];
124
125 prop_buildout_less = 3;
126
127 prop_angles = [ 15, 30, 45, 60 ];
128
129 bumper = [ 0.250, -0.025 ];
130 // ^ One side.  Overall size is increased by twice this.
131 // If no bumpers, is the gap around the phone.
132
133 enable_support = 1;
134
135 led_window_style = 3;
136 // 0: no window
137 // 1: simply an opening
138 // 2: opening with separate cover model, for printing in clear (two colour)
139 // 3: like 2 but one-layer window for ad-hoc multi-colour
140
141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
142 initial_layer_width = 0.750; // ^ needed for mode 3 only
143 multicolour_gap = 0.15; // each side
144
145 phone_cnr_rad = 6.0;
146 phone_rim_depth = 0.80; // includes allowance for a screen protector
147
148 button_cutout_depth = 9;
149
150 phone_edge_thick = 9.0;
151 phone_total_thick = 12.0;
152 phone_backside_slope_inner = 1.5; // larger means shallower
153 phone_backside_slope_outer = 1.0; // larger means shallower
154
155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
157
158 jack_pos = [ 13.83, 8.485 ];
159 jack_dia = 10.64 + .5; // some jack I had lying around
160
161 led_pos = [ 13.98, 10.00 ];
162 led_aperture = 9;
163 led_window_ledge = 0.75; // each side
164
165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
166 noisecancelmic_dia = 4.00;
167
168 //fingerpushhole_dias = [ 15, 18 ];
169 fingerpushhole_dias = [];
170
171 lanyard_half_dia = 1.15;
172
173 rearspeaker_pos_bl = [ 12.64, 18.72 ];
174 rearspeaker_size   = [  3.76,  7.36 ];
175
176 microusb_above = 3.27 - 0.25;
177 microusb_below = 0.0;
178 microusb_width = 16.12 + 1.25;
179
180 case_th_bottom = 2.5;
181 case_th_lid = 3.0;
182 case_th_side = 2.3;
183 case_th_lip = 1.2;
184
185 lid_screen_gap_extra = .66;
186
187 case_struts_count = 6;
188 case_struts_solid_below = 1.00;
189 case_struts_solid_above = 0.75;
190 case_struts_width = 0.10;
191
192 keeper_th_z = 0.75;
193 keeper_th_x = 0.75;
194 keeper_inner_width = 2.75;
195 keeper_inner_height = 2.75;
196 keeper_slant_slope = 2; // larger means steeper
197
198 keeper_gap_z_top = 0.25;
199 keeper_gap_z_bot = 0.75;
200 keeper_gap_x     = 0.25;
201 keeper_gap_x_holes = 0.75;
202
203 keeper_side = 0; // 0 = lhs; 1 = rhs
204
205 case_lip = 1.25;
206
207 lid_gap_x = 0.25;
208 lid_gap_z = 0.25;
209 lid_lip = 1.75;
210 lid_edgepart_width = 5.0;
211 lid_buttoncover_thick = 1.3;
212
213 catch_slop = 0.50;
214
215 foldover_gap = 0.50;
216 foldover_lever_gap = 0.50;
217
218 // properties of the hinge fasteners
219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
220 hingescrew_shaft_len = 12;
221 hingescrew_fasteners_extra_thick = 0.40;
222 // ^ amount of thread protruding if everything was completely nominal
223 //   and we are using two nuts
224 hingescrew_nut_access_dia = 4.72 + 0.50;
225 // ^ washer is 4.72 dia
226 //   also, want to get pliers or tiny spanner in to do up locknut
227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
228 hingescrew_nut_thick = 1.93;
229 hingescrew_head_th = 1.38 + 0.75;
230 hingescrew_head_dia = 3.92;
231
232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
233
234 lever_cover_th = 0.75;
235 hingemount_th = 2.5;
236 hingemount_wd = 4.8725;
237
238 $fa = 5;
239 $fs = 0.1;
240
241 button_l_fudge = 4.4;
242 buttonishleg_default_l_is_fudge = 10;
243
244 hinge_base_slope = 1.5; // bigger is steeper
245
246 strut_min_at_end = 1.5;
247
248 hinge_x_gap = 0.125;
249 hinge_x_postscrew_gap = 0.75;
250 hinge_x_arms_gap = 0.35;
251 hinge_r_arms_gap = 0.55;
252
253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
254
255 catch_len = 7.5;
256 catch_width = 15;
257 catch_thickness = 1.0;
258 catch_side_gap = 0.75; // each side
259
260 catch_depth = 0.75;
261 catch_height = 0.35;
262 catch_finger_height = 1.5;
263 catch_finger_depth = 2.5;
264
265 catch_topcurve_r = 5.0;
266
267 prop_recess_under = 0.50;
268 prop_recess_slop = 0.200; // each side
269 prop_end_dia = 0.5;
270 prop_main_th = 3;
271 prop_taper_len = 6;
272 prop_main_width = 4;
273 prop_side_gap = 0.75; // each side
274 prop_lidrecess_behind = 0.75;
275 prop_caserecess_behind = 0.75;
276 prop_caserecess_taper = 0.45; // one side only
277 prop_prop_gap = 0.5;
278 prop_prong_heel_slope = 0.5;
279
280 lid_fold_clearance_antislop = 0.5;
281
282 // ---------- calculated ----------
283
284 phone_width =  (phone + bumper*2)[0];
285 phone_height = (phone + bumper*2)[1];
286
287 inside_br = [phone_width, -phone_height];
288
289 prop_prong_h = prop_main_th;
290
291 //echo(camera_pos_tl + bumper,
292 //     camera_pos_br + bumper);
293
294 // ----- could be changed -----
295 lid_buttoncover_gap = lid_gap_x;
296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
297
298 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
299
300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
301
302 //prop_nose_len = case_th_lid - prop_recess_under;
303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
305
306
307 //lid_lip_overlap_width xxx bad name = ;
308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
309
310 epp0 = [0,0];
311 epp1 = [0, -phone_edge_thick];
312 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
313 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
314 epp3 = epp2i + [10, 0];
315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
316 epp4 = epp5 + [-1,0] * case_th_side;
317
318 kppe = [0,0];
319 kppd = kppe + [1,0] * keeper_inner_width;
320 kppc = kppd + [0,1] * keeper_th_z;
321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
322 kppf = kppe - [0,1] * keeper_inner_height;
323 kppa = [ kppb[0], kppf[1] ];
324
325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
327
328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
329 // exact x posn not very important; must extend past end of keeper
330
331 lpp15 = [ lpp14[0],
332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
333           + lid_screen_gap_extra ];
334 // ^ beam theory says to maximise force before contact,
335 //   the gap below the `beam' (the lid) must be 1/3
336 //   the thickness (ie the lid thickness) if the beam
337 //   is solid, or 1/2 if it has a top and bottom only.
338 //   ours is mostly solid.
339
340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
341              case_th_lip);
342
343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
345
346 case_bottom_z = epp2o[1] - case_th_bottom;
347
348 // button profile
349 bppM = epp4 + [0,5];
350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
352 bppS = [ epp1[0], bppR[1] ];
353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
355 bppO = [ bppN[0], bppP[1] ];
356 bppL = lpp10 + [5,0];
357 bppK = [ bppL[0], bppN[1] ];
358 bppJ = [ bppN[0], bppL[1] ];
359 bppU = [ bppJ[0], lpp12[1] ];
360 bppV = lpp11;
361 bppW = lpp10;
362
363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
364
365 // notification led aperture
366
367 nla_r0 = led_aperture/2;
368 nla_r1 = nla_r0 + led_window_ledge;
369 nla_r2 = nla_r1 + multicolour_gap;
370 nla_t =
371   led_window_style >= 3 ? initial_layer_thick :
372   led_window_style >= 2 ? led_window_ledge : 0;
373
374
375 // hinge plan
376 hp_rn = hingescrew_nut_access_dia/2;
377 hp_r2_min = hp_rn + lever_cover_th;
378 hp_rs = hingescrew_shaft_dia/2;
379 hp_r1_min = hp_rs + hingemount_th;
380
381 hp_r1 = max(hp_r1_min, hp_r2_min);
382 hp_r2 = hp_r1;
383
384 hppU = lpp13;
385 hppS = epp2o + [0,-1] * case_th_bottom;
386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
387
388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
389          0.5 * (hppU + hppS)[1] ];
390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
391 hppB = hppT + [0,-1] * hp_k;
392
393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
395 hppE = [ hppE_x, hppE_y ];
396
397 // hinge elevation x coords
398
399 hex20 = max(epp2o[0],
400             phone_cnr_rad,
401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
402 hex21 = hex20 + hingemount_wd;
403 hex22 = hex21 + hinge_x_gap;
404 hex27 = hex20 + hingescrew_shaft_len;
405 hex24 = hex27 + hinge_x_postscrew_gap;
406 hex23 = hex27 - (hingescrew_nut_thick*2
407                  + hingescrew_fasteners_extra_thick);
408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
409
410 echo(hex20, hex21, hex22, hex23, hex24);
411 //  6, 10.8725, 10.9975, 13.74, 18.75
412 module chk(act,exp) {
413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
414   else echo("ok", act);
415 }
416 chk(hex20, 6);
417 chk(hex21, 10.8725);
418 chk(hex22, 10.9975);
419 chk(hex23, 13.74);
420 chk(hex24, 18.75);
421
422 lid_fold_clearance_skew =
423   (lpp10[1] - hppB[1]) /
424   (lpp10[0] - hppB[0]);
425
426 echo("SK",lid_fold_clearance_skew);
427
428 // catch
429
430 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
431 cppA = cppJ + [lid_gap_x, -lid_gap_z];
432 cppB = [ epp0[0], cppA[1] ];
433 cppP = [ epp4[0], cppJ[1] ];
434
435 cppS = cppJ + [0,-1] * catch_len;
436 cppD = [ cppA[0], cppS[1] + catch_slop ];
437 cppC = [ cppB[0], cppD[1] ];
438 cppT = cppS + [1,0] * catch_depth;
439 cppU = cppT + [0,-1] * catch_height;
440 cppV = [ cppS[0], cppU[1] - catch_depth ];
441
442 cppR = 0.5*(cppP + cppJ);
443
444 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
445 cppQ = [ cppR[0],
446          cppV[1] - (catch_finger_height - cp_rQ) ];
447 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
448
449 // lanyard
450
451 ly_r = lanyard_half_dia / 2;
452
453 // prop recess in case
454
455 prop_x_pos = phone_width/2;
456
457 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
458
459 prc_r1 = prop_end_dia/2;
460 prc_r3 = prc_r1 + prop_recess_slop;
461
462 prcp2 = [ epp4[0] + prop_buildout_less,
463           case_bottom_z ];
464
465 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
466
467 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
468           epp2i[1] - prc_r3 - prop_recess_under];
469
470 // prop recess in lid
471
472 prl_r10 = prop_end_dia/2;
473 prl_r10o = prl_r10 + prop_recess_slop;
474
475 prlp10 = lpp10 + [1,1] * prl_r10o
476   + [1,0] * prop_lidrecess_behind
477   + [0,1] * prop_recess_under;
478
479 // prop
480
481 $prpp10 = [0,0];
482 $prpp11 = [0, prop_taper_len];
483
484 $prp_r10 = prl_r10;
485
486 // ---------- modules ----------
487
488 module AdhocMultiprintFrame(phase, z0, zs) {
489   // from z0 to z0 + zs*layer
490   extra = phase * (initial_layer_width + multicolour_gap) + 5;
491   xextra = extra + -epp4[0];
492   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
493   yextra = extra + -epp4[0];
494   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
495   p0 = [ xrange[0], yrange[0] ];
496   p1 = [ xrange[1], yrange[1] ];
497   echo(p0, p1);
498   translate([0,0, z0])
499     mirror([0,0, zs<0 ? 1 : 0])
500     linear_extrude(height= initial_layer_thick)
501     difference(){
502       rectfromto(p0 - [1,1] * initial_layer_width,
503                  p1 + [1,1] * initial_layer_width);
504       rectfromto(p0, p1);
505     }
506 }
507
508 module KeeperProfile(slant=0){
509   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
510   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
511 }
512
513 module EdgeProfile(){
514   difference(){
515     hull(){
516       translate(epp3) square(case_th_bottom*2, center=true);
517       circleat(epp2o, r=case_th_bottom);
518       circleat(epp1, r=case_th_side);
519       rectfromto(epp0, epp4);
520     }
521     polygon([ epp5 + [0,10],
522               epp1,
523               epp2i,
524               epp3 + [10,0] ]);
525   }
526 }
527
528 module LanyardLanyardProfile(entry=false){
529   hull(){
530     for (xs=[-1,+1] * (entry ? 2 : 1))
531       translate(xs * 0.5 * lanyard_half_dia * [1,0])
532         circle(r= lanyard_half_dia/2);
533   }
534 }
535
536 module LanyardMainChannelProfile(){
537   translate([0, -ly_r])
538     LanyardLanyardProfile();
539   difference(){
540     square(center=true, ly_r * [6, 2]);
541     for (xs=[-1,+1])
542       translate(ly_r * [3 * xs, -1])
543         circle(r = ly_r);
544   }
545 }
546
547 module LidEdgeProfile(){
548   polygon([ lpp10,
549             lpp11,
550             lpp12,
551             lpp13,
552             lpp13 + [10, 0],
553             lpp15 + [10, 0],
554             lpp15,
555             lpp14,
556             ]);
557   intersection(){
558     circleat(lpp12, r=lp_r12);
559     rectfromto( lpp12 + [-10,   0],
560                 lpp12 + [+10, +10] );
561   }
562 }
563
564 module LidEdgeFoldClearanceProfile(){
565   translate([-lid_fold_clearance_antislop, 0])
566     polygon([ lpp10,
567               lpp11,
568               lpp11 + [-20,  0],
569               lpp11 + [-20, 20],
570               lpp11 + [+20, 20],
571               lpp10 + [+20,  0] ]);
572 }
573
574 module ButtonCoverProfile(){
575   intersection(){
576     polygon(concat([ bppM, bppP, bppO, bppJ ],
577                    (enable_support && !$button_suppress_over_keeper
578                     ? [ bppU, bppV, bppW ] : []),
579                    [ bppL, bppK ]));
580     hull(){
581       EdgeProfile();
582       LidEdgeProfile();
583     }
584   }
585 }
586
587 module ButtonPlan(l, deep, cut){
588   epsilon =
589     (cut  ? 0 : lid_buttoncover_gap);
590
591   delta =
592     (deep ? lid_buttoncover_overlap : 0);
593
594   C = [0,0]; // by definition
595   T = [ 0, epp4[1] ];
596   G = T + [0,10];
597
598   B0 = C + [0,-1] * button_cutout_depth;
599   B1 = B0 + [0,1] * epsilon;
600
601   r0 = 0.5 * (T[1] - B0[1]);
602   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
603   H = A + [0,-1] * delta;
604
605   D = A + [-2,0] * r0;
606   F = D + [0,10];
607
608   E0 = 0.5 * (D + A);
609   E1 = E0 + [1,0] * epsilon;
610
611   I0 = [ E0[0], H[1] ];
612   I1 = [ E1[0], H[1] ];
613
614   hull(){
615     for (m=[0,1]) mirror([m,0])
616       circleat(H, r0 - epsilon);
617   }
618   for (m=[0,1]) mirror([m,0]) {
619     difference(){
620       polygon([ E1,
621                 I1,
622                 H,
623                 B1,
624                 G,
625                 F,
626                 D
627                 ]);
628       circleat(D, r0 + epsilon);
629     }
630   }
631 }
632
633 module CatchCatchProfile(){
634   hull(){
635     for (c=[ cppR, cppQ ])
636       circleat(c, cp_rQ);
637   }
638   hull(){
639     circleat(lpp12, lp_r12);
640     circleat(lpp12 + [5,0], lp_r12);
641     rectfromto(cppP, cppP + [5,0.1]);
642   }
643   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
644 }
645
646 module CatchCutProfile(){
647   polygon([ cppB,
648             cppA,
649             cppD,
650             cppF,
651             cppF + [0,-10],
652             cppF + [-10,-10],
653             lpp12 + [-10,0],
654             lpp12 + [10,0]
655             ]);
656 }
657
658 module Flip_rhs(yn=[0,1]) {
659   for ($rhsflip=yn) {
660     translate([phone_width/2, 0, 0])
661       mirror([$rhsflip,0,0])
662       translate([-phone_width/2, 0, 0])
663       children();
664   }
665 }
666
667 module Flip_bot(yn=[0,1]) {
668   for ($botflip=yn) {
669     translate([0, -phone_height/2, 0])
670       mirror([0, $botflip, 0])
671       translate([0, phone_height/2, 0])
672       children();
673   }
674 }  
675
676 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
677   // sides
678   Flip_rhs(){
679     translate([0, -phone_cnr_rad, 0])
680       rotate([90,0,0])
681       linear_extrude(height = phone_height - phone_cnr_rad*2)
682       children(0);
683   }
684   // corners
685   Flip_rhs() Flip_bot() {
686     translate([+1,-1] * phone_cnr_rad)
687       intersection(){
688         rotate_extrude()
689           intersection(){
690             mirror([1,0,0])
691               translate([-1,0] * phone_cnr_rad)
692               children(0);
693             rectfromto([0,-20],[10,20]);
694           }
695         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
696           cube([10,10,40]);
697       }
698   }
699   // top and bottom
700   Flip_bot(){
701     translate([ phone_width - phone_cnr_rad, 0,0 ])
702       rotate([90,0,-90])
703       linear_extrude(height = phone_width - phone_cnr_rad*2)
704       children(0);
705   }
706   // fill
707   translate([0,0, fill_zstart])
708     mirror([0,0, fill_downwards])
709     linear_extrude(height = fill_th)
710     rectfromto([+1,-1] * phone_cnr_rad,
711                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
712 }
713
714 module CaseAperture(pos, dia, $fn) {
715   theta = 180/$fn;
716   translate([ pos[0] + bumper[0],
717               -epp2i[0],
718               -pos[1] ])
719     rotate([-90, theta, 0])
720     cylinder(r = dia/2 / cos(theta),
721              h = 60);
722 }
723
724 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
725   // y_ref_sign:
726   //   +1  measured from top    of actual phone to top    of button
727   //   -1  measured from bottom of actual phone to bottom of button
728   //    0  y is centre of button in coordinate system
729   $button_l= l;
730   $button_suppress_over_keeper= suppress_over_keeper;
731   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
732           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
733           y;
734   //echo(eff_y);
735   translate([0, eff_y, 0])
736     children();
737 }
738
739 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
740   $button_leg_only = true;
741   SideButton(y, y_ref_sign, l) children();
742 }
743
744 module Buttons(){
745   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
746   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
747   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
748   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
749 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
750 }
751
752 module Struts(x_start, z_min, th){
753   // if th is negative, starts at z_min and works towards -ve z
754   // and object should then be printed other way up
755   for (i= [1 : 1 : case_struts_count]) {
756     translate([0,
757                0,
758                z_min])
759       mirror([0,0, th<0 ? 1 : 0])
760       translate([0,
761                  -phone_height * i / (case_struts_count+1),
762                  case_struts_solid_below])
763       linear_extrude(height= abs(th)
764                      -(case_struts_solid_below+case_struts_solid_above))
765       rectfromto([               x_start, -0.5 * case_struts_width ],
766                  [ phone_width - x_start, +0.5 * case_struts_width ]);
767   }
768 }
769
770 module OrdinaryRearAperture(rhs,bot, pos){
771   Flip_rhs(rhs) Flip_bot(bot)
772     linextr(-20, 20)
773     mirror([0,1])
774     translate(pos + bumper)
775     children();
776 }
777
778 module MicroUSB(){
779   Flip_bot(1){
780     rotate([90,0,0])
781       mirror([0,0,1])
782       linextr(-epp2i[0], 60)
783       translate([0.5 * phone_width, 0, 0])
784       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
785                  [+microusb_width/2, epp0[1] + -microusb_above]);
786   }
787 }
788
789 module OrdinaryRearApertures(){
790   // rear speaker
791   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
792     rectfromto(-rearspeaker_gap,
793                rearspeaker_size + rearspeaker_gap);
794
795   // finger hole to remove phone
796   if (len(fingerpushhole_dias))
797     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
798                                 phone[1]/2 ])
799     scale(fingerpushhole_dias)
800     circle(r= 0.5 );
801 }
802
803 module RearCameraAperture(){
804   Flip_rhs(1)
805     mirror([0, 0, 1])
806     linear_extrude(height = 20)
807     mirror([0, 1, 0])
808     translate(bumper)
809     rectfromto(camera_pos_tl, camera_pos_br);
810 }
811
812 module HingeLidProfile(){
813   hull(){
814     circleat(hppT, hp_r1);
815     circleat(lpp12, lp_r12);
816     polygon([lpp10,
817              lpp13 + [2,0],
818              lpp12,
819              hppT]);
820   }
821 }
822
823 module HingeBaseProfile(){
824   difference(){
825     hull(){
826       circleat(hppB, hp_r1);
827       circleat(hppE, hp_r1);
828       circleat(epp2o, case_th_bottom);
829       circleat(hppB + [10,0], hp_r1);
830     }
831     polygon([epp5, epp1, epp2i, epp3, bppL]);
832   }
833 }
834
835 module HingeLeverOuterProfile(){
836   hull(){
837     circleat(hppT, hp_r2);
838     circleat(hppB, hp_r2);
839   }
840 }
841
842 module HingeLeverInnerProfile(){
843   for (s = [-1,+1]) {
844     c = s > 0 ? hppT : hppB;
845     translate(c)
846       mirror([0,0,s>0])
847       rotate(s<0 ? -40 : 0)
848       hull()
849       for (x=[-20,20])
850         for (y=[0, s * 10])
851           translate([x,y])
852             circle(hp_rn);
853   }
854 }
855
856 module HingeLeverNutProfile(){
857   for (c= [hppB, hppT]) {
858     translate(c)
859       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
860   }
861 }
862
863 module Flip_hinge(doflip=1){
864   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
865   translate(hinge_origin)
866     rotate([doflip*180,0,0])
867     translate(-hinge_origin)
868     children();
869 }
870
871 module HingePortion(x0,x1){
872   Flip_rhs() Flip_bot(1)
873     translate([x0,0,0])
874     mirror([1,0,0])
875     rotate([90,0,-90])
876     linear_extrude(height=x1-x0)
877     children();
878 }
879
880 module CatchPortion(xwidth, ztop){
881   width = catch_width + xwidth;
882   w = width + catch_topcurve_r*2 + 1;
883   translate([phone_width/2, 0,0]){
884     difference(){
885       rotate([90,0,-90])
886         linextr(-w/2, w/2)
887         children(0);
888       translate([0, 50, 0])
889         rotate([90,0,0])
890         linear_extrude(height=100){
891         for (m=[0,1]) mirror([m,0,0]) {
892           hull(){
893             translate([w/2, ztop - catch_topcurve_r])
894               circle(catch_topcurve_r);
895             translate([w/2, -50])
896               square(catch_topcurve_r*2, center=true);
897           }
898         }
899       }
900     }
901   }
902 }
903
904 module CaseBase(){
905   AroundEdges(epp3[1], case_th_bottom, 1)
906     EdgeProfile();
907 }
908
909 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
910
911 module PropProfileAssignments(gamma){
912   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
913   x = prop_x(gamma);
914   p = phone_height + prlp10[0] - hppB[0];
915   b = p + x;
916
917   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
918   a = q + x;
919   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
920   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
921
922   $prp_theta = 90 - $prp_alpha;
923   beta = 180 - $prp_alpha - gamma;
924   psi = 90 - beta;
925
926   //echo("abc", a,b,c);
927
928   v1 = [ [ cos(psi), -sin(psi) ],    // x
929          [ sin(psi),  cos(psi) ] ];  // y
930
931   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
932
933   $prp_r1 = prc_r1;
934   $prp_r11 = prop_main_th/2;
935
936   $prpp1 = $prpp7 + [1,0] *
937     // this is approximate, but will do
938     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
939   $prpp3 = $prpp1 +
940     v1[0] * -$prp_r1 +
941     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
942   $prpp12 = $prpp3 + v1[0] *
943     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
944   $prp_r8 = prop_main_th;
945   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
946   $prp_r5 = $prp_r8;
947   $prpp5 = [ $prpp12[0] - $prp_r5,
948             $prpp3[1] - prop_prong_h + $prp_r5 ];
949   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
950          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
951   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
952   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
953
954   children();
955 }
956
957 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
958   PropProfileAssignments(gamma){
959
960     //#circleat($prpp3,1);
961     //#circleat($prpp12,1);
962
963     if (!cut) {
964       hull(){
965         translate($prpp8)
966           intersection(){
967             circle($prp_r8);
968             polygon([[-20,-0], [20,20], [0,0]]);
969           }
970         rectfromto($prpp6, $prpp9);
971         translate($prpp5) intersection(){
972           circle($prp_r5);
973           polygon([[-10,-10], [0,0], [10,0]]);
974         }
975         rectfromto($prpp12 + [0,-0.1], $prpp3);
976       }
977       hull(){
978         circleat($prpp1, $prp_r1);
979         rectfromto($prpp12 + [0,-0.1], $prpp3);
980       }
981     }
982     // main shaft
983     rotate([0,0, rot*-$prp_theta]){
984       hull(){
985         extra = cut ? prop_recess_slop : 0;
986         rectfromto($prpp6, $prpp9);
987         circleat($prpp11, $prp_r11 + extra);
988         circleat($prpp10, $prp_r10 + extra);
989       }
990     }
991   }
992 }
993
994 module PropAggregateProfile(){
995   for (angle = prop_angles)
996     PropProfile(angle, 0,0);
997 }
998
999 module Prop(){ ////toplevel
1000   hw = prop_main_width/2;
1001   linextr(-hw, +hw)
1002     PropAggregateProfile();
1003 }
1004
1005 module Case(){ ////toplevel
1006   difference(){
1007     union(){
1008       CaseBase();
1009
1010       // ledge (fixed keeper)
1011       Flip_rhs(1-keeper_side) intersection(){
1012         rotate([90, 0, 0])
1013           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1014           KeeperProfile(1);
1015
1016         // outline of the whole case, to stop it protruding
1017         translate([0,0, -25])
1018           linear_extrude(height = 50)
1019           hull()
1020           Flip_bot()
1021           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1022       }
1023
1024       // hinge
1025       HingePortion(hex20, hex21) HingeBaseProfile();
1026
1027       // buildout for prop recess
1028       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1029         linextr(case_bottom_z, epp2i[1])
1030         hull() {
1031           for (dxs = [-1,+1])
1032             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1033                        -epp2o[0] ],
1034                      r = epp2o[0] - prcp2[0]);
1035         }
1036     }
1037
1038     // slot for keeper
1039     Flip_rhs(keeper_side)
1040       translate([0, -phone_cnr_rad, 0])
1041       rotate([90, 0, 0])
1042       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1043       minkowski(){
1044         KeeperProfile();
1045         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1046                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1047       }
1048
1049     // front camera
1050     RearCameraAperture();
1051
1052     // struts (invisible, because they're buried in the case)
1053     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1054
1055     Buttons(){
1056       mirror([1,0,0])
1057         rotate([90,0,90]) {
1058           if (!($button_leg_only && enable_support))
1059           intersection(){
1060             translate([0,0,-10])
1061               linear_extrude(height= 20)
1062               ButtonPlan($button_l, 0,1);
1063             if ($button_leg_only)
1064               rotate([-90,90,0])
1065                 translate([phone_width/2, -400, kppe[1]])
1066                 mirror([1-abs($rhsflip - keeper_side),0,0])
1067                 cube([400, 800, 50]);
1068             if (enable_support && !$button_suppress_over_keeper)
1069               rotate([-90,90,0])
1070               translate([-400, -400, kppd[1]])
1071                 mirror([0,0,1])
1072                 cube([800,800,100]);
1073           }
1074           translate([0,0, -bppR[0]])
1075             linear_extrude(height= 20)
1076             ButtonPlan($button_l, 1,1);
1077         }
1078       
1079     }
1080
1081     // apertures along top edge
1082     CaseAperture(jack_pos, jack_dia, 8);
1083     Flip_rhs(1)
1084       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1085
1086     OrdinaryRearApertures();
1087
1088     MicroUSB();
1089
1090     // gaps for the lid's hinge arms
1091     HingePortion(hex20 - hinge_x_arms_gap,
1092                  hex21 + hinge_x_arms_gap)
1093       minkowski(){
1094         HingeLidProfile();
1095         circle(r= hinge_r_arms_gap, $fn= 8);
1096       }
1097
1098     // screw holes in the hinge arms
1099     HingeScrews();
1100
1101     // catch striker
1102     CatchPortion(catch_side_gap*2, epp4[1])
1103       CatchCutProfile();
1104
1105     // prop recess
1106     Flip_rhs(1)
1107       translate([prop_x_pos,0,0])
1108       mirror([0,1,0])
1109       rotate([90,0,90])
1110       linextr(-prop_recess_hw, +prop_recess_hw)
1111       hull(){
1112         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1113           circleat(prcp1 + 20*d,
1114                    prc_r3);
1115       }
1116   }
1117 }
1118
1119 module LidAdhocMultiprintFrame(phase){
1120   if (led_window_style >= 3) {
1121     AdhocMultiprintFrame(phase, lpp13[1], -1);
1122   }
1123 }
1124
1125 module LidAroundEdges(){
1126   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1127     children();
1128 }
1129
1130 module Lid(){ ////toplevel
1131   skew_centre = [0, lpp11[0], lpp11[1]];
1132   difference(){
1133     union(){
1134       intersection(){
1135         LidAroundEdges()
1136           LidEdgeProfile();
1137
1138         translate(skew_centre)
1139           multmatrix([[ 1, 0, 0, 0 ],
1140                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1141                       [ 0, 0, 1, 0 ],
1142                       [ 0, 0, 0, 1 ]])
1143           translate(-skew_centre)
1144           LidAroundEdges()
1145           LidEdgeFoldClearanceProfile();
1146       }
1147
1148       // button covers
1149       Buttons(){
1150         intersection(){
1151           rotate([90,0,90])
1152             translate([0,0,-10])
1153             linear_extrude(height= 20)
1154             ButtonPlan($button_l, 1,0);
1155           rotate([90,0,0])
1156              translate([0,0,-100])
1157             linear_extrude(height= 200)
1158             ButtonCoverProfile();
1159         }
1160       }
1161
1162       // hinge arms
1163       HingePortion(hex20, hex21) {
1164         LidEdgeProfile();
1165         HingeLidProfile();
1166       }
1167
1168       // catch
1169       CatchPortion(0, lpp12[1])
1170         CatchCatchProfile();
1171     }
1172     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1173
1174     // screw holes in the hinge arms
1175     HingeScrews();
1176
1177     // prop recess
1178     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1179       mirror([0,1,0])
1180       rotate([90,0,90])
1181       linextr(-prop_recess_hw, +prop_recess_hw)
1182       hull()
1183       for (pa = prop_angles)
1184         PropProfile(pa, 1,1);
1185
1186     // notification led aperture
1187     if (led_window_style)
1188       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1189         translate([0,0,-10])
1190           cylinder(r=nla_r0, h=20);
1191         if (led_window_style >= 2)
1192           translate([0,0, -nla_t])
1193             cylinder(r=nla_r2, height=20);
1194       }
1195
1196     }
1197
1198   LidAdhocMultiprintFrame(1);
1199 }
1200
1201 module HingeLever(){ ////toplevel
1202   difference() {
1203     // outer body, positive
1204     HingePortion(hex22, hex22 + phone_width/2)
1205       HingeLeverOuterProfile();
1206
1207     // space for the screws
1208     HingePortion(hex26, hex24)
1209       HingeLeverInnerProfile();
1210
1211     // recesses for the nuts
1212     HingePortion(hex23, hex26+1)
1213       HingeLeverNutProfile();
1214
1215     // bores for the screws
1216     HingeScrews();
1217
1218     // space for the charging cable
1219     MicroUSB();
1220     Flip_hinge() MicroUSB();
1221   }
1222 }
1223
1224 module LidWindow(){ ////toplevel
1225   translate([led_pos[0], -led_pos[1], lpp13[1]])
1226     mirror([0,0,1])
1227     cylinder(r= nla_r1, h=nla_t);
1228   LidAdhocMultiprintFrame(0);
1229 }
1230
1231 module LidWindowPrint(){ ////toplevel
1232   rotate([0,180,0])
1233     LidWindow();
1234 }
1235
1236 module DemoLidWindowSelect(){
1237   translate([led_pos[0], led_pos[1], -100]) {
1238     translate([0, -30, 0]) cube([400, 400, 200]);
1239   }
1240 }
1241
1242 module DemoLidWindow(){ ////toplevel
1243   %Lid();
1244   LidWindow();
1245   translate([0,40,0]){
1246     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1247     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1248   }
1249 }
1250
1251 module HingeLeverPrint(){ ////toplevel
1252   rotate([-90,0,0])
1253     translate([-phone_width/2, phone_height, 0])
1254     HingeLever();
1255 }
1256
1257 module TestSelectLength(){
1258   translate([-30, -200, -20])
1259     cube([30 + 15, 250, 40]);
1260 }
1261
1262 module TestLength(){ ////toplevel
1263   intersection(){
1264     Case();
1265     TestSelectLength();
1266   }
1267 }
1268
1269 module TestLengthRight(){ ////toplevel
1270   intersection(){
1271     Case();
1272     Flip_rhs(1)
1273       TestSelectLength();
1274   }
1275 }
1276
1277 module TestSelectWidth(){
1278   translate([-30, -(phone_height - 25), -20])
1279     mirror([0, 1, 0])
1280     cube([200, 50, 40]);
1281 }
1282
1283 module TestWidth(){ ////toplevel
1284   intersection(){
1285     Case();
1286     TestSelectWidth();
1287   }
1288 }
1289
1290 module TestLidWidthPrint(){ ////toplevel
1291   rotate([0,180.0]) intersection(){
1292     Lid();
1293     TestSelectWidth();
1294   }
1295 }
1296
1297 module TestSelectRearAperture(){
1298   minkowski(){
1299     union() children();
1300     translate([20, 0,0])
1301       cube([42, 2, 1], center=true);
1302   }
1303 }
1304
1305 module TestSelectCamera(){
1306   minkowski(){
1307     TestSelectRearAperture()
1308       RearCameraAperture();
1309     cube([0.1, 50, 0.1]);
1310   }
1311 }
1312
1313 module TestSelectOrdinaryRearApertures(){
1314   TestSelectRearAperture()
1315     OrdinaryRearApertures();
1316 }
1317
1318 module TestCamera(){ ////toplevel
1319   intersection(){
1320     Case();
1321     TestSelectCamera();
1322   }
1323 }
1324
1325 module TestLidByCamera(){ ////toplevel
1326   intersection(){
1327     Lid();
1328     TestSelectCamera();
1329   }
1330 }
1331
1332 module TestLidByCameraPrint(){ ////toplevel
1333   rotate([180,0,0]) TestLidByCamera();
1334 }
1335
1336 module DemoByCamera(){ ////toplevel
1337   color("blue") TestLidByCamera();
1338   color("red")  TestCamera();
1339 }
1340
1341 module OneKeeper(){ ////toplevel
1342   translate([0, -phone_cnr_rad, 0])
1343     rotate([90, 0, 0])
1344     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1345     KeeperProfile();
1346 }
1347
1348 module OneKeeperPrint(){ ////toplevel
1349   rotate([0,180,0])
1350     OneKeeper();
1351 }
1352
1353 module LidPrint(){ ////toplevel
1354   rotate([0,180,0])
1355     Lid();
1356 }
1357
1358 module TestSelectFrame(){
1359   include = [1,-1] * (epp2i[0] + 4);
1360
1361   difference(){
1362     cube(1000, center=true);
1363     translate([0,0, -100])
1364       linear_extrude(height=200)
1365       rectfromto(include,  inside_br - include);
1366   }
1367 }
1368
1369 module TestSelectLidFrame(){
1370   TestSelectFrame();
1371   translate([led_pos[0], -led_pos[1], -50])
1372     cylinder(r= nla_r2+3, h=100);
1373 }
1374
1375 module TestFrameCase(){ ////toplevel
1376   intersection(){
1377     Case();
1378     union(){
1379       TestSelectFrame();
1380       TestSelectCamera();
1381       TestSelectOrdinaryRearApertures();
1382     }
1383   }
1384 }
1385
1386 module TestSelectTopApertures(){
1387   translate([-100, -35, -100])
1388     cube([400, 100, 200]);
1389   LidAdhocMultiprintFrame(0);
1390   LidAdhocMultiprintFrame(1);
1391 }
1392
1393 module TestTopApertures(){ ////toplevel
1394   intersection(){
1395     Case();
1396     TestSelectFrame();
1397     TestSelectTopApertures();
1398   }
1399 }
1400
1401 module TestLidTopAperturesPrint(){ ////toplevel
1402   rotate([0,180,0]) intersection(){
1403     Lid();
1404     TestSelectLidFrame();
1405     TestSelectTopApertures();
1406   }
1407 }
1408
1409 module TestLidWindowTopAperturesPrint(){ ////toplevel
1410   rotate([0,180,0]) intersection(){
1411     LidWindow();
1412     TestSelectTopApertures();
1413   }
1414 }
1415
1416 module TestFrameLidPrint(){ ////toplevel
1417   rotate([0,180,0]) intersection(){
1418     Lid();
1419     TestSelectLidFrame();
1420   }
1421 }
1422
1423 module ButtonPlanForDemo(z, deep, cut){
1424   translate([0,0,z])
1425     ButtonPlan(8, deep, cut);
1426 }
1427
1428 module HingeScrews(){
1429   Flip_rhs() Flip_bot(1){
1430     for (c= [ hppT, hppB ])
1431       translate([ hex20,
1432                   -c[0],
1433                   c[1] ]){
1434         rotate([0,90,0])
1435           translate([0,0,-.2])
1436           cylinder( r= hingescrew_shaft_dia/2,
1437                     h = hingescrew_shaft_len+0.2 );
1438         rotate([0,-90,0])
1439           translate([0,0,+.1])
1440           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1441       }
1442   }
1443 }
1444
1445 module DemoPropAngleSelect(c){
1446   color(c) difference(){
1447     union(){ children(); }
1448     translate([ prop_x_pos, -400, -200 ])
1449       cube([ 400,800,400 ]);
1450   }
1451 }
1452
1453 module DemoPropAngle(ang){
1454   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1455   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1456
1457   translate(hL)
1458     rotate([ang/2,0,0])
1459     translate(-hL)
1460     translate(hC)
1461     rotate([ang/2,0,0])
1462     translate(-hC) {
1463       DemoPropAngleSelect("red") Case();
1464
1465       color("orange")
1466         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1467         PropProfileAssignments(ang) {
1468           echo($prpp1);
1469           rotate([-$prp_theta, 0, 0])
1470           translate([0, $prpp1[0], -$prpp1[1]])
1471           rotate([90,0,-90])
1472           Prop();
1473         }
1474     }
1475
1476   translate([0,0, -hp_k*2])
1477     DemoPropAngleSelect("blue")
1478     Lid();
1479 }
1480
1481 module DemoPropAngles(){ ////toplevel
1482   for (i=[0 : len(prop_angles)-1])
1483     translate(i * [0, -100, 100])
1484     DemoPropAngle(prop_angles[i]);
1485 }
1486
1487 module DemoHingeAngle(ang1,ang2){
1488   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1489   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1490
1491   translate(hL)
1492     rotate([ang2,0,0])
1493     translate(-hL)
1494     translate(hC)
1495     rotate([ang1,0,0])
1496     translate(-hC) {
1497       color("red") Lid();
1498     }
1499
1500   color("blue") intersection(){
1501     Case();
1502     union(){
1503       translate([bppJ[0], -400, -200])
1504         mirror([1,0,0])
1505         cube([400, 800, 400]);
1506       translate([10, -400, -200])
1507         cube([10, 800, 400]);
1508     }
1509   }
1510 }
1511
1512 module DemoHingeAngles(){ ////toplevel
1513   angles = [ 0, 4, 8, 12 ];
1514   echo("angles",angles);
1515   for (i=[0 : len(angles)-1]) {
1516     translate(i * [0, 0, 30]) {
1517       DemoHingeAngle(0,angles[i]);
1518       translate([0, 200, 0])
1519         DemoHingeAngle(angles[i],0);
1520     }
1521   }
1522 }
1523
1524 module DemoSelectAdhocLeftRight(right=0) {
1525   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1526     mirror([1-right, 0,0])
1527     cube([400, 800, 200]);
1528 }
1529
1530 module DemoLeft(){ ////toplevel
1531   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1532   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1533 }
1534
1535 module DemoFrame(){ ////toplevel
1536   color("red") TestFrameCase();
1537   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1538   color("black") HingeScrews();
1539   %HingeLever();
1540 }
1541
1542 module DemoHingedFrame(){ ///toplevel
1543   color("red") TestFrameCase();
1544   translate([0,0, -2*hp_k])
1545   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1546
1547   Flip_hinge(){
1548     color("orange") HingeLever();
1549     color("black") HingeScrews();
1550   }
1551 }
1552
1553 module DemoHinge(){ ////toplevel
1554   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1555     DemoFrame();
1556     translate([0,0, -hp_k*3])
1557       DemoHingedFrame();
1558   }
1559 }
1560
1561 module DemoProfiles(){ ////toplevel
1562   LidEdgeProfile();
1563   %EdgeProfile();
1564   KeeperProfile();
1565   translate([0,0,-1]) color("black") KeeperProfile(1);
1566   color("purple") translate(epp2i)
1567     rotate(atan2vector(epp2i - epp1)) {
1568     translate(lanyard_half_dia * 0.5 * [-3,-1])
1569       LanyardLanyardProfile();
1570     translate(lanyard_half_dia * 0.5 * [-3,+1])
1571       translate([0,-1] * case_th_side)
1572       LanyardLanyardProfile(true);
1573   }
1574
1575   translate([0,20]) {
1576     LanyardMainChannelProfile();
1577   }
1578
1579   translate([20,0]) {
1580     LidEdgeProfile();
1581     %EdgeProfile();
1582
1583     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1584   
1585     color("blue") ButtonCoverProfile();
1586     color("red") {
1587       rectfromto(bppQ, demopoint_QR);
1588       rectfromto(bppR, demopoint_QR);
1589     }
1590   }
1591
1592   translate([-20,0]) {
1593     color("black") ButtonPlanForDemo(-2, 0,1);
1594     color("red" )  ButtonPlanForDemo(-4, 1,1);
1595     color("blue")  ButtonPlanForDemo(-6, 1,0);
1596   }
1597
1598   translate([0, -30]) {
1599     %LidEdgeProfile();
1600     %EdgeProfile();
1601     color("blue") HingeLidProfile();
1602     color("red")  HingeBaseProfile();
1603     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1604   }
1605
1606   for (f=[0,1]) {
1607     translate([-30, -60 + 30*f]) {
1608       translate([0,0,-4]) EdgeProfile();
1609       %translate([0,0,-10]) HingeBaseProfile();
1610       translate([0,-2] * f * hp_k) {
1611         translate([0,0,-4]) LidEdgeProfile();
1612         %translate([0,0,-10]) %HingeLidProfile();
1613       }
1614       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1615         translate([0,0,-2]) color("black") HingeLeverOuterProfile(); 
1616         translate([0,0,0]) color("red") difference(){
1617           HingeLeverOuterProfile();
1618           HingeLeverInnerProfile();
1619         }
1620         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1621       }
1622     }
1623   }
1624
1625   translate([20,-30]) {
1626     %EdgeProfile();
1627     %LidEdgeProfile();
1628     //translate([0,0,1]) CatchCutProfile();
1629     color("blue") CatchCatchProfile();
1630     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1631   }
1632
1633   translate([40,-30]) {
1634     difference(){
1635       LidEdgeProfile();
1636       translate(prlp10)
1637         PropProfile(10, 1, 0);
1638     }
1639     translate(prlp10)
1640       PropProfile(15, 0);
1641   }
1642   translate([60,-30]) {
1643     PropAggregateProfile();
1644   }
1645 }
1646
1647 //EdgeProfile();
1648 //KeeperProfile();
1649 //CaseBase();
1650 //%Case();
1651 //Keeper();
1652 //LidEdgeProfile();
1653 //KeeperProfile();
1654 //DemoProfiles();
1655 //PropRecess();