fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2.0;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207 lid_edgepart_width = 5.0;
 208 lid_buttoncover_thick = 1.0;
 209
 210 catch_slop = 0.50;
 211
 212 foldover_gap = 0.50;
 213 foldover_lever_gap = 0.50;
 214
 215 // properties of the hinge fasteners
 216 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 217 hingescrew_shaft_len = 12;
 218 hingescrew_fasteners_extra_thick = 0.40;
 219 // ^ amount of thread protruding if everything was completely nominal
 220 //   and we are using two nuts
 221 hingescrew_nut_access_dia = 4.72 + 0.50;
 222 // ^ washer is 4.72 dia
 223 //   also, want to get pliers or tiny spanner in to do up locknut
 224 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 225 hingescrew_nut_thick = 1.93;
 226 hingescrew_head_th = 1.38 + 0.75;
 227 hingescrew_head_dia = 3.92;
 228
 229 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 230
 231 lever_cover_th = 0.75;
 232 hingemount_th = 2.5;
 233 hingemount_wd = 4.8725;
 234
 235 $fa = 5;
 236 $fs = 0.1;
 237
 238 button_l_fudge = 4.4;
 239 buttonishleg_default_l_is_fudge = 10;
 240
 241 hinge_base_slope = 1.5; // bigger is steeper
 242
 243 strut_min_at_end = 1.5;
 244
 245 hinge_x_gap = 0.125;
 246 hinge_x_postscrew_gap = 0.75;
 247 hinge_x_arms_gap = 0.35;
 248 hinge_r_arms_gap = 0.55;
 249
 250 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 251
 252 catch_len = 7.5;
 253 catch_width = 15;
 254 catch_thickness = 1.0;
 255 catch_side_gap = 0.75; // each side
 256
 257 catch_depth = 0.75;
 258 catch_height = 0.35;
 259 catch_finger_height = 1.5;
 260 catch_finger_depth = 2.5;
 261
 262 prop_recess_under = 0.50;
 263 prop_recess_slop = 0.200; // each side
 264 prop_end_dia = 0.5;
 265 prop_main_th = 3;
 266 prop_taper_len = 6;
 267 prop_main_width = 4;
 268 prop_side_gap = 0.75; // each side
 269 prop_lidrecess_behind = 0.75;
 270 prop_caserecess_behind = 0.75;
 271 prop_caserecess_taper = 0.45; // one side only
 272 prop_prop_gap = 0.5;
 273 prop_prong_heel_slope = 0.5;
 274
 275 lid_fold_clearance_antislop = 0.5;
 276
 277 // ---------- calculated ----------
 278
 279 phone_width =  (phone + bumper*2)[0];
 280 phone_height = (phone + bumper*2)[1];
 281
 282 inside_br = [phone_width, -phone_height];
 283
 284 prop_prong_h = prop_main_th;
 285
 286 //echo(camera_pos_tl + bumper,
 287 //     camera_pos_br + bumper);
 288
 289 // ----- could be changed -----
 290 lid_buttoncover_gap = lid_gap_x;
 291 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 292
 293 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 294
 295 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 296
 297 //prop_nose_len = case_th_lid - prop_recess_under;
 298 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 299 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 300
 301
 302 //lid_lip_overlap_width xxx bad name = ;
 303 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 304
 305 epp0 = [0,0];
 306 epp1 = [0, -phone_edge_thick];
 307 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 308 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 309 epp3 = epp2i + [10, 0];
 310 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 311 epp4 = epp5 + [-1,0] * case_th_side;
 312
 313 kppe = [0,0];
 314 kppd = kppe + [1,0] * keeper_inner_width;
 315 kppc = kppd + [0,1] * keeper_th_z;
 316 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 317 kppf = kppe - [0,1] * keeper_inner_height;
 318 kppa = [ kppb[0], kppf[1] ];
 319
 320 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 321 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 322
 323 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 324 // exact x posn not very important; must extend past end of keeper
 325
 326 lpp15 = [ lpp14[0],
 327           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 328           + lid_screen_gap_extra ];
 329 // ^ beam theory says to maximise force before contact,
 330 //   the gap below the `beam' (the lid) must be 1/3
 331 //   the thickness (ie the lid thickness) if the beam
 332 //   is solid, or 1/2 if it has a top and bottom only.
 333 //   ours is mostly solid.
 334
 335 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 336              case_th_lip);
 337
 338 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 339 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 340
 341 case_bottom_z = epp2o[1] - case_th_bottom;
 342
 343 // button profile
 344 bppM = epp4 + [0,5];
 345 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 346 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 347 bppS = [ epp1[0], bppR[1] ];
 348 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 349 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 350 bppO = [ bppN[0], bppP[1] ];
 351 bppL = lpp10 + [5,0];
 352 bppK = [ bppL[0], bppN[1] ];
 353 bppJ = [ bppN[0], bppL[1] ];
 354 bppU = [ bppJ[0], lpp12[1] ];
 355 bppV = lpp11;
 356 bppW = lpp10;
 357
 358 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 359
 360 // notification led aperture
 361
 362 nla_r0 = led_aperture/2;
 363 nla_r1 = nla_r0 + led_window_ledge;
 364 nla_r2 = nla_r1 + multicolour_gap;
 365 nla_t =
 366   led_window_style >= 3 ? initial_layer_thick :
 367   led_window_style >= 2 ? led_window_ledge : 0;
 368
 369
 370 // hinge plan
 371 hp_rn = hingescrew_nut_access_dia/2;
 372 hp_r2_min = hp_rn + lever_cover_th;
 373 hp_rs = hingescrew_shaft_dia/2;
 374 hp_r1_min = hp_rs + hingemount_th;
 375
 376 hp_r1 = max(hp_r1_min, hp_r2_min);
 377 hp_r2 = hp_r1;
 378
 379 hppU = lpp13;
 380 hppS = epp2o + [0,-1] * case_th_bottom;
 381 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 382
 383 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 384          0.5 * (hppU + hppS)[1] ];
 385 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 386 hppB = hppT + [0,-1] * hp_k;
 387
 388 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 389 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 390 hppE = [ hppE_x, hppE_y ];
 391
 392 // hinge elevation x coords
 393
 394 hex20 = max(epp2o[0],
 395             phone_cnr_rad,
 396             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 397 hex21 = hex20 + hingemount_wd;
 398 hex22 = hex21 + hinge_x_gap;
 399 hex27 = hex20 + hingescrew_shaft_len;
 400 hex24 = hex27 + hinge_x_postscrew_gap;
 401 hex23 = hex27 - (hingescrew_nut_thick*2
 402                  + hingescrew_fasteners_extra_thick);
 403 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 404
 405 echo(hex20, hex21, hex22, hex23, hex24);
 406 //  6, 10.8725, 10.9975, 13.74, 18.75
 407 module chk(act,exp) {
 408   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 409   else echo("ok", act);
 410 }
 411 chk(hex20, 6);
 412 chk(hex21, 10.8725);
 413 chk(hex22, 10.9975);
 414 chk(hex23, 13.74);
 415 chk(hex24, 18.75);
 416
 417 lid_fold_clearance_skew =
 418   (lpp10[1] - hppB[1]) /
 419   (lpp10[0] - hppB[0]);
 420
 421 echo("SK",lid_fold_clearance_skew);
 422
 423 // catch
 424
 425 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 426 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 427 cppB = [ epp0[0], cppA[1] ];
 428 cppP = [ epp4[0], cppJ[1] ];
 429
 430 cppS = cppJ + [0,-1] * catch_len;
 431 cppD = [ cppA[0], cppS[1] + catch_slop ];
 432 cppC = [ cppB[0], cppD[1] ];
 433 cppT = cppS + [1,0] * catch_depth;
 434 cppU = cppT + [0,-1] * catch_height;
 435 cppV = [ cppS[0], cppU[1] - catch_depth ];
 436
 437 cppR = 0.5*(cppP + cppJ);
 438
 439 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 440 cppQ = [ cppR[0],
 441          cppV[1] - (catch_finger_height - cp_rQ) ];
 442 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 443
 444 // prop recess in case
 445
 446 prop_x_pos = phone_width/2;
 447
 448 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 449
 450 prc_r1 = prop_end_dia/2;
 451 prc_r3 = prc_r1 + prop_recess_slop;
 452
 453 prcp2 = [ epp4[0] + prop_buildout_less,
 454           case_bottom_z ];
 455
 456 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 457
 458 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 459           epp2i[1] - prc_r3 - prop_recess_under];
 460
 461 // prop recess in lid
 462
 463 prl_r10 = prop_end_dia/2;
 464 prl_r10o = prl_r10 + prop_recess_slop;
 465
 466 prlp10 = lpp10 + [1,1] * prl_r10o
 467   + [1,0] * prop_lidrecess_behind
 468   + [0,1] * prop_recess_under;
 469
 470 // prop
 471
 472 $prpp10 = [0,0];
 473 $prpp11 = [0, prop_taper_len];
 474
 475 $prp_r10 = prl_r10;
 476
 477 // ---------- modules ----------
 478
 479 module AdhocMultiprintFrame(phase, z0, zs) {
 480   // from z0 to z0 + zs*layer
 481   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 482   xextra = extra + -epp4[0];
 483   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 484   yextra = extra + -epp4[0];
 485   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 486   p0 = [ xrange[0], yrange[0] ];
 487   p1 = [ xrange[1], yrange[1] ];
 488   echo(p0, p1);
 489   translate([0,0, z0])
 490     mirror([0,0, zs<0 ? 1 : 0])
 491     linear_extrude(height= initial_layer_thick)
 492     difference(){
 493       rectfromto(p0 - [1,1] * initial_layer_width,
 494                  p1 + [1,1] * initial_layer_width);
 495       rectfromto(p0, p1);
 496     }
 497 }
 498
 499 module KeeperProfile(slant=0){
 500   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 501   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 502 }
 503
 504 module EdgeProfile(){
 505   difference(){
 506     hull(){
 507       translate(epp3) square(case_th_bottom*2, center=true);
 508       circleat(epp2o, r=case_th_bottom);
 509       circleat(epp1, r=case_th_side);
 510       rectfromto(epp0, epp4);
 511     }
 512     polygon([ epp5 + [0,10],
 513               epp1,
 514               epp2i,
 515               epp3 + [10,0] ]);
 516   }
 517 }
 518
 519 module LidEdgeProfile(){
 520   polygon([ lpp10,
 521             lpp11,
 522             lpp12,
 523             lpp13,
 524             lpp13 + [10, 0],
 525             lpp15 + [10, 0],
 526             lpp15,
 527             lpp14,
 528             ]);
 529   intersection(){
 530     circleat(lpp12, r=lp_r12);
 531     rectfromto( lpp12 + [-10,   0],
 532                 lpp12 + [+10, +10] );
 533   }
 534 }
 535
 536 module LidEdgeFoldClearanceProfile(){
 537   translate([-lid_fold_clearance_antislop, 0])
 538     polygon([ lpp10,
 539               lpp11,
 540               lpp11 + [-20,  0],
 541               lpp11 + [-20, 20],
 542               lpp11 + [+20, 20],
 543               lpp10 + [+20,  0] ]);
 544 }
 545
 546 module ButtonCoverProfile(){
 547   intersection(){
 548     polygon(concat([ bppM, bppP, bppO, bppJ ],
 549                    (enable_support && !$button_suppress_over_keeper
 550                     ? [ bppU, bppV, bppW ] : []),
 551                    [ bppL, bppK ]));
 552     hull(){
 553       EdgeProfile();
 554       LidEdgeProfile();
 555     }
 556   }
 557 }
 558
 559 module ButtonPlan(l, deep, cut){
 560   epsilon =
 561     (cut  ? 0 : lid_buttoncover_gap);
 562
 563   delta =
 564     (deep ? lid_buttoncover_overlap : 0);
 565
 566   C = [0,0]; // by definition
 567   T = [ 0, epp4[1] ];
 568   G = T + [0,10];
 569
 570   B0 = C + [0,-1] * button_cutout_depth;
 571   B1 = B0 + [0,1] * epsilon;
 572
 573   r0 = 0.5 * (T[1] - B0[1]);
 574   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 575   H = A + [0,-1] * delta;
 576
 577   D = A + [-2,0] * r0;
 578   F = D + [0,10];
 579
 580   E0 = 0.5 * (D + A);
 581   E1 = E0 + [1,0] * epsilon;
 582
 583   I0 = [ E0[0], H[1] ];
 584   I1 = [ E1[0], H[1] ];
 585
 586   hull(){
 587     for (m=[0,1]) mirror([m,0])
 588       circleat(H, r0 - epsilon);
 589   }
 590   for (m=[0,1]) mirror([m,0]) {
 591     difference(){
 592       polygon([ E1,
 593                 I1,
 594                 H,
 595                 B1,
 596                 G,
 597                 F,
 598                 D
 599                 ]);
 600       circleat(D, r0 + epsilon);
 601     }
 602   }
 603 }
 604
 605 module CatchCatchProfile(){
 606   hull(){
 607     for (c=[ cppR, cppQ ])
 608       circleat(c, cp_rQ);
 609   }
 610   hull(){
 611     circleat(lpp12, lp_r12);
 612     circleat(lpp12 + [5,0], lp_r12);
 613     rectfromto(cppP, cppP + [5,0.1]);
 614   }
 615   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 616 }
 617
 618 module CatchCutProfile(){
 619   polygon([ cppB,
 620             cppA,
 621             cppD,
 622             cppF,
 623             cppF + [0,-10],
 624             cppF + [-10,-10],
 625             lpp12 + [-10,0],
 626             lpp12 + [10,0]
 627             ]);
 628 }
 629
 630 module Flip_rhs(yn=[0,1]) {
 631   for ($rhsflip=yn) {
 632     translate([phone_width/2, 0, 0])
 633       mirror([$rhsflip,0,0])
 634       translate([-phone_width/2, 0, 0])
 635       children();
 636   }
 637 }
 638
 639 module Flip_bot(yn=[0,1]) {
 640   for ($botflip=yn) {
 641     translate([0, -phone_height/2, 0])
 642       mirror([0, $botflip, 0])
 643       translate([0, phone_height/2, 0])
 644       children();
 645   }
 646 }
 647
 648 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 649   // sides
 650   Flip_rhs(){
 651     translate([0, -phone_cnr_rad, 0])
 652       rotate([90,0,0])
 653       linear_extrude(height = phone_height - phone_cnr_rad*2)
 654       children(0);
 655   }
 656   // corners
 657   Flip_rhs() Flip_bot() {
 658     translate([+1,-1] * phone_cnr_rad)
 659       intersection(){
 660         rotate_extrude()
 661           intersection(){
 662             mirror([1,0,0])
 663               translate([-1,0] * phone_cnr_rad)
 664               children(0);
 665             rectfromto([0,-20],[10,20]);
 666           }
 667         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 668           cube([10,10,40]);
 669       }
 670   }
 671   // top and bottom
 672   Flip_bot(){
 673     translate([ phone_width - phone_cnr_rad, 0,0 ])
 674       rotate([90,0,-90])
 675       linear_extrude(height = phone_width - phone_cnr_rad*2)
 676       children(0);
 677   }
 678   // fill
 679   translate([0,0, fill_zstart])
 680     mirror([0,0, fill_downwards])
 681     linear_extrude(height = fill_th)
 682     rectfromto([+1,-1] * phone_cnr_rad,
 683                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 684 }
 685
 686 module CaseAperture(pos, dia, $fn) {
 687   theta = 180/$fn;
 688   translate([ pos[0] + bumper[0],
 689               -epp2i[0],
 690               -pos[1] ])
 691     rotate([-90, theta, 0])
 692     cylinder(r = dia/2 / cos(theta),
 693              h = 60);
 694 }
 695
 696 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 697   // y_ref_sign:
 698   //   +1  measured from top    of actual phone to top    of button
 699   //   -1  measured from bottom of actual phone to bottom of button
 700   //    0  y is centre of button in coordinate system
 701   $button_l= l;
 702   $button_suppress_over_keeper= suppress_over_keeper;
 703   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 704           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 705           y;
 706   //echo(eff_y);
 707   translate([0, eff_y, 0])
 708     children();
 709 }
 710
 711 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 712   $button_leg_only = true;
 713   SideButton(y, y_ref_sign, l) children();
 714 }
 715
 716 module Buttons(){
 717   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 718   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 719   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 720   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 721 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 722 }
 723
 724 module Struts(x_start, z_min, th){
 725   // if th is negative, starts at z_min and works towards -ve z
 726   // and object should then be printed other way up
 727   for (i= [1 : 1 : case_struts_count]) {
 728     translate([0,
 729                0,
 730                z_min])
 731       mirror([0,0, th<0 ? 1 : 0])
 732       translate([0,
 733                  -phone_height * i / (case_struts_count+1),
 734                  case_struts_solid_below])
 735       linear_extrude(height= abs(th)
 736                      -(case_struts_solid_below+case_struts_solid_above))
 737       rectfromto([               x_start, -0.5 * case_struts_width ],
 738                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 739   }
 740 }
 741
 742 module OrdinaryRearAperture(rhs,bot, pos){
 743   Flip_rhs(rhs) Flip_bot(bot)
 744     linextr(-20, 20)
 745     mirror([0,1])
 746     translate(pos + bumper)
 747     children();
 748 }
 749
 750 module MicroUSB(){
 751   Flip_bot(1){
 752     rotate([90,0,0])
 753       mirror([0,0,1])
 754       linextr(-epp2i[0], 60)
 755       translate([0.5 * phone_width, 0, 0])
 756       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 757                  [+microusb_width/2, epp0[1] + -microusb_above]);
 758   }
 759 }
 760
 761 module OrdinaryRearApertures(){
 762   // rear speaker
 763   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 764     rectfromto(-rearspeaker_gap,
 765                rearspeaker_size + rearspeaker_gap);
 766
 767   // finger hole to remove phone
 768   if (len(fingerpushhole_dias))
 769     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 770                                 phone[1]/2 ])
 771     scale(fingerpushhole_dias)
 772     circle(r= 0.5 );
 773 }
 774
 775 module RearCameraAperture(){
 776   Flip_rhs(1)
 777     mirror([0, 0, 1])
 778     linear_extrude(height = 20)
 779     mirror([0, 1, 0])
 780     translate(bumper)
 781     rectfromto(camera_pos_tl, camera_pos_br);
 782 }
 783
 784 module HingeLidProfile(){
 785   hull(){
 786     circleat(hppT, hp_r1);
 787     circleat(lpp12, lp_r12);
 788     polygon([lpp10,
 789              lpp13 + [2,0],
 790              lpp12,
 791              hppT]);
 792   }
 793 }
 794
 795 module HingeBaseProfile(){
 796   difference(){
 797     hull(){
 798       circleat(hppB, hp_r1);
 799       circleat(hppE, hp_r1);
 800       circleat(epp2o, case_th_bottom);
 801       circleat(hppB + [10,0], hp_r1);
 802     }
 803     polygon([epp5, epp1, epp2i, epp3, bppL]);
 804   }
 805 }
 806
 807 module HingeLeverOuterProfile(){
 808   hull(){
 809     circleat(hppT, hp_r2);
 810     circleat(hppB, hp_r2);
 811   }
 812 }
 813
 814 module HingeLeverInnerProfile(){
 815   for (s = [-1,+1]) {
 816     c = s > 0 ? hppT : hppB;
 817     translate(c)
 818       mirror([0,0,s>0])
 819       rotate(s<0 ? -40 : 0)
 820       hull()
 821       for (x=[-20,20])
 822         for (y=[0, s * 10])
 823           translate([x,y])
 824             circle(hp_rn);
 825   }
 826 }
 827
 828 module HingeLeverNutProfile(){
 829   for (c= [hppB, hppT]) {
 830     translate(c)
 831       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 832   }
 833 }
 834
 835 module Flip_hinge(doflip=1){
 836   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 837   translate(hinge_origin)
 838     rotate([doflip*180,0,0])
 839     translate(-hinge_origin)
 840     children();
 841 }
 842
 843 module HingePortion(x0,x1){
 844   Flip_rhs() Flip_bot(1)
 845     translate([x0,0,0])
 846     mirror([1,0,0])
 847     rotate([90,0,-90])
 848     linear_extrude(height=x1-x0)
 849     children();
 850 }
 851
 852 module CatchPortion(width){
 853   translate([phone_width/2, 0,0])
 854     rotate([90,0,-90])
 855     linextr(-width/2, width/2)
 856     children(0);
 857 }
 858
 859 module CaseBase(){
 860   AroundEdges(epp3[1], case_th_bottom, 1)
 861     EdgeProfile();
 862 }
 863
 864 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 865
 866 module PropProfileAssignments(gamma){
 867   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 868   x = prop_x(gamma);
 869   p = phone_height + prlp10[0] - hppB[0];
 870   b = p + x;
 871
 872   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 873   a = q + x;
 874   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 875   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 876
 877   $prp_theta = 90 - $prp_alpha;
 878   beta = 180 - $prp_alpha - gamma;
 879   psi = 90 - beta;
 880
 881   //echo("abc", a,b,c);
 882
 883   v1 = [ [ cos(psi), -sin(psi) ],    // x
 884          [ sin(psi),  cos(psi) ] ];  // y
 885
 886   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 887
 888   $prp_r1 = prc_r1;
 889   $prp_r11 = prop_main_th/2;
 890
 891   $prpp1 = $prpp7 + [1,0] *
 892     // this is approximate, but will do
 893     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 894   $prpp3 = $prpp1 +
 895     v1[0] * -$prp_r1 +
 896     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 897   $prpp12 = $prpp3 + v1[0] *
 898     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 899   $prp_r8 = prop_main_th;
 900   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 901   $prp_r5 = $prp_r8;
 902   $prpp5 = [ $prpp12[0] - $prp_r5,
 903             $prpp3[1] - prop_prong_h + $prp_r5 ];
 904   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 905          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 906   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 907   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 908
 909   children();
 910 }
 911
 912 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 913   PropProfileAssignments(gamma){
 914
 915     //#circleat($prpp3,1);
 916     //#circleat($prpp12,1);
 917
 918     if (!cut) {
 919       hull(){
 920         translate($prpp8)
 921           intersection(){
 922             circle($prp_r8);
 923             polygon([[-20,-0], [20,20], [0,0]]);
 924           }
 925         rectfromto($prpp6, $prpp9);
 926         translate($prpp5) intersection(){
 927           circle($prp_r5);
 928           polygon([[-10,-10], [0,0], [10,0]]);
 929         }
 930         rectfromto($prpp12 + [0,-0.1], $prpp3);
 931       }
 932       hull(){
 933         circleat($prpp1, $prp_r1);
 934         rectfromto($prpp12 + [0,-0.1], $prpp3);
 935       }
 936     }
 937     // main shaft
 938     rotate([0,0, rot*-$prp_theta]){
 939       hull(){
 940         extra = cut ? prop_recess_slop : 0;
 941         rectfromto($prpp6, $prpp9);
 942         circleat($prpp11, $prp_r11 + extra);
 943         circleat($prpp10, $prp_r10 + extra);
 944       }
 945     }
 946   }
 947 }
 948
 949 module PropAggregateProfile(){
 950   for (angle = prop_angles)
 951     PropProfile(angle, 0,0);
 952 }
 953
 954 module Prop(){ ////toplevel
 955   hw = prop_main_width/2;
 956   linextr(-hw, +hw)
 957     PropAggregateProfile();
 958 }
 959
 960 module Case(){ ////toplevel
 961   difference(){
 962     union(){
 963       CaseBase();
 964
 965       // ledge (fixed keeper)
 966       Flip_rhs(1-keeper_side) intersection(){
 967         rotate([90, 0, 0])
 968           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 969           KeeperProfile(1);
 970
 971         // outline of the whole case, to stop it protruding
 972         translate([0,0, -25])
 973           linear_extrude(height = 50)
 974           hull()
 975           Flip_bot()
 976           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 977       }
 978
 979       // hinge
 980       HingePortion(hex20, hex21) HingeBaseProfile();
 981
 982       // buildout for prop recess
 983       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 984         linextr(case_bottom_z, epp2i[1])
 985         hull() {
 986           for (dxs = [-1,+1])
 987             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 988                        -epp2o[0] ],
 989                      r = epp2o[0] - prcp2[0]);
 990         }
 991     }
 992
 993     // slot for keeper
 994     Flip_rhs(keeper_side)
 995       translate([0, -phone_cnr_rad, 0])
 996       rotate([90, 0, 0])
 997       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 998       minkowski(){
 999         KeeperProfile();
1000         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1001                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1002       }
1003
1004     // front camera
1005     RearCameraAperture();
1006
1007     // struts (invisible, because they're buried in the case)
1008     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1009
1010     Buttons(){
1011       mirror([1,0,0])
1012         rotate([90,0,90]) {
1013           if (!($button_leg_only && enable_support))
1014           intersection(){
1015             translate([0,0,-10])
1016               linear_extrude(height= 20)
1017               ButtonPlan($button_l, 0,1);
1018             if ($button_leg_only)
1019               rotate([-90,90,0])
1020                 translate([phone_width/2, -400, kppe[1]])
1021                 mirror([1-abs($rhsflip - keeper_side),0,0])
1022                 cube([400, 800, 50]);
1023             if (enable_support && !$button_suppress_over_keeper)
1024               rotate([-90,90,0])
1025               translate([-400, -400, kppd[1]])
1026                 mirror([0,0,1])
1027                 cube([800,800,100]);
1028           }
1029           translate([0,0, -bppR[0]])
1030             linear_extrude(height= 20)
1031             ButtonPlan($button_l, 1,1);
1032         }
1033
1034     }
1035
1036     // apertures along top edge
1037     CaseAperture(jack_pos, jack_dia, 8);
1038     Flip_rhs(1)
1039       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1040
1041     OrdinaryRearApertures();
1042
1043     MicroUSB();
1044
1045     // gaps for the lid's hinge arms
1046     HingePortion(hex20 - hinge_x_arms_gap,
1047                  hex21 + hinge_x_arms_gap)
1048       minkowski(){
1049         HingeLidProfile();
1050         circle(r= hinge_r_arms_gap, $fn= 8);
1051       }
1052
1053     // screw holes in the hinge arms
1054     HingeScrews();
1055
1056     // catch striker
1057     CatchPortion(catch_width + catch_side_gap*2)
1058       CatchCutProfile();
1059
1060     // prop recess
1061     Flip_rhs(1)
1062       translate([prop_x_pos,0,0])
1063       mirror([0,1,0])
1064       rotate([90,0,90])
1065       linextr(-prop_recess_hw, +prop_recess_hw)
1066       hull(){
1067         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1068           circleat(prcp1 + 20*d,
1069                    prc_r3);
1070       }
1071   }
1072 }
1073
1074 module LidAdhocMultiprintFrame(phase){
1075   if (led_window_style >= 3) {
1076     AdhocMultiprintFrame(phase, lpp13[1], -1);
1077   }
1078 }
1079
1080 module LidAroundEdges(){
1081   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1082     children();
1083 }
1084
1085 module Lid(){ ////toplevel
1086   skew_centre = [0, lpp11[0], lpp11[1]];
1087   difference(){
1088     union(){
1089       intersection(){
1090         LidAroundEdges()
1091           LidEdgeProfile();
1092
1093         translate(skew_centre)
1094           multmatrix([[ 1, 0, 0, 0 ],
1095                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1096                       [ 0, 0, 1, 0 ],
1097                       [ 0, 0, 0, 1 ]])
1098           translate(-skew_centre)
1099           LidAroundEdges()
1100           LidEdgeFoldClearanceProfile();
1101       }
1102
1103       // button covers
1104       Buttons(){
1105         intersection(){
1106           rotate([90,0,90])
1107             translate([0,0,-10])
1108             linear_extrude(height= 20)
1109             ButtonPlan($button_l, 1,0);
1110           rotate([90,0,0])
1111              translate([0,0,-100])
1112             linear_extrude(height= 200)
1113             ButtonCoverProfile();
1114         }
1115       }
1116
1117       // hinge arms
1118       HingePortion(hex20, hex21) {
1119         LidEdgeProfile();
1120         HingeLidProfile();
1121       }
1122
1123       // catch
1124       CatchPortion(catch_width)
1125         CatchCatchProfile();
1126     }
1127     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1128
1129     // screw holes in the hinge arms
1130     HingeScrews();
1131
1132     // prop recess
1133     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1134       mirror([0,1,0])
1135       rotate([90,0,90])
1136       linextr(-prop_recess_hw, +prop_recess_hw)
1137       hull()
1138       for (pa = prop_angles)
1139         PropProfile(pa, 1,1);
1140
1141     // notification led aperture
1142     if (led_window_style)
1143       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1144         translate([0,0,-10])
1145           cylinder(r=nla_r0, h=20);
1146         if (led_window_style >= 2)
1147           translate([0,0, -nla_t])
1148             cylinder(r=nla_r2, height=20);
1149       }
1150
1151     }
1152
1153   LidAdhocMultiprintFrame(1);
1154 }
1155
1156 module HingeLever(){ ////toplevel
1157   difference() {
1158     // outer body, positive
1159     HingePortion(hex22, hex22 + phone_width/2)
1160       HingeLeverOuterProfile();
1161
1162     // space for the screws
1163     HingePortion(hex26, hex24)
1164       HingeLeverInnerProfile();
1165
1166     // recesses for the nuts
1167     HingePortion(hex23, hex26+1)
1168       HingeLeverNutProfile();
1169
1170     // bores for the screws
1171     HingeScrews();
1172
1173     // space for the charging cable
1174     MicroUSB();
1175     Flip_hinge() MicroUSB();
1176   }
1177 }
1178
1179 module LidWindow(){ ////toplevel
1180   translate([led_pos[0], -led_pos[1], lpp13[1]])
1181     mirror([0,0,1])
1182     cylinder(r= nla_r1, h=nla_t);
1183   LidAdhocMultiprintFrame(0);
1184 }
1185
1186 module LidWindowPrint(){ ////toplevel
1187   rotate([0,180,0])
1188     LidWindow();
1189 }
1190
1191 module DemoLidWindowSelect(){
1192   translate([led_pos[0], led_pos[1], -100]) {
1193     translate([0, -30, 0]) cube([400, 400, 200]);
1194   }
1195 }
1196
1197 module DemoLidWindow(){ ////toplevel
1198   %Lid();
1199   LidWindow();
1200   translate([0,40,0]){
1201     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1202     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1203   }
1204 }
1205
1206 module HingeLeverPrint(){ ////toplevel
1207   rotate([-90,0,0])
1208     translate([-phone_width/2, phone_height, 0])
1209     HingeLever();
1210 }
1211
1212 module TestSelectLength(){
1213   translate([-30, -200, -20])
1214     cube([30 + 15, 250, 40]);
1215 }
1216
1217 module TestLength(){ ////toplevel
1218   intersection(){
1219     Case();
1220     TestSelectLength();
1221   }
1222 }
1223
1224 module TestLengthRight(){ ////toplevel
1225   intersection(){
1226     Case();
1227     Flip_rhs(1)
1228       TestSelectLength();
1229   }
1230 }
1231
1232 module TestSelectWidth(){
1233   translate([-30, -(phone_height - 25), -20])
1234     mirror([0, 1, 0])
1235     cube([200, 50, 40]);
1236 }
1237
1238 module TestWidth(){ ////toplevel
1239   intersection(){
1240     Case();
1241     TestSelectWidth();
1242   }
1243 }
1244
1245 module TestLidWidthPrint(){ ////toplevel
1246   rotate([0,180.0]) intersection(){
1247     Lid();
1248     TestSelectWidth();
1249   }
1250 }
1251
1252 module TestSelectRearAperture(){
1253   minkowski(){
1254     union() children();
1255     translate([20, 0,0])
1256       cube([42, 2, 1], center=true);
1257   }
1258 }
1259
1260 module TestSelectCamera(){
1261   minkowski(){
1262     TestSelectRearAperture()
1263       RearCameraAperture();
1264     cube([0.1, 50, 0.1]);
1265   }
1266 }
1267
1268 module TestSelectOrdinaryRearApertures(){
1269   TestSelectRearAperture()
1270     OrdinaryRearApertures();
1271 }
1272
1273 module TestCamera(){ ////toplevel
1274   intersection(){
1275     Case();
1276     TestSelectCamera();
1277   }
1278 }
1279
1280 module TestLidByCamera(){ ////toplevel
1281   intersection(){
1282     Lid();
1283     TestSelectCamera();
1284   }
1285 }
1286
1287 module TestLidByCameraPrint(){ ////toplevel
1288   rotate([180,0,0]) TestLidByCamera();
1289 }
1290
1291 module DemoByCamera(){ ////toplevel
1292   color("blue") TestLidByCamera();
1293   color("red")  TestCamera();
1294 }
1295
1296 module OneKeeper(){ ////toplevel
1297   translate([0, -phone_cnr_rad, 0])
1298     rotate([90, 0, 0])
1299     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1300     KeeperProfile();
1301 }
1302
1303 module OneKeeperPrint(){ ////toplevel
1304   rotate([0,180,0])
1305     OneKeeper();
1306 }
1307
1308 module LidPrint(){ ////toplevel
1309   rotate([0,180,0])
1310     Lid();
1311 }
1312
1313 module TestSelectFrame(){
1314   include = [1,-1] * (epp2i[0] + 4);
1315
1316   difference(){
1317     cube(1000, center=true);
1318     translate([0,0, -100])
1319       linear_extrude(height=200)
1320       rectfromto(include,  inside_br - include);
1321   }
1322 }
1323
1324 module TestSelectLidFrame(){
1325   TestSelectFrame();
1326   translate([led_pos[0], -led_pos[1], -50])
1327     cylinder(r= nla_r2+3, h=100);
1328 }
1329
1330 module TestFrameCase(){ ////toplevel
1331   intersection(){
1332     Case();
1333     union(){
1334       TestSelectFrame();
1335       TestSelectCamera();
1336       TestSelectOrdinaryRearApertures();
1337     }
1338   }
1339 }
1340
1341 module TestSelectTopApertures(){
1342   translate([-100, -35, -100])
1343     cube([400, 100, 200]);
1344   LidAdhocMultiprintFrame(0);
1345   LidAdhocMultiprintFrame(1);
1346 }
1347
1348 module TestTopApertures(){ ////toplevel
1349   intersection(){
1350     Case();
1351     TestSelectFrame();
1352     TestSelectTopApertures();
1353   }
1354 }
1355
1356 module TestLidTopAperturesPrint(){ ////toplevel
1357   rotate([0,180,0]) intersection(){
1358     Lid();
1359     TestSelectLidFrame();
1360     TestSelectTopApertures();
1361   }
1362 }
1363
1364 module TestLidWindowTopAperturesPrint(){ ////toplevel
1365   rotate([0,180,0]) intersection(){
1366     LidWindow();
1367     TestSelectTopApertures();
1368   }
1369 }
1370
1371 module TestFrameLidPrint(){ ////toplevel
1372   rotate([0,180,0]) intersection(){
1373     Lid();
1374     TestSelectLidFrame();
1375   }
1376 }
1377
1378 module ButtonPlanForDemo(z, deep, cut){
1379   translate([0,0,z])
1380     ButtonPlan(8, deep, cut);
1381 }
1382
1383 module HingeScrews(){
1384   Flip_rhs() Flip_bot(1){
1385     for (c= [ hppT, hppB ])
1386       translate([ hex20,
1387                   -c[0],
1388                   c[1] ]){
1389         rotate([0,90,0])
1390           translate([0,0,-.2])
1391           cylinder( r= hingescrew_shaft_dia/2,
1392                     h = hingescrew_shaft_len+0.2 );
1393         rotate([0,-90,0])
1394           translate([0,0,+.1])
1395           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1396       }
1397   }
1398 }
1399
1400 module DemoPropAngleSelect(c){
1401   color(c) difference(){
1402     union(){ children(); }
1403     translate([ prop_x_pos, -400, -200 ])
1404       cube([ 400,800,400 ]);
1405   }
1406 }
1407
1408 module DemoPropAngle(ang){
1409   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1410   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1411
1412   translate(hL)
1413     rotate([ang/2,0,0])
1414     translate(-hL)
1415     translate(hC)
1416     rotate([ang/2,0,0])
1417     translate(-hC) {
1418       DemoPropAngleSelect("red") Case();
1419
1420       color("orange")
1421         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1422         PropProfileAssignments(ang) {
1423           echo($prpp1);
1424           rotate([-$prp_theta, 0, 0])
1425           translate([0, $prpp1[0], -$prpp1[1]])
1426           rotate([90,0,-90])
1427           Prop();
1428         }
1429     }
1430
1431   translate([0,0, -hp_k*2])
1432     DemoPropAngleSelect("blue")
1433     Lid();
1434 }
1435
1436 module DemoPropAngles(){ ////toplevel
1437   for (i=[0 : len(prop_angles)-1])
1438     translate(i * [0, -100, 100])
1439     DemoPropAngle(prop_angles[i]);
1440 }
1441
1442 module DemoHingeAngle(ang1,ang2){
1443   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1444   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1445
1446   translate(hL)
1447     rotate([ang2,0,0])
1448     translate(-hL)
1449     translate(hC)
1450     rotate([ang1,0,0])
1451     translate(-hC) {
1452       color("red") Lid();
1453     }
1454
1455   color("blue") intersection(){
1456     Case();
1457     union(){
1458       translate([bppJ[0], -400, -200])
1459         mirror([1,0,0])
1460         cube([400, 800, 400]);
1461       translate([10, -400, -200])
1462         cube([10, 800, 400]);
1463     }
1464   }
1465 }
1466
1467 module DemoHingeAngles(){ ////toplevel
1468   angles = [ 0, 4, 8, 12 ];
1469   echo("angles",angles);
1470   for (i=[0 : len(angles)-1]) {
1471     translate(i * [0, 0, 30]) {
1472       DemoHingeAngle(0,angles[i]);
1473       translate([0, 200, 0])
1474         DemoHingeAngle(angles[i],0);
1475     }
1476   }
1477 }
1478
1479 module DemoSelectAdhocLeftRight(right=0) {
1480   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1481     mirror([1-right, 0,0])
1482     cube([400, 800, 200]);
1483 }
1484
1485 module DemoLeft(){ ////toplevel
1486   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1487   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1488 }
1489
1490 module DemoFrame(){ ////toplevel
1491   color("red") TestFrameCase();
1492   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1493   color("black") HingeScrews();
1494   %HingeLever();
1495 }
1496
1497 module DemoHingedFrame(){ ///toplevel
1498   color("red") TestFrameCase();
1499   translate([0,0, -2*hp_k])
1500   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1501
1502   Flip_hinge(){
1503     color("orange") HingeLever();
1504     color("black") HingeScrews();
1505   }
1506 }
1507
1508 module DemoHinge(){ ////toplevel
1509   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1510     DemoFrame();
1511     translate([0,0, -hp_k*3])
1512       DemoHingedFrame();
1513   }
1514 }
1515
1516 module DemoProfiles(){ ////toplevel
1517   LidEdgeProfile();
1518   %EdgeProfile();
1519   KeeperProfile();
1520   translate([0,0,-1]) color("black") KeeperProfile(1);
1521
1522   translate([20,0]) {
1523     LidEdgeProfile();
1524     %EdgeProfile();
1525
1526     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1527
1528     color("blue") ButtonCoverProfile();
1529     color("red") {
1530       rectfromto(bppQ, demopoint_QR);
1531       rectfromto(bppR, demopoint_QR);
1532     }
1533   }
1534
1535   translate([-20,0]) {
1536     color("black") ButtonPlanForDemo(-2, 0,1);
1537     color("red" )  ButtonPlanForDemo(-4, 1,1);
1538     color("blue")  ButtonPlanForDemo(-6, 1,0);
1539   }
1540
1541   translate([0, -30]) {
1542     %LidEdgeProfile();
1543     %EdgeProfile();
1544     color("blue") HingeLidProfile();
1545     color("red")  HingeBaseProfile();
1546     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1547   }
1548
1549   for (f=[0,1]) {
1550     translate([-30, -60 + 30*f]) {
1551       translate([0,0,-4]) EdgeProfile();
1552       %translate([0,0,-10]) HingeBaseProfile();
1553       translate([0,-2] * f * hp_k) {
1554         translate([0,0,-4]) LidEdgeProfile();
1555         %translate([0,0,-10]) %HingeLidProfile();
1556       }
1557       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1558         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1559         translate([0,0,0]) color("red") difference(){
1560           HingeLeverOuterProfile();
1561           HingeLeverInnerProfile();
1562         }
1563         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1564       }
1565     }
1566   }
1567
1568   translate([20,-30]) {
1569     %EdgeProfile();
1570     %LidEdgeProfile();
1571     //translate([0,0,1]) CatchCutProfile();
1572     color("blue") CatchCatchProfile();
1573     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1574   }
1575
1576   translate([40,-30]) {
1577     difference(){
1578       LidEdgeProfile();
1579       translate(prlp10)
1580         PropProfile(10, 1, 0);
1581     }
1582     translate(prlp10)
1583       PropProfile(15, 0);
1584   }
1585   translate([60,-30]) {
1586     PropAggregateProfile();
1587   }
1588 }
1589
1590 //EdgeProfile();
1591 //KeeperProfile();
1592 //CaseBase();
1593 //%Case();
1594 //Keeper();
1595 //LidEdgeProfile();
1596 //KeeperProfile();
1597 //DemoProfiles();
1598 //PropRecess();