chiark / gitweb /
a9d042364262c45604ebd331c5a6c7b14dee368f
[reprap-play.git] / fairphone-case.scad
1 // -*- C -*-
2
3 // Hard case for Fairphone 2
4 //
5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
6 //  See below for full licensing and disclaimer.
7 //
8 // Instructions
9 //
10 //  1. You will want to git clone this repository.
11 //
12 //  2. Decide about the notification LED aperture. See the variable
13 //     led_window_style, below.  The default here is "ad-hoc
14 //     multi-colour", which can produces a translucent (clear-ish)
15 //     window set into the lid, even on a single-nozzle printer.
16 //     See "Ad-hoc multi-colour", below.
17 //
18 //  3. use "make" to generate the necessary files:
19 //
20 //     make -j8 fairphone-case.auto.scads `for f in   \
21 //        HingePrint        \
22 //        LidWindowPrint    \
23 //        LidPrint          \
24 //        OneKeeperPrint    \
25 //        Case              \
26 //     ; do echo fairphone-case,$f.auto.stl; done`
27 //
28 //  4. Print them.  Case and OneKeeperPrint should probably be
29 //     the same colour.
30 //
31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
32 //     multi-colour:
33 //        i.   Set up for clear filament
34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
35 //             It won't take long.  As soon as it finishes, tell
36 //             your printer to warm up (so that in fact it does
37 //             not cool down).
38 //        iii. Leaving the output so far on the printbed, reload
39 //             your printer with the main lid colour.
40 //        iv.  Print LidPrint.  You can let this go unattended.
41 //
42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
43 //     and 8x M2 full nuts.
44 //
45 //     Make sure you get the hinge the right way round.  If you're not
46 //     sure, run
47 //         openscad fairphone-case,DemoHinge.auto.scad
48 //     to see an assembly diagram.
49 //
50 //     The nuts recess into the hinge.  You will want very fine
51 //     pliers.  As you screw each screw in, add the second nut when
52 //     the screw thread emerges from the first - this will be a
53 //     locknut.  Screw each screw to an appropriate tightness for the
54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
55 //     that makes closing the case work better.
56 //
57 //     When you have the stiffness right, tighten the locknuts onto
58 //     each first nut.
59 //
60 //  6. In use:
61 // 
62 //      - To put the phone in, drop its RH side into the RH side of
63 //        the case.  Then feed the keeper through the small hole.
64 //        Feed it right through.
65 //
66 //      - The optional prop can be used to prop the phone up (in
67 //        portrait orientation only right now).  See
68 //            openscad fairphone-case,DemoPropAngles.auto.scad
69 //
70 // Ad-hoc multi-colour
71 //     
72 //  This file is set up to let you make a translucent window using a
73 //  single-extruder printer, using a "two print run" technique.  This
74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
75 //  Cura.  If you are using a different printer, you may need to
76 //  adjust the parameters or try a different technique.  In particular,
77 //      initial_layer_thick
78 //         set so that the window is one layer thick
79 //      initial_layer_width
80 //         set so that the slicer draws a rectangle around the whole
81 //         object, rather than putting a "skirt" or anything inside
82 //
83 //  If you have a dual-extruder printer, you can set led_window_style
84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
85 //
86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
87 //
88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
90 //
91 // Other phones
92 //
93 //  It might well be possible to adapt this file for other phones.
94 //  If you do, let me know how you get on.
95 //
96 //
97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
98 //
99 //   Copyright (C)2018 Ian Jackson.
100 //
101 //    This program for generating a 3D model is free software: you can
102 //    redistribute it and/or modify it under the terms of the GNU
103 //    General Public License as published by the Free Software
104 //    Foundation, either version 3 of the License, or (at your option)
105 //    any later version.
106 //
107 //    This program is distributed in the hope that it will be useful,
108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
110 //    GNU General Public License for more details.
111 //
112 //    You should have received a copy of the GNU General Public
113 //    License along with this program.  If not, see
114 //    <http://www.gnu.org/licenses/>.
115 //
116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
118 //  this case will meet your needs.
119
120 include <utils.scad>
121 include <funcs.scad>
122
123 phone = [ 75.0, 145.0 ];
124
125 prop_buildout_less = 3;
126
127 prop_angles = [ 15, 30, 45, 60 ];
128
129 bumper = [ 0.250, -0.025 ];
130 // ^ One side.  Overall size is increased by twice this.
131 // If no bumpers, is the gap around the phone.
132
133 enable_support = 1;
134
135 led_window_style = 3;
136 // 0: no window
137 // 1: simply an opening
138 // 2: opening with separate cover model, for printing in clear (two colour)
139 // 3: like 2 but one-layer window for ad-hoc multi-colour
140
141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
142 initial_layer_width = 0.750; // ^ needed for mode 3 only
143 multicolour_gap = 0.15; // each side
144
145 phone_cnr_rad = 6.0;
146 phone_rim_depth = 0.80; // includes allowance for a screen protector
147
148 button_cutout_depth = 9;
149
150 phone_edge_thick = 9.0;
151 phone_total_thick = 12.0;
152 phone_backside_slope_inner = 1.5; // larger means shallower
153 phone_backside_slope_outer = 1.0; // larger means shallower
154
155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
157
158 jack_pos = [ 13.83, 8.485 ];
159 jack_dia = 10.64 + .5; // some jack I had lying around
160
161 led_pos = [ 13.98, 10.00 ];
162 led_aperture = 9;
163 led_window_ledge = 0.75; // each side
164
165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
166 noisecancelmic_dia = 4.00;
167
168 //fingerpushhole_dias = [ 15, 18 ];
169 fingerpushhole_dias = [];
170
171 lanyard_half_dia = 1.15;
172 lanyard_entry_rel_breadth = 2;
173 lanyard_channel_len = 15;
174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
175 rearspeaker_size   = [  3.76,  7.36 ];
176
177 microusb_above = 3.27 - 0.25;
178 microusb_below = 0.0;
179 microusb_width = 16.12 + 1.25;
180
181 case_th_bottom = 2.5;
182 case_th_lid = 3.0;
183 case_th_side = 2.3;
184 case_th_lip = 1.2;
185
186 lid_screen_gap_extra = .66;
187
188 case_struts_count = 6;
189 case_struts_solid_below = 1.00;
190 case_struts_solid_above = 0.75;
191 case_struts_width = 0.10;
192
193 keeper_th_z = 0.75;
194 keeper_th_x = 0.75;
195 keeper_inner_width = 2.75;
196 keeper_inner_height = 2.75;
197 keeper_slant_slope = 2; // larger means steeper
198
199 keeper_gap_z_top = 0.25;
200 keeper_gap_z_bot = 0.75;
201 keeper_gap_x     = 0.25;
202 keeper_gap_x_holes = 0.75;
203
204 keeper_side = 0; // 0 = lhs; 1 = rhs
205
206 case_lip = 1.25;
207
208 lid_gap_x = 0.25;
209 lid_gap_z = 0.25;
210 lid_lip = 1.75;
211 lid_edgepart_width = 5.0;
212 lid_buttoncover_thick = 1.3;
213 lid_buttoncover_reinf = 0.65;
214
215 foldover_gap = 0.50;
216 foldover_lever_gap = 0.50;
217
218 // properties of the hinge fasteners
219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
220 hingescrew_shaft_len = 12;
221 hingescrew_fasteners_extra_thick = 0.40;
222 // ^ amount of thread protruding if everything was completely nominal
223 //   and we are using two nuts
224 hingescrew_nut_access_dia = 4.72 + 0.50;
225 // ^ washer is 4.72 dia
226 //   also, want to get pliers or tiny spanner in to do up locknut
227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
228 hingescrew_nut_thick = 1.93;
229 hingescrew_head_th = 1.38 + 0.75;
230 hingescrew_head_dia = 3.92;
231
232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
233
234 lever_cover_th = 0.75;
235 hingemount_th = 2.5;
236 hingemount_wd = 4.8725;
237
238 $fa = 5;
239 $fs = 0.1;
240
241 button_l_fudge = 4.4;
242 buttonishleg_default_l_is_fudge = 10;
243
244 hinge_base_slope = 1.5; // bigger is steeper
245
246 strut_min_at_end = 1.5;
247
248 hinge_x_gap = 0.125;
249 hinge_x_postscrew_gap = 0.75;
250 hinge_x_arms_gap = 0.35;
251 hinge_r_arms_gap = 0.55;
252
253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
254
255 thumbrecess_depth = 1.3;
256
257 catch_slop = -0.75;
258
259 catch_len = 4.5;
260 catch_width = 15;
261 catch_thickness = 1.3;
262 catch_side_gap = 0.75; // each side
263
264 catch_depth = 0.75;
265 catch_height = 0.35;
266 catch_finger_height = 1.5;
267 catch_finger_depth = 2.5;
268 catch_catch_slope = 2.00;
269 catch_close_slope = 3.00;
270
271 catch_topcurve_r = 5.0;
272
273 prop_recess_under = 0.50;
274 prop_recess_slop = 0.200; // each side
275 prop_end_dia = 0.5;
276 prop_main_th = 3;
277 prop_taper_len = 6;
278 prop_main_width = 4;
279 prop_side_gap = 0.75; // each side
280 prop_lidrecess_behind = 0.75;
281 prop_caserecess_behind = 0.75;
282 prop_caserecess_taper = 0.45; // one side only
283 prop_prop_gap = 0.5;
284 prop_prong_heel_slope = 0.5;
285
286 lid_fold_clearance_antislop = 0.5;
287
288 // ---------- calculated ----------
289
290 phone_width =  (phone + bumper*2)[0];
291 phone_height = (phone + bumper*2)[1];
292
293 inside_br = [phone_width, -phone_height];
294
295 prop_prong_h = prop_main_th;
296
297 //echo(camera_pos_tl + bumper,
298 //     camera_pos_br + bumper);
299
300 // ----- could be changed -----
301 lid_buttoncover_gap = lid_gap_x;
302 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
303
304 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
305
306 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
307
308 //prop_nose_len = case_th_lid - prop_recess_under;
309 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
310 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
311
312
313 //lid_lip_overlap_width xxx bad name = ;
314 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
315
316 epp0 = [0,0];
317 epp1 = [0, -phone_edge_thick];
318 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
319 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
320 epp3 = epp2i + [10, 0];
321 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
322 epp4 = epp5 + [-1,0] * case_th_side;
323
324 kppe = [0,0];
325 kppd = kppe + [1,0] * keeper_inner_width;
326 kppc = kppd + [0,1] * keeper_th_z;
327 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
328 kppf = kppe - [0,1] * keeper_inner_height;
329 kppa = [ kppb[0], kppf[1] ];
330
331 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
332 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
333
334 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
335 // exact x posn not very important; must extend past end of keeper
336
337 lpp15 = [ lpp14[0],
338           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
339           + lid_screen_gap_extra ];
340 // ^ beam theory says to maximise force before contact,
341 //   the gap below the `beam' (the lid) must be 1/3
342 //   the thickness (ie the lid thickness) if the beam
343 //   is solid, or 1/2 if it has a top and bottom only.
344 //   ours is mostly solid.
345
346 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
347              case_th_lip);
348
349 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
350 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
351
352 case_bottom_z = epp2o[1] - case_th_bottom;
353
354 // button profile
355 bppM = epp4 + [0,5];
356 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
357 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
358 bppS = [ epp1[0], bppR[1] ];
359 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
360 bppP = bppQ + [0,1] * lid_buttoncover_gap;
361 bppO = [ bppN[0], bppP[1] ];
362 bppL = lpp10 + [5,0];
363 bppK = [ bppL[0], bppN[1] ];
364 bppJ = [ bppN[0], bppL[1] ];
365 bppU = [ bppJ[0], lpp12[1] ];
366 bppV = lpp11;
367 bppW = lpp10;
368
369 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
370
371 // notification led aperture
372
373 nla_r0 = led_aperture/2;
374 nla_r1 = nla_r0 + led_window_ledge;
375 nla_r2 = nla_r1 + multicolour_gap;
376 nla_t =
377   led_window_style >= 3 ? initial_layer_thick :
378   led_window_style >= 2 ? led_window_ledge : 0;
379
380
381 // hinge plan
382 hp_rn = hingescrew_nut_access_dia/2;
383 hp_r2_min = hp_rn + lever_cover_th;
384 hp_rs = hingescrew_shaft_dia/2;
385 hp_r1_min = hp_rs + hingemount_th;
386
387 hp_r1 = max(hp_r1_min, hp_r2_min);
388 hp_r2 = hp_r1;
389
390 hppU = lpp13;
391 hppS = epp2o + [0,-1] * case_th_bottom;
392 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
393
394 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
395          0.5 * (hppU + hppS)[1] ];
396 hppT = [ hppM[0], hppU[1] - hp_r1 ];
397 hppB = hppT + [0,-1] * hp_k;
398
399 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
400 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
401 hppE = [ hppE_x, hppE_y ];
402
403 // hinge elevation x coords
404
405 hex20 = max(epp2o[0],
406             phone_cnr_rad,
407             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
408 hex21 = hex20 + hingemount_wd;
409 hex22 = hex21 + hinge_x_gap;
410 hex27 = hex20 + hingescrew_shaft_len;
411 hex24 = hex27 + hinge_x_postscrew_gap;
412 hex23 = hex27 - (hingescrew_nut_thick*2
413                  + hingescrew_fasteners_extra_thick);
414 hex26 = hex23 + hingescrew_nut_thick * 2/3;
415
416 echo(hex20, hex21, hex22, hex23, hex24);
417 //  6, 10.8725, 10.9975, 13.74, 18.75
418 module chk(act,exp) {
419   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
420   else echo("ok", act);
421 }
422 chk(hex20, 6);
423 chk(hex21, 10.8725);
424 chk(hex22, 10.9975);
425 chk(hex23, 13.74);
426 chk(hex24, 18.75);
427
428 lid_fold_clearance_skew =
429   (lpp10[1] - hppB[1]) /
430   (lpp10[0] - hppB[0]);
431
432 echo("SK",lid_fold_clearance_skew);
433
434 // thumb recess (used to be "catch" hence cpp*
435
436 cppA = epp4 + [thumbrecess_depth, 0];
437 cppB = [ cppA[0], epp1[1] ];
438
439 // lanyard
440
441 ly_r = lanyard_half_dia / 2;
442 ly_rc = ly_r * 2;
443
444 ly_theta = -atan2vector(epp2i - epp1);
445 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
446
447 max_case_bottom_edge_thickness =
448   case_th_bottom
449   + sin(ly_theta) * (epp2i-epp2o)[0];
450
451 ly_q_z = -(ly_rc + ly_r);
452 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
453
454 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
455
456 // prop recess in case
457
458 prop_x_pos = phone_width/2;
459
460 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
461
462 prc_r1 = prop_end_dia/2;
463 prc_r3 = prc_r1 + prop_recess_slop;
464
465 prcp2 = [ epp4[0] + prop_buildout_less,
466           case_bottom_z ];
467
468 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
469
470 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
471           epp2i[1] - prc_r3 - prop_recess_under];
472
473 // prop recess in lid
474
475 prl_r10 = prop_end_dia/2;
476 prl_r10o = prl_r10 + prop_recess_slop;
477
478 prlp10 = lpp10 + [1,1] * prl_r10o
479   + [1,0] * prop_lidrecess_behind
480   + [0,1] * prop_recess_under;
481
482 // prop
483
484 $prpp10 = [0,0];
485 $prpp11 = [0, prop_taper_len];
486
487 $prp_r10 = prl_r10;
488
489 // ---------- modules ----------
490
491 module AdhocMultiprintFrame(phase, z0, zs) {
492   // from z0 to z0 + zs*layer
493   extra = phase * (initial_layer_width + multicolour_gap) + 5;
494   xextra = extra + -epp4[0];
495   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
496   yextra = extra + -epp4[0];
497   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
498   p0 = [ xrange[0], yrange[0] ];
499   p1 = [ xrange[1], yrange[1] ];
500   echo(p0, p1);
501   translate([0,0, z0])
502     mirror([0,0, zs<0 ? 1 : 0])
503     linear_extrude(height= initial_layer_thick)
504     difference(){
505       rectfromto(p0 - [1,1] * initial_layer_width,
506                  p1 + [1,1] * initial_layer_width);
507       rectfromto(p0, p1);
508     }
509 }
510
511 module KeeperProfile(slant=0){
512   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
513   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
514 }
515
516 module EdgeProfile(){
517   difference(){
518     hull(){
519       translate(epp3) square(case_th_bottom*2, center=true);
520       circleat(epp2o, r=case_th_bottom);
521       circleat(epp1, r=case_th_side);
522       rectfromto(epp0, epp4);
523     }
524     polygon([ epp5 + [0,10],
525               epp1,
526               epp2i,
527               epp3 + [10,0] ]);
528   }
529 }
530
531 module LanyardLanyardProfile(entry=false){
532   hull(){
533     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
534       translate(xs * 0.5 * lanyard_half_dia * [1,0])
535         circle(r= lanyard_half_dia/2);
536   }
537 }
538
539 module LanyardCurveChannelProfile(){
540   translate([0, -ly_r])
541     LanyardLanyardProfile();
542 }  
543
544 module LanyardEntryChannelProfile(){
545   LanyardLanyardProfile(true);
546 }  
547
548 module LanyardMainChannelProfile(){
549   LanyardCurveChannelProfile();
550   difference(){
551     square(center=true, ly_r * [6, 2]);
552     for (xs=[-1,+1])
553       translate(ly_r * [3 * xs, -1])
554         circle(r = ly_r);
555   }
556 }
557
558 module LanyardEntryOuterProfile(){
559   circleat([ly_re + ly_r, 0], ly_re);
560 }
561
562 module LanyardEntry(){
563   q_z = ly_q_z;
564   oec_y = ly_oec_y;
565
566   d_x = -ly_rc;
567
568   translate([d_x, 0, q_z]) {
569     intersection(){
570       rotate([90,0,0])
571         rotate_extrude(convexity=10)
572         rotate(90)
573         translate([0, -q_z])
574         LanyardCurveChannelProfile();
575       translate([0,-10,0])
576         cube([20,20,20]);
577     }
578   }
579
580   mirror([0,0,1])
581     translate([0,0,-1])
582     linear_extrude(height=20)
583     rotate(-90)
584     LanyardEntryChannelProfile();
585
586   translate([0, ly_r*2, 0])
587     rotate([90,0,0])
588     linear_extrude(height = ly_r*4){
589     difference(){
590       rectfromto([d_x, q_z], [ly_r, 0]);
591       circleat([d_x, q_z], ly_rc);
592     }
593   }
594
595   translate([0,0,q_z]){
596     for (my=[0,1])
597       mirror([0,my,0]){
598         translate([0, oec_y, 0]){
599           difference(){
600             translate(ly_re * [-1,0,-2])
601               cube(ly_re * [2,1,2]);
602             rotate_extrude(convexity=10)
603               LanyardEntryOuterProfile();
604           }
605         }
606       }
607     difference(){
608       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
609         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
610       for (mx=[0,1])
611         mirror([mx,0,0])
612           rotate([90,0,0])
613           translate([0,0,-10])
614           linear_extrude(height=20)
615           LanyardEntryOuterProfile();
616     }
617   }
618 }
619
620 module LanyardCutout(l){
621   rotate([0,-90,0])
622     linear_extrude(height=l)
623     rotate(-90)
624     LanyardMainChannelProfile();
625
626   for (ee=[0,1]){
627     translate(ee * l * [-1,0])
628       mirror([ee,0,0])
629       LanyardEntry();
630   }
631 }
632
633 module LidEdgeProfile(){
634   polygon([ lpp10,
635             lpp11,
636             lpp12,
637             lpp13,
638             lpp13 + [10, 0],
639             lpp15 + [10, 0],
640             lpp15,
641             lpp14,
642             ]);
643   intersection(){
644     circleat(lpp12, r=lp_r12);
645     rectfromto( lpp12 + [-10,   0],
646                 lpp12 + [+10, +10] );
647   }
648 }
649
650 module LidEdgeFoldClearanceProfile(){
651   translate([-lid_fold_clearance_antislop, 0])
652     polygon([ lpp10,
653               lpp11,
654               lpp11 + [-20,  0],
655               lpp11 + [-20, 20],
656               lpp11 + [+20, 20],
657               lpp10 + [+20,  0] ]);
658 }
659
660 module ButtonCoverProfile(){
661   intersection(){
662     polygon(concat([ bppM, bppP, bppO, bppJ ],
663                    (enable_support && !$button_suppress_over_keeper
664                     ? [ bppU, bppV, bppW ] : []),
665                    [ bppL, bppK ]));
666     hull(){
667       EdgeProfile();
668       LidEdgeProfile();
669     }
670   }
671 }
672
673 module ButtonPlan(l, deep, cut){
674   epsilon =
675     (cut  ? 0 : lid_buttoncover_gap);
676
677   delta =
678     (deep ? lid_buttoncover_overlap : 0);
679
680   C = [0,0]; // by definition
681   T = [ 0, epp4[1] ];
682   G = T + [0,10];
683
684   B0 = C + [0,-1] * button_cutout_depth;
685   B1 = B0 + [0,1] * epsilon;
686
687   r0 = 0.5 * (T[1] - B0[1]);
688   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
689   H = A + [0,-1] * delta;
690
691   D = A + [-2,0] * r0;
692   F = D + [0,10];
693
694   E0 = 0.5 * (D + A);
695   E1 = E0 + [1,0] * epsilon;
696
697   I0 = [ E0[0], H[1] ];
698   I1 = [ E1[0], H[1] ];
699
700   hull(){
701     for (m=[0,1]) mirror([m,0])
702       circleat(H, r0 - epsilon);
703   }
704   for (m=[0,1]) mirror([m,0]) {
705     difference(){
706       polygon([ E1,
707                 I1,
708                 H,
709                 B1,
710                 G,
711                 F,
712                 D
713                 ]);
714       circleat(D, r0 + epsilon);
715     }
716   }
717 }
718
719 module ButtonCoverReinf(){ ////toplevel
720   minkowski(){
721     rotate([90,0,0])
722       linear_extrude(height=0.01)
723       intersection(){
724         ButtonCoverProfile();
725         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
726           square([100,100]);
727     }
728     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
729       circle(r= lid_buttoncover_reinf);
730       translate([-20,0]) square(40, center=true);
731     }
732   }
733 }
734
735 module CatchCutProfile(){
736   difference(){
737     polygon([ cppA + [-10,0],
738               cppB + [-10,0],
739               cppB,
740               cppA ]);
741     circleat(epp1, r=case_th_side);
742   }
743 }
744
745 module Flip_rhs(yn=[0,1]) {
746   for ($rhsflip=yn) {
747     translate([phone_width/2, 0, 0])
748       mirror([$rhsflip,0,0])
749       translate([-phone_width/2, 0, 0])
750       children();
751   }
752 }
753
754 module Flip_bot(yn=[0,1]) {
755   for ($botflip=yn) {
756     translate([0, -phone_height/2, 0])
757       mirror([0, $botflip, 0])
758       translate([0, phone_height/2, 0])
759       children();
760   }
761 }  
762
763 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
764   // sides
765   Flip_rhs(){
766     translate([0, -phone_cnr_rad, 0])
767       rotate([90,0,0])
768       linear_extrude(height = phone_height - phone_cnr_rad*2)
769       children(0);
770   }
771   // corners
772   Flip_rhs() Flip_bot() {
773     translate([+1,-1] * phone_cnr_rad)
774       intersection(){
775         rotate_extrude()
776           intersection(){
777             mirror([1,0,0])
778               translate([-1,0] * phone_cnr_rad)
779               children(0);
780             rectfromto([0,-20],[10,20]);
781           }
782         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
783           cube([10,10,40]);
784       }
785   }
786   // top and bottom
787   Flip_bot(){
788     translate([ phone_width - phone_cnr_rad, 0,0 ])
789       rotate([90,0,-90])
790       linear_extrude(height = phone_width - phone_cnr_rad*2)
791       children(0);
792   }
793   // fill
794   translate([0,0, fill_zstart])
795     mirror([0,0, fill_downwards])
796     linear_extrude(height = fill_th)
797     rectfromto([+1,-1] * phone_cnr_rad,
798                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
799 }
800
801 module CaseAperture(pos, dia, $fn) {
802   theta = 180/$fn;
803   translate([ pos[0] + bumper[0],
804               -epp2i[0],
805               -pos[1] ])
806     rotate([-90, theta, 0])
807     cylinder(r = dia/2 / cos(theta),
808              h = 60);
809 }
810
811 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
812   // y_ref_sign:
813   //   +1  measured from top    of actual phone to top    of button
814   //   -1  measured from bottom of actual phone to bottom of button
815   //    0  y is centre of button in coordinate system
816   $button_l= l;
817   $button_suppress_over_keeper= suppress_over_keeper;
818   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
819           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
820           y;
821   //echo(eff_y);
822   translate([0, eff_y, 0])
823     children();
824 }
825
826 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
827   $button_leg_only = true;
828   SideButton(y, y_ref_sign, l) children();
829 }
830
831 module Buttons(){
832   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
833   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
834   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
835   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
836 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
837 }
838
839 module Struts(x_start, z_min, th){
840   // if th is negative, starts at z_min and works towards -ve z
841   // and object should then be printed other way up
842   for (i= [1 : 1 : case_struts_count]) {
843     translate([0,
844                0,
845                z_min])
846       mirror([0,0, th<0 ? 1 : 0])
847       translate([0,
848                  -phone_height * i / (case_struts_count+1),
849                  case_struts_solid_below])
850       linear_extrude(height= abs(th)
851                      -(case_struts_solid_below+case_struts_solid_above))
852       rectfromto([               x_start, -0.5 * case_struts_width ],
853                  [ phone_width - x_start, +0.5 * case_struts_width ]);
854   }
855 }
856
857 module OrdinaryRearAperture(rhs,bot, pos){
858   Flip_rhs(rhs) Flip_bot(bot)
859     linextr(-20, 20)
860     mirror([0,1])
861     translate(pos + bumper)
862     children();
863 }
864
865 module MicroUSB(){
866   Flip_bot(1){
867     rotate([90,0,0])
868       mirror([0,0,1])
869       linextr(-epp2i[0], 60)
870       translate([0.5 * phone_width, 0, 0])
871       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
872                  [+microusb_width/2, epp0[1] + -microusb_above]);
873   }
874 }
875
876 module OrdinaryRearApertures(){
877   // rear speaker
878   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
879     rectfromto(-rearspeaker_gap,
880                rearspeaker_size + rearspeaker_gap);
881
882   // finger hole to remove phone
883   if (len(fingerpushhole_dias))
884     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
885                                 phone[1]/2 ])
886     scale(fingerpushhole_dias)
887     circle(r= 0.5 );
888 }
889
890 module RearCameraAperture(){
891   Flip_rhs(1)
892     mirror([0, 0, 1])
893     linear_extrude(height = 20)
894     mirror([0, 1, 0])
895     translate(bumper)
896     rectfromto(camera_pos_tl, camera_pos_br);
897 }
898
899 module HingeLidProfile(){
900   hull(){
901     circleat(hppT, hp_r1);
902     circleat(lpp12, lp_r12);
903     polygon([lpp10,
904              lpp13 + [2,0],
905              lpp12,
906              hppT]);
907   }
908 }
909
910 module HingeBaseProfile(){
911   difference(){
912     hull(){
913       circleat(hppB, hp_r1);
914       circleat(hppE, hp_r1);
915       circleat(epp2o, case_th_bottom);
916       circleat(hppB + [10,0], hp_r1);
917     }
918     polygon([epp5, epp1, epp2i, epp3, bppL]);
919   }
920 }
921
922 module HingeLeverOuterProfile(){
923   hull(){
924     circleat(hppT, hp_r2);
925     circleat(hppB, hp_r2);
926   }
927 }
928
929 module HingeLeverInnerProfile(){
930   for (s = [-1,+1]) {
931     c = s > 0 ? hppT : hppB;
932     translate(c)
933       mirror([0,0,s>0])
934       rotate(s<0 ? -40 : 0)
935       hull()
936       for (x=[-20,20])
937         for (y=[0, s * 10])
938           translate([x,y])
939             circle(hp_rn);
940   }
941 }
942
943 module HingeLeverNutProfile(){
944   for (c= [hppB, hppT]) {
945     translate(c)
946       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
947   }
948 }
949
950 module Flip_hinge(doflip=1){
951   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
952   translate(hinge_origin)
953     rotate([doflip*180,0,0])
954     translate(-hinge_origin)
955     children();
956 }
957
958 module HingePortion(x0,x1){
959   Flip_rhs() Flip_bot(1)
960     translate([x0,0,0])
961     mirror([1,0,0])
962     rotate([90,0,-90])
963     linear_extrude(height=x1-x0)
964     children();
965 }
966
967 module CatchPortion(ztop){
968   xwidth = catch_side_gap*2;
969   width = catch_width + xwidth;
970   w = width + catch_topcurve_r*2 + 1;
971   translate([phone_width/2, 0,0]){
972     difference(){
973       rotate([90,0,-90])
974         linextr(-w/2, w/2)
975         children(0);
976       translate([0, 50, 0])
977         rotate([90,0,0])
978         linear_extrude(height=100){
979         for (m=[0,1]) mirror([m,0,0]) {
980           hull(){
981             translate([w/2, ztop - catch_topcurve_r])
982               circle(catch_topcurve_r);
983             translate([w/2, -50])
984               square(catch_topcurve_r*2, center=true);
985           }
986         }
987       }
988     }
989   }
990 }
991
992 module CaseBase(){
993   AroundEdges(epp3[1], case_th_bottom, 1)
994     EdgeProfile();
995 }
996
997 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
998
999 module PropProfileAssignments(gamma){
1000   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1001   x = prop_x(gamma);
1002   p = phone_height + prlp10[0] - hppB[0];
1003   b = p + x;
1004
1005   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1006   a = q + x;
1007   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1008   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1009
1010   $prp_theta = 90 - $prp_alpha;
1011   beta = 180 - $prp_alpha - gamma;
1012   psi = 90 - beta;
1013
1014   //echo("abc", a,b,c);
1015
1016   v1 = [ [ cos(psi), -sin(psi) ],    // x
1017          [ sin(psi),  cos(psi) ] ];  // y
1018
1019   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1020
1021   $prp_r1 = prc_r1;
1022   $prp_r11 = prop_main_th/2;
1023
1024   $prpp1 = $prpp7 + [1,0] *
1025     // this is approximate, but will do
1026     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1027   $prpp3 = $prpp1 +
1028     v1[0] * -$prp_r1 +
1029     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1030   $prpp12 = $prpp3 + v1[0] *
1031     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1032   $prp_r8 = prop_main_th;
1033   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1034   $prp_r5 = $prp_r8;
1035   $prpp5 = [ $prpp12[0] - $prp_r5,
1036             $prpp3[1] - prop_prong_h + $prp_r5 ];
1037   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1038          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1039   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1040   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1041
1042   children();
1043 }
1044
1045 module PropProfile(gamma, cut=0, rot=0){
1046   PropProfileAssignments(gamma){
1047
1048     //#circleat($prpp3,1);
1049     //#circleat($prpp12,1);
1050
1051     if (!cut) {
1052       hull(){
1053         translate($prpp8)
1054           intersection(){
1055             circle($prp_r8);
1056             polygon([[-20,-0], [20,20], [0,0]]);
1057           }
1058         rectfromto($prpp6, $prpp9);
1059         translate($prpp5) intersection(){
1060           circle($prp_r5);
1061           polygon([[-10,-10], [0,0], [10,0]]);
1062         }
1063         rectfromto($prpp12 + [0,-0.1], $prpp3);
1064       }
1065       hull(){
1066         circleat($prpp1, $prp_r1);
1067         rectfromto($prpp12 + [0,-0.1], $prpp3);
1068       }
1069     }
1070     // main shaft
1071     rotate([0,0, rot*-$prp_theta]){
1072       hull(){
1073         extra = cut ? prop_recess_slop : 0;
1074         rectfromto($prpp6, $prpp9);
1075         circleat($prpp11, $prp_r11 + extra);
1076         circleat($prpp10, $prp_r10 + extra);
1077       }
1078     }
1079   }
1080 }
1081
1082 module PropAggregateProfile(){
1083   for (angle = prop_angles)
1084     PropProfile(angle, 0,0);
1085 }
1086
1087 module Prop(){ ////toplevel
1088   hw = prop_main_width/2;
1089   linextr(-hw, +hw)
1090     PropAggregateProfile();
1091 }
1092
1093 module Case(){ ////toplevel
1094   difference(){
1095     union(){
1096       CaseBase();
1097
1098       // ledge (fixed keeper)
1099       Flip_rhs(1-keeper_side) intersection(){
1100         rotate([90, 0, 0])
1101           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1102           KeeperProfile(1);
1103
1104         // outline of the whole case, to stop it protruding
1105         translate([0,0, -25])
1106           linear_extrude(height = 50)
1107           hull()
1108           Flip_bot()
1109           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1110       }
1111
1112       // hinge
1113       HingePortion(hex20, hex21) HingeBaseProfile();
1114
1115       // buildout for prop recess
1116       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1117         linextr(case_bottom_z, epp2i[1])
1118         hull() {
1119           for (dxs = [-1,+1])
1120             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1121                        -epp2o[0] ],
1122                      r = epp2o[0] - prcp2[0]);
1123         }
1124     }
1125
1126     // slot for keeper
1127     Flip_rhs(keeper_side)
1128       translate([0, -phone_cnr_rad, 0])
1129       rotate([90, 0, 0])
1130       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1131       minkowski(){
1132         KeeperProfile();
1133         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1134                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1135       }
1136
1137     // front camera
1138     RearCameraAperture();
1139
1140     // struts (invisible, because they're buried in the case)
1141     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1142
1143     Buttons(){
1144       mirror([1,0,0])
1145         rotate([90,0,90]) {
1146           if (!($button_leg_only && enable_support))
1147           intersection(){
1148             translate([0,0,-10])
1149               linear_extrude(height= 20)
1150               ButtonPlan($button_l, 0,1);
1151             if ($button_leg_only)
1152               rotate([-90,90,0])
1153                 translate([phone_width/2, -400, kppe[1]])
1154                 mirror([1-abs($rhsflip - keeper_side),0,0])
1155                 cube([400, 800, 50]);
1156             if (enable_support && !$button_suppress_over_keeper)
1157               rotate([-90,90,0])
1158               translate([-400, -400, kppd[1]])
1159                 mirror([0,0,1])
1160                 cube([800,800,100]);
1161           }
1162           translate([0,0, -bppR[0]])
1163             linear_extrude(height= 20)
1164             ButtonPlan($button_l, 1,1);
1165         }
1166       
1167     }
1168
1169     // apertures along top edge
1170     CaseAperture(jack_pos, jack_dia, 8);
1171     Flip_rhs(1)
1172       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1173
1174     OrdinaryRearApertures();
1175
1176     MicroUSB();
1177
1178     // gaps for the lid's hinge arms
1179     HingePortion(hex20 - hinge_x_arms_gap,
1180                  hex21 + hinge_x_arms_gap)
1181       minkowski(){
1182         HingeLidProfile();
1183         circle(r= hinge_r_arms_gap, $fn= 8);
1184       }
1185
1186     // screw holes in the hinge arms
1187     HingeScrews();
1188
1189     // catch striker
1190     CatchPortion(epp4[1])
1191       CatchCutProfile();
1192
1193     // lanyard
1194     Flip_bot(1)
1195       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1196       rotate([0, ly_theta, 0])
1197       rotate([0,0,90])
1198       LanyardCutout(lanyard_channel_len);
1199
1200     // prop recess
1201     Flip_rhs(1)
1202       translate([prop_x_pos,0,0])
1203       mirror([0,1,0])
1204       rotate([90,0,90])
1205       linextr(-prop_recess_hw, +prop_recess_hw)
1206       hull(){
1207         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1208           circleat(prcp1 + 20*d,
1209                    prc_r3);
1210       }
1211   }
1212 }
1213
1214 module LidAdhocMultiprintFrame(phase){
1215   if (led_window_style >= 3) {
1216     AdhocMultiprintFrame(phase, lpp13[1], -1);
1217   }
1218 }
1219
1220 module LidAroundEdges(){
1221   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1222     children();
1223 }
1224
1225 module Lid(){ ////toplevel
1226   skew_centre = [0, lpp11[0], lpp11[1]];
1227   difference(){
1228     union(){
1229       intersection(){
1230         LidAroundEdges()
1231           LidEdgeProfile();
1232
1233         translate(skew_centre)
1234           multmatrix([[ 1, 0, 0, 0 ],
1235                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1236                       [ 0, 0, 1, 0 ],
1237                       [ 0, 0, 0, 1 ]])
1238           translate(-skew_centre)
1239           LidAroundEdges()
1240           LidEdgeFoldClearanceProfile();
1241       }
1242
1243       // button covers
1244       Buttons(){
1245         intersection(){
1246           rotate([90,0,90])
1247             translate([0,0,-10])
1248             linear_extrude(height= 20)
1249             ButtonPlan($button_l, 1,0);
1250           union(){
1251             rotate([90,0,0])
1252               translate([0,0,-100])
1253               linear_extrude(height= 200)
1254               ButtonCoverProfile();
1255             hull()
1256               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1257                                  - lid_buttoncover_reinf))
1258                 translate([0,y,0])
1259                   ButtonCoverReinf();
1260           }
1261         }
1262       }
1263
1264       // hinge arms
1265       HingePortion(hex20, hex21) {
1266         LidEdgeProfile();
1267         HingeLidProfile();
1268       }
1269     }
1270     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1271
1272     // screw holes in the hinge arms
1273     HingeScrews();
1274
1275     // prop recess
1276     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1277       mirror([0,1,0])
1278       rotate([90,0,90])
1279       linextr(-prop_recess_hw, +prop_recess_hw)
1280       hull()
1281       for (pa = prop_angles)
1282         PropProfile(pa, 1,1);
1283
1284     // notification led aperture
1285     if (led_window_style)
1286       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1287         translate([0,0,-10])
1288           cylinder(r=nla_r0, h=20);
1289         if (led_window_style >= 2)
1290           translate([0,0, -nla_t])
1291             cylinder(r=nla_r2, height=20);
1292       }
1293
1294     }
1295
1296   LidAdhocMultiprintFrame(1);
1297 }
1298
1299 module HingeLever(){ ////toplevel
1300   difference() {
1301     // outer body, positive
1302     HingePortion(hex22, hex22 + phone_width/2)
1303       HingeLeverOuterProfile();
1304
1305     // space for the screws
1306     HingePortion(hex26, hex24)
1307       HingeLeverInnerProfile();
1308
1309     // recesses for the nuts
1310     HingePortion(hex23, hex26+1)
1311       HingeLeverNutProfile();
1312
1313     // bores for the screws
1314     HingeScrews();
1315
1316     // space for the charging cable
1317     MicroUSB();
1318     Flip_hinge() MicroUSB();
1319   }
1320 }
1321
1322 module LidWindow(){ ////toplevel
1323   translate([led_pos[0], -led_pos[1], lpp13[1]])
1324     mirror([0,0,1])
1325     cylinder(r= nla_r1, h=nla_t);
1326   LidAdhocMultiprintFrame(0);
1327 }
1328
1329 module LidWindowPrint(){ ////toplevel
1330   rotate([0,180,0])
1331     LidWindow();
1332 }
1333
1334 module DemoLidWindowSelect(){
1335   translate([led_pos[0], led_pos[1], -100]) {
1336     translate([0, -30, 0]) cube([400, 400, 200]);
1337   }
1338 }
1339
1340 module DemoLidWindow(){ ////toplevel
1341   %Lid();
1342   LidWindow();
1343   translate([0,40,0]){
1344     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1345     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1346   }
1347 }
1348
1349 module HingeLeverPrint(){ ////toplevel
1350   rotate([-90,0,0])
1351     translate([-phone_width/2, phone_height, 0])
1352     HingeLever();
1353 }
1354
1355 module TestSelectLength(){
1356   translate([-30, -200, -20])
1357     cube([30 + 15, 250, 40]);
1358 }
1359
1360 module TestLength(){ ////toplevel
1361   intersection(){
1362     Case();
1363     TestSelectLength();
1364   }
1365 }
1366
1367 module TestLengthRight(){ ////toplevel
1368   intersection(){
1369     Case();
1370     Flip_rhs(1)
1371       TestSelectLength();
1372   }
1373 }
1374
1375 module TestSelectWidth(){
1376   translate([-30, -(phone_height - 25), -20])
1377     mirror([0, 1, 0])
1378     cube([200, 50, 40]);
1379 }
1380
1381 module TestWidth(){ ////toplevel
1382   intersection(){
1383     Case();
1384     TestSelectWidth();
1385   }
1386 }
1387
1388 module TestLidWidthPrint(){ ////toplevel
1389   rotate([0,180.0]) intersection(){
1390     Lid();
1391     TestSelectWidth();
1392   }
1393 }
1394
1395 module TestSelectRearAperture(){
1396   minkowski(){
1397     union() children();
1398     translate([20, 0,0])
1399       cube([42, 2, 1], center=true);
1400   }
1401 }
1402
1403 module TestSelectCamera(){
1404   minkowski(){
1405     TestSelectRearAperture()
1406       RearCameraAperture();
1407     cube([0.1, 50, 0.1]);
1408   }
1409 }
1410
1411 module TestSelectOrdinaryRearApertures(){
1412   TestSelectRearAperture()
1413     OrdinaryRearApertures();
1414 }
1415
1416 module TestCamera(){ ////toplevel
1417   intersection(){
1418     Case();
1419     TestSelectCamera();
1420   }
1421 }
1422
1423 module TestLidByCamera(){ ////toplevel
1424   intersection(){
1425     Lid();
1426     TestSelectCamera();
1427   }
1428 }
1429
1430 module TestLidByCameraPrint(){ ////toplevel
1431   rotate([180,0,0]) TestLidByCamera();
1432 }
1433
1434 module DemoByCamera(){ ////toplevel
1435   color("blue") TestLidByCamera();
1436   color("red")  TestCamera();
1437 }
1438
1439 module OneKeeper(){ ////toplevel
1440   translate([0, -phone_cnr_rad, 0])
1441     rotate([90, 0, 0])
1442     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1443     KeeperProfile();
1444 }
1445
1446 module OneKeeperPrint(){ ////toplevel
1447   rotate([0,180,0])
1448     OneKeeper();
1449 }
1450
1451 module LidPrint(){ ////toplevel
1452   rotate([0,180,0])
1453     Lid();
1454 }
1455
1456 module TestSelectFrame(){
1457   include = [1,-1] * (epp2i[0] + 4);
1458
1459   difference(){
1460     cube(1000, center=true);
1461     translate([0,0, -100])
1462       linear_extrude(height=200)
1463       rectfromto(include,  inside_br - include);
1464   }
1465 }
1466
1467 module TestSelectLidFrame(){
1468   TestSelectFrame();
1469   translate([led_pos[0], -led_pos[1], -50])
1470     cylinder(r= nla_r2+3, h=100);
1471 }
1472
1473 module TestFrameCase(){ ////toplevel
1474   intersection(){
1475     Case();
1476     union(){
1477       TestSelectFrame();
1478       TestSelectCamera();
1479       TestSelectOrdinaryRearApertures();
1480     }
1481   }
1482 }
1483
1484 module TestSelectTopApertures(){
1485   translate([-100, -35, -100])
1486     cube([400, 100, 200]);
1487   LidAdhocMultiprintFrame(0);
1488   LidAdhocMultiprintFrame(1);
1489 }
1490
1491 module TestTopApertures(){ ////toplevel
1492   intersection(){
1493     Case();
1494     TestSelectFrame();
1495     TestSelectTopApertures();
1496   }
1497 }
1498
1499 module TestLidTopAperturesPrint(){ ////toplevel
1500   rotate([0,180,0]) intersection(){
1501     Lid();
1502     TestSelectLidFrame();
1503     TestSelectTopApertures();
1504   }
1505 }
1506
1507 module TestLidWindowTopAperturesPrint(){ ////toplevel
1508   rotate([0,180,0]) intersection(){
1509     LidWindow();
1510     TestSelectTopApertures();
1511   }
1512 }
1513
1514 module TestFrameLidPrint(){ ////toplevel
1515   rotate([0,180,0]) intersection(){
1516     Lid();
1517     TestSelectLidFrame();
1518   }
1519 }
1520
1521 module ButtonPlanForDemo(z, deep, cut){
1522   translate([0,0,z])
1523     ButtonPlan(8, deep, cut);
1524 }
1525
1526 module HingeScrews(){
1527   Flip_rhs() Flip_bot(1){
1528     for (c= [ hppT, hppB ])
1529       translate([ hex20,
1530                   -c[0],
1531                   c[1] ]){
1532         rotate([0,90,0])
1533           translate([0,0,-.2])
1534           cylinder( r= hingescrew_shaft_dia/2,
1535                     h = hingescrew_shaft_len+0.2 );
1536         rotate([0,-90,0])
1537           translate([0,0,+.1])
1538           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1539       }
1540   }
1541 }
1542
1543 module DemoPropAngleSelect(c){
1544   color(c) difference(){
1545     union(){ children(); }
1546     translate([ prop_x_pos, -400, -200 ])
1547       cube([ 400,800,400 ]);
1548   }
1549 }
1550
1551 module DemoPropAngle(ang){
1552   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1553   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1554
1555   translate(hL)
1556     rotate([ang/2,0,0])
1557     translate(-hL)
1558     translate(hC)
1559     rotate([ang/2,0,0])
1560     translate(-hC) {
1561       DemoPropAngleSelect("red") Case();
1562
1563       color("orange")
1564         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1565         PropProfileAssignments(ang) {
1566           echo($prpp1);
1567           rotate([-$prp_theta, 0, 0])
1568           translate([0, $prpp1[0], -$prpp1[1]])
1569           rotate([90,0,-90])
1570           Prop();
1571         }
1572     }
1573
1574   translate([0,0, -hp_k*2])
1575     DemoPropAngleSelect("blue")
1576     Lid();
1577 }
1578
1579 module DemoPropAngles(){ ////toplevel
1580   for (i=[0 : len(prop_angles)-1])
1581     translate(i * [0, -100, 100])
1582     DemoPropAngle(prop_angles[i]);
1583 }
1584
1585 module DemoHingeAngle(ang1,ang2){
1586   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1587   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1588
1589   translate(hL)
1590     rotate([ang2,0,0])
1591     translate(-hL)
1592     translate(hC)
1593     rotate([ang1,0,0])
1594     translate(-hC) {
1595       color("red") Lid();
1596     }
1597
1598   color("blue") intersection(){
1599     Case();
1600     union(){
1601       translate([bppJ[0], -400, -200])
1602         mirror([1,0,0])
1603         cube([400, 800, 400]);
1604       translate([10, -400, -200])
1605         cube([10, 800, 400]);
1606     }
1607   }
1608 }
1609
1610 module DemoHingeAngles(){ ////toplevel
1611   angles = [ 0, 4, 8, 12 ];
1612   echo("angles",angles);
1613   for (i=[0 : len(angles)-1]) {
1614     translate(i * [0, 0, 30]) {
1615       DemoHingeAngle(0,angles[i]);
1616       translate([0, 200, 0])
1617         DemoHingeAngle(angles[i],0);
1618     }
1619   }
1620 }
1621
1622 module DemoSelectAdhocLeftRight(right=0) {
1623   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1624     mirror([1-right, 0,0])
1625     cube([400, 800, 200]);
1626 }
1627
1628 module DemoLeft(){ ////toplevel
1629   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1630   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1631 }
1632
1633 module DemoFrame(){ ////toplevel
1634   color("red") TestFrameCase();
1635   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1636   color("black") HingeScrews();
1637   %HingeLever();
1638 }
1639
1640 module DemoLanyardCutout(){ ////toplevel
1641   LanyardCutout(25);
1642 }
1643
1644 module DemoHingedFrame(){ ///toplevel
1645   color("red") TestFrameCase();
1646   translate([0,0, -2*hp_k])
1647   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1648
1649   Flip_hinge(){
1650     color("orange") HingeLever();
1651     color("black") HingeScrews();
1652   }
1653 }
1654
1655 module DemoHinge(){ ////toplevel
1656   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1657     DemoFrame();
1658     translate([0,0, -hp_k*3])
1659       DemoHingedFrame();
1660   }
1661 }
1662
1663 module DemoProfiles(){ ////toplevel
1664   LidEdgeProfile();
1665   %EdgeProfile();
1666   KeeperProfile();
1667   translate([0,0,-1]) color("black") KeeperProfile(1);
1668   translate(ly_o){
1669     rotate(-ly_theta){
1670       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1671       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1672       translate([0, ly_q_z]){
1673         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1674         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1675       }
1676     }
1677   }
1678   translate([0,0,-5]) color("white") translate(epp2i)
1679     rotate(-ly_theta)
1680     rectfromto([-15, 0],
1681                [+15, -max_case_bottom_edge_thickness]);
1682
1683   translate([0,20]) {
1684     LanyardMainChannelProfile();
1685     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1686     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1687   }
1688
1689   translate([20,0]) {
1690     LidEdgeProfile();
1691     %EdgeProfile();
1692
1693     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1694   
1695     color("blue") ButtonCoverProfile();
1696     color("red") {
1697       rectfromto(bppQ, demopoint_QR);
1698       rectfromto(bppR, demopoint_QR);
1699     }
1700   }
1701
1702   translate([-20,0]) {
1703     color("black") ButtonPlanForDemo(-2, 0,1);
1704     color("red" )  ButtonPlanForDemo(-4, 1,1);
1705     color("blue")  ButtonPlanForDemo(-6, 1,0);
1706   }
1707
1708   translate([0, -30]) {
1709     %LidEdgeProfile();
1710     %EdgeProfile();
1711     color("blue") HingeLidProfile();
1712     color("red")  HingeBaseProfile();
1713     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1714   }
1715
1716   for (f=[0,1]) {
1717     translate([-30, -60 + 30*f]) {
1718       translate([0,0,-4]) EdgeProfile();
1719       %translate([0,0,-10]) HingeBaseProfile();
1720       translate([0,-2] * f * hp_k) {
1721         translate([0,0,-4]) LidEdgeProfile();
1722         %translate([0,0,-10]) %HingeLidProfile();
1723       }
1724       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1725         translate([0,0,-2]) color("black") HingeLeverOuterProfile(); 
1726         translate([0,0,0]) color("red") difference(){
1727           HingeLeverOuterProfile();
1728           HingeLeverInnerProfile();
1729         }
1730         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1731       }
1732     }
1733   }
1734
1735   translate([20,-30]) {
1736     %EdgeProfile();
1737     %LidEdgeProfile();
1738     //translate([0,0,1]) CatchCutProfile();
1739     translate([0,0,+1]) color("red")
1740       difference(){ EdgeProfile(); CatchCutProfile(); }
1741   }
1742
1743   translate([40,-30]) {
1744     difference(){
1745       LidEdgeProfile();
1746       translate(prlp10)
1747         PropProfile(10, 1, 0);
1748     }
1749     translate(prlp10)
1750       PropProfile(15, 0);
1751   }
1752   translate([60,-30]) {
1753     PropAggregateProfile();
1754   }
1755 }
1756
1757 //EdgeProfile();
1758 //KeeperProfile();
1759 //CaseBase();
1760 //%Case();
1761 //Keeper();
1762 //LidEdgeProfile();
1763 //KeeperProfile();
1764 //DemoProfiles();
1765 //PropRecess();