fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207
 208 catch_slop = 0.50;
 209
 210 foldover_gap = 0.50;
 211 foldover_lever_gap = 0.50;
 212
 213 // properties of the hinge fasteners
 214 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 215 hingescrew_shaft_len = 12;
 216 hingescrew_fasteners_extra_thick = 0.40;
 217 // ^ amount of thread protruding if everything was completely nominal
 218 //   and we are using two nuts
 219 hingescrew_nut_access_dia = 4.72 + 0.50;
 220 // ^ washer is 4.72 dia
 221 //   also, want to get pliers or tiny spanner in to do up locknut
 222 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 223 hingescrew_nut_thick = 1.93;
 224 hingescrew_head_th = 1.38 + 0.75;
 225 hingescrew_head_dia = 3.92;
 226
 227 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 228
 229 lever_cover_th = 0.75;
 230 hingemount_th = 2.5;
 231 hingemount_wd = 4.8725;
 232
 233 $fa = 5;
 234 $fs = 0.1;
 235
 236 button_l_fudge = 4.4;
 237 buttonishleg_default_l_is_fudge = 10;
 238
 239 hinge_base_slope = 1.5; // bigger is steeper
 240
 241 strut_min_at_end = 1.5;
 242
 243 hinge_x_gap = 0.125;
 244 hinge_x_postscrew_gap = 0.75;
 245 hinge_x_arms_gap = 0.35;
 246 hinge_r_arms_gap = 0.55;
 247
 248 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 249
 250 catch_len = 7.5;
 251 catch_width = 15;
 252 catch_thickness = 1.0;
 253 catch_side_gap = 0.75; // each side
 254
 255 catch_depth = 0.75;
 256 catch_height = 0.35;
 257 catch_finger_height = 1.5;
 258 catch_finger_depth = 2.5;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 // ---------- calculated ----------
 274
 275 phone_width =  (phone + bumper*2)[0];
 276 phone_height = (phone + bumper*2)[1];
 277
 278 inside_br = [phone_width, -phone_height];
 279
 280 prop_prong_h = prop_main_th;
 281
 282 //echo(camera_pos_tl + bumper,
 283 //     camera_pos_br + bumper);
 284
 285 // ----- could be changed -----
 286 lid_buttoncover_gap = lid_gap_x;
 287 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 288
 289 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 290
 291 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 292
 293 //prop_nose_len = case_th_lid - prop_recess_under;
 294 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 295 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 296
 297
 298 //lid_lip_overlap_width xxx bad name = ;
 299 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 300
 301 epp0 = [0,0];
 302 epp1 = [0, -phone_edge_thick];
 303 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 304 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 305 epp3 = epp2i + [10, 0];
 306 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 307 epp4 = epp5 + [-1,0] * case_th_side;
 308
 309 kppe = [0,0];
 310 kppd = kppe + [1,0] * keeper_inner_width;
 311 kppc = kppd + [0,1] * keeper_th_z;
 312 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 313 kppf = kppe - [0,1] * keeper_inner_height;
 314 kppa = [ kppb[0], kppf[1] ];
 315
 316 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 317 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 318
 319 lpp14 = lpp10 + [1,0] * keeper_inner_width;
 320 // exact x posn not very important; must extend past end of keeper
 321
 322 lpp15 = [ lpp14[0],
 323           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 324           + lid_screen_gap_extra ];
 325 // ^ beam theory says to maximise force before contact,
 326 //   the gap below the `beam' (the lid) must be 1/3
 327 //   the thickness (ie the lid thickness) if the beam
 328 //   is solid, or 1/2 if it has a top and bottom only.
 329 //   ours is mostly solid.
 330
 331 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 332              case_th_lip);
 333
 334 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 335 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 336
 337 case_bottom_z = epp2o[1] - case_th_bottom;
 338
 339 // button profile
 340 bppM = epp4 + [0,5];
 341 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 342 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 343 bppS = [ epp1[0], bppR[1] ];
 344 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 345 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 346 bppO = [ bppN[0], bppP[1] ];
 347 bppL = lpp10 + [5,0];
 348 bppK = [ bppL[0], bppN[1] ];
 349 bppJ = [ bppN[0], bppL[1] ];
 350 bppU = [ bppJ[0], lpp12[1] ];
 351 bppV = lpp11;
 352 bppW = lpp10;
 353
 354 // notification led aperture
 355
 356 nla_r0 = led_aperture/2;
 357 nla_r1 = nla_r0 + led_window_ledge;
 358 nla_r2 = nla_r1 + multicolour_gap;
 359 nla_t =
 360   led_window_style >= 3 ? initial_layer_thick :
 361   led_window_style >= 2 ? led_window_ledge : 0;
 362
 363
 364 // hinge plan
 365 hp_rn = hingescrew_nut_access_dia/2;
 366 hp_r2_min = hp_rn + lever_cover_th;
 367 hp_rs = hingescrew_shaft_dia/2;
 368 hp_r1_min = hp_rs + hingemount_th;
 369
 370 hp_r1 = max(hp_r1_min, hp_r2_min);
 371 hp_r2 = hp_r1;
 372
 373 hppU = lpp13;
 374 hppS = epp2o + [0,-1] * case_th_bottom;
 375 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 376
 377 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 378          0.5 * (hppU + hppS)[1] ];
 379 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 380 hppB = hppT + [0,-1] * hp_k;
 381
 382 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 383 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 384 hppE = [ hppE_x, hppE_y ];
 385
 386 // hinge elevation x coords
 387
 388 hex20 = max(epp2o[0],
 389             phone_cnr_rad,
 390             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 391 hex21 = hex20 + hingemount_wd;
 392 hex22 = hex21 + hinge_x_gap;
 393 hex27 = hex20 + hingescrew_shaft_len;
 394 hex24 = hex27 + hinge_x_postscrew_gap;
 395 hex23 = hex27 - (hingescrew_nut_thick*2
 396                  + hingescrew_fasteners_extra_thick);
 397 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 398
 399 echo(hex20, hex21, hex22, hex23, hex24);
 400 //  6, 10.8725, 10.9975, 13.74, 18.75
 401 module chk(act,exp) {
 402   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 403   else echo("ok", act);
 404 }
 405 chk(hex20, 6);
 406 chk(hex21, 10.8725);
 407 chk(hex22, 10.9975);
 408 chk(hex23, 13.74);
 409 chk(hex24, 18.75);
 410
 411 // catch
 412
 413 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 414 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 415 cppB = [ epp0[0], cppA[1] ];
 416 cppP = [ epp4[0], cppJ[1] ];
 417
 418 cppS = cppJ + [0,-1] * catch_len;
 419 cppD = [ cppA[0], cppS[1] + catch_slop ];
 420 cppC = [ cppB[0], cppD[1] ];
 421 cppT = cppS + [1,0] * catch_depth;
 422 cppU = cppT + [0,-1] * catch_height;
 423 cppV = [ cppS[0], cppU[1] - catch_depth ];
 424
 425 cppR = 0.5*(cppP + cppJ);
 426
 427 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 428 cppQ = [ cppR[0],
 429          cppV[1] - (catch_finger_height - cp_rQ) ];
 430 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 431
 432 // prop recess in case
 433
 434 prop_x_pos = phone_width/2;
 435
 436 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 437
 438 prc_r1 = prop_end_dia/2;
 439 prc_r3 = prc_r1 + prop_recess_slop;
 440
 441 prcp2 = [ epp4[0] + prop_buildout_less,
 442           case_bottom_z ];
 443
 444 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 445
 446 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 447           epp2i[1] - prc_r3 - prop_recess_under];
 448
 449 // prop recess in lid
 450
 451 prl_r10 = prop_end_dia/2;
 452 prl_r10o = prl_r10 + prop_recess_slop;
 453
 454 prlp10 = lpp10 + [1,1] * prl_r10o
 455   + [1,0] * prop_lidrecess_behind
 456   + [0,1] * prop_recess_under;
 457
 458 // prop
 459
 460 $prpp10 = [0,0];
 461 $prpp11 = [0, prop_taper_len];
 462
 463 $prp_r10 = prl_r10;
 464
 465 // ---------- modules ----------
 466
 467 module AdhocMultiprintFrame(phase, z0, zs) {
 468   // from z0 to z0 + zs*layer
 469   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 470   xextra = extra + -epp4[0];
 471   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 472   yextra = extra + -epp4[0];
 473   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 474   p0 = [ xrange[0], yrange[0] ];
 475   p1 = [ xrange[1], yrange[1] ];
 476   echo(p0, p1);
 477   translate([0,0, z0])
 478     mirror([0,0, zs<0 ? 1 : 0])
 479     linear_extrude(height= initial_layer_thick)
 480     difference(){
 481       rectfromto(p0 - [1,1] * initial_layer_width,
 482                  p1 + [1,1] * initial_layer_width);
 483       rectfromto(p0, p1);
 484     }
 485 }
 486
 487 module KeeperProfile(slant=0){
 488   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 489   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 490 }
 491
 492 module EdgeProfile(){
 493   difference(){
 494     hull(){
 495       translate(epp3) square(case_th_bottom*2, center=true);
 496       circleat(epp2o, r=case_th_bottom);
 497       circleat(epp1, r=case_th_side);
 498       rectfromto(epp0, epp4);
 499     }
 500     polygon([ epp5 + [0,10],
 501               epp1,
 502               epp2i,
 503               epp3 + [10,0] ]);
 504   }
 505 }
 506
 507 module LidEdgeProfile(){
 508   polygon([ lpp10,
 509             lpp11,
 510             lpp12,
 511             lpp13,
 512             lpp13 + [10, 0],
 513             lpp15 + [10, 0],
 514             lpp15,
 515             lpp14,
 516             ]);
 517   intersection(){
 518     circleat(lpp12, r=lp_r12);
 519     rectfromto( lpp12 + [-10,   0],
 520                 lpp12 + [+10, +10] );
 521   }
 522 }
 523
 524 module ButtonCoverProfile(){
 525   intersection(){
 526     polygon(concat([ bppM, bppP, bppO, bppJ ],
 527                    (enable_support && !$button_suppress_over_keeper
 528                     ? [ bppU, bppV, bppW ] : []),
 529                    [ bppL, bppK ]));
 530     hull(){
 531       EdgeProfile();
 532       LidEdgeProfile();
 533     }
 534   }
 535 }
 536
 537 module ButtonPlan(l, deep, cut){
 538   epsilon =
 539     (cut  ? 0 : lid_buttoncover_gap);
 540
 541   delta =
 542     (deep ? lid_buttoncover_overlap : 0);
 543
 544   C = [0,0]; // by definition
 545   T = [ 0, epp4[1] ];
 546   G = T + [0,10];
 547
 548   B0 = C + [0,-1] * button_cutout_depth;
 549   B1 = B0 + [0,1] * epsilon;
 550
 551   r0 = 0.5 * (T[1] - B0[1]);
 552   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 553   H = A + [0,-1] * delta;
 554
 555   D = A + [-2,0] * r0;
 556   F = D + [0,10];
 557
 558   E0 = 0.5 * (D + A);
 559   E1 = E0 + [1,0] * epsilon;
 560
 561   I0 = [ E0[0], H[1] ];
 562   I1 = [ E1[0], H[1] ];
 563
 564   multmatrix([[ 1, $button_plan_shear ? 0.4 : 0, 0 ],
 565               [ 0,1,0 ],
 566               [ 0,0,1 ],
 567               ]){
 568   hull(){
 569     for (m=[0,1]) mirror([m,0])
 570       circleat(H, r0 - epsilon);
 571   }
 572   for (m=[0,1]) mirror([m,0]) {
 573     difference(){
 574       polygon([ E1,
 575                 I1,
 576                 H,
 577                 B1,
 578                 G,
 579                 F,
 580                 D
 581                 ]);
 582       circleat(D, r0 + epsilon);
 583     }
 584   }
 585   }
 586 }
 587
 588 module CatchCatchProfile(){
 589   hull(){
 590     for (c=[ cppR, cppQ ])
 591       circleat(c, cp_rQ);
 592   }
 593   hull(){
 594     circleat(lpp12, lp_r12);
 595     circleat(lpp12 + [5,0], lp_r12);
 596     rectfromto(cppP, cppP + [5,0.1]);
 597   }
 598   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 599 }
 600
 601 module CatchCutProfile(){
 602   polygon([ cppB,
 603             cppA,
 604             cppD,
 605             cppF,
 606             cppF + [0,-10],
 607             cppF + [-10,-10],
 608             lpp12 + [-10,0],
 609             lpp12 + [10,0]
 610             ]);
 611 }
 612
 613 module Flip_rhs(yn=[0,1]) {
 614   for ($rhsflip=yn) {
 615     translate([phone_width/2, 0, 0])
 616       mirror([$rhsflip,0,0])
 617       translate([-phone_width/2, 0, 0])
 618       children();
 619   }
 620 }
 621
 622 module Flip_bot(yn=[0,1]) {
 623   for ($botflip=yn) {
 624     translate([0, -phone_height/2, 0])
 625       mirror([0, $botflip, 0])
 626       translate([0, phone_height/2, 0])
 627       children();
 628   }
 629 }
 630
 631 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 632   // sides
 633   Flip_rhs(){
 634     translate([0, -phone_cnr_rad, 0])
 635       rotate([90,0,0])
 636       linear_extrude(height = phone_height - phone_cnr_rad*2)
 637       children(0);
 638   }
 639   // corners
 640   Flip_rhs() Flip_bot() {
 641     translate([+1,-1] * phone_cnr_rad)
 642       intersection(){
 643         rotate_extrude()
 644           intersection(){
 645             mirror([1,0,0])
 646               translate([-1,0] * phone_cnr_rad)
 647               children(0);
 648             rectfromto([0,-20],[10,20]);
 649           }
 650         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 651           cube([10,10,40]);
 652       }
 653   }
 654   // top and bottom
 655   Flip_bot(){
 656     translate([ phone_width - phone_cnr_rad, 0,0 ])
 657       rotate([90,0,-90])
 658       linear_extrude(height = phone_width - phone_cnr_rad*2)
 659       children(0);
 660   }
 661   // fill
 662   translate([0,0, fill_zstart])
 663     mirror([0,0, fill_downwards])
 664     linear_extrude(height = fill_th)
 665     rectfromto([+1,-1] * phone_cnr_rad,
 666                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 667 }
 668
 669 module CaseAperture(pos, dia, $fn) {
 670   theta = 180/$fn;
 671   translate([ pos[0] + bumper[0],
 672               -epp2i[0],
 673               -pos[1] ])
 674     rotate([-90, theta, 0])
 675     cylinder(r = dia/2 / cos(theta),
 676              h = 60);
 677 }
 678
 679 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 680   // y_ref_sign:
 681   //   +1  measured from top    of actual phone to top    of button
 682   //   -1  measured from bottom of actual phone to bottom of button
 683   //    0  y is centre of button in coordinate system
 684   $button_l= l;
 685   $button_suppress_over_keeper= suppress_over_keeper;
 686   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 687           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 688           y;
 689   //echo(eff_y);
 690   translate([0, eff_y, 0])
 691     children();
 692 }
 693
 694 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 695   $button_leg_only = true;
 696   $button_plan_shear = true;
 697   SideButton(y, y_ref_sign, l) children();
 698 }
 699
 700 module Buttons(){
 701   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 702   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 703   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 704   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 705 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 706 }
 707
 708 module Struts(x_start, z_min, th){
 709   // if th is negative, starts at z_min and works towards -ve z
 710   // and object should then be printed other way up
 711   for (i= [1 : 1 : case_struts_count]) {
 712     translate([0,
 713                0,
 714                z_min])
 715       mirror([0,0, th<0 ? 1 : 0])
 716       translate([0,
 717                  -phone_height * i / (case_struts_count+1),
 718                  case_struts_solid_below])
 719       linear_extrude(height= abs(th)
 720                      -(case_struts_solid_below+case_struts_solid_above))
 721       rectfromto([               x_start, -0.5 * case_struts_width ],
 722                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 723   }
 724 }
 725
 726 module OrdinaryRearAperture(rhs,bot, pos){
 727   Flip_rhs(rhs) Flip_bot(bot)
 728     linextr(-20, 20)
 729     mirror([0,1])
 730     translate(pos + bumper)
 731     children();
 732 }
 733
 734 module MicroUSB(){
 735   Flip_bot(1){
 736     rotate([90,0,0])
 737       mirror([0,0,1])
 738       linextr(-epp2i[0], 60)
 739       translate([0.5 * phone_width, 0, 0])
 740       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 741                  [+microusb_width/2, epp0[1] + -microusb_above]);
 742   }
 743 }
 744
 745 module OrdinaryRearApertures(){
 746   // rear speaker
 747   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 748     rectfromto(-rearspeaker_gap,
 749                rearspeaker_size + rearspeaker_gap);
 750
 751   // finger hole to remove phone
 752   if (len(fingerpushhole_dias))
 753     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 754                                 phone[1]/2 ])
 755     scale(fingerpushhole_dias)
 756     circle(r= 0.5 );
 757 }
 758
 759 module RearCameraAperture(){
 760   Flip_rhs(1)
 761     mirror([0, 0, 1])
 762     linear_extrude(height = 20)
 763     mirror([0, 1, 0])
 764     translate(bumper)
 765     rectfromto(camera_pos_tl, camera_pos_br);
 766 }
 767
 768 module HingeLidProfile(){
 769   hull(){
 770     circleat(hppT, hp_r1);
 771     circleat(lpp12, lp_r12);
 772     polygon([lpp10,
 773              lpp13 + [2,0],
 774              lpp12,
 775              hppT]);
 776   }
 777 }
 778
 779 module HingeBaseProfile(){
 780   difference(){
 781     hull(){
 782       circleat(hppB, hp_r1);
 783       circleat(hppE, hp_r1);
 784       circleat(epp2o, case_th_bottom);
 785       circleat(hppB + [10,0], hp_r1);
 786     }
 787     polygon([epp5, epp1, epp2i, epp3, bppL]);
 788   }
 789 }
 790
 791 module HingeLeverOuterProfile(){
 792   hull(){
 793     circleat(hppT, hp_r2);
 794     circleat(hppB, hp_r2);
 795   }
 796 }
 797
 798 module HingeLeverInnerProfile(){
 799   for (s = [-1,+1]) {
 800     c = s > 0 ? hppT : hppB;
 801     translate(c)
 802       mirror([0,0,s>0])
 803       rotate(s<0 ? -40 : 0)
 804       hull()
 805       for (x=[-20,20])
 806         for (y=[0, s * 10])
 807           translate([x,y])
 808             circle(hp_rn);
 809   }
 810 }
 811
 812 module HingeLeverNutProfile(){
 813   for (c= [hppB, hppT]) {
 814     translate(c)
 815       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 816   }
 817 }
 818
 819 module Flip_hinge(doflip=1){
 820   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 821   translate(hinge_origin)
 822     rotate([doflip*180,0,0])
 823     translate(-hinge_origin)
 824     children();
 825 }
 826
 827 module HingePortion(x0,x1){
 828   Flip_rhs() Flip_bot(1)
 829     translate([x0,0,0])
 830     mirror([1,0,0])
 831     rotate([90,0,-90])
 832     linear_extrude(height=x1-x0)
 833     children(0);
 834 }
 835
 836 module CatchPortion(width){
 837   translate([phone_width/2, 0,0])
 838     rotate([90,0,-90])
 839     linextr(-width/2, width/2)
 840     children(0);
 841 }
 842
 843 module CaseBase(){
 844   AroundEdges(epp3[1], case_th_bottom, 1)
 845     EdgeProfile();
 846 }
 847
 848 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 849
 850 module PropProfileAssignments(gamma){
 851   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 852   x = prop_x(gamma);
 853   p = phone_height + prlp10[0] - hppB[0];
 854   b = p + x;
 855
 856   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 857   a = q + x;
 858   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 859   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 860
 861   $prp_theta = 90 - $prp_alpha;
 862   beta = 180 - $prp_alpha - gamma;
 863   psi = 90 - beta;
 864
 865   //echo("abc", a,b,c);
 866
 867   v1 = [ [ cos(psi), -sin(psi) ],    // x
 868          [ sin(psi),  cos(psi) ] ];  // y
 869
 870   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 871
 872   $prp_r1 = prc_r1;
 873   $prp_r11 = prop_main_th/2;
 874
 875   $prpp1 = $prpp7 + [1,0] *
 876     // this is approximate, but will do
 877     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 878   $prpp3 = $prpp1 +
 879     v1[0] * -$prp_r1 +
 880     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 881   $prpp12 = $prpp3 + v1[0] *
 882     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 883   $prp_r8 = prop_main_th;
 884   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 885   $prp_r5 = $prp_r8;
 886   $prpp5 = [ $prpp12[0] - $prp_r5,
 887             $prpp3[1] - prop_prong_h + $prp_r5 ];
 888   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 889          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 890   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 891   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 892
 893   children();
 894 }
 895
 896 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 897   PropProfileAssignments(gamma){
 898
 899     //#circleat($prpp3,1);
 900     //#circleat($prpp12,1);
 901
 902     if (!cut) {
 903       hull(){
 904         translate($prpp8)
 905           intersection(){
 906             circle($prp_r8);
 907             polygon([[-20,-0], [20,20], [0,0]]);
 908           }
 909         rectfromto($prpp6, $prpp9);
 910         translate($prpp5) intersection(){
 911           circle($prp_r5);
 912           polygon([[-10,-10], [0,0], [10,0]]);
 913         }
 914         rectfromto($prpp12 + [0,-0.1], $prpp3);
 915       }
 916       hull(){
 917         circleat($prpp1, $prp_r1);
 918         rectfromto($prpp12 + [0,-0.1], $prpp3);
 919       }
 920     }
 921     // main shaft
 922     rotate([0,0, rot*-$prp_theta]){
 923       hull(){
 924         extra = cut ? prop_recess_slop : 0;
 925         rectfromto($prpp6, $prpp9);
 926         circleat($prpp11, $prp_r11 + extra);
 927         circleat($prpp10, $prp_r10 + extra);
 928       }
 929     }
 930   }
 931 }
 932
 933 module PropAggregateProfile(){
 934   for (angle = prop_angles)
 935     PropProfile(angle, 0,0);
 936 }
 937
 938 module Prop(){ ////toplevel
 939   hw = prop_main_width/2;
 940   linextr(-hw, +hw)
 941     PropAggregateProfile();
 942 }
 943
 944 module Case(){ ////toplevel
 945   difference(){
 946     union(){
 947       CaseBase();
 948
 949       // ledge (fixed keeper)
 950       Flip_rhs(1-keeper_side) intersection(){
 951         rotate([90, 0, 0])
 952           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 953           KeeperProfile(1);
 954
 955         // outline of the whole case, to stop it protruding
 956         translate([0,0, -25])
 957           linear_extrude(height = 50)
 958           hull()
 959           Flip_bot()
 960           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 961       }
 962
 963       // hinge
 964       HingePortion(hex20, hex21) HingeBaseProfile();
 965
 966       // buildout for prop recess
 967       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 968         linextr(case_bottom_z, epp2i[1])
 969         hull() {
 970           for (dxs = [-1,+1])
 971             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 972                        -epp2o[0] ],
 973                      r = epp2o[0] - prcp2[0]);
 974         }
 975     }
 976
 977     // slot for keeper
 978     Flip_rhs(keeper_side)
 979       translate([0, -phone_cnr_rad, 0])
 980       rotate([90, 0, 0])
 981       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 982       minkowski(){
 983         KeeperProfile();
 984         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 985                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 986       }
 987
 988     // front camera
 989     RearCameraAperture();
 990
 991     // struts (invisible, because they're buried in the case)
 992     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 993
 994     Buttons(){
 995       mirror([1,0,0])
 996         rotate([90,0,90]) {
 997           if (!($button_leg_only && enable_support))
 998           intersection(){
 999             translate([0,0,-10])
1000               linear_extrude(height= 20)
1001               ButtonPlan($button_l, 0,1);
1002             if ($button_leg_only)
1003               rotate([-90,90,0])
1004                 translate([phone_width/2, -400, kppe[1]])
1005                 mirror([1-abs($rhsflip - keeper_side),0,0])
1006                 cube([400, 800, 50]);
1007             if (enable_support && !$button_suppress_over_keeper)
1008               rotate([-90,90,0])
1009               translate([-400, -400, kppd[1]])
1010                 mirror([0,0,1])
1011                 cube([800,800,100]);
1012           }
1013           translate([0,0, -bppR[0]])
1014             linear_extrude(height= 20)
1015             ButtonPlan($button_l, 1,1);
1016         }
1017
1018     }
1019
1020     // apertures along top edge
1021     CaseAperture(jack_pos, jack_dia, 8);
1022     Flip_rhs(1)
1023       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1024
1025     OrdinaryRearApertures();
1026
1027     MicroUSB();
1028
1029     // gaps for the lid's hinge arms
1030     HingePortion(hex20 - hinge_x_arms_gap,
1031                  hex21 + hinge_x_arms_gap)
1032       minkowski(){
1033         HingeLidProfile();
1034         circle(r= hinge_r_arms_gap, $fn= 8);
1035       }
1036
1037     // screw holes in the hinge arms
1038     HingeScrews();
1039
1040     // catch striker
1041     CatchPortion(catch_width + catch_side_gap*2)
1042       CatchCutProfile();
1043
1044     // prop recess
1045     Flip_rhs(1)
1046       translate([prop_x_pos,0,0])
1047       mirror([0,1,0])
1048       rotate([90,0,90])
1049       linextr(-prop_recess_hw, +prop_recess_hw)
1050       hull(){
1051         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1052           circleat(prcp1 + 20*d,
1053                    prc_r3);
1054       }
1055   }
1056 }
1057
1058 module LidAdhocMultiprintFrame(phase){
1059   if (led_window_style >= 3) {
1060     AdhocMultiprintFrame(phase, lpp13[1], -1);
1061   }
1062 }
1063
1064 module Lid(){ ////toplevel
1065   difference(){
1066     union(){
1067       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
1068         LidEdgeProfile();
1069
1070       // button covers
1071       Buttons(){
1072         intersection(){
1073           rotate([90,0,90])
1074             translate([0,0,-10])
1075             linear_extrude(height= 20)
1076             ButtonPlan($button_l, 1,0);
1077           rotate([90,0,0])
1078              translate([0,0,-100])
1079             linear_extrude(height= 200)
1080             ButtonCoverProfile();
1081         }
1082       }
1083
1084       // hinge arms
1085       HingePortion(hex20, hex21) HingeLidProfile();
1086
1087       // catch
1088       CatchPortion(catch_width)
1089         CatchCatchProfile();
1090     }
1091     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1092
1093     // screw holes in the hinge arms
1094     HingeScrews();
1095
1096     // prop recess
1097     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1098       mirror([0,1,0])
1099       rotate([90,0,90])
1100       linextr(-prop_recess_hw, +prop_recess_hw)
1101       hull()
1102       for (pa = prop_angles)
1103         PropProfile(pa, 1,1);
1104
1105     // notification led aperture
1106     if (led_window_style)
1107       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1108         translate([0,0,-10])
1109           cylinder(r=nla_r0, h=20);
1110         if (led_window_style >= 2)
1111           translate([0,0, -nla_t])
1112             cylinder(r=nla_r2, height=20);
1113       }
1114
1115     }
1116
1117   LidAdhocMultiprintFrame(1);
1118 }
1119
1120 module HingeLever(){ ////toplevel
1121   difference() {
1122     // outer body, positive
1123     HingePortion(hex22, hex22 + phone_width/2)
1124       HingeLeverOuterProfile();
1125
1126     // space for the screws
1127     HingePortion(hex26, hex24)
1128       HingeLeverInnerProfile();
1129
1130     // recesses for the nuts
1131     HingePortion(hex23, hex26+1)
1132       HingeLeverNutProfile();
1133
1134     // bores for the screws
1135     HingeScrews();
1136
1137     // space for the charging cable
1138     MicroUSB();
1139     Flip_hinge() MicroUSB();
1140   }
1141 }
1142
1143 module LidWindow(){ ////toplevel
1144   translate([led_pos[0], -led_pos[1], lpp13[1]])
1145     mirror([0,0,1])
1146     cylinder(r= nla_r1, h=nla_t);
1147   LidAdhocMultiprintFrame(0);
1148 }
1149
1150 module LidWindowPrint(){ ////toplevel
1151   rotate([0,180,0])
1152     LidWindow();
1153 }
1154
1155 module DemoLidWindowSelect(){
1156   translate([led_pos[0], led_pos[1], -100]) {
1157     translate([0, -30, 0]) cube([400, 400, 200]);
1158   }
1159 }
1160
1161 module DemoLidWindow(){ ////toplevel
1162   %Lid();
1163   LidWindow();
1164   translate([0,40,0]){
1165     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1166     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1167   }
1168 }
1169
1170 module HingeLeverPrint(){ ////toplevel
1171   rotate([-90,0,0])
1172     translate([-phone_width/2, phone_height, 0])
1173     HingeLever();
1174 }
1175
1176 module TestSelectLength(){
1177   translate([-30, -200, -20])
1178     cube([30 + 15, 250, 40]);
1179 }
1180
1181 module TestLength(){ ////toplevel
1182   intersection(){
1183     Case();
1184     TestSelectLength();
1185   }
1186 }
1187
1188 module TestLengthRight(){ ////toplevel
1189   intersection(){
1190     Case();
1191     Flip_rhs(1)
1192       TestSelectLength();
1193   }
1194 }
1195
1196 module TestSelectWidth(){
1197   translate([-30, -(phone_height - 25), -20])
1198     mirror([0, 1, 0])
1199     cube([200, 50, 40]);
1200 }
1201
1202 module TestWidth(){ ////toplevel
1203   intersection(){
1204     Case();
1205     TestSelectWidth();
1206   }
1207 }
1208
1209 module TestLidWidthPrint(){ ////toplevel
1210   rotate([0,180.0]) intersection(){
1211     Lid();
1212     TestSelectWidth();
1213   }
1214 }
1215
1216 module TestSelectRearAperture(){
1217   minkowski(){
1218     union() children();
1219     translate([20, 0,0])
1220       cube([42, 2, 1], center=true);
1221   }
1222 }
1223
1224 module TestSelectCamera(){
1225   minkowski(){
1226     TestSelectRearAperture()
1227       RearCameraAperture();
1228     cube([0.1, 50, 0.1]);
1229   }
1230 }
1231
1232 module TestSelectOrdinaryRearApertures(){
1233   TestSelectRearAperture()
1234     OrdinaryRearApertures();
1235 }
1236
1237 module TestCamera(){ ////toplevel
1238   intersection(){
1239     Case();
1240     TestSelectCamera();
1241   }
1242 }
1243
1244 module TestLidByCamera(){ ////toplevel
1245   intersection(){
1246     Lid();
1247     TestSelectCamera();
1248   }
1249 }
1250
1251 module TestLidByCameraPrint(){ ////toplevel
1252   rotate([180,0,0]) TestLidByCamera();
1253 }
1254
1255 module DemoByCamera(){ ////toplevel
1256   color("blue") TestLidByCamera();
1257   color("red")  TestCamera();
1258 }
1259
1260 module OneKeeper(){ ////toplevel
1261   translate([0, -phone_cnr_rad, 0])
1262     rotate([90, 0, 0])
1263     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1264     KeeperProfile();
1265 }
1266
1267 module OneKeeperPrint(){ ////toplevel
1268   rotate([0,180,0])
1269     OneKeeper();
1270 }
1271
1272 module LidPrint(){ ////toplevel
1273   rotate([0,180,0])
1274     Lid();
1275 }
1276
1277 module TestSelectFrame(){
1278   include = [1,-1] * (epp2i[0] + 4);
1279
1280   difference(){
1281     cube(1000, center=true);
1282     translate([0,0, -100])
1283       linear_extrude(height=200)
1284       rectfromto(include,  inside_br - include);
1285   }
1286 }
1287
1288 module TestSelectLidFrame(){
1289   TestSelectFrame();
1290   translate([led_pos[0], -led_pos[1], -50])
1291     cylinder(r= nla_r2+3, h=100);
1292 }
1293
1294 module TestFrameCase(){ ////toplevel
1295   intersection(){
1296     Case();
1297     union(){
1298       TestSelectFrame();
1299       TestSelectCamera();
1300       TestSelectOrdinaryRearApertures();
1301     }
1302   }
1303 }
1304
1305 module TestSelectTopApertures(){
1306   translate([-100, -35, -100])
1307     cube([400, 100, 200]);
1308   LidAdhocMultiprintFrame(0);
1309   LidAdhocMultiprintFrame(1);
1310 }
1311
1312 module TestTopApertures(){ ////toplevel
1313   intersection(){
1314     Case();
1315     TestSelectFrame();
1316     TestSelectTopApertures();
1317   }
1318 }
1319
1320 module TestLidTopAperturesPrint(){ ////toplevel
1321   rotate([0,180,0]) intersection(){
1322     Lid();
1323     TestSelectLidFrame();
1324     TestSelectTopApertures();
1325   }
1326 }
1327
1328 module TestLidWindowTopAperturesPrint(){ ////toplevel
1329   rotate([0,180,0]) intersection(){
1330     LidWindow();
1331     TestSelectTopApertures();
1332   }
1333 }
1334
1335 module TestFrameLidPrint(){ ////toplevel
1336   rotate([0,180,0]) intersection(){
1337     Lid();
1338     TestSelectLidFrame();
1339   }
1340 }
1341
1342 module ButtonPlanForDemo(z, deep, cut){
1343   translate([0,0,z])
1344     ButtonPlan(8, deep, cut);
1345 }
1346
1347 module HingeScrews(){
1348   Flip_rhs() Flip_bot(1){
1349     for (c= [ hppT, hppB ])
1350       translate([ hex20,
1351                   -c[0],
1352                   c[1] ]){
1353         rotate([0,90,0])
1354           translate([0,0,-.2])
1355           cylinder( r= hingescrew_shaft_dia/2,
1356                     h = hingescrew_shaft_len+0.2 );
1357         rotate([0,-90,0])
1358           translate([0,0,+.1])
1359           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1360       }
1361   }
1362 }
1363
1364 module DemoPropAngleSelect(c){
1365   color(c) difference(){
1366     union(){ children(); }
1367     translate([ prop_x_pos, -400, -200 ])
1368       cube([ 400,800,400 ]);
1369   }
1370 }
1371
1372 module DemoPropAngle(ang){
1373   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1374   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1375
1376   translate(hL)
1377     rotate([ang/2,0,0])
1378     translate(-hL)
1379     translate(hC)
1380     rotate([ang/2,0,0])
1381     translate(-hC) {
1382       DemoPropAngleSelect("red") Case();
1383
1384       color("orange")
1385         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1386         PropProfileAssignments(ang) {
1387           echo($prpp1);
1388           rotate([-$prp_theta, 0, 0])
1389           translate([0, $prpp1[0], -$prpp1[1]])
1390           rotate([90,0,-90])
1391           Prop();
1392         }
1393     }
1394
1395   translate([0,0, -hp_k*2])
1396     DemoPropAngleSelect("blue")
1397     Lid();
1398 }
1399
1400 module DemoPropAngles(){ ////toplevel
1401   for (i=[0 : len(prop_angles)-1])
1402     translate(i * [0, -100, 100])
1403     DemoPropAngle(prop_angles[i]);
1404 }
1405
1406 module DemoHingeAngle(ang1,ang2){
1407   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1408   hC = [0, -(phone_height - hppB[0]), hppB[1] - hp_k*2];
1409
1410   translate(hL)
1411     rotate([ang2,0,0])
1412     translate(-hL)
1413     translate(hC)
1414     rotate([ang1,0,0])
1415     translate(-hC) {
1416       color("red") Lid();
1417     }
1418
1419   color("blue") intersection(){
1420     Case();
1421     union(){
1422       translate([bppJ[0], -400, -200])
1423         mirror([1,0,0])
1424         cube([400, 800, 400]);
1425       translate([10, -400, -200])
1426         cube([10, 800, 400]);
1427     }
1428   }
1429 }
1430
1431 module DemoHingeAngles(){ ////toplevel
1432   DemoHingeAngle(0,12);
1433 //  for (i=[0 : len(prop_angles)-1])
1434 //    translate(i * [0, -100, 100])
1435 //    DemoHingeAngle(prop_angles[i]);
1436 }
1437
1438 module DemoSelectAdhocLeftRight(right=0) {
1439   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1440     mirror([1-right, 0,0])
1441     cube([400, 800, 200]);
1442 }
1443
1444 module DemoLeft(){ ////toplevel
1445   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1446   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1447 }
1448
1449 module DemoFrame(){ ////toplevel
1450   color("red") TestFrameCase();
1451   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1452   color("black") HingeScrews();
1453   %HingeLever();
1454 }
1455
1456 module DemoHingedFrame(){ ///toplevel
1457   color("red") TestFrameCase();
1458   translate([0,0, -2*hp_k])
1459   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1460
1461   Flip_hinge(){
1462     color("orange") HingeLever();
1463     color("black") HingeScrews();
1464   }
1465 }
1466
1467 module DemoHinge(){ ////toplevel
1468   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1469     DemoFrame();
1470     translate([0,0, -hp_k*3])
1471       DemoHingedFrame();
1472   }
1473 }
1474
1475 module DemoProfiles(){ ////toplevel
1476   LidEdgeProfile();
1477   %EdgeProfile();
1478   KeeperProfile();
1479   translate([0,0,-1]) color("black") KeeperProfile(1);
1480
1481   translate([20,0]) {
1482     LidEdgeProfile();
1483     %EdgeProfile();
1484
1485     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1486
1487     color("blue") ButtonCoverProfile();
1488     color("red") {
1489       rectfromto(bppQ, demopoint_QR);
1490       rectfromto(bppR, demopoint_QR);
1491     }
1492   }
1493
1494   translate([-20,0]) {
1495     color("black") ButtonPlanForDemo(-2, 0,1);
1496     color("red" )  ButtonPlanForDemo(-4, 1,1);
1497     color("blue")  ButtonPlanForDemo(-6, 1,0);
1498   }
1499
1500   translate([0, -30]) {
1501     %LidEdgeProfile();
1502     %EdgeProfile();
1503     color("blue") HingeLidProfile();
1504     color("red")  HingeBaseProfile();
1505     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1506   }
1507
1508   for (f=[0,1]) {
1509     translate([-30, -60 + 30*f]) {
1510       translate([0,0,-4]) EdgeProfile();
1511       %translate([0,0,-10]) HingeBaseProfile();
1512       translate([0,-2] * f * hp_k) {
1513         translate([0,0,-4]) LidEdgeProfile();
1514         %translate([0,0,-10]) %HingeLidProfile();
1515       }
1516       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1517         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1518         translate([0,0,0]) color("red") difference(){
1519           HingeLeverOuterProfile();
1520           HingeLeverInnerProfile();
1521         }
1522         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1523       }
1524     }
1525   }
1526
1527   translate([20,-30]) {
1528     %EdgeProfile();
1529     %LidEdgeProfile();
1530     //translate([0,0,1]) CatchCutProfile();
1531     color("blue") CatchCatchProfile();
1532     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1533   }
1534
1535   translate([40,-30]) {
1536     difference(){
1537       LidEdgeProfile();
1538       translate(prlp10)
1539         PropProfile(10, 1, 0);
1540     }
1541     translate(prlp10)
1542       PropProfile(15, 0);
1543   }
1544   translate([60,-30]) {
1545     PropAggregateProfile();
1546   }
1547 }
1548
1549 //EdgeProfile();
1550 //KeeperProfile();
1551 //CaseBase();
1552 //%Case();
1553 //Keeper();
1554 //LidEdgeProfile();
1555 //KeeperProfile();
1556 //DemoProfiles();
1557 //PropRecess();