fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 catch_slop = -0.75;
 256
 257 catch_len = 4.5;
 258 catch_width = 15;
 259 catch_thickness = 1.3;
 260 catch_side_gap = 0.75; // each side
 261
 262 catch_depth = 0.75;
 263 catch_height = 0.35;
 264 catch_finger_height = 1.5;
 265 catch_finger_depth = 2.5;
 266 catch_catch_slope = 2.00;
 267 catch_close_slope = 3.00;
 268
 269 catch_topcurve_r = 5.0;
 270
 271 prop_recess_under = 0.50;
 272 prop_recess_slop = 0.200; // each side
 273 prop_end_dia = 0.5;
 274 prop_main_th = 3;
 275 prop_taper_len = 6;
 276 prop_main_width = 4;
 277 prop_side_gap = 0.75; // each side
 278 prop_lidrecess_behind = 0.75;
 279 prop_caserecess_behind = 0.75;
 280 prop_caserecess_taper = 0.45; // one side only
 281 prop_prop_gap = 0.5;
 282 prop_prong_heel_slope = 0.5;
 283
 284 lid_fold_clearance_antislop = 0.5;
 285
 286 // ---------- calculated ----------
 287
 288 phone_width =  (phone + bumper*2)[0];
 289 phone_height = (phone + bumper*2)[1];
 290
 291 inside_br = [phone_width, -phone_height];
 292
 293 prop_prong_h = prop_main_th;
 294
 295 //echo(camera_pos_tl + bumper,
 296 //     camera_pos_br + bumper);
 297
 298 // ----- could be changed -----
 299 lid_buttoncover_gap = lid_gap_x;
 300 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 301
 302 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 303
 304 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 305
 306 //prop_nose_len = case_th_lid - prop_recess_under;
 307 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 308 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 309
 310
 311 //lid_lip_overlap_width xxx bad name = ;
 312 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 313
 314 epp0 = [0,0];
 315 epp1 = [0, -phone_edge_thick];
 316 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 317 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 318 epp3 = epp2i + [10, 0];
 319 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 320 epp4 = epp5 + [-1,0] * case_th_side;
 321
 322 kppe = [0,0];
 323 kppd = kppe + [1,0] * keeper_inner_width;
 324 kppc = kppd + [0,1] * keeper_th_z;
 325 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 326 kppf = kppe - [0,1] * keeper_inner_height;
 327 kppa = [ kppb[0], kppf[1] ];
 328
 329 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 330 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 331
 332 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 333 // exact x posn not very important; must extend past end of keeper
 334
 335 lpp15 = [ lpp14[0],
 336           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 337           + lid_screen_gap_extra ];
 338 // ^ beam theory says to maximise force before contact,
 339 //   the gap below the `beam' (the lid) must be 1/3
 340 //   the thickness (ie the lid thickness) if the beam
 341 //   is solid, or 1/2 if it has a top and bottom only.
 342 //   ours is mostly solid.
 343
 344 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 345              case_th_lip);
 346
 347 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 348 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 349
 350 case_bottom_z = epp2o[1] - case_th_bottom;
 351
 352 // button profile
 353 bppM = epp4 + [0,5];
 354 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 355 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 356 bppS = [ epp1[0], bppR[1] ];
 357 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 358 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 359 bppO = [ bppN[0], bppP[1] ];
 360 bppL = lpp10 + [5,0];
 361 bppK = [ bppL[0], bppN[1] ];
 362 bppJ = [ bppN[0], bppL[1] ];
 363 bppU = [ bppJ[0], lpp12[1] ];
 364 bppV = lpp11;
 365 bppW = lpp10;
 366
 367 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 368
 369 // notification led aperture
 370
 371 nla_r0 = led_aperture/2;
 372 nla_r1 = nla_r0 + led_window_ledge;
 373 nla_r2 = nla_r1 + multicolour_gap;
 374 nla_t =
 375   led_window_style >= 3 ? initial_layer_thick :
 376   led_window_style >= 2 ? led_window_ledge : 0;
 377
 378
 379 // hinge plan
 380 hp_rn = hingescrew_nut_access_dia/2;
 381 hp_r2_min = hp_rn + lever_cover_th;
 382 hp_rs = hingescrew_shaft_dia/2;
 383 hp_r1_min = hp_rs + hingemount_th;
 384
 385 hp_r1 = max(hp_r1_min, hp_r2_min);
 386 hp_r2 = hp_r1;
 387
 388 hppU = lpp13;
 389 hppS = epp2o + [0,-1] * case_th_bottom;
 390 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 391
 392 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 393          0.5 * (hppU + hppS)[1] ];
 394 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 395 hppB = hppT + [0,-1] * hp_k;
 396
 397 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 398 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 399 hppE = [ hppE_x, hppE_y ];
 400
 401 // hinge elevation x coords
 402
 403 hex20 = max(epp2o[0],
 404             phone_cnr_rad,
 405             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 406 hex21 = hex20 + hingemount_wd;
 407 hex22 = hex21 + hinge_x_gap;
 408 hex27 = hex20 + hingescrew_shaft_len;
 409 hex24 = hex27 + hinge_x_postscrew_gap;
 410 hex23 = hex27 - (hingescrew_nut_thick*2
 411                  + hingescrew_fasteners_extra_thick);
 412 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 413
 414 echo(hex20, hex21, hex22, hex23, hex24);
 415 //  6, 10.8725, 10.9975, 13.74, 18.75
 416 module chk(act,exp) {
 417   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 418   else echo("ok", act);
 419 }
 420 chk(hex20, 6);
 421 chk(hex21, 10.8725);
 422 chk(hex22, 10.9975);
 423 chk(hex23, 13.74);
 424 chk(hex24, 18.75);
 425
 426 lid_fold_clearance_skew =
 427   (lpp10[1] - hppB[1]) /
 428   (lpp10[0] - hppB[0]);
 429
 430 echo("SK",lid_fold_clearance_skew);
 431
 432 // catch
 433
 434 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 435 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 436 cppB = [ epp0[0], cppA[1] ];
 437 cppP = [ epp4[0], cppJ[1] ];
 438
 439 cppS = cppJ + [0,-1] * catch_len;
 440 cppD = [ cppA[0], cppS[1] + catch_slop ];
 441 cppC = [ cppB[0], cppD[1] ];
 442 cppT = cppS + [1, -catch_catch_slope] * catch_depth;
 443 cppU = cppT + [0,-1] * catch_height;
 444 cppV = [ cppS[0], cppU[1] - catch_depth * catch_close_slope ];
 445
 446 cppR = 0.5*(cppP + cppJ);
 447
 448 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 449 cppQ = [ cppR[0],
 450          cppV[1] - (catch_finger_height - cp_rQ) ];
 451 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 452
 453 // lanyard
 454
 455 ly_r = lanyard_half_dia / 2;
 456 ly_rc = ly_r * 2;
 457
 458 ly_theta = -atan2vector(epp2i - epp1);
 459 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 460
 461 max_case_bottom_edge_thickness =
 462   case_th_bottom
 463   + sin(ly_theta) * (epp2i-epp2o)[0];
 464
 465 ly_q_z = -(ly_rc + ly_r);
 466 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 467
 468 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 469
 470 // prop recess in case
 471
 472 prop_x_pos = phone_width/2;
 473
 474 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 475
 476 prc_r1 = prop_end_dia/2;
 477 prc_r3 = prc_r1 + prop_recess_slop;
 478
 479 prcp2 = [ epp4[0] + prop_buildout_less,
 480           case_bottom_z ];
 481
 482 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 483
 484 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 485           epp2i[1] - prc_r3 - prop_recess_under];
 486
 487 // prop recess in lid
 488
 489 prl_r10 = prop_end_dia/2;
 490 prl_r10o = prl_r10 + prop_recess_slop;
 491
 492 prlp10 = lpp10 + [1,1] * prl_r10o
 493   + [1,0] * prop_lidrecess_behind
 494   + [0,1] * prop_recess_under;
 495
 496 // prop
 497
 498 $prpp10 = [0,0];
 499 $prpp11 = [0, prop_taper_len];
 500
 501 $prp_r10 = prl_r10;
 502
 503 // ---------- modules ----------
 504
 505 module AdhocMultiprintFrame(phase, z0, zs) {
 506   // from z0 to z0 + zs*layer
 507   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 508   xextra = extra + -epp4[0];
 509   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 510   yextra = extra + -epp4[0];
 511   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 512   p0 = [ xrange[0], yrange[0] ];
 513   p1 = [ xrange[1], yrange[1] ];
 514   echo(p0, p1);
 515   translate([0,0, z0])
 516     mirror([0,0, zs<0 ? 1 : 0])
 517     linear_extrude(height= initial_layer_thick)
 518     difference(){
 519       rectfromto(p0 - [1,1] * initial_layer_width,
 520                  p1 + [1,1] * initial_layer_width);
 521       rectfromto(p0, p1);
 522     }
 523 }
 524
 525 module KeeperProfile(slant=0){
 526   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 527   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 528 }
 529
 530 module EdgeProfile(){
 531   difference(){
 532     hull(){
 533       translate(epp3) square(case_th_bottom*2, center=true);
 534       circleat(epp2o, r=case_th_bottom);
 535       circleat(epp1, r=case_th_side);
 536       rectfromto(epp0, epp4);
 537     }
 538     polygon([ epp5 + [0,10],
 539               epp1,
 540               epp2i,
 541               epp3 + [10,0] ]);
 542   }
 543 }
 544
 545 module LanyardLanyardProfile(entry=false){
 546   hull(){
 547     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 548       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 549         circle(r= lanyard_half_dia/2);
 550   }
 551 }
 552
 553 module LanyardCurveChannelProfile(){
 554   translate([0, -ly_r])
 555     LanyardLanyardProfile();
 556 }
 557
 558 module LanyardEntryChannelProfile(){
 559   LanyardLanyardProfile(true);
 560 }
 561
 562 module LanyardMainChannelProfile(){
 563   LanyardCurveChannelProfile();
 564   difference(){
 565     square(center=true, ly_r * [6, 2]);
 566     for (xs=[-1,+1])
 567       translate(ly_r * [3 * xs, -1])
 568         circle(r = ly_r);
 569   }
 570 }
 571
 572 module LanyardEntryOuterProfile(){
 573   circleat([ly_re + ly_r, 0], ly_re);
 574 }
 575
 576 module LanyardEntry(){
 577   q_z = ly_q_z;
 578   oec_y = ly_oec_y;
 579
 580   d_x = -ly_rc;
 581
 582   translate([d_x, 0, q_z]) {
 583     intersection(){
 584       rotate([90,0,0])
 585         rotate_extrude(convexity=10)
 586         rotate(90)
 587         translate([0, -q_z])
 588         LanyardCurveChannelProfile();
 589       translate([0,-10,0])
 590         cube([20,20,20]);
 591     }
 592   }
 593
 594   mirror([0,0,1])
 595     translate([0,0,-1])
 596     linear_extrude(height=20)
 597     rotate(-90)
 598     LanyardEntryChannelProfile();
 599
 600   translate([0, ly_r*2, 0])
 601     rotate([90,0,0])
 602     linear_extrude(height = ly_r*4){
 603     difference(){
 604       rectfromto([d_x, q_z], [ly_r, 0]);
 605       circleat([d_x, q_z], ly_rc);
 606     }
 607   }
 608
 609   translate([0,0,q_z]){
 610     for (my=[0,1])
 611       mirror([0,my,0]){
 612         translate([0, oec_y, 0]){
 613           difference(){
 614             translate(ly_re * [-1,0,-2])
 615               cube(ly_re * [2,1,2]);
 616             rotate_extrude(convexity=10)
 617               LanyardEntryOuterProfile();
 618           }
 619         }
 620       }
 621     difference(){
 622       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 623         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 624       for (mx=[0,1])
 625         mirror([mx,0,0])
 626           rotate([90,0,0])
 627           translate([0,0,-10])
 628           linear_extrude(height=20)
 629           LanyardEntryOuterProfile();
 630     }
 631   }
 632 }
 633
 634 module LanyardCutout(l){
 635   rotate([0,-90,0])
 636     linear_extrude(height=l)
 637     rotate(-90)
 638     LanyardMainChannelProfile();
 639
 640   for (ee=[0,1]){
 641     translate(ee * l * [-1,0])
 642       mirror([ee,0,0])
 643       LanyardEntry();
 644   }
 645 }
 646
 647 module LidEdgeProfile(){
 648   polygon([ lpp10,
 649             lpp11,
 650             lpp12,
 651             lpp13,
 652             lpp13 + [10, 0],
 653             lpp15 + [10, 0],
 654             lpp15,
 655             lpp14,
 656             ]);
 657   intersection(){
 658     circleat(lpp12, r=lp_r12);
 659     rectfromto( lpp12 + [-10,   0],
 660                 lpp12 + [+10, +10] );
 661   }
 662 }
 663
 664 module LidEdgeFoldClearanceProfile(){
 665   translate([-lid_fold_clearance_antislop, 0])
 666     polygon([ lpp10,
 667               lpp11,
 668               lpp11 + [-20,  0],
 669               lpp11 + [-20, 20],
 670               lpp11 + [+20, 20],
 671               lpp10 + [+20,  0] ]);
 672 }
 673
 674 module ButtonCoverProfile(){
 675   intersection(){
 676     polygon(concat([ bppM, bppP, bppO, bppJ ],
 677                    (enable_support && !$button_suppress_over_keeper
 678                     ? [ bppU, bppV, bppW ] : []),
 679                    [ bppL, bppK ]));
 680     hull(){
 681       EdgeProfile();
 682       LidEdgeProfile();
 683     }
 684   }
 685 }
 686
 687 module ButtonPlan(l, deep, cut){
 688   epsilon =
 689     (cut  ? 0 : lid_buttoncover_gap);
 690
 691   delta =
 692     (deep ? lid_buttoncover_overlap : 0);
 693
 694   C = [0,0]; // by definition
 695   T = [ 0, epp4[1] ];
 696   G = T + [0,10];
 697
 698   B0 = C + [0,-1] * button_cutout_depth;
 699   B1 = B0 + [0,1] * epsilon;
 700
 701   r0 = 0.5 * (T[1] - B0[1]);
 702   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 703   H = A + [0,-1] * delta;
 704
 705   D = A + [-2,0] * r0;
 706   F = D + [0,10];
 707
 708   E0 = 0.5 * (D + A);
 709   E1 = E0 + [1,0] * epsilon;
 710
 711   I0 = [ E0[0], H[1] ];
 712   I1 = [ E1[0], H[1] ];
 713
 714   hull(){
 715     for (m=[0,1]) mirror([m,0])
 716       circleat(H, r0 - epsilon);
 717   }
 718   for (m=[0,1]) mirror([m,0]) {
 719     difference(){
 720       polygon([ E1,
 721                 I1,
 722                 H,
 723                 B1,
 724                 G,
 725                 F,
 726                 D
 727                 ]);
 728       circleat(D, r0 + epsilon);
 729     }
 730   }
 731 }
 732
 733 module ButtonCoverReinf(){ ////toplevel
 734   minkowski(){
 735     rotate([90,0,0])
 736       linear_extrude(height=0.01)
 737       intersection(){
 738         ButtonCoverProfile();
 739         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 740           square([100,100]);
 741     }
 742     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 743       circle(r= lid_buttoncover_reinf);
 744       translate([-20,0]) square(40, center=true);
 745     }
 746   }
 747 }
 748
 749 module CatchCutProfile(){
 750   polygon([ cppB,
 751             cppA,
 752             cppD,
 753             cppF,
 754             cppF + [0,-10],
 755             cppF + [-10,-10],
 756             lpp12 + [-10,0],
 757             lpp12 + [10,0]
 758             ]);
 759 }
 760
 761 module Flip_rhs(yn=[0,1]) {
 762   for ($rhsflip=yn) {
 763     translate([phone_width/2, 0, 0])
 764       mirror([$rhsflip,0,0])
 765       translate([-phone_width/2, 0, 0])
 766       children();
 767   }
 768 }
 769
 770 module Flip_bot(yn=[0,1]) {
 771   for ($botflip=yn) {
 772     translate([0, -phone_height/2, 0])
 773       mirror([0, $botflip, 0])
 774       translate([0, phone_height/2, 0])
 775       children();
 776   }
 777 }
 778
 779 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 780   // sides
 781   Flip_rhs(){
 782     translate([0, -phone_cnr_rad, 0])
 783       rotate([90,0,0])
 784       linear_extrude(height = phone_height - phone_cnr_rad*2)
 785       children(0);
 786   }
 787   // corners
 788   Flip_rhs() Flip_bot() {
 789     translate([+1,-1] * phone_cnr_rad)
 790       intersection(){
 791         rotate_extrude()
 792           intersection(){
 793             mirror([1,0,0])
 794               translate([-1,0] * phone_cnr_rad)
 795               children(0);
 796             rectfromto([0,-20],[10,20]);
 797           }
 798         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 799           cube([10,10,40]);
 800       }
 801   }
 802   // top and bottom
 803   Flip_bot(){
 804     translate([ phone_width - phone_cnr_rad, 0,0 ])
 805       rotate([90,0,-90])
 806       linear_extrude(height = phone_width - phone_cnr_rad*2)
 807       children(0);
 808   }
 809   // fill
 810   translate([0,0, fill_zstart])
 811     mirror([0,0, fill_downwards])
 812     linear_extrude(height = fill_th)
 813     rectfromto([+1,-1] * phone_cnr_rad,
 814                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 815 }
 816
 817 module CaseAperture(pos, dia, $fn) {
 818   theta = 180/$fn;
 819   translate([ pos[0] + bumper[0],
 820               -epp2i[0],
 821               -pos[1] ])
 822     rotate([-90, theta, 0])
 823     cylinder(r = dia/2 / cos(theta),
 824              h = 60);
 825 }
 826
 827 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 828   // y_ref_sign:
 829   //   +1  measured from top    of actual phone to top    of button
 830   //   -1  measured from bottom of actual phone to bottom of button
 831   //    0  y is centre of button in coordinate system
 832   $button_l= l;
 833   $button_suppress_over_keeper= suppress_over_keeper;
 834   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 835           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 836           y;
 837   //echo(eff_y);
 838   translate([0, eff_y, 0])
 839     children();
 840 }
 841
 842 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 843   $button_leg_only = true;
 844   SideButton(y, y_ref_sign, l) children();
 845 }
 846
 847 module Buttons(){
 848   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 849   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 850   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 851   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 852 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 853 }
 854
 855 module Struts(x_start, z_min, th){
 856   // if th is negative, starts at z_min and works towards -ve z
 857   // and object should then be printed other way up
 858   for (i= [1 : 1 : case_struts_count]) {
 859     translate([0,
 860                0,
 861                z_min])
 862       mirror([0,0, th<0 ? 1 : 0])
 863       translate([0,
 864                  -phone_height * i / (case_struts_count+1),
 865                  case_struts_solid_below])
 866       linear_extrude(height= abs(th)
 867                      -(case_struts_solid_below+case_struts_solid_above))
 868       rectfromto([               x_start, -0.5 * case_struts_width ],
 869                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 870   }
 871 }
 872
 873 module OrdinaryRearAperture(rhs,bot, pos){
 874   Flip_rhs(rhs) Flip_bot(bot)
 875     linextr(-20, 20)
 876     mirror([0,1])
 877     translate(pos + bumper)
 878     children();
 879 }
 880
 881 module MicroUSB(){
 882   Flip_bot(1){
 883     rotate([90,0,0])
 884       mirror([0,0,1])
 885       linextr(-epp2i[0], 60)
 886       translate([0.5 * phone_width, 0, 0])
 887       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 888                  [+microusb_width/2, epp0[1] + -microusb_above]);
 889   }
 890 }
 891
 892 module OrdinaryRearApertures(){
 893   // rear speaker
 894   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 895     rectfromto(-rearspeaker_gap,
 896                rearspeaker_size + rearspeaker_gap);
 897
 898   // finger hole to remove phone
 899   if (len(fingerpushhole_dias))
 900     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 901                                 phone[1]/2 ])
 902     scale(fingerpushhole_dias)
 903     circle(r= 0.5 );
 904 }
 905
 906 module RearCameraAperture(){
 907   Flip_rhs(1)
 908     mirror([0, 0, 1])
 909     linear_extrude(height = 20)
 910     mirror([0, 1, 0])
 911     translate(bumper)
 912     rectfromto(camera_pos_tl, camera_pos_br);
 913 }
 914
 915 module HingeLidProfile(){
 916   hull(){
 917     circleat(hppT, hp_r1);
 918     circleat(lpp12, lp_r12);
 919     polygon([lpp10,
 920              lpp13 + [2,0],
 921              lpp12,
 922              hppT]);
 923   }
 924 }
 925
 926 module HingeBaseProfile(){
 927   difference(){
 928     hull(){
 929       circleat(hppB, hp_r1);
 930       circleat(hppE, hp_r1);
 931       circleat(epp2o, case_th_bottom);
 932       circleat(hppB + [10,0], hp_r1);
 933     }
 934     polygon([epp5, epp1, epp2i, epp3, bppL]);
 935   }
 936 }
 937
 938 module HingeLeverOuterProfile(){
 939   hull(){
 940     circleat(hppT, hp_r2);
 941     circleat(hppB, hp_r2);
 942   }
 943 }
 944
 945 module HingeLeverInnerProfile(){
 946   for (s = [-1,+1]) {
 947     c = s > 0 ? hppT : hppB;
 948     translate(c)
 949       mirror([0,0,s>0])
 950       rotate(s<0 ? -40 : 0)
 951       hull()
 952       for (x=[-20,20])
 953         for (y=[0, s * 10])
 954           translate([x,y])
 955             circle(hp_rn);
 956   }
 957 }
 958
 959 module HingeLeverNutProfile(){
 960   for (c= [hppB, hppT]) {
 961     translate(c)
 962       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 963   }
 964 }
 965
 966 module Flip_hinge(doflip=1){
 967   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 968   translate(hinge_origin)
 969     rotate([doflip*180,0,0])
 970     translate(-hinge_origin)
 971     children();
 972 }
 973
 974 module HingePortion(x0,x1){
 975   Flip_rhs() Flip_bot(1)
 976     translate([x0,0,0])
 977     mirror([1,0,0])
 978     rotate([90,0,-90])
 979     linear_extrude(height=x1-x0)
 980     children();
 981 }
 982
 983 module CatchPortion(xwidth, ztop){
 984   width = catch_width + xwidth;
 985   w = width + catch_topcurve_r*2 + 1;
 986   translate([phone_width/2, 0,0]){
 987     difference(){
 988       rotate([90,0,-90])
 989         linextr(-w/2, w/2)
 990         children(0);
 991       translate([0, 50, 0])
 992         rotate([90,0,0])
 993         linear_extrude(height=100){
 994         for (m=[0,1]) mirror([m,0,0]) {
 995           hull(){
 996             translate([w/2, ztop - catch_topcurve_r])
 997               circle(catch_topcurve_r);
 998             translate([w/2, -50])
 999               square(catch_topcurve_r*2, center=true);
1000           }
1001         }
1002       }
1003     }
1004   }
1005 }
1006
1007 module CaseBase(){
1008   AroundEdges(epp3[1], case_th_bottom, 1)
1009     EdgeProfile();
1010 }
1011
1012 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1013
1014 module PropProfileAssignments(gamma){
1015   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1016   x = prop_x(gamma);
1017   p = phone_height + prlp10[0] - hppB[0];
1018   b = p + x;
1019
1020   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1021   a = q + x;
1022   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1023   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1024
1025   $prp_theta = 90 - $prp_alpha;
1026   beta = 180 - $prp_alpha - gamma;
1027   psi = 90 - beta;
1028
1029   //echo("abc", a,b,c);
1030
1031   v1 = [ [ cos(psi), -sin(psi) ],    // x
1032          [ sin(psi),  cos(psi) ] ];  // y
1033
1034   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1035
1036   $prp_r1 = prc_r1;
1037   $prp_r11 = prop_main_th/2;
1038
1039   $prpp1 = $prpp7 + [1,0] *
1040     // this is approximate, but will do
1041     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1042   $prpp3 = $prpp1 +
1043     v1[0] * -$prp_r1 +
1044     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1045   $prpp12 = $prpp3 + v1[0] *
1046     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1047   $prp_r8 = prop_main_th;
1048   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1049   $prp_r5 = $prp_r8;
1050   $prpp5 = [ $prpp12[0] - $prp_r5,
1051             $prpp3[1] - prop_prong_h + $prp_r5 ];
1052   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1053          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1054   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1055   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1056
1057   children();
1058 }
1059
1060 module PropProfile(gamma, cut=0, rot=0){
1061   PropProfileAssignments(gamma){
1062
1063     //#circleat($prpp3,1);
1064     //#circleat($prpp12,1);
1065
1066     if (!cut) {
1067       hull(){
1068         translate($prpp8)
1069           intersection(){
1070             circle($prp_r8);
1071             polygon([[-20,-0], [20,20], [0,0]]);
1072           }
1073         rectfromto($prpp6, $prpp9);
1074         translate($prpp5) intersection(){
1075           circle($prp_r5);
1076           polygon([[-10,-10], [0,0], [10,0]]);
1077         }
1078         rectfromto($prpp12 + [0,-0.1], $prpp3);
1079       }
1080       hull(){
1081         circleat($prpp1, $prp_r1);
1082         rectfromto($prpp12 + [0,-0.1], $prpp3);
1083       }
1084     }
1085     // main shaft
1086     rotate([0,0, rot*-$prp_theta]){
1087       hull(){
1088         extra = cut ? prop_recess_slop : 0;
1089         rectfromto($prpp6, $prpp9);
1090         circleat($prpp11, $prp_r11 + extra);
1091         circleat($prpp10, $prp_r10 + extra);
1092       }
1093     }
1094   }
1095 }
1096
1097 module PropAggregateProfile(){
1098   for (angle = prop_angles)
1099     PropProfile(angle, 0,0);
1100 }
1101
1102 module Prop(){ ////toplevel
1103   hw = prop_main_width/2;
1104   linextr(-hw, +hw)
1105     PropAggregateProfile();
1106 }
1107
1108 module Case(){ ////toplevel
1109   difference(){
1110     union(){
1111       CaseBase();
1112
1113       // ledge (fixed keeper)
1114       Flip_rhs(1-keeper_side) intersection(){
1115         rotate([90, 0, 0])
1116           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1117           KeeperProfile(1);
1118
1119         // outline of the whole case, to stop it protruding
1120         translate([0,0, -25])
1121           linear_extrude(height = 50)
1122           hull()
1123           Flip_bot()
1124           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1125       }
1126
1127       // hinge
1128       HingePortion(hex20, hex21) HingeBaseProfile();
1129
1130       // buildout for prop recess
1131       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1132         linextr(case_bottom_z, epp2i[1])
1133         hull() {
1134           for (dxs = [-1,+1])
1135             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1136                        -epp2o[0] ],
1137                      r = epp2o[0] - prcp2[0]);
1138         }
1139     }
1140
1141     // slot for keeper
1142     Flip_rhs(keeper_side)
1143       translate([0, -phone_cnr_rad, 0])
1144       rotate([90, 0, 0])
1145       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1146       minkowski(){
1147         KeeperProfile();
1148         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1149                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1150       }
1151
1152     // front camera
1153     RearCameraAperture();
1154
1155     // struts (invisible, because they're buried in the case)
1156     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1157
1158     Buttons(){
1159       mirror([1,0,0])
1160         rotate([90,0,90]) {
1161           if (!($button_leg_only && enable_support))
1162           intersection(){
1163             translate([0,0,-10])
1164               linear_extrude(height= 20)
1165               ButtonPlan($button_l, 0,1);
1166             if ($button_leg_only)
1167               rotate([-90,90,0])
1168                 translate([phone_width/2, -400, kppe[1]])
1169                 mirror([1-abs($rhsflip - keeper_side),0,0])
1170                 cube([400, 800, 50]);
1171             if (enable_support && !$button_suppress_over_keeper)
1172               rotate([-90,90,0])
1173               translate([-400, -400, kppd[1]])
1174                 mirror([0,0,1])
1175                 cube([800,800,100]);
1176           }
1177           translate([0,0, -bppR[0]])
1178             linear_extrude(height= 20)
1179             ButtonPlan($button_l, 1,1);
1180         }
1181
1182     }
1183
1184     // apertures along top edge
1185     CaseAperture(jack_pos, jack_dia, 8);
1186     Flip_rhs(1)
1187       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1188
1189     OrdinaryRearApertures();
1190
1191     MicroUSB();
1192
1193     // gaps for the lid's hinge arms
1194     HingePortion(hex20 - hinge_x_arms_gap,
1195                  hex21 + hinge_x_arms_gap)
1196       minkowski(){
1197         HingeLidProfile();
1198         circle(r= hinge_r_arms_gap, $fn= 8);
1199       }
1200
1201     // screw holes in the hinge arms
1202     HingeScrews();
1203
1204     // catch striker
1205     CatchPortion(catch_side_gap*2, epp4[1])
1206       CatchCutProfile();
1207
1208     // lanyard
1209     Flip_bot(1)
1210       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1211       rotate([0, ly_theta, 0])
1212       rotate([0,0,90])
1213       LanyardCutout(lanyard_channel_len);
1214
1215     // prop recess
1216     Flip_rhs(1)
1217       translate([prop_x_pos,0,0])
1218       mirror([0,1,0])
1219       rotate([90,0,90])
1220       linextr(-prop_recess_hw, +prop_recess_hw)
1221       hull(){
1222         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1223           circleat(prcp1 + 20*d,
1224                    prc_r3);
1225       }
1226   }
1227 }
1228
1229 module LidAdhocMultiprintFrame(phase){
1230   if (led_window_style >= 3) {
1231     AdhocMultiprintFrame(phase, lpp13[1], -1);
1232   }
1233 }
1234
1235 module LidAroundEdges(){
1236   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1237     children();
1238 }
1239
1240 module Lid(){ ////toplevel
1241   skew_centre = [0, lpp11[0], lpp11[1]];
1242   difference(){
1243     union(){
1244       intersection(){
1245         LidAroundEdges()
1246           LidEdgeProfile();
1247
1248         translate(skew_centre)
1249           multmatrix([[ 1, 0, 0, 0 ],
1250                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1251                       [ 0, 0, 1, 0 ],
1252                       [ 0, 0, 0, 1 ]])
1253           translate(-skew_centre)
1254           LidAroundEdges()
1255           LidEdgeFoldClearanceProfile();
1256       }
1257
1258       // button covers
1259       Buttons(){
1260         intersection(){
1261           rotate([90,0,90])
1262             translate([0,0,-10])
1263             linear_extrude(height= 20)
1264             ButtonPlan($button_l, 1,0);
1265           union(){
1266             rotate([90,0,0])
1267               translate([0,0,-100])
1268               linear_extrude(height= 200)
1269               ButtonCoverProfile();
1270             hull()
1271               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1272                                  - lid_buttoncover_reinf))
1273                 translate([0,y,0])
1274                   ButtonCoverReinf();
1275           }
1276         }
1277       }
1278
1279       // hinge arms
1280       HingePortion(hex20, hex21) {
1281         LidEdgeProfile();
1282         HingeLidProfile();
1283       }
1284     }
1285     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1286
1287     // screw holes in the hinge arms
1288     HingeScrews();
1289
1290     // prop recess
1291     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1292       mirror([0,1,0])
1293       rotate([90,0,90])
1294       linextr(-prop_recess_hw, +prop_recess_hw)
1295       hull()
1296       for (pa = prop_angles)
1297         PropProfile(pa, 1,1);
1298
1299     // notification led aperture
1300     if (led_window_style)
1301       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1302         translate([0,0,-10])
1303           cylinder(r=nla_r0, h=20);
1304         if (led_window_style >= 2)
1305           translate([0,0, -nla_t])
1306             cylinder(r=nla_r2, height=20);
1307       }
1308
1309     }
1310
1311   LidAdhocMultiprintFrame(1);
1312 }
1313
1314 module HingeLever(){ ////toplevel
1315   difference() {
1316     // outer body, positive
1317     HingePortion(hex22, hex22 + phone_width/2)
1318       HingeLeverOuterProfile();
1319
1320     // space for the screws
1321     HingePortion(hex26, hex24)
1322       HingeLeverInnerProfile();
1323
1324     // recesses for the nuts
1325     HingePortion(hex23, hex26+1)
1326       HingeLeverNutProfile();
1327
1328     // bores for the screws
1329     HingeScrews();
1330
1331     // space for the charging cable
1332     MicroUSB();
1333     Flip_hinge() MicroUSB();
1334   }
1335 }
1336
1337 module LidWindow(){ ////toplevel
1338   translate([led_pos[0], -led_pos[1], lpp13[1]])
1339     mirror([0,0,1])
1340     cylinder(r= nla_r1, h=nla_t);
1341   LidAdhocMultiprintFrame(0);
1342 }
1343
1344 module LidWindowPrint(){ ////toplevel
1345   rotate([0,180,0])
1346     LidWindow();
1347 }
1348
1349 module DemoLidWindowSelect(){
1350   translate([led_pos[0], led_pos[1], -100]) {
1351     translate([0, -30, 0]) cube([400, 400, 200]);
1352   }
1353 }
1354
1355 module DemoLidWindow(){ ////toplevel
1356   %Lid();
1357   LidWindow();
1358   translate([0,40,0]){
1359     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1360     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1361   }
1362 }
1363
1364 module HingeLeverPrint(){ ////toplevel
1365   rotate([-90,0,0])
1366     translate([-phone_width/2, phone_height, 0])
1367     HingeLever();
1368 }
1369
1370 module TestSelectLength(){
1371   translate([-30, -200, -20])
1372     cube([30 + 15, 250, 40]);
1373 }
1374
1375 module TestLength(){ ////toplevel
1376   intersection(){
1377     Case();
1378     TestSelectLength();
1379   }
1380 }
1381
1382 module TestLengthRight(){ ////toplevel
1383   intersection(){
1384     Case();
1385     Flip_rhs(1)
1386       TestSelectLength();
1387   }
1388 }
1389
1390 module TestSelectWidth(){
1391   translate([-30, -(phone_height - 25), -20])
1392     mirror([0, 1, 0])
1393     cube([200, 50, 40]);
1394 }
1395
1396 module TestWidth(){ ////toplevel
1397   intersection(){
1398     Case();
1399     TestSelectWidth();
1400   }
1401 }
1402
1403 module TestLidWidthPrint(){ ////toplevel
1404   rotate([0,180.0]) intersection(){
1405     Lid();
1406     TestSelectWidth();
1407   }
1408 }
1409
1410 module TestSelectRearAperture(){
1411   minkowski(){
1412     union() children();
1413     translate([20, 0,0])
1414       cube([42, 2, 1], center=true);
1415   }
1416 }
1417
1418 module TestSelectCamera(){
1419   minkowski(){
1420     TestSelectRearAperture()
1421       RearCameraAperture();
1422     cube([0.1, 50, 0.1]);
1423   }
1424 }
1425
1426 module TestSelectOrdinaryRearApertures(){
1427   TestSelectRearAperture()
1428     OrdinaryRearApertures();
1429 }
1430
1431 module TestCamera(){ ////toplevel
1432   intersection(){
1433     Case();
1434     TestSelectCamera();
1435   }
1436 }
1437
1438 module TestLidByCamera(){ ////toplevel
1439   intersection(){
1440     Lid();
1441     TestSelectCamera();
1442   }
1443 }
1444
1445 module TestLidByCameraPrint(){ ////toplevel
1446   rotate([180,0,0]) TestLidByCamera();
1447 }
1448
1449 module DemoByCamera(){ ////toplevel
1450   color("blue") TestLidByCamera();
1451   color("red")  TestCamera();
1452 }
1453
1454 module OneKeeper(){ ////toplevel
1455   translate([0, -phone_cnr_rad, 0])
1456     rotate([90, 0, 0])
1457     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1458     KeeperProfile();
1459 }
1460
1461 module OneKeeperPrint(){ ////toplevel
1462   rotate([0,180,0])
1463     OneKeeper();
1464 }
1465
1466 module LidPrint(){ ////toplevel
1467   rotate([0,180,0])
1468     Lid();
1469 }
1470
1471 module TestSelectFrame(){
1472   include = [1,-1] * (epp2i[0] + 4);
1473
1474   difference(){
1475     cube(1000, center=true);
1476     translate([0,0, -100])
1477       linear_extrude(height=200)
1478       rectfromto(include,  inside_br - include);
1479   }
1480 }
1481
1482 module TestSelectLidFrame(){
1483   TestSelectFrame();
1484   translate([led_pos[0], -led_pos[1], -50])
1485     cylinder(r= nla_r2+3, h=100);
1486 }
1487
1488 module TestFrameCase(){ ////toplevel
1489   intersection(){
1490     Case();
1491     union(){
1492       TestSelectFrame();
1493       TestSelectCamera();
1494       TestSelectOrdinaryRearApertures();
1495     }
1496   }
1497 }
1498
1499 module TestSelectTopApertures(){
1500   translate([-100, -35, -100])
1501     cube([400, 100, 200]);
1502   LidAdhocMultiprintFrame(0);
1503   LidAdhocMultiprintFrame(1);
1504 }
1505
1506 module TestTopApertures(){ ////toplevel
1507   intersection(){
1508     Case();
1509     TestSelectFrame();
1510     TestSelectTopApertures();
1511   }
1512 }
1513
1514 module TestLidTopAperturesPrint(){ ////toplevel
1515   rotate([0,180,0]) intersection(){
1516     Lid();
1517     TestSelectLidFrame();
1518     TestSelectTopApertures();
1519   }
1520 }
1521
1522 module TestLidWindowTopAperturesPrint(){ ////toplevel
1523   rotate([0,180,0]) intersection(){
1524     LidWindow();
1525     TestSelectTopApertures();
1526   }
1527 }
1528
1529 module TestFrameLidPrint(){ ////toplevel
1530   rotate([0,180,0]) intersection(){
1531     Lid();
1532     TestSelectLidFrame();
1533   }
1534 }
1535
1536 module ButtonPlanForDemo(z, deep, cut){
1537   translate([0,0,z])
1538     ButtonPlan(8, deep, cut);
1539 }
1540
1541 module HingeScrews(){
1542   Flip_rhs() Flip_bot(1){
1543     for (c= [ hppT, hppB ])
1544       translate([ hex20,
1545                   -c[0],
1546                   c[1] ]){
1547         rotate([0,90,0])
1548           translate([0,0,-.2])
1549           cylinder( r= hingescrew_shaft_dia/2,
1550                     h = hingescrew_shaft_len+0.2 );
1551         rotate([0,-90,0])
1552           translate([0,0,+.1])
1553           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1554       }
1555   }
1556 }
1557
1558 module DemoPropAngleSelect(c){
1559   color(c) difference(){
1560     union(){ children(); }
1561     translate([ prop_x_pos, -400, -200 ])
1562       cube([ 400,800,400 ]);
1563   }
1564 }
1565
1566 module DemoPropAngle(ang){
1567   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1568   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1569
1570   translate(hL)
1571     rotate([ang/2,0,0])
1572     translate(-hL)
1573     translate(hC)
1574     rotate([ang/2,0,0])
1575     translate(-hC) {
1576       DemoPropAngleSelect("red") Case();
1577
1578       color("orange")
1579         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1580         PropProfileAssignments(ang) {
1581           echo($prpp1);
1582           rotate([-$prp_theta, 0, 0])
1583           translate([0, $prpp1[0], -$prpp1[1]])
1584           rotate([90,0,-90])
1585           Prop();
1586         }
1587     }
1588
1589   translate([0,0, -hp_k*2])
1590     DemoPropAngleSelect("blue")
1591     Lid();
1592 }
1593
1594 module DemoPropAngles(){ ////toplevel
1595   for (i=[0 : len(prop_angles)-1])
1596     translate(i * [0, -100, 100])
1597     DemoPropAngle(prop_angles[i]);
1598 }
1599
1600 module DemoHingeAngle(ang1,ang2){
1601   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1602   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1603
1604   translate(hL)
1605     rotate([ang2,0,0])
1606     translate(-hL)
1607     translate(hC)
1608     rotate([ang1,0,0])
1609     translate(-hC) {
1610       color("red") Lid();
1611     }
1612
1613   color("blue") intersection(){
1614     Case();
1615     union(){
1616       translate([bppJ[0], -400, -200])
1617         mirror([1,0,0])
1618         cube([400, 800, 400]);
1619       translate([10, -400, -200])
1620         cube([10, 800, 400]);
1621     }
1622   }
1623 }
1624
1625 module DemoHingeAngles(){ ////toplevel
1626   angles = [ 0, 4, 8, 12 ];
1627   echo("angles",angles);
1628   for (i=[0 : len(angles)-1]) {
1629     translate(i * [0, 0, 30]) {
1630       DemoHingeAngle(0,angles[i]);
1631       translate([0, 200, 0])
1632         DemoHingeAngle(angles[i],0);
1633     }
1634   }
1635 }
1636
1637 module DemoSelectAdhocLeftRight(right=0) {
1638   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1639     mirror([1-right, 0,0])
1640     cube([400, 800, 200]);
1641 }
1642
1643 module DemoLeft(){ ////toplevel
1644   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1645   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1646 }
1647
1648 module DemoFrame(){ ////toplevel
1649   color("red") TestFrameCase();
1650   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1651   color("black") HingeScrews();
1652   %HingeLever();
1653 }
1654
1655 module DemoLanyardCutout(){ ////toplevel
1656   LanyardCutout(25);
1657 }
1658
1659 module DemoHingedFrame(){ ///toplevel
1660   color("red") TestFrameCase();
1661   translate([0,0, -2*hp_k])
1662   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1663
1664   Flip_hinge(){
1665     color("orange") HingeLever();
1666     color("black") HingeScrews();
1667   }
1668 }
1669
1670 module DemoHinge(){ ////toplevel
1671   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1672     DemoFrame();
1673     translate([0,0, -hp_k*3])
1674       DemoHingedFrame();
1675   }
1676 }
1677
1678 module DemoProfiles(){ ////toplevel
1679   LidEdgeProfile();
1680   %EdgeProfile();
1681   KeeperProfile();
1682   translate([0,0,-1]) color("black") KeeperProfile(1);
1683   translate(ly_o){
1684     rotate(-ly_theta){
1685       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1686       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1687       translate([0, ly_q_z]){
1688         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1689         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1690       }
1691     }
1692   }
1693   translate([0,0,-5]) color("white") translate(epp2i)
1694     rotate(-ly_theta)
1695     rectfromto([-15, 0],
1696                [+15, -max_case_bottom_edge_thickness]);
1697
1698   translate([0,20]) {
1699     LanyardMainChannelProfile();
1700     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1701     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1702   }
1703
1704   translate([20,0]) {
1705     LidEdgeProfile();
1706     %EdgeProfile();
1707
1708     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1709
1710     color("blue") ButtonCoverProfile();
1711     color("red") {
1712       rectfromto(bppQ, demopoint_QR);
1713       rectfromto(bppR, demopoint_QR);
1714     }
1715   }
1716
1717   translate([-20,0]) {
1718     color("black") ButtonPlanForDemo(-2, 0,1);
1719     color("red" )  ButtonPlanForDemo(-4, 1,1);
1720     color("blue")  ButtonPlanForDemo(-6, 1,0);
1721   }
1722
1723   translate([0, -30]) {
1724     %LidEdgeProfile();
1725     %EdgeProfile();
1726     color("blue") HingeLidProfile();
1727     color("red")  HingeBaseProfile();
1728     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1729   }
1730
1731   for (f=[0,1]) {
1732     translate([-30, -60 + 30*f]) {
1733       translate([0,0,-4]) EdgeProfile();
1734       %translate([0,0,-10]) HingeBaseProfile();
1735       translate([0,-2] * f * hp_k) {
1736         translate([0,0,-4]) LidEdgeProfile();
1737         %translate([0,0,-10]) %HingeLidProfile();
1738       }
1739       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1740         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1741         translate([0,0,0]) color("red") difference(){
1742           HingeLeverOuterProfile();
1743           HingeLeverInnerProfile();
1744         }
1745         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1746       }
1747     }
1748   }
1749
1750   translate([20,-30]) {
1751     %EdgeProfile();
1752     %LidEdgeProfile();
1753     //translate([0,0,1]) CatchCutProfile();
1754     translate([0,0,+1]) color("red")
1755       difference(){ EdgeProfile(); CatchCutProfile(); }
1756   }
1757
1758   translate([40,-30]) {
1759     difference(){
1760       LidEdgeProfile();
1761       translate(prlp10)
1762         PropProfile(10, 1, 0);
1763     }
1764     translate(prlp10)
1765       PropProfile(15, 0);
1766   }
1767   translate([60,-30]) {
1768     PropAggregateProfile();
1769   }
1770 }
1771
1772 //EdgeProfile();
1773 //KeeperProfile();
1774 //CaseBase();
1775 //%Case();
1776 //Keeper();
1777 //LidEdgeProfile();
1778 //KeeperProfile();
1779 //DemoProfiles();
1780 //PropRecess();