fairphone-case.scad

   1 // -*- C -*-
   2
   3 include <utils.scad>
   4
   5 phone = [ 75.0, 145.0 ];
   6
   7 bumper = [ 0.250, -0.025 ];
   8 // ^ One side.  Overall size is increased by twice this.
   9 // If no bumpers, is the gap around the phone.
  10
  11 enable_support = 1;
  12
  13 phone_cnr_rad = 6.0;
  14
  15 button_cutout_depth = 9;
  16
  17 phone_edge_thick = 9.0;
  18 phone_total_thick = 12.0;
  19 phone_backside_slope_inner = 1.5; // larger means shallower
  20 phone_backside_slope_outer = 1.0; // larger means shallower
  21
  22 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  23 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  24
  25 jack_pos = [ 13.92, 7.96 ];
  26 jack_dia = 9.1 + .5; // some jack I had lying around
  27
  28 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  29 noisecancelmic_dia = 1.75;
  30
  31 fingerpushhole_dias = [ 15, 18 ];
  32
  33 rearspeaker_pos_bl = [ 12.64, 18.72 ];
  34 rearspeaker_size   = [  3.76,  7.36 ];
  35
  36 microusb_above = 3.27 - 0.25;
  37 microusb_below = 0.0;
  38 microusb_width = 16.12 + 0.25;
  39
  40 case_th_bottom = 2.5;
  41 case_th_lid = 2.5;
  42 case_th_side = 2;
  43 case_th_lip = 1.2;
  44
  45 case_struts_count = 6;
  46 case_struts_solid_below = 1.00;
  47 case_struts_solid_above = 0.75;
  48 case_struts_width = 0.10;
  49
  50 keeper_th_z = 0.75;
  51 keeper_th_x = 0.75;
  52 keeper_inner_width = 2.75;
  53 keeper_inner_height = 2.75;
  54 keeper_slant_slope = 2; // larger means steeper
  55
  56 keeper_gap_z_top = 0.25;
  57 keeper_gap_z_bot = 0.75;
  58 keeper_gap_x     = 0.25;
  59 keeper_gap_x_holes = 0.75;
  60
  61 keeper_side = 0; // 0 = lhs; 1 = rhs
  62
  63 case_lip = 1.25;
  64
  65 lid_gap_x = 0.25;
  66 lid_gap_z = 0.25;
  67 lid_lip = 1.75;
  68
  69 catch_slop = 0.25;
  70
  71 foldover_gap = 0.50;
  72 foldover_lever_gap = 0.50;
  73
  74 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
  75 hingescrew_shaft_len = 12;
  76 hingescrew_nut_thick = 1.93 + 0.20; // incl. washer
  77 hingescrew_nut_dia = 4.72 + 0.50; // washer, actually
  78 hingescrew_head_th = 1.38 + 0.75;
  79 hingescrew_head_dia = 3.92;
  80 lever_cover_th = 0.75;
  81 hingemount_th = 2.5;
  82
  83 $fa = 5;
  84 $fs = 0.1;
  85
  86 button_l_fudge = 4.4;
  87 buttonishleg_default_l_is_fudge = 10;
  88
  89 hinge_base_slope = 1.5; // bigger is steeper
  90
  91 strut_min_at_end = 1.5;
  92
  93 hinge_x_gap = 0.125;
  94 hinge_x_postscrew_gap = 0.75;
  95 hinge_x_arms_gap = 0.35;
  96 hinge_r_arms_gap = 0.55;
  97
  98 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  99
 100 catch_len = 7.5;
 101 catch_width = 15;
 102 catch_thickness = 1.0;
 103 catch_side_gap = 0.75; // each side
 104
 105 catch_depth = 1.25;
 106 catch_height = 0.35;
 107 catch_finger_height = 1.5;
 108 catch_finger_depth = 2.5;
 109
 110 // ---------- calculated ----------
 111
 112 phone_width =  (phone + bumper*2)[0];
 113 phone_height = (phone + bumper*2)[1];
 114
 115 inside_br = [phone_width, -phone_height];
 116
 117 //echo(camera_pos_tl + bumper,
 118 //     camera_pos_br + bumper);
 119
 120 // ----- could be changed -----
 121 lid_buttoncover_gap = lid_gap_x;
 122 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 123
 124 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 125
 126 //lid_lip_overlap_width xxx bad name = ;
 127 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 128
 129 epp0 = [0,0];
 130 epp1 = [0, -phone_edge_thick];
 131 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 132 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 133 epp3 = epp2i + [10, 0];
 134 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 135 epp4 = epp5 + [-1,0] * case_th_side;
 136
 137 kppe = [0,0];
 138 kppd = kppe + [1,0] * keeper_inner_width;
 139 kppc = kppd + [0,1] * keeper_th_z;
 140 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 141 kppf = kppe - [0,1] * keeper_inner_height;
 142 kppa = [ kppb[0], kppf[1] ];
 143
 144 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 145 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 146
 147 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 148
 149 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 150 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 151
 152 // button profile
 153 bppM = epp4 + [0,5];
 154 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 155 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 156 bppS = [ epp1[0], bppR[1] ];
 157 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 158 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 159 bppO = [ bppN[0], bppP[1] ];
 160 bppL = lpp10 + [5,0];
 161 bppK = [ bppL[0], bppN[1] ];
 162 bppJ = [ bppN[0], bppL[1] ];
 163
 164 // hinge plan
 165 hp_rn = hingescrew_nut_dia/2;
 166 hp_r2_min = hp_rn + lever_cover_th;
 167 hp_rs = hingescrew_shaft_dia/2;
 168 hp_r1_min = hp_rs + hingemount_th;
 169
 170 hp_r1 = max(hp_r1_min, hp_r2_min);
 171 hp_r2 = hp_r1;
 172
 173 hppU = lpp13;
 174 hppS = epp2o + [0,-1] * case_th_bottom;
 175 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 176
 177 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 178          0.5 * (hppU + hppS)[1] ];
 179 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 180 hppB = hppT + [0,-1] * hp_k;
 181
 182 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 183 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 184 hppE = [ hppE_x, hppE_y ];
 185
 186 // hinge elevation x coords
 187
 188 hingescrew_portion_len =
 189   0.5* (hingescrew_shaft_len - hingescrew_nut_thick - hinge_x_gap);
 190
 191 hex20 = max(epp2o[0],
 192             phone_cnr_rad,
 193             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 194 hex21 = hex20 + hingescrew_portion_len;
 195 hex22 = hex21 + hinge_x_gap;
 196 hex23 = hex22 + hingescrew_portion_len
 197   - hingescrew_nut_thick; // bodge, need to divvy this up more sensibly
 198 hex24 = hex20 + hingescrew_shaft_len + hinge_x_postscrew_gap;
 199 echo(hex20, hex21, hex22, hex23, hex24);
 200 echo(hingescrew_portion_len);
 201
 202 // catch
 203
 204 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 205 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 206 cppB = [ epp0[0], cppA[1] ];
 207 cppP = [ epp4[0], cppJ[1] ];
 208
 209 cppS = cppJ + [0,-1] * catch_len;
 210 cppD = [ cppA[0], cppS[1] + catch_slop ];
 211 cppC = [ cppB[0], cppD[1] ];
 212 cppT = cppS + [1,0] * catch_depth;
 213 cppU = cppT + [0,-1] * catch_height;
 214 cppV = [ cppS[0], cppU[1] - catch_depth ];
 215
 216 cppR = 0.5*(cppP + cppJ);
 217
 218 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 219 cppQ = [ cppR[0],
 220          cppV[1] - (catch_finger_height - cp_rQ) ];
 221 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 222
 223 // ---------- modules ----------
 224
 225 module KeeperProfile(slant=0){
 226   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 227   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 228 }
 229
 230 module EdgeProfile(){
 231   difference(){
 232     hull(){
 233       translate(epp3) square(case_th_bottom*2, center=true);
 234       circleat(epp2o, r=case_th_bottom);
 235       circleat(epp1, r=case_th_side);
 236       rectfromto(epp0, epp4);
 237     }
 238     polygon([ epp5 + [0,10],
 239               epp1,
 240               epp2i,
 241               epp3 + [10,0] ]);
 242   }
 243 }
 244
 245 module LidEdgeProfile(){
 246   polygon([ lpp10,
 247             lpp11,
 248             lpp12,
 249             lpp13,
 250             lpp13 + [10, 0],
 251             lpp10 + [10, 0]
 252             ]);
 253   intersection(){
 254     circleat(lpp12, r=lp_r12);
 255     rectfromto( lpp12 + [-10,   0],
 256                 lpp12 + [+10, +10] );
 257   }
 258 }
 259
 260 module ButtonCoverProfile(){
 261   intersection(){
 262     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 263     hull(){
 264       EdgeProfile();
 265       LidEdgeProfile();
 266     }
 267   }
 268 }
 269
 270 module ButtonPlan(l, deep, cut){
 271   epsilon =
 272     (cut  ? 0 : lid_buttoncover_gap);
 273
 274   delta =
 275     (deep ? lid_buttoncover_overlap : 0);
 276
 277   C = [0,0]; // by definition
 278   T = [ 0, epp4[1] ];
 279   G = T + [0,10];
 280
 281   B0 = C + [0,-1] * button_cutout_depth;
 282   B1 = B0 + [0,1] * epsilon;
 283
 284   r0 = 0.5 * (T[1] - B0[1]);
 285   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 286   H = A + [0,-1] * delta;
 287
 288   D = A + [-2,0] * r0;
 289   F = D + [0,10];
 290
 291   E0 = 0.5 * (D + A);
 292   E1 = E0 + [1,0] * epsilon;
 293
 294   I0 = [ E0[0], H[1] ];
 295   I1 = [ E1[0], H[1] ];
 296
 297   hull(){
 298     for (m=[0,1]) mirror([m,0])
 299       circleat(H, r0 - epsilon);
 300   }
 301   for (m=[0,1]) mirror([m,0]) {
 302     difference(){
 303       polygon([ E1,
 304                 I1,
 305                 H,
 306                 B1,
 307                 G,
 308                 F,
 309                 D
 310                 ]);
 311       circleat(D, r0 + epsilon);
 312     }
 313   }
 314 }
 315
 316 module CatchCatchProfile(){
 317   hull(){
 318     for (c=[ cppR, cppQ ])
 319       circleat(c, cp_rQ);
 320   }
 321   hull(){
 322     circleat(lpp12, lp_r12);
 323     circleat(lpp12 + [5,0], lp_r12);
 324     rectfromto(cppP, cppP + [5,0.1]);
 325   }
 326   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 327 }
 328
 329 module CatchCutProfile(){
 330   polygon([ cppB,
 331             cppA,
 332             cppD,
 333             cppF,
 334             cppF + [0,-10],
 335             cppF + [-10,-10],
 336             lpp12 + [-10,0],
 337             lpp12 + [10,0]
 338             ]);
 339 }
 340
 341 module Flip_rhs(yn=[0,1]) {
 342   for ($rhsflip=yn) {
 343     translate([phone_width/2, 0, 0])
 344       mirror([$rhsflip,0,0])
 345       translate([-phone_width/2, 0, 0])
 346       children();
 347   }
 348 }
 349
 350 module Flip_bot(yn=[0,1]) {
 351   for ($botflip=yn) {
 352     translate([0, -phone_height/2, 0])
 353       mirror([0, $botflip, 0])
 354       translate([0, phone_height/2, 0])
 355       children();
 356   }
 357 }
 358
 359 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 360   // sides
 361   Flip_rhs(){
 362     translate([0, -phone_cnr_rad, 0])
 363       rotate([90,0,0])
 364       linear_extrude(height = phone_height - phone_cnr_rad*2)
 365       children(0);
 366   }
 367   // corners
 368   Flip_rhs() Flip_bot() {
 369     translate([+1,-1] * phone_cnr_rad)
 370       intersection(){
 371         rotate_extrude()
 372           intersection(){
 373             mirror([1,0,0])
 374               translate([-1,0] * phone_cnr_rad)
 375               children(0);
 376             rectfromto([0,-20],[10,20]);
 377           }
 378         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 379           cube([10,10,40]);
 380       }
 381   }
 382   // top and bottom
 383   Flip_bot(){
 384     translate([ phone_width - phone_cnr_rad, 0,0 ])
 385       rotate([90,0,-90])
 386       linear_extrude(height = phone_width - phone_cnr_rad*2)
 387       children(0);
 388   }
 389   // fill
 390   translate([0,0, fill_zstart])
 391     mirror([0,0, fill_downwards])
 392     linear_extrude(height = fill_th)
 393     rectfromto([+1,-1] * phone_cnr_rad,
 394                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 395 }
 396
 397 module CaseAperture(pos, dia, $fn) {
 398   theta = 180/$fn;
 399   translate([ pos[0] + bumper[0],
 400               -epp2i[0],
 401               -pos[1] ])
 402     rotate([-90, theta, 0])
 403     cylinder(r = dia/2 / cos(theta),
 404              h = 60);
 405 }
 406
 407 module SideButton(y, y_ref_sign, l){
 408   // y_ref_sign:
 409   //   +1  measured from top    of actual phone to top    of button
 410   //   -1  measured from bottom of actual phone to bottom of button
 411   //    0  y is centre of button in coordinate system
 412   $button_l= l;
 413   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 414           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 415           y;
 416   //echo(eff_y);
 417   translate([0, eff_y, 0])
 418     children();
 419 }
 420
 421 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 422   $button_leg_only = true;
 423   SideButton(y, y_ref_sign, l) children();
 424 }
 425
 426 module Buttons(){
 427   Flip_rhs(1) SideButton(15.580, +1, 8.9) children(); // power
 428   Flip_rhs(1) SideButton(48.700, -1, 8.920) children(); // camera
 429   Flip_rhs(0) SideButton(30.800, +1, 21.96) children(); // volume
 430   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 431 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 432 }
 433
 434 module Struts(x_start, z_min, th){
 435   // if th is negative, starts at z_min and works towards -ve z
 436   // and object should then be printed other way up
 437   for (i= [1 : 1 : case_struts_count]) {
 438     translate([0,
 439                0,
 440                z_min])
 441       mirror([0,0, th<0 ? 1 : 0])
 442       translate([0,
 443                  -phone_height * i / (case_struts_count+1),
 444                  case_struts_solid_below])
 445       linear_extrude(height= abs(th)
 446                      -(case_struts_solid_below+case_struts_solid_above))
 447       rectfromto([               x_start, -0.5 * case_struts_width ],
 448                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 449   }
 450 }
 451
 452 module OrdinaryRearAperture(rhs,bot, pos){
 453   Flip_rhs(rhs) Flip_bot(bot)
 454     linextr(-20, 20)
 455     mirror([0,1])
 456     translate(pos + bumper)
 457     children();
 458 }
 459
 460 module MicroUSB(){
 461   Flip_bot(1){
 462     rotate([90,0,0])
 463       mirror([0,0,1])
 464       linextr(-epp2i[0], 60)
 465       translate([0.5 * phone_width, 0, 0])
 466       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 467                  [+microusb_width/2, epp0[1] + -microusb_above]);
 468   }
 469 }
 470
 471 module OrdinaryRearApertures(){
 472   // rear speaker
 473   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 474     rectfromto(-rearspeaker_gap,
 475                rearspeaker_size + rearspeaker_gap);
 476
 477   // finger hole to remove phone
 478   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 479                               phone[1]/2 ])
 480     scale(fingerpushhole_dias)
 481     circle(r= 0.5 );
 482 }
 483
 484 module RearCameraAperture(){
 485   Flip_rhs(1)
 486     mirror([0, 0, 1])
 487     linear_extrude(height = 20)
 488     mirror([0, 1, 0])
 489     translate(bumper)
 490     rectfromto(camera_pos_tl, camera_pos_br);
 491 }
 492
 493 module HingeLidProfile(){
 494   hull(){
 495     circleat(hppT, hp_r1);
 496     circleat(lpp12, lp_r12);
 497     polygon([lpp10,
 498              lpp13 + [2,0],
 499              lpp12,
 500              hppT]);
 501   }
 502 }
 503
 504 module HingeBaseProfile(){
 505   difference(){
 506     hull(){
 507       circleat(hppB, hp_r1);
 508       circleat(hppE, hp_r1);
 509       circleat(epp2o, case_th_bottom);
 510       circleat(hppB + [10,0], hp_r1);
 511     }
 512     polygon([epp5, epp1, epp2i, epp3, bppL]);
 513   }
 514 }
 515
 516 module HingeLeverOuterProfile(){
 517   hull(){
 518     circleat(hppT, hp_r2);
 519     circleat(hppB, hp_r2);
 520   }
 521 }
 522
 523 module HingeLeverInnerProfile(){
 524   for (c = [hppT, hppB]) {
 525     hull()
 526       for (x=[-20,20])
 527         for (y=[0, c[1] - hppM[1]])
 528           translate([x,y])
 529             circleat(c, hp_rn);
 530   }
 531 }
 532
 533 module Flip_hinge(){
 534   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 535   translate(hinge_origin)
 536     rotate([180,0,0])
 537     translate(-hinge_origin)
 538     children();
 539 }
 540
 541 module HingePortion(x0,x1){
 542   Flip_rhs() Flip_bot(1)
 543     translate([x0,0,0])
 544     mirror([1,0,0])
 545     rotate([90,0,-90])
 546     linear_extrude(height=x1-x0)
 547     children(0);
 548 }
 549
 550 module CatchPortion(width){
 551   translate([phone_width/2, 0,0])
 552     rotate([90,0,-90])
 553     linextr(-width/2, width/2)
 554     children(0);
 555 }
 556
 557 module CaseBase(){
 558   AroundEdges(epp3[1], case_th_bottom, 1)
 559     EdgeProfile();
 560 }
 561
 562 module Case(){ ////toplevel
 563   difference(){
 564     union(){
 565       CaseBase();
 566
 567       // ledge (fixed keeper)
 568       Flip_rhs(1-keeper_side) intersection(){
 569         rotate([90, 0, 0])
 570           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 571           KeeperProfile(1);
 572
 573         // outline of the whole case, to stop it protruding
 574         translate([0,0, -25])
 575           linear_extrude(height = 50)
 576           hull()
 577           Flip_bot()
 578           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 579       }
 580
 581       // hinge
 582       HingePortion(hex20, hex21) HingeBaseProfile();
 583     }
 584
 585     // slot for keeper
 586     Flip_rhs(keeper_side)
 587       translate([0, -phone_cnr_rad, 0])
 588       rotate([90, 0, 0])
 589       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 590       minkowski(){
 591         KeeperProfile();
 592         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 593                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 594       }
 595
 596     // front camera
 597     RearCameraAperture();
 598
 599     // struts (invisible, because they're buried in the case)
 600     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 601
 602     Buttons(){
 603       mirror([1,0,0])
 604         rotate([90,0,90]) {
 605           if (!($button_leg_only && enable_support))
 606           intersection(){
 607             translate([0,0,-10])
 608               linear_extrude(height= 20)
 609               ButtonPlan($button_l, 0,1);
 610             if ($button_leg_only)
 611               rotate([-90,90,0])
 612                 translate([phone_width/2, -400, kppe[1]])
 613                 mirror([1-abs($rhsflip - keeper_side),0,0])
 614                 cube([400, 800, 50]);
 615             if (enable_support)
 616               rotate([-90,90,0])
 617               translate([-400, -400, kppd[1]])
 618                 mirror([0,0,1])
 619                 cube([800,800,100]);
 620           }
 621           translate([0,0, -bppR[0]])
 622             linear_extrude(height= 20)
 623             ButtonPlan($button_l, 1,1);
 624         }
 625     }
 626
 627     // apertures along top edge
 628     CaseAperture(jack_pos, jack_dia, 8);
 629     Flip_rhs(1)
 630       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 631
 632     OrdinaryRearApertures();
 633
 634     MicroUSB();
 635
 636     // gaps for the lid's hinge arms
 637     HingePortion(hex20 - hinge_x_arms_gap,
 638                  hex21 + hinge_x_arms_gap)
 639       minkowski(){
 640         HingeLidProfile();
 641         circle(r= hinge_r_arms_gap, $fn= 8);
 642       }
 643
 644     // screw holes in the hinge arms
 645     HingeScrews();
 646
 647     // catch striker
 648     CatchPortion(catch_width + catch_side_gap*2)
 649       CatchCutProfile();
 650   }
 651 }
 652
 653 module Lid(){ ////toplevel
 654   difference(){
 655     union(){
 656       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 657         LidEdgeProfile();
 658
 659       // button covers
 660       Buttons(){
 661         intersection(){
 662           rotate([90,0,90])
 663             translate([0,0,-10])
 664             linear_extrude(height= 20)
 665             ButtonPlan($button_l, 1,0);
 666           rotate([90,0,0])
 667              translate([0,0,-100])
 668             linear_extrude(height= 200)
 669             ButtonCoverProfile();
 670         }
 671       }
 672
 673       // hinge arms
 674       HingePortion(hex20, hex21) HingeLidProfile();
 675
 676       // catch
 677       CatchPortion(catch_width)
 678         CatchCatchProfile();
 679     }
 680     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 681
 682     // screw holes in the hinge arms
 683     HingeScrews();
 684   }
 685 }
 686
 687 module HingeLever(){ ////toplevel
 688   difference() {
 689     // outer body, positive
 690     HingePortion(hex22, hex22 + phone_width/2)
 691       HingeLeverOuterProfile();
 692
 693     // space for the screws
 694     HingePortion(hex23, hex24)
 695       HingeLeverInnerProfile();
 696
 697     // bores for the screws
 698     HingeScrews();
 699
 700     // space for the charging cable
 701     MicroUSB();
 702     Flip_hinge() MicroUSB();
 703   }
 704 }
 705
 706 module HingeLeverPrint(){ ////toplevel
 707   rotate([90,0,0])
 708     HingeLever();
 709 }
 710
 711 module TestSelectLength(){
 712   translate([-30, -200, -20])
 713     cube([30 + 15, 250, 40]);
 714 }
 715
 716 module TestLength(){ ////toplevel
 717   intersection(){
 718     Case();
 719     TestSelectLength();
 720   }
 721 }
 722
 723 module TestLengthRight(){ ////toplevel
 724   intersection(){
 725     Case();
 726     Flip_rhs(1)
 727       TestSelectLength();
 728   }
 729 }
 730
 731 module TestSelectWidth(){
 732   translate([-30, -(phone_height - 25), -20])
 733     mirror([0, 1, 0])
 734     cube([200, 50, 40]);
 735 }
 736
 737 module TestWidth(){ ////toplevel
 738   intersection(){
 739     Case();
 740     TestSelectWidth();
 741   }
 742 }
 743
 744 module TestLidWidthPrint(){ ////toplevel
 745   rotate([0,180.0]) intersection(){
 746     Lid();
 747     TestSelectWidth();
 748   }
 749 }
 750
 751 module TestSelectRearAperture(){
 752   minkowski(){
 753     union() children();
 754     translate([20, 0,0])
 755       cube([42, 2, 1], center=true);
 756   }
 757 }
 758
 759 module TestSelectCamera(){
 760   minkowski(){
 761     TestSelectRearAperture()
 762       RearCameraAperture();
 763     cube([0.1, 50, 0.1]);
 764   }
 765 }
 766
 767 module TestSelectOrdinaryRearApertures(){
 768   TestSelectRearAperture()
 769     OrdinaryRearApertures();
 770 }
 771
 772 module TestCamera(){ ////toplevel
 773   intersection(){
 774     Case();
 775     TestSelectCamera();
 776   }
 777 }
 778
 779 module TestLidByCamera(){ ////toplevel
 780   intersection(){
 781     Lid();
 782     TestSelectCamera();
 783   }
 784 }
 785
 786 module TestLidByCameraPrint(){ ////toplevel
 787   rotate([180,0,0]) TestLidByCamera();
 788 }
 789
 790 module DemoByCamera(){ ////toplevel
 791   color("blue") TestLidByCamera();
 792   color("red")  TestCamera();
 793 }
 794
 795 module OneKeeper(){ ////toplevel
 796   translate([0, -phone_cnr_rad, 0])
 797     rotate([90, 0, 0])
 798     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 799     KeeperProfile();
 800 }
 801
 802 module OneKeeperPrint(){ ////toplevel
 803   rotate([0,180,0])
 804     OneKeeper();
 805 }
 806
 807 module LidPrint(){ ////toplevel
 808   rotate([0,180,0])
 809     Lid();
 810 }
 811
 812 module TestSelectFrame(){
 813   include = [1,-1] * (epp2i[0] + 4);
 814
 815   difference(){
 816     cube(1000, center=true);
 817     translate([0,0, -100])
 818       linear_extrude(height=200)
 819       rectfromto(include,  inside_br - include);
 820   }
 821 }
 822
 823 module TestFrameCase(){ ////toplevel
 824   intersection(){
 825     Case();
 826     union(){
 827       TestSelectFrame();
 828       TestSelectCamera();
 829       TestSelectOrdinaryRearApertures();
 830     }
 831   }
 832 }
 833
 834 module TestFrameLidPrint(){ ////toplevel
 835   rotate([0,180,0]) intersection(){
 836     Lid();
 837     TestSelectFrame();
 838   }
 839 }
 840
 841 module ButtonPlanForDemo(z, deep, cut){
 842   translate([0,0,z])
 843     ButtonPlan(8, deep, cut);
 844 }
 845
 846 module HingeScrews(){
 847   Flip_rhs() Flip_bot(1){
 848     for (c= [ hppT, hppB ])
 849       translate([ hex20,
 850                   -c[0],
 851                   c[1] ]){
 852         rotate([0,90,0])
 853           translate([0,0,-.2])
 854           cylinder( r= hingescrew_shaft_dia/2,
 855                     h = hingescrew_shaft_len+0.2 );
 856         rotate([0,-90,0])
 857           translate([0,0,+.1])
 858           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
 859       }
 860   }
 861 }
 862
 863 module DemoFrame(){ ////toplevel
 864   color("red") TestFrameCase();
 865   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 866   color("black") HingeScrews();
 867   %HingeLever();
 868 }
 869
 870 module DemoHingedFrame(){ ///toplevel
 871   color("red") TestFrameCase();
 872   translate([0,0, -2*hp_k])
 873   color("blue") intersection(){ Lid(); TestSelectFrame(); }
 874
 875   Flip_hinge(){
 876     color("orange") HingeLever();
 877     color("black") HingeScrews();
 878   }
 879 }
 880
 881 module DemoHinge(){ ////toplevel
 882   DemoFrame();
 883   translate([0,0, -hp_k*3])
 884     DemoHingedFrame();
 885 }
 886
 887 module DemoProfiles(){ ////toplevel
 888   LidEdgeProfile();
 889   %EdgeProfile();
 890   KeeperProfile();
 891   translate([0,0,-1]) color("black") KeeperProfile(1);
 892
 893   translate([20,0]) {
 894     LidEdgeProfile();
 895     %EdgeProfile();
 896
 897     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 898
 899     color("blue") ButtonCoverProfile();
 900     color("red") {
 901       rectfromto(bppQ, demopoint_QR);
 902       rectfromto(bppR, demopoint_QR);
 903     }
 904   }
 905
 906   translate([-20,0]) {
 907     color("black") ButtonPlanForDemo(-2, 0,1);
 908     color("red" )  ButtonPlanForDemo(-4, 1,1);
 909     color("blue")  ButtonPlanForDemo(-6, 1,0);
 910   }
 911
 912   translate([0, -30]) {
 913     %LidEdgeProfile();
 914     %EdgeProfile();
 915     color("blue") HingeLidProfile();
 916     color("red")  HingeBaseProfile();
 917     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
 918     color("orange") translate([0,0,-1]) HingeLeverInnerProfile();
 919   }
 920
 921   translate([20,-30]) {
 922     %EdgeProfile();
 923     %LidEdgeProfile();
 924     //translate([0,0,1]) CatchCutProfile();
 925     color("blue") CatchCatchProfile();
 926     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
 927   }
 928 }
 929
 930 //EdgeProfile();
 931 //KeeperProfile();
 932 //CaseBase();
 933 //%Case();
 934 //Keeper();
 935 //LidEdgeProfile();
 936 //KeeperProfile();
 937 //DemoProfiles();