fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213
 214 catch_slop = 0.50;
 215
 216 foldover_gap = 0.50;
 217 foldover_lever_gap = 0.50;
 218
 219 // properties of the hinge fasteners
 220 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 221 hingescrew_shaft_len = 12;
 222 hingescrew_fasteners_extra_thick = 0.40;
 223 // ^ amount of thread protruding if everything was completely nominal
 224 //   and we are using two nuts
 225 hingescrew_nut_access_dia = 4.72 + 0.50;
 226 // ^ washer is 4.72 dia
 227 //   also, want to get pliers or tiny spanner in to do up locknut
 228 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 229 hingescrew_nut_thick = 1.93;
 230 hingescrew_head_th = 1.38 + 0.75;
 231 hingescrew_head_dia = 3.92;
 232
 233 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 234
 235 lever_cover_th = 0.75;
 236 hingemount_th = 2.5;
 237 hingemount_wd = 4.8725;
 238
 239 $fa = 5;
 240 $fs = 0.1;
 241
 242 button_l_fudge = 4.4;
 243 buttonishleg_default_l_is_fudge = 10;
 244
 245 hinge_base_slope = 1.5; // bigger is steeper
 246
 247 strut_min_at_end = 1.5;
 248
 249 hinge_x_gap = 0.125;
 250 hinge_x_postscrew_gap = 0.75;
 251 hinge_x_arms_gap = 0.35;
 252 hinge_r_arms_gap = 0.55;
 253
 254 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 255
 256 catch_len = 7.5;
 257 catch_width = 15;
 258 catch_thickness = 1.3;
 259 catch_side_gap = 0.75; // each side
 260
 261 catch_depth = 1.25;
 262 catch_height = 0.35;
 263 catch_finger_height = 1.5;
 264 catch_finger_depth = 2.5;
 265 catch_catch_slope = 0.25;
 266
 267 catch_topcurve_r = 5.0;
 268
 269 prop_recess_under = 0.50;
 270 prop_recess_slop = 0.200; // each side
 271 prop_end_dia = 0.5;
 272 prop_main_th = 3;
 273 prop_taper_len = 6;
 274 prop_main_width = 4;
 275 prop_side_gap = 0.75; // each side
 276 prop_lidrecess_behind = 0.75;
 277 prop_caserecess_behind = 0.75;
 278 prop_caserecess_taper = 0.45; // one side only
 279 prop_prop_gap = 0.5;
 280 prop_prong_heel_slope = 0.5;
 281
 282 lid_fold_clearance_antislop = 0.5;
 283
 284 // ---------- calculated ----------
 285
 286 phone_width =  (phone + bumper*2)[0];
 287 phone_height = (phone + bumper*2)[1];
 288
 289 inside_br = [phone_width, -phone_height];
 290
 291 prop_prong_h = prop_main_th;
 292
 293 //echo(camera_pos_tl + bumper,
 294 //     camera_pos_br + bumper);
 295
 296 // ----- could be changed -----
 297 lid_buttoncover_gap = lid_gap_x;
 298 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 299
 300 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 301
 302 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 303
 304 //prop_nose_len = case_th_lid - prop_recess_under;
 305 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 306 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 307
 308
 309 //lid_lip_overlap_width xxx bad name = ;
 310 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 311
 312 epp0 = [0,0];
 313 epp1 = [0, -phone_edge_thick];
 314 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 315 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 316 epp3 = epp2i + [10, 0];
 317 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 318 epp4 = epp5 + [-1,0] * case_th_side;
 319
 320 kppe = [0,0];
 321 kppd = kppe + [1,0] * keeper_inner_width;
 322 kppc = kppd + [0,1] * keeper_th_z;
 323 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 324 kppf = kppe - [0,1] * keeper_inner_height;
 325 kppa = [ kppb[0], kppf[1] ];
 326
 327 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 328 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 329
 330 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 331 // exact x posn not very important; must extend past end of keeper
 332
 333 lpp15 = [ lpp14[0],
 334           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 335           + lid_screen_gap_extra ];
 336 // ^ beam theory says to maximise force before contact,
 337 //   the gap below the `beam' (the lid) must be 1/3
 338 //   the thickness (ie the lid thickness) if the beam
 339 //   is solid, or 1/2 if it has a top and bottom only.
 340 //   ours is mostly solid.
 341
 342 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 343              case_th_lip);
 344
 345 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 346 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 347
 348 case_bottom_z = epp2o[1] - case_th_bottom;
 349
 350 // button profile
 351 bppM = epp4 + [0,5];
 352 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 353 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 354 bppS = [ epp1[0], bppR[1] ];
 355 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 356 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 357 bppO = [ bppN[0], bppP[1] ];
 358 bppL = lpp10 + [5,0];
 359 bppK = [ bppL[0], bppN[1] ];
 360 bppJ = [ bppN[0], bppL[1] ];
 361 bppU = [ bppJ[0], lpp12[1] ];
 362 bppV = lpp11;
 363 bppW = lpp10;
 364
 365 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 366
 367 // notification led aperture
 368
 369 nla_r0 = led_aperture/2;
 370 nla_r1 = nla_r0 + led_window_ledge;
 371 nla_r2 = nla_r1 + multicolour_gap;
 372 nla_t =
 373   led_window_style >= 3 ? initial_layer_thick :
 374   led_window_style >= 2 ? led_window_ledge : 0;
 375
 376
 377 // hinge plan
 378 hp_rn = hingescrew_nut_access_dia/2;
 379 hp_r2_min = hp_rn + lever_cover_th;
 380 hp_rs = hingescrew_shaft_dia/2;
 381 hp_r1_min = hp_rs + hingemount_th;
 382
 383 hp_r1 = max(hp_r1_min, hp_r2_min);
 384 hp_r2 = hp_r1;
 385
 386 hppU = lpp13;
 387 hppS = epp2o + [0,-1] * case_th_bottom;
 388 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 389
 390 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 391          0.5 * (hppU + hppS)[1] ];
 392 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 393 hppB = hppT + [0,-1] * hp_k;
 394
 395 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 396 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 397 hppE = [ hppE_x, hppE_y ];
 398
 399 // hinge elevation x coords
 400
 401 hex20 = max(epp2o[0],
 402             phone_cnr_rad,
 403             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 404 hex21 = hex20 + hingemount_wd;
 405 hex22 = hex21 + hinge_x_gap;
 406 hex27 = hex20 + hingescrew_shaft_len;
 407 hex24 = hex27 + hinge_x_postscrew_gap;
 408 hex23 = hex27 - (hingescrew_nut_thick*2
 409                  + hingescrew_fasteners_extra_thick);
 410 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 411
 412 echo(hex20, hex21, hex22, hex23, hex24);
 413 //  6, 10.8725, 10.9975, 13.74, 18.75
 414 module chk(act,exp) {
 415   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 416   else echo("ok", act);
 417 }
 418 chk(hex20, 6);
 419 chk(hex21, 10.8725);
 420 chk(hex22, 10.9975);
 421 chk(hex23, 13.74);
 422 chk(hex24, 18.75);
 423
 424 lid_fold_clearance_skew =
 425   (lpp10[1] - hppB[1]) /
 426   (lpp10[0] - hppB[0]);
 427
 428 echo("SK",lid_fold_clearance_skew);
 429
 430 // catch
 431
 432 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 433 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 434 cppB = [ epp0[0], cppA[1] ];
 435 cppP = [ epp4[0], cppJ[1] ];
 436
 437 cppS = cppJ + [0,-1] * catch_len;
 438 cppD = [ cppA[0], cppS[1] + catch_slop ];
 439 cppC = [ cppB[0], cppD[1] ];
 440 cppT = cppS + [1, -catch_catch_slope] * catch_depth;
 441 cppU = cppT + [0,-1] * catch_height;
 442 cppV = [ cppS[0], cppU[1] - catch_depth ];
 443
 444 cppR = 0.5*(cppP + cppJ);
 445
 446 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 447 cppQ = [ cppR[0],
 448          cppV[1] - (catch_finger_height - cp_rQ) ];
 449 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 450
 451 // lanyard
 452
 453 ly_r = lanyard_half_dia / 2;
 454 ly_rc = ly_r * 2;
 455
 456 ly_theta = -atan2vector(epp2i - epp1);
 457 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 458
 459 max_case_bottom_edge_thickness =
 460   case_th_bottom
 461   + sin(ly_theta) * (epp2i-epp2o)[0];
 462
 463 ly_q_z = -(ly_rc + ly_r);
 464 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 465
 466 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 467
 468 // prop recess in case
 469
 470 prop_x_pos = phone_width/2;
 471
 472 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 473
 474 prc_r1 = prop_end_dia/2;
 475 prc_r3 = prc_r1 + prop_recess_slop;
 476
 477 prcp2 = [ epp4[0] + prop_buildout_less,
 478           case_bottom_z ];
 479
 480 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 481
 482 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 483           epp2i[1] - prc_r3 - prop_recess_under];
 484
 485 // prop recess in lid
 486
 487 prl_r10 = prop_end_dia/2;
 488 prl_r10o = prl_r10 + prop_recess_slop;
 489
 490 prlp10 = lpp10 + [1,1] * prl_r10o
 491   + [1,0] * prop_lidrecess_behind
 492   + [0,1] * prop_recess_under;
 493
 494 // prop
 495
 496 $prpp10 = [0,0];
 497 $prpp11 = [0, prop_taper_len];
 498
 499 $prp_r10 = prl_r10;
 500
 501 // ---------- modules ----------
 502
 503 module AdhocMultiprintFrame(phase, z0, zs) {
 504   // from z0 to z0 + zs*layer
 505   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 506   xextra = extra + -epp4[0];
 507   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 508   yextra = extra + -epp4[0];
 509   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 510   p0 = [ xrange[0], yrange[0] ];
 511   p1 = [ xrange[1], yrange[1] ];
 512   echo(p0, p1);
 513   translate([0,0, z0])
 514     mirror([0,0, zs<0 ? 1 : 0])
 515     linear_extrude(height= initial_layer_thick)
 516     difference(){
 517       rectfromto(p0 - [1,1] * initial_layer_width,
 518                  p1 + [1,1] * initial_layer_width);
 519       rectfromto(p0, p1);
 520     }
 521 }
 522
 523 module KeeperProfile(slant=0){
 524   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 525   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 526 }
 527
 528 module EdgeProfile(){
 529   difference(){
 530     hull(){
 531       translate(epp3) square(case_th_bottom*2, center=true);
 532       circleat(epp2o, r=case_th_bottom);
 533       circleat(epp1, r=case_th_side);
 534       rectfromto(epp0, epp4);
 535     }
 536     polygon([ epp5 + [0,10],
 537               epp1,
 538               epp2i,
 539               epp3 + [10,0] ]);
 540   }
 541 }
 542
 543 module LanyardLanyardProfile(entry=false){
 544   hull(){
 545     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 546       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 547         circle(r= lanyard_half_dia/2);
 548   }
 549 }
 550
 551 module LanyardCurveChannelProfile(){
 552   translate([0, -ly_r])
 553     LanyardLanyardProfile();
 554 }
 555
 556 module LanyardEntryChannelProfile(){
 557   LanyardLanyardProfile(true);
 558 }
 559
 560 module LanyardMainChannelProfile(){
 561   LanyardCurveChannelProfile();
 562   difference(){
 563     square(center=true, ly_r * [6, 2]);
 564     for (xs=[-1,+1])
 565       translate(ly_r * [3 * xs, -1])
 566         circle(r = ly_r);
 567   }
 568 }
 569
 570 module LanyardEntryOuterProfile(){
 571   circleat([ly_re + ly_r, 0], ly_re);
 572 }
 573
 574 module LanyardEntry(){
 575   q_z = ly_q_z;
 576   oec_y = ly_oec_y;
 577
 578   d_x = -ly_rc;
 579
 580   translate([d_x, 0, q_z]) {
 581     intersection(){
 582       rotate([90,0,0])
 583         rotate_extrude(convexity=10)
 584         rotate(90)
 585         translate([0, -q_z])
 586         LanyardCurveChannelProfile();
 587       translate([0,-10,0])
 588         cube([20,20,20]);
 589     }
 590   }
 591
 592   mirror([0,0,1])
 593     translate([0,0,-1])
 594     linear_extrude(height=20)
 595     rotate(-90)
 596     LanyardEntryChannelProfile();
 597
 598   translate([0, ly_r*2, 0])
 599     rotate([90,0,0])
 600     linear_extrude(height = ly_r*4){
 601     difference(){
 602       rectfromto([d_x, q_z], [ly_r, 0]);
 603       circleat([d_x, q_z], ly_rc);
 604     }
 605   }
 606
 607   translate([0,0,q_z]){
 608     for (my=[0,1])
 609       mirror([0,my,0]){
 610         translate([0, oec_y, 0]){
 611           difference(){
 612             translate(ly_re * [-1,0,-2])
 613               cube(ly_re * [2,1,2]);
 614             rotate_extrude(convexity=10)
 615               LanyardEntryOuterProfile();
 616           }
 617         }
 618       }
 619     difference(){
 620       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 621         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 622       for (mx=[0,1])
 623         mirror([mx,0,0])
 624           rotate([90,0,0])
 625           translate([0,0,-10])
 626           linear_extrude(height=20)
 627           LanyardEntryOuterProfile();
 628     }
 629   }
 630 }
 631
 632 module LanyardCutout(l){
 633   rotate([0,-90,0])
 634     linear_extrude(height=l)
 635     rotate(-90)
 636     LanyardMainChannelProfile();
 637
 638   for (ee=[0,1]){
 639     translate(ee * l * [-1,0])
 640       mirror([ee,0,0])
 641       LanyardEntry();
 642   }
 643 }
 644
 645 module LidEdgeProfile(){
 646   polygon([ lpp10,
 647             lpp11,
 648             lpp12,
 649             lpp13,
 650             lpp13 + [10, 0],
 651             lpp15 + [10, 0],
 652             lpp15,
 653             lpp14,
 654             ]);
 655   intersection(){
 656     circleat(lpp12, r=lp_r12);
 657     rectfromto( lpp12 + [-10,   0],
 658                 lpp12 + [+10, +10] );
 659   }
 660 }
 661
 662 module LidEdgeFoldClearanceProfile(){
 663   translate([-lid_fold_clearance_antislop, 0])
 664     polygon([ lpp10,
 665               lpp11,
 666               lpp11 + [-20,  0],
 667               lpp11 + [-20, 20],
 668               lpp11 + [+20, 20],
 669               lpp10 + [+20,  0] ]);
 670 }
 671
 672 module ButtonCoverProfile(){
 673   intersection(){
 674     polygon(concat([ bppM, bppP, bppO, bppJ ],
 675                    (enable_support && !$button_suppress_over_keeper
 676                     ? [ bppU, bppV, bppW ] : []),
 677                    [ bppL, bppK ]));
 678     hull(){
 679       EdgeProfile();
 680       LidEdgeProfile();
 681     }
 682   }
 683 }
 684
 685 module ButtonPlan(l, deep, cut){
 686   epsilon =
 687     (cut  ? 0 : lid_buttoncover_gap);
 688
 689   delta =
 690     (deep ? lid_buttoncover_overlap : 0);
 691
 692   C = [0,0]; // by definition
 693   T = [ 0, epp4[1] ];
 694   G = T + [0,10];
 695
 696   B0 = C + [0,-1] * button_cutout_depth;
 697   B1 = B0 + [0,1] * epsilon;
 698
 699   r0 = 0.5 * (T[1] - B0[1]);
 700   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 701   H = A + [0,-1] * delta;
 702
 703   D = A + [-2,0] * r0;
 704   F = D + [0,10];
 705
 706   E0 = 0.5 * (D + A);
 707   E1 = E0 + [1,0] * epsilon;
 708
 709   I0 = [ E0[0], H[1] ];
 710   I1 = [ E1[0], H[1] ];
 711
 712   hull(){
 713     for (m=[0,1]) mirror([m,0])
 714       circleat(H, r0 - epsilon);
 715   }
 716   for (m=[0,1]) mirror([m,0]) {
 717     difference(){
 718       polygon([ E1,
 719                 I1,
 720                 H,
 721                 B1,
 722                 G,
 723                 F,
 724                 D
 725                 ]);
 726       circleat(D, r0 + epsilon);
 727     }
 728   }
 729 }
 730
 731 module ButtonCoverReinf(){ ////toplevel
 732   minkowski(){
 733     rotate([90,0,0])
 734       linear_extrude(height=0.01)
 735       ButtonCoverProfile();
 736     if(0) linear_extrude(height=0.01) intersection(){
 737       circle(r=2);
 738       translate([-20,0]) square(40, center=true);
 739     }
 740   }
 741 }
 742
 743 module CatchCatchProfile(){
 744   hull(){
 745     for (c=[ cppR, cppQ ])
 746       circleat(c, cp_rQ);
 747   }
 748   hull(){
 749     circleat(lpp12, lp_r12);
 750     circleat(lpp12 + [5,0], lp_r12);
 751     rectfromto(cppP, cppP + [5,0.1]);
 752   }
 753   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 754 }
 755
 756 module CatchCutProfile(){
 757   polygon([ cppB,
 758             cppA,
 759             cppD,
 760             cppF,
 761             cppF + [0,-10],
 762             cppF + [-10,-10],
 763             lpp12 + [-10,0],
 764             lpp12 + [10,0]
 765             ]);
 766 }
 767
 768 module Flip_rhs(yn=[0,1]) {
 769   for ($rhsflip=yn) {
 770     translate([phone_width/2, 0, 0])
 771       mirror([$rhsflip,0,0])
 772       translate([-phone_width/2, 0, 0])
 773       children();
 774   }
 775 }
 776
 777 module Flip_bot(yn=[0,1]) {
 778   for ($botflip=yn) {
 779     translate([0, -phone_height/2, 0])
 780       mirror([0, $botflip, 0])
 781       translate([0, phone_height/2, 0])
 782       children();
 783   }
 784 }
 785
 786 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 787   // sides
 788   Flip_rhs(){
 789     translate([0, -phone_cnr_rad, 0])
 790       rotate([90,0,0])
 791       linear_extrude(height = phone_height - phone_cnr_rad*2)
 792       children(0);
 793   }
 794   // corners
 795   Flip_rhs() Flip_bot() {
 796     translate([+1,-1] * phone_cnr_rad)
 797       intersection(){
 798         rotate_extrude()
 799           intersection(){
 800             mirror([1,0,0])
 801               translate([-1,0] * phone_cnr_rad)
 802               children(0);
 803             rectfromto([0,-20],[10,20]);
 804           }
 805         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 806           cube([10,10,40]);
 807       }
 808   }
 809   // top and bottom
 810   Flip_bot(){
 811     translate([ phone_width - phone_cnr_rad, 0,0 ])
 812       rotate([90,0,-90])
 813       linear_extrude(height = phone_width - phone_cnr_rad*2)
 814       children(0);
 815   }
 816   // fill
 817   translate([0,0, fill_zstart])
 818     mirror([0,0, fill_downwards])
 819     linear_extrude(height = fill_th)
 820     rectfromto([+1,-1] * phone_cnr_rad,
 821                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 822 }
 823
 824 module CaseAperture(pos, dia, $fn) {
 825   theta = 180/$fn;
 826   translate([ pos[0] + bumper[0],
 827               -epp2i[0],
 828               -pos[1] ])
 829     rotate([-90, theta, 0])
 830     cylinder(r = dia/2 / cos(theta),
 831              h = 60);
 832 }
 833
 834 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 835   // y_ref_sign:
 836   //   +1  measured from top    of actual phone to top    of button
 837   //   -1  measured from bottom of actual phone to bottom of button
 838   //    0  y is centre of button in coordinate system
 839   $button_l= l;
 840   $button_suppress_over_keeper= suppress_over_keeper;
 841   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 842           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 843           y;
 844   //echo(eff_y);
 845   translate([0, eff_y, 0])
 846     children();
 847 }
 848
 849 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 850   $button_leg_only = true;
 851   SideButton(y, y_ref_sign, l) children();
 852 }
 853
 854 module Buttons(){
 855   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 856   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 857   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 858   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 859 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 860 }
 861
 862 module Struts(x_start, z_min, th){
 863   // if th is negative, starts at z_min and works towards -ve z
 864   // and object should then be printed other way up
 865   for (i= [1 : 1 : case_struts_count]) {
 866     translate([0,
 867                0,
 868                z_min])
 869       mirror([0,0, th<0 ? 1 : 0])
 870       translate([0,
 871                  -phone_height * i / (case_struts_count+1),
 872                  case_struts_solid_below])
 873       linear_extrude(height= abs(th)
 874                      -(case_struts_solid_below+case_struts_solid_above))
 875       rectfromto([               x_start, -0.5 * case_struts_width ],
 876                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 877   }
 878 }
 879
 880 module OrdinaryRearAperture(rhs,bot, pos){
 881   Flip_rhs(rhs) Flip_bot(bot)
 882     linextr(-20, 20)
 883     mirror([0,1])
 884     translate(pos + bumper)
 885     children();
 886 }
 887
 888 module MicroUSB(){
 889   Flip_bot(1){
 890     rotate([90,0,0])
 891       mirror([0,0,1])
 892       linextr(-epp2i[0], 60)
 893       translate([0.5 * phone_width, 0, 0])
 894       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 895                  [+microusb_width/2, epp0[1] + -microusb_above]);
 896   }
 897 }
 898
 899 module OrdinaryRearApertures(){
 900   // rear speaker
 901   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 902     rectfromto(-rearspeaker_gap,
 903                rearspeaker_size + rearspeaker_gap);
 904
 905   // finger hole to remove phone
 906   if (len(fingerpushhole_dias))
 907     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 908                                 phone[1]/2 ])
 909     scale(fingerpushhole_dias)
 910     circle(r= 0.5 );
 911 }
 912
 913 module RearCameraAperture(){
 914   Flip_rhs(1)
 915     mirror([0, 0, 1])
 916     linear_extrude(height = 20)
 917     mirror([0, 1, 0])
 918     translate(bumper)
 919     rectfromto(camera_pos_tl, camera_pos_br);
 920 }
 921
 922 module HingeLidProfile(){
 923   hull(){
 924     circleat(hppT, hp_r1);
 925     circleat(lpp12, lp_r12);
 926     polygon([lpp10,
 927              lpp13 + [2,0],
 928              lpp12,
 929              hppT]);
 930   }
 931 }
 932
 933 module HingeBaseProfile(){
 934   difference(){
 935     hull(){
 936       circleat(hppB, hp_r1);
 937       circleat(hppE, hp_r1);
 938       circleat(epp2o, case_th_bottom);
 939       circleat(hppB + [10,0], hp_r1);
 940     }
 941     polygon([epp5, epp1, epp2i, epp3, bppL]);
 942   }
 943 }
 944
 945 module HingeLeverOuterProfile(){
 946   hull(){
 947     circleat(hppT, hp_r2);
 948     circleat(hppB, hp_r2);
 949   }
 950 }
 951
 952 module HingeLeverInnerProfile(){
 953   for (s = [-1,+1]) {
 954     c = s > 0 ? hppT : hppB;
 955     translate(c)
 956       mirror([0,0,s>0])
 957       rotate(s<0 ? -40 : 0)
 958       hull()
 959       for (x=[-20,20])
 960         for (y=[0, s * 10])
 961           translate([x,y])
 962             circle(hp_rn);
 963   }
 964 }
 965
 966 module HingeLeverNutProfile(){
 967   for (c= [hppB, hppT]) {
 968     translate(c)
 969       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 970   }
 971 }
 972
 973 module Flip_hinge(doflip=1){
 974   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 975   translate(hinge_origin)
 976     rotate([doflip*180,0,0])
 977     translate(-hinge_origin)
 978     children();
 979 }
 980
 981 module HingePortion(x0,x1){
 982   Flip_rhs() Flip_bot(1)
 983     translate([x0,0,0])
 984     mirror([1,0,0])
 985     rotate([90,0,-90])
 986     linear_extrude(height=x1-x0)
 987     children();
 988 }
 989
 990 module CatchPortion(xwidth, ztop){
 991   width = catch_width + xwidth;
 992   w = width + catch_topcurve_r*2 + 1;
 993   translate([phone_width/2, 0,0]){
 994     difference(){
 995       rotate([90,0,-90])
 996         linextr(-w/2, w/2)
 997         children(0);
 998       translate([0, 50, 0])
 999         rotate([90,0,0])
1000         linear_extrude(height=100){
1001         for (m=[0,1]) mirror([m,0,0]) {
1002           hull(){
1003             translate([w/2, ztop - catch_topcurve_r])
1004               circle(catch_topcurve_r);
1005             translate([w/2, -50])
1006               square(catch_topcurve_r*2, center=true);
1007           }
1008         }
1009       }
1010     }
1011   }
1012 }
1013
1014 module CaseBase(){
1015   AroundEdges(epp3[1], case_th_bottom, 1)
1016     EdgeProfile();
1017 }
1018
1019 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1020
1021 module PropProfileAssignments(gamma){
1022   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1023   x = prop_x(gamma);
1024   p = phone_height + prlp10[0] - hppB[0];
1025   b = p + x;
1026
1027   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1028   a = q + x;
1029   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1030   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1031
1032   $prp_theta = 90 - $prp_alpha;
1033   beta = 180 - $prp_alpha - gamma;
1034   psi = 90 - beta;
1035
1036   //echo("abc", a,b,c);
1037
1038   v1 = [ [ cos(psi), -sin(psi) ],    // x
1039          [ sin(psi),  cos(psi) ] ];  // y
1040
1041   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1042
1043   $prp_r1 = prc_r1;
1044   $prp_r11 = prop_main_th/2;
1045
1046   $prpp1 = $prpp7 + [1,0] *
1047     // this is approximate, but will do
1048     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1049   $prpp3 = $prpp1 +
1050     v1[0] * -$prp_r1 +
1051     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1052   $prpp12 = $prpp3 + v1[0] *
1053     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1054   $prp_r8 = prop_main_th;
1055   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1056   $prp_r5 = $prp_r8;
1057   $prpp5 = [ $prpp12[0] - $prp_r5,
1058             $prpp3[1] - prop_prong_h + $prp_r5 ];
1059   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1060          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1061   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1062   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1063
1064   children();
1065 }
1066
1067 module PropProfile(gamma, cut=0, rot=0){
1068   PropProfileAssignments(gamma){
1069
1070     //#circleat($prpp3,1);
1071     //#circleat($prpp12,1);
1072
1073     if (!cut) {
1074       hull(){
1075         translate($prpp8)
1076           intersection(){
1077             circle($prp_r8);
1078             polygon([[-20,-0], [20,20], [0,0]]);
1079           }
1080         rectfromto($prpp6, $prpp9);
1081         translate($prpp5) intersection(){
1082           circle($prp_r5);
1083           polygon([[-10,-10], [0,0], [10,0]]);
1084         }
1085         rectfromto($prpp12 + [0,-0.1], $prpp3);
1086       }
1087       hull(){
1088         circleat($prpp1, $prp_r1);
1089         rectfromto($prpp12 + [0,-0.1], $prpp3);
1090       }
1091     }
1092     // main shaft
1093     rotate([0,0, rot*-$prp_theta]){
1094       hull(){
1095         extra = cut ? prop_recess_slop : 0;
1096         rectfromto($prpp6, $prpp9);
1097         circleat($prpp11, $prp_r11 + extra);
1098         circleat($prpp10, $prp_r10 + extra);
1099       }
1100     }
1101   }
1102 }
1103
1104 module PropAggregateProfile(){
1105   for (angle = prop_angles)
1106     PropProfile(angle, 0,0);
1107 }
1108
1109 module Prop(){ ////toplevel
1110   hw = prop_main_width/2;
1111   linextr(-hw, +hw)
1112     PropAggregateProfile();
1113 }
1114
1115 module Case(){ ////toplevel
1116   difference(){
1117     union(){
1118       CaseBase();
1119
1120       // ledge (fixed keeper)
1121       Flip_rhs(1-keeper_side) intersection(){
1122         rotate([90, 0, 0])
1123           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1124           KeeperProfile(1);
1125
1126         // outline of the whole case, to stop it protruding
1127         translate([0,0, -25])
1128           linear_extrude(height = 50)
1129           hull()
1130           Flip_bot()
1131           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1132       }
1133
1134       // hinge
1135       HingePortion(hex20, hex21) HingeBaseProfile();
1136
1137       // buildout for prop recess
1138       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1139         linextr(case_bottom_z, epp2i[1])
1140         hull() {
1141           for (dxs = [-1,+1])
1142             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1143                        -epp2o[0] ],
1144                      r = epp2o[0] - prcp2[0]);
1145         }
1146     }
1147
1148     // slot for keeper
1149     Flip_rhs(keeper_side)
1150       translate([0, -phone_cnr_rad, 0])
1151       rotate([90, 0, 0])
1152       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1153       minkowski(){
1154         KeeperProfile();
1155         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1156                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1157       }
1158
1159     // front camera
1160     RearCameraAperture();
1161
1162     // struts (invisible, because they're buried in the case)
1163     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1164
1165     Buttons(){
1166       mirror([1,0,0])
1167         rotate([90,0,90]) {
1168           if (!($button_leg_only && enable_support))
1169           intersection(){
1170             translate([0,0,-10])
1171               linear_extrude(height= 20)
1172               ButtonPlan($button_l, 0,1);
1173             if ($button_leg_only)
1174               rotate([-90,90,0])
1175                 translate([phone_width/2, -400, kppe[1]])
1176                 mirror([1-abs($rhsflip - keeper_side),0,0])
1177                 cube([400, 800, 50]);
1178             if (enable_support && !$button_suppress_over_keeper)
1179               rotate([-90,90,0])
1180               translate([-400, -400, kppd[1]])
1181                 mirror([0,0,1])
1182                 cube([800,800,100]);
1183           }
1184           translate([0,0, -bppR[0]])
1185             linear_extrude(height= 20)
1186             ButtonPlan($button_l, 1,1);
1187         }
1188
1189     }
1190
1191     // apertures along top edge
1192     CaseAperture(jack_pos, jack_dia, 8);
1193     Flip_rhs(1)
1194       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1195
1196     OrdinaryRearApertures();
1197
1198     MicroUSB();
1199
1200     // gaps for the lid's hinge arms
1201     HingePortion(hex20 - hinge_x_arms_gap,
1202                  hex21 + hinge_x_arms_gap)
1203       minkowski(){
1204         HingeLidProfile();
1205         circle(r= hinge_r_arms_gap, $fn= 8);
1206       }
1207
1208     // screw holes in the hinge arms
1209     HingeScrews();
1210
1211     // catch striker
1212     CatchPortion(catch_side_gap*2, epp4[1])
1213       CatchCutProfile();
1214
1215     // lanyard
1216     Flip_bot(1)
1217       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1218       rotate([0, ly_theta, 0])
1219       rotate([0,0,90])
1220       LanyardCutout(lanyard_channel_len);
1221
1222     // prop recess
1223     Flip_rhs(1)
1224       translate([prop_x_pos,0,0])
1225       mirror([0,1,0])
1226       rotate([90,0,90])
1227       linextr(-prop_recess_hw, +prop_recess_hw)
1228       hull(){
1229         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1230           circleat(prcp1 + 20*d,
1231                    prc_r3);
1232       }
1233   }
1234 }
1235
1236 module LidAdhocMultiprintFrame(phase){
1237   if (led_window_style >= 3) {
1238     AdhocMultiprintFrame(phase, lpp13[1], -1);
1239   }
1240 }
1241
1242 module LidAroundEdges(){
1243   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1244     children();
1245 }
1246
1247 module Lid(){ ////toplevel
1248   skew_centre = [0, lpp11[0], lpp11[1]];
1249   difference(){
1250     union(){
1251       intersection(){
1252         LidAroundEdges()
1253           LidEdgeProfile();
1254
1255         translate(skew_centre)
1256           multmatrix([[ 1, 0, 0, 0 ],
1257                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1258                       [ 0, 0, 1, 0 ],
1259                       [ 0, 0, 0, 1 ]])
1260           translate(-skew_centre)
1261           LidAroundEdges()
1262           LidEdgeFoldClearanceProfile();
1263       }
1264
1265       // button covers
1266       Buttons(){
1267         intersection(){
1268           rotate([90,0,90])
1269             translate([0,0,-10])
1270             linear_extrude(height= 20)
1271             ButtonPlan($button_l, 1,0);
1272           rotate([90,0,0])
1273              translate([0,0,-100])
1274             linear_extrude(height= 200)
1275             ButtonCoverProfile();
1276         }
1277       }
1278
1279       // hinge arms
1280       HingePortion(hex20, hex21) {
1281         LidEdgeProfile();
1282         HingeLidProfile();
1283       }
1284
1285       // catch
1286       CatchPortion(0, lpp12[1])
1287         CatchCatchProfile();
1288     }
1289     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1290
1291     // screw holes in the hinge arms
1292     HingeScrews();
1293
1294     // prop recess
1295     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1296       mirror([0,1,0])
1297       rotate([90,0,90])
1298       linextr(-prop_recess_hw, +prop_recess_hw)
1299       hull()
1300       for (pa = prop_angles)
1301         PropProfile(pa, 1,1);
1302
1303     // notification led aperture
1304     if (led_window_style)
1305       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1306         translate([0,0,-10])
1307           cylinder(r=nla_r0, h=20);
1308         if (led_window_style >= 2)
1309           translate([0,0, -nla_t])
1310             cylinder(r=nla_r2, height=20);
1311       }
1312
1313     }
1314
1315   LidAdhocMultiprintFrame(1);
1316 }
1317
1318 module HingeLever(){ ////toplevel
1319   difference() {
1320     // outer body, positive
1321     HingePortion(hex22, hex22 + phone_width/2)
1322       HingeLeverOuterProfile();
1323
1324     // space for the screws
1325     HingePortion(hex26, hex24)
1326       HingeLeverInnerProfile();
1327
1328     // recesses for the nuts
1329     HingePortion(hex23, hex26+1)
1330       HingeLeverNutProfile();
1331
1332     // bores for the screws
1333     HingeScrews();
1334
1335     // space for the charging cable
1336     MicroUSB();
1337     Flip_hinge() MicroUSB();
1338   }
1339 }
1340
1341 module LidWindow(){ ////toplevel
1342   translate([led_pos[0], -led_pos[1], lpp13[1]])
1343     mirror([0,0,1])
1344     cylinder(r= nla_r1, h=nla_t);
1345   LidAdhocMultiprintFrame(0);
1346 }
1347
1348 module LidWindowPrint(){ ////toplevel
1349   rotate([0,180,0])
1350     LidWindow();
1351 }
1352
1353 module DemoLidWindowSelect(){
1354   translate([led_pos[0], led_pos[1], -100]) {
1355     translate([0, -30, 0]) cube([400, 400, 200]);
1356   }
1357 }
1358
1359 module DemoLidWindow(){ ////toplevel
1360   %Lid();
1361   LidWindow();
1362   translate([0,40,0]){
1363     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1364     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1365   }
1366 }
1367
1368 module HingeLeverPrint(){ ////toplevel
1369   rotate([-90,0,0])
1370     translate([-phone_width/2, phone_height, 0])
1371     HingeLever();
1372 }
1373
1374 module TestSelectLength(){
1375   translate([-30, -200, -20])
1376     cube([30 + 15, 250, 40]);
1377 }
1378
1379 module TestLength(){ ////toplevel
1380   intersection(){
1381     Case();
1382     TestSelectLength();
1383   }
1384 }
1385
1386 module TestLengthRight(){ ////toplevel
1387   intersection(){
1388     Case();
1389     Flip_rhs(1)
1390       TestSelectLength();
1391   }
1392 }
1393
1394 module TestSelectWidth(){
1395   translate([-30, -(phone_height - 25), -20])
1396     mirror([0, 1, 0])
1397     cube([200, 50, 40]);
1398 }
1399
1400 module TestWidth(){ ////toplevel
1401   intersection(){
1402     Case();
1403     TestSelectWidth();
1404   }
1405 }
1406
1407 module TestLidWidthPrint(){ ////toplevel
1408   rotate([0,180.0]) intersection(){
1409     Lid();
1410     TestSelectWidth();
1411   }
1412 }
1413
1414 module TestSelectRearAperture(){
1415   minkowski(){
1416     union() children();
1417     translate([20, 0,0])
1418       cube([42, 2, 1], center=true);
1419   }
1420 }
1421
1422 module TestSelectCamera(){
1423   minkowski(){
1424     TestSelectRearAperture()
1425       RearCameraAperture();
1426     cube([0.1, 50, 0.1]);
1427   }
1428 }
1429
1430 module TestSelectOrdinaryRearApertures(){
1431   TestSelectRearAperture()
1432     OrdinaryRearApertures();
1433 }
1434
1435 module TestCamera(){ ////toplevel
1436   intersection(){
1437     Case();
1438     TestSelectCamera();
1439   }
1440 }
1441
1442 module TestLidByCamera(){ ////toplevel
1443   intersection(){
1444     Lid();
1445     TestSelectCamera();
1446   }
1447 }
1448
1449 module TestLidByCameraPrint(){ ////toplevel
1450   rotate([180,0,0]) TestLidByCamera();
1451 }
1452
1453 module DemoByCamera(){ ////toplevel
1454   color("blue") TestLidByCamera();
1455   color("red")  TestCamera();
1456 }
1457
1458 module OneKeeper(){ ////toplevel
1459   translate([0, -phone_cnr_rad, 0])
1460     rotate([90, 0, 0])
1461     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1462     KeeperProfile();
1463 }
1464
1465 module OneKeeperPrint(){ ////toplevel
1466   rotate([0,180,0])
1467     OneKeeper();
1468 }
1469
1470 module LidPrint(){ ////toplevel
1471   rotate([0,180,0])
1472     Lid();
1473 }
1474
1475 module TestSelectFrame(){
1476   include = [1,-1] * (epp2i[0] + 4);
1477
1478   difference(){
1479     cube(1000, center=true);
1480     translate([0,0, -100])
1481       linear_extrude(height=200)
1482       rectfromto(include,  inside_br - include);
1483   }
1484 }
1485
1486 module TestSelectLidFrame(){
1487   TestSelectFrame();
1488   translate([led_pos[0], -led_pos[1], -50])
1489     cylinder(r= nla_r2+3, h=100);
1490 }
1491
1492 module TestFrameCase(){ ////toplevel
1493   intersection(){
1494     Case();
1495     union(){
1496       TestSelectFrame();
1497       TestSelectCamera();
1498       TestSelectOrdinaryRearApertures();
1499     }
1500   }
1501 }
1502
1503 module TestSelectTopApertures(){
1504   translate([-100, -35, -100])
1505     cube([400, 100, 200]);
1506   LidAdhocMultiprintFrame(0);
1507   LidAdhocMultiprintFrame(1);
1508 }
1509
1510 module TestTopApertures(){ ////toplevel
1511   intersection(){
1512     Case();
1513     TestSelectFrame();
1514     TestSelectTopApertures();
1515   }
1516 }
1517
1518 module TestLidTopAperturesPrint(){ ////toplevel
1519   rotate([0,180,0]) intersection(){
1520     Lid();
1521     TestSelectLidFrame();
1522     TestSelectTopApertures();
1523   }
1524 }
1525
1526 module TestLidWindowTopAperturesPrint(){ ////toplevel
1527   rotate([0,180,0]) intersection(){
1528     LidWindow();
1529     TestSelectTopApertures();
1530   }
1531 }
1532
1533 module TestFrameLidPrint(){ ////toplevel
1534   rotate([0,180,0]) intersection(){
1535     Lid();
1536     TestSelectLidFrame();
1537   }
1538 }
1539
1540 module ButtonPlanForDemo(z, deep, cut){
1541   translate([0,0,z])
1542     ButtonPlan(8, deep, cut);
1543 }
1544
1545 module HingeScrews(){
1546   Flip_rhs() Flip_bot(1){
1547     for (c= [ hppT, hppB ])
1548       translate([ hex20,
1549                   -c[0],
1550                   c[1] ]){
1551         rotate([0,90,0])
1552           translate([0,0,-.2])
1553           cylinder( r= hingescrew_shaft_dia/2,
1554                     h = hingescrew_shaft_len+0.2 );
1555         rotate([0,-90,0])
1556           translate([0,0,+.1])
1557           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1558       }
1559   }
1560 }
1561
1562 module DemoPropAngleSelect(c){
1563   color(c) difference(){
1564     union(){ children(); }
1565     translate([ prop_x_pos, -400, -200 ])
1566       cube([ 400,800,400 ]);
1567   }
1568 }
1569
1570 module DemoPropAngle(ang){
1571   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1572   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1573
1574   translate(hL)
1575     rotate([ang/2,0,0])
1576     translate(-hL)
1577     translate(hC)
1578     rotate([ang/2,0,0])
1579     translate(-hC) {
1580       DemoPropAngleSelect("red") Case();
1581
1582       color("orange")
1583         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1584         PropProfileAssignments(ang) {
1585           echo($prpp1);
1586           rotate([-$prp_theta, 0, 0])
1587           translate([0, $prpp1[0], -$prpp1[1]])
1588           rotate([90,0,-90])
1589           Prop();
1590         }
1591     }
1592
1593   translate([0,0, -hp_k*2])
1594     DemoPropAngleSelect("blue")
1595     Lid();
1596 }
1597
1598 module DemoPropAngles(){ ////toplevel
1599   for (i=[0 : len(prop_angles)-1])
1600     translate(i * [0, -100, 100])
1601     DemoPropAngle(prop_angles[i]);
1602 }
1603
1604 module DemoHingeAngle(ang1,ang2){
1605   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1606   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1607
1608   translate(hL)
1609     rotate([ang2,0,0])
1610     translate(-hL)
1611     translate(hC)
1612     rotate([ang1,0,0])
1613     translate(-hC) {
1614       color("red") Lid();
1615     }
1616
1617   color("blue") intersection(){
1618     Case();
1619     union(){
1620       translate([bppJ[0], -400, -200])
1621         mirror([1,0,0])
1622         cube([400, 800, 400]);
1623       translate([10, -400, -200])
1624         cube([10, 800, 400]);
1625     }
1626   }
1627 }
1628
1629 module DemoHingeAngles(){ ////toplevel
1630   angles = [ 0, 4, 8, 12 ];
1631   echo("angles",angles);
1632   for (i=[0 : len(angles)-1]) {
1633     translate(i * [0, 0, 30]) {
1634       DemoHingeAngle(0,angles[i]);
1635       translate([0, 200, 0])
1636         DemoHingeAngle(angles[i],0);
1637     }
1638   }
1639 }
1640
1641 module DemoSelectAdhocLeftRight(right=0) {
1642   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1643     mirror([1-right, 0,0])
1644     cube([400, 800, 200]);
1645 }
1646
1647 module DemoLeft(){ ////toplevel
1648   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1649   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1650 }
1651
1652 module DemoFrame(){ ////toplevel
1653   color("red") TestFrameCase();
1654   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1655   color("black") HingeScrews();
1656   %HingeLever();
1657 }
1658
1659 module DemoLanyardCutout(){ ////toplevel
1660   LanyardCutout(25);
1661 }
1662
1663 module DemoHingedFrame(){ ///toplevel
1664   color("red") TestFrameCase();
1665   translate([0,0, -2*hp_k])
1666   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1667
1668   Flip_hinge(){
1669     color("orange") HingeLever();
1670     color("black") HingeScrews();
1671   }
1672 }
1673
1674 module DemoHinge(){ ////toplevel
1675   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1676     DemoFrame();
1677     translate([0,0, -hp_k*3])
1678       DemoHingedFrame();
1679   }
1680 }
1681
1682 module DemoProfiles(){ ////toplevel
1683   LidEdgeProfile();
1684   %EdgeProfile();
1685   KeeperProfile();
1686   translate([0,0,-1]) color("black") KeeperProfile(1);
1687   translate(ly_o){
1688     rotate(-ly_theta){
1689       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1690       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1691       translate([0, ly_q_z]){
1692         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1693         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1694       }
1695     }
1696   }
1697   translate([0,0,-5]) color("white") translate(epp2i)
1698     rotate(-ly_theta)
1699     rectfromto([-15, 0],
1700                [+15, -max_case_bottom_edge_thickness]);
1701
1702   translate([0,20]) {
1703     LanyardMainChannelProfile();
1704     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1705     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1706   }
1707
1708   translate([20,0]) {
1709     LidEdgeProfile();
1710     %EdgeProfile();
1711
1712     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1713
1714     color("blue") ButtonCoverProfile();
1715     color("red") {
1716       rectfromto(bppQ, demopoint_QR);
1717       rectfromto(bppR, demopoint_QR);
1718     }
1719   }
1720
1721   translate([-20,0]) {
1722     color("black") ButtonPlanForDemo(-2, 0,1);
1723     color("red" )  ButtonPlanForDemo(-4, 1,1);
1724     color("blue")  ButtonPlanForDemo(-6, 1,0);
1725   }
1726
1727   translate([0, -30]) {
1728     %LidEdgeProfile();
1729     %EdgeProfile();
1730     color("blue") HingeLidProfile();
1731     color("red")  HingeBaseProfile();
1732     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1733   }
1734
1735   for (f=[0,1]) {
1736     translate([-30, -60 + 30*f]) {
1737       translate([0,0,-4]) EdgeProfile();
1738       %translate([0,0,-10]) HingeBaseProfile();
1739       translate([0,-2] * f * hp_k) {
1740         translate([0,0,-4]) LidEdgeProfile();
1741         %translate([0,0,-10]) %HingeLidProfile();
1742       }
1743       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1744         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1745         translate([0,0,0]) color("red") difference(){
1746           HingeLeverOuterProfile();
1747           HingeLeverInnerProfile();
1748         }
1749         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1750       }
1751     }
1752   }
1753
1754   translate([20,-30]) {
1755     %EdgeProfile();
1756     %LidEdgeProfile();
1757     //translate([0,0,1]) CatchCutProfile();
1758     color("blue") CatchCatchProfile();
1759     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1760   }
1761
1762   translate([40,-30]) {
1763     difference(){
1764       LidEdgeProfile();
1765       translate(prlp10)
1766         PropProfile(10, 1, 0);
1767     }
1768     translate(prlp10)
1769       PropProfile(15, 0);
1770   }
1771   translate([60,-30]) {
1772     PropAggregateProfile();
1773   }
1774 }
1775
1776 //EdgeProfile();
1777 //KeeperProfile();
1778 //CaseBase();
1779 //%Case();
1780 //Keeper();
1781 //LidEdgeProfile();
1782 //KeeperProfile();
1783 //DemoProfiles();
1784 //PropRecess();