fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone = [ 75.0, 145.0 ];
   4
   5 bumper = [ 0.250, 0.250 ];
   6 // ^ One side.  Overall size is increased by twice this.
   7 // If no bumpers, is the gap around the phone.
   8
   9 phone_cnr_rad = 6.0;
  10
  11 button_cutout_depth = 9;
  12
  13 phone_edge_thick = 9.0;
  14 phone_total_thick = 12.0;
  15 phone_backside_slope_inner = 1.5; // larger means shallower
  16 phone_backside_slope_outer = 1.0; // larger means shallower
  17
  18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
  19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
  20
  21 jack_pos = [ 13.92, 7.96 ];
  22 jack_dia = 9.1 + .5; // some jack I had lying around
  23
  24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
  25 noisecancelmic_dia = 1.75;
  26
  27 fingerpushhole_dias = [ 14, 17 ];
  28
  29 rearspeaker_pos_bl = [ 14.92, 18.72 ];
  30 rearspeaker_size   = [  3.76,  7.36 ];
  31
  32 case_th_bottom = 2.5;
  33 case_th_lid = 2.5;
  34 case_th_side = 2;
  35 case_th_lip = 1.2;
  36
  37 case_struts_count = 6;
  38 case_struts_solid_below = 1.00;
  39 case_struts_solid_above = 0.75;
  40 case_struts_width = 0.10;
  41
  42 keeper_th_z = 0.75;
  43 keeper_th_x = 0.75;
  44 keeper_inner_width = 2.75;
  45 keeper_inner_height = 2.75;
  46 keeper_slant_slope = 2; // larger means steeper
  47
  48 keeper_gap_z_top = 0.25;
  49 keeper_gap_z_bot = 0.75;
  50 keeper_gap_x     = 0.25;
  51 keeper_gap_x_holes = 0.75;
  52
  53 case_lip = 1.25;
  54
  55 lid_gap_x = 0.25;
  56 lid_gap_z = 0.25;
  57 lid_lip = 1.75;
  58
  59 $fa = 5;
  60 $fs = 0.1;
  61
  62 button_l_fudge = 4.4;
  63 buttonishleg_default_l_is_fudge = 10;
  64
  65 strut_min_at_end = 1.5;
  66
  67 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
  68
  69 // ---------- calculated ----------
  70
  71 phone_width =  (phone + bumper*2)[0];
  72 phone_height = (phone + bumper*2)[1];
  73
  74 inside_br = [phone_width, -phone_height];
  75
  76 //echo(camera_pos_tl + bumper,
  77 //     camera_pos_br + bumper);
  78
  79 // ----- could be changed -----
  80 lid_buttoncover_gap = lid_gap_x;
  81 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  82
  83 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  84
  85 //lid_lip_overlap_width xxx bad name = ;
  86 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  87
  88 epp0 = [0,0];
  89 epp1 = [0, -phone_edge_thick];
  90 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  91 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  92 epp3 = epp2i + [10, 0];
  93 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  94 epp4 = epp5 + [-1,0] * case_th_side;
  95
  96 kppe = [0,0];
  97 kppd = kppe + [1,0] * keeper_inner_width;
  98 kppc = kppd + [0,1] * keeper_th_z;
  99 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 100 kppf = kppe - [0,1] * keeper_inner_height;
 101 kppa = [ kppb[0], kppf[1] ];
 102
 103 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 104 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 105
 106 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
 107
 108 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 109 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 110
 111 // button profile
 112 bppM = epp4 + [0,5];
 113 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 114 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 115 bppS = [ epp1[0], bppR[1] ];
 116 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 117 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 118 bppO = [ bppN[0], bppP[1] ];
 119 bppL = lpp10 + [5,0];
 120 bppK = [ bppL[0], bppN[1] ];
 121 bppJ = [ bppN[0], bppL[1] ];
 122
 123 module rectfromto(a,b) {
 124   ab = b - a;
 125   translate([min(a[0], b[0]), min(a[1], b[1])])
 126     square([abs(ab[0]), abs(ab[1])]);
 127 }
 128 module circleat(c,r) { translate(c) circle(r); }
 129 module linextr(z0,z1) {
 130   translate([0,0,z0])
 131     linear_extrude(height=z1-z0)
 132     children();
 133 }
 134
 135 module KeeperProfile(slant=0){
 136   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 137   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 138 }
 139
 140 module EdgeProfile(){
 141   difference(){
 142     hull(){
 143       translate(epp3) square(case_th_bottom*2, center=true);
 144       circleat(epp2o, r=case_th_bottom);
 145       circleat(epp1, r=case_th_side);
 146       rectfromto(epp0, epp4);
 147     }
 148     polygon([ epp5 + [0,10],
 149               epp1,
 150               epp2i,
 151               epp3 + [10,0] ]);
 152   }
 153 }
 154
 155 module LidEdgeProfile(){
 156   polygon([ lpp10,
 157             lpp11,
 158             lpp12,
 159             lpp13,
 160             lpp13 + [10, 0],
 161             lpp10 + [10, 0]
 162             ]);
 163   intersection(){
 164     circleat(lpp12, r=lp_r12);
 165     rectfromto( lpp12 + [-10,   0],
 166                 lpp12 + [+10, +10] );
 167   }
 168 }
 169
 170 module ButtonCoverProfile(){
 171   intersection(){
 172     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 173     hull(){
 174       EdgeProfile();
 175       LidEdgeProfile();
 176     }
 177   }
 178 }
 179
 180 module ButtonPlan(l, deep, cut){
 181   epsilon =
 182     (cut  ? 0 : lid_buttoncover_gap);
 183
 184   delta =
 185     (deep ? lid_buttoncover_overlap : 0);
 186
 187   C = [0,0]; // by definition
 188   T = [ 0, epp4[1] ];
 189   G = T + [0,10];
 190
 191   B0 = C + [0,-1] * button_cutout_depth;
 192   B1 = B0 + [0,1] * epsilon;
 193
 194   r0 = 0.5 * (T[1] - B0[1]);
 195   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 196   H = A + [0,-1] * delta;
 197
 198   D = A + [-2,0] * r0;
 199   F = D + [0,10];
 200
 201   E0 = 0.5 * (D + A);
 202   E1 = E0 + [1,0] * epsilon;
 203
 204   I0 = [ E0[0], H[1] ];
 205   I1 = [ E1[0], H[1] ];
 206
 207   hull(){
 208     for (m=[0,1]) mirror([m,0])
 209       circleat(H, r0 - epsilon);
 210   }
 211   for (m=[0,1]) mirror([m,0]) {
 212     difference(){
 213       polygon([ E1,
 214                 I1,
 215                 H,
 216                 B1,
 217                 G,
 218                 F,
 219                 D
 220                 ]);
 221       circleat(D, r0 + epsilon);
 222     }
 223   }
 224 }
 225
 226 module CaseBase_rhsflip(yn=[0,1]) {
 227   for ($rhsflip=yn) {
 228     translate([phone_width/2, 0, 0])
 229       mirror([$rhsflip,0,0])
 230       translate([-phone_width/2, 0, 0])
 231       children();
 232   }
 233 }
 234
 235 module CaseBase_botflip(yn=[0,1]) {
 236   for ($botflip=yn) {
 237     translate([0, -phone_height/2, 0])
 238       mirror([0, $botflip, 0])
 239       translate([0, phone_height/2, 0])
 240       children();
 241   }
 242 }
 243
 244 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 245   // sides
 246   CaseBase_rhsflip(){
 247     translate([0, -phone_cnr_rad, 0])
 248       rotate([90,0,0])
 249       linear_extrude(height = phone_height - phone_cnr_rad*2)
 250       children(0);
 251   }
 252   // corners
 253   CaseBase_rhsflip() CaseBase_botflip() {
 254     translate([+1,-1] * phone_cnr_rad)
 255       intersection(){
 256         rotate_extrude()
 257           intersection(){
 258             mirror([1,0,0])
 259               translate([-1,0] * phone_cnr_rad)
 260               children(0);
 261             rectfromto([0,-20],[10,20]);
 262           }
 263         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 264           cube([10,10,40]);
 265       }
 266   }
 267   // top and bottom
 268   CaseBase_botflip(){
 269     translate([ phone_width - phone_cnr_rad, 0,0 ])
 270       rotate([90,0,-90])
 271       linear_extrude(height = phone_width - phone_cnr_rad*2)
 272       children(0);
 273   }
 274   // fill
 275   translate([0,0, fill_zstart])
 276     mirror([0,0, fill_downwards])
 277     linear_extrude(height = fill_th)
 278     rectfromto([+1,-1] * phone_cnr_rad,
 279                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 280 }
 281
 282 module CaseAperture(pos, dia, $fn) {
 283   theta = 180/$fn;
 284   translate([ pos[0] + bumper[0],
 285               -epp2i[0],
 286               -pos[1] ])
 287     rotate([-90, theta, 0])
 288     cylinder(r = dia/2 / cos(theta),
 289              h = 60);
 290 }
 291
 292 module SideButton(y, y_ref_sign, l){
 293   // y_ref_sign:
 294   //   +1  measured from top    of actual phone to top    of button
 295   //   -1  measured from bottom of actual phone to bottom of button
 296   //    0  y is centre of button in coordinate system
 297   $button_l= l;
 298   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 299           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 300           y;
 301   echo(eff_y);
 302   translate([0, eff_y, 0])
 303     children();
 304 }
 305
 306 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 307   $button_leg_only = true;
 308   SideButton(y, y_ref_sign, l) children();
 309 }
 310
 311 module Buttons(){
 312   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
 313   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
 314   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
 315   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
 316 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
 317 }
 318
 319 module Struts(x_start, z_min, th){
 320   // if th is negative, starts at z_min and works towards -ve z
 321   // and object should then be printed other way up
 322   for (i= [1 : 1 : case_struts_count]) {
 323     translate([0,
 324                0,
 325                z_min])
 326       mirror([0,0, th<0 ? 1 : 0])
 327       translate([0,
 328                  -phone_height * i / (case_struts_count+1),
 329                  case_struts_solid_below])
 330       linear_extrude(height= abs(th)
 331                      -(case_struts_solid_below+case_struts_solid_above))
 332       rectfromto([               x_start, -0.5 * case_struts_width ],
 333                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 334   }
 335 }
 336
 337 module OrdinaryRearAperture(rhs,bot, pos){
 338   CaseBase_rhsflip(rhs) CaseBase_botflip(bot)
 339     linextr(-20, 20)
 340     mirror([0,1])
 341     translate(pos + bumper)
 342     children();
 343 }
 344
 345 module OrdinaryRearApertures(){
 346   // rear speaker
 347   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 348     rectfromto(-rearspeaker_gap,
 349                rearspeaker_size + rearspeaker_gap);
 350
 351   // finger hole to remove phone
 352   OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 353                               phone[1]/2 ])
 354     scale(fingerpushhole_dias)
 355     circle(r= 0.5 );
 356 }
 357
 358 module RearCameraAperture(){
 359   CaseBase_rhsflip([1])
 360     mirror([0, 0, 1])
 361     linear_extrude(height = 20)
 362     mirror([0, 1, 0])
 363     translate(bumper)
 364     rectfromto(camera_pos_tl, camera_pos_br);
 365 }
 366
 367 module CaseBase(){
 368   AroundEdges(epp3[1], case_th_bottom, 1)
 369     EdgeProfile();
 370 }
 371
 372 module Case(){ ////toplevel
 373   difference(){
 374     union(){
 375       CaseBase();
 376
 377       // ledge (fixed keeper)
 378       intersection(){
 379         rotate([90, 0, 0])
 380           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 381           KeeperProfile(1);
 382
 383         // outline of the whole case, to stop it protruding
 384         translate([0,0, -25])
 385           linear_extrude(height = 50)
 386           hull()
 387           // CaseBase_rhsflip() // actually, we only care about the LH
 388           CaseBase_botflip()
 389           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 390       }
 391     }
 392
 393     // slot for keeper
 394     CaseBase_rhsflip(1)
 395       translate([0, -phone_cnr_rad, 0])
 396       rotate([90, 0, 0])
 397       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 398       minkowski(){
 399         KeeperProfile();
 400         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 401                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 402       }
 403
 404     // front camera
 405     RearCameraAperture();
 406
 407     // struts (invisible, because they're buried in the case)
 408     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 409
 410     Buttons(){
 411       mirror([1,0,0])
 412         rotate([90,0,90]) {
 413           intersection(){
 414             translate([0,0,-10])
 415               linear_extrude(height= 20)
 416               ButtonPlan($button_l, 0,1);
 417             if ($button_leg_only)
 418               rotate([-90,90,0])
 419                 translate([phone_width/2, -400, kppe[1]])
 420                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
 421           }
 422           translate([0,0, -bppR[0]])
 423             linear_extrude(height= 20)
 424             ButtonPlan($button_l, 1,1);
 425         }
 426     }
 427
 428     // apertures along top edge
 429     CaseAperture(jack_pos, jack_dia, 8);
 430     CaseBase_rhsflip([1])
 431       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
 432
 433     OrdinaryRearApertures();
 434   }
 435 }
 436
 437 module Lid(){ ////toplevel
 438   difference(){
 439     union(){
 440       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 441         LidEdgeProfile();
 442
 443       // button covers
 444       Buttons(){
 445         intersection(){
 446           rotate([90,0,90])
 447             translate([0,0,-10])
 448             linear_extrude(height= 20)
 449             ButtonPlan($button_l, 1,0);
 450           rotate([90,0,0])
 451              translate([0,0,-100])
 452             linear_extrude(height= 200)
 453             ButtonCoverProfile();
 454         }
 455       }
 456     }
 457     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 458   }
 459 }
 460
 461 module TestLength(){ ////toplevel
 462   intersection(){
 463     Case();
 464     translate([-30, -200, -20])
 465     cube([30 + 15, 250, 40]);
 466   }
 467 }
 468
 469 module TestSelectWidth(){
 470   translate([-30, -(phone_height - 25), -20])
 471     mirror([0, 1, 0])
 472     cube([200, 50, 40]);
 473 }
 474
 475 module TestWidth(){ ////toplevel
 476   intersection(){
 477     Case();
 478     TestSelectWidth();
 479   }
 480 }
 481
 482 module TestLidWidthPrint(){ ////toplevel
 483   rotate([0,180.0]) intersection(){
 484     Lid();
 485     TestSelectWidth();
 486   }
 487 }
 488
 489 module TestSelectRearAperture(){
 490   minkowski(){
 491     union() children();
 492     translate([20, 0,0])
 493       cube([42, 2, 1], center=true);
 494   }
 495 }
 496
 497 module TestSelectCamera(){
 498   minkowski(){
 499     TestSelectRearAperture()
 500       RearCameraAperture();
 501     cube([0.1, 50, 0.1]);
 502   }
 503 }
 504
 505 module TestSelectOrdinaryRearApertures(){
 506   TestSelectRearAperture()
 507     OrdinaryRearApertures();
 508 }
 509
 510 module TestCamera(){ ////toplevel
 511   intersection(){
 512     Case();
 513     TestSelectCamera();
 514   }
 515 }
 516
 517 module TestLidByCamera(){ ////toplevel
 518   intersection(){
 519     Lid();
 520     TestSelectCamera();
 521   }
 522 }
 523
 524 module TestLidByCameraPrint(){ ////toplevel
 525   rotate([180,0,0]) TestLidByCamera();
 526 }
 527
 528 module DemoByCamera(){ ////toplevel
 529   color("blue") TestLidByCamera();
 530   color("red")  TestCamera();
 531 }
 532
 533 module OneKeeper(){ ////toplevel
 534   translate([0, -phone_cnr_rad, 0])
 535     rotate([90, 0, 0])
 536     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 537     KeeperProfile();
 538 }
 539
 540 module OneKeeperPrint(){ ////toplevel
 541   rotate([0,180,0])
 542     OneKeeper();
 543 }
 544
 545 module LidPrint(){ ////toplevel
 546   rotate([0,180,0])
 547     Lid();
 548 }
 549
 550 module TestSelectFrame(){
 551   include = [1,-1] * (epp2i[0] + 4);
 552
 553   difference(){
 554     cube(1000, center=true);
 555     translate([0,0, -100])
 556       linear_extrude(height=200)
 557       rectfromto(include,  inside_br - include);
 558   }
 559 }
 560
 561 module TestFrameCase(){ ////toplevel
 562   intersection(){
 563     Case();
 564     union(){
 565       TestSelectFrame();
 566       TestSelectCamera();
 567       TestSelectOrdinaryRearApertures();
 568     }
 569   }
 570 }
 571
 572 module TestFrameLidPrint(){ ////toplevel
 573   rotate([0,0,180]) intersection(){
 574     Lid();
 575     TestSelectFrame();
 576   }
 577 }
 578
 579 module Keeper(){ ////toplevel
 580   CaseBase_rhsflip()
 581     OneKeeper();
 582 }
 583
 584 module ButtonPlanForDemo(z, deep, cut){
 585   translate([0,0,z])
 586     ButtonPlan(8, deep, cut);
 587 }
 588
 589 module DemoProfiles(){ ////toplevel
 590   LidEdgeProfile();
 591   %EdgeProfile();
 592   KeeperProfile();
 593   translate([0,0,-1]) color("black") KeeperProfile(1);
 594
 595   translate([20,0]) {
 596     LidEdgeProfile();
 597     %EdgeProfile();
 598
 599     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 600
 601     color("blue") ButtonCoverProfile();
 602     color("red") {
 603       rectfromto(bppQ, demopoint_QR);
 604       rectfromto(bppR, demopoint_QR);
 605     }
 606   }
 607
 608   translate([-20,0]) {
 609     color("black") ButtonPlanForDemo(-2, 0,1);
 610     color("red" )  ButtonPlanForDemo(-4, 1,1);
 611     color("blue")  ButtonPlanForDemo(-6, 1,0);
 612   }
 613 }
 614
 615 //EdgeProfile();
 616 //KeeperProfile();
 617 //CaseBase();
 618 //%Case();
 619 //Keeper();
 620 //LidEdgeProfile();
 621 //KeeperProfile();
 622 //DemoProfiles();