fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone_height = 146.5 - .80;
   4 phone_width = 76.75;
   5
   6 phone_cnr_rad = 6.0;
   7
   8 button_cutout_depth = 9;
   9
  10 phone_edge_thick = 9.0;
  11 phone_total_thick = 12.0;
  12 phone_backside_slope_inner = 1.5; // larger means shallower
  13 phone_backside_slope_outer = 1.0; // larger means shallower
  14
  15 camera_pos_tl = [  7.0, 13.0 ]; // measured from tl corner
  16 camera_pos_br = [ 24.0, 39.5 ]; // tl/br as seen from back
  17
  18 case_th_bottom = 2.5;
  19 case_th_lid = 2.5;
  20 case_th_side = 2;
  21 case_th_lip = 1.2;
  22
  23 case_struts_count = 6;
  24 case_struts_solid_below = 0.75;
  25 case_struts_solid_above = 1.00;
  26 case_struts_width = 0.10;
  27
  28 keeper_th_z = 0.75;
  29 keeper_th_x = 0.75;
  30 keeper_inner_width = 2.75;
  31 keeper_inner_height = 2.75;
  32 keeper_slant_slope = 2; // larger means steeper
  33
  34 keeper_gap_z_top = 0.25;
  35 keeper_gap_z_bot = 0.75;
  36 keeper_gap_x     = 0.25;
  37 keeper_gap_x_holes = 0.75;
  38
  39 case_lip = 1.25;
  40
  41 lid_gap_x = 0.25;
  42 lid_gap_z = 0.25;
  43 lid_lip = 1.75;
  44
  45 $fa = 5;
  46 $fs = 0.1;
  47
  48 button_l_fudge = 4.5;
  49
  50 // ---------- calculated ----------
  51
  52 // ----- could be changed -----
  53 lid_buttoncover_gap = lid_gap_x;
  54 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  55
  56 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  57
  58 //lid_lip_overlap_width xxx bad name = ;
  59 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  60
  61 epp0 = [0,0];
  62 epp1 = [0, -phone_edge_thick];
  63 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  64 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  65 epp3 = epp2i + [10, 0];
  66 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  67 epp4 = epp5 + [-1,0] * case_th_side;
  68
  69 kppe = [0,0];
  70 kppd = kppe + [1,0] * keeper_inner_width;
  71 kppc = kppd + [0,1] * keeper_th_z;
  72 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  73 kppf = kppe - [0,1] * keeper_inner_height;
  74 kppa = [ kppb[0], kppf[1] ];
  75
  76 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  77 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  78 lpp12 = [ epp4[0] + lid_lip,   lpp11[1] ];
  79 lpp13 = [ lpp12[0],            lpp12[1] + lid_lip ];
  80
  81 // button profile
  82 bppM = epp4 + [0,5];
  83 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  84 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
  85 bppS = [ epp1[0], bppR[1] ];
  86 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
  87 bppP = bppQ + [0,1] * lid_buttoncover_gap;
  88 bppO = [ bppN[0], bppP[1] ];
  89 bppL = lpp10 + [5,0];
  90 bppK = [ bppL[0], bppN[1] ];
  91 bppJ = [ bppN[0], bppL[1] ];
  92
  93 module rectfromto(a,b) {
  94   ab = b - a;
  95   translate([min(a[0], b[0]), min(a[1], b[1])])
  96     square([abs(ab[0]), abs(ab[1])]);
  97 }
  98 module circleat(c,r) { translate(c) circle(r); }
  99
 100 module KeeperProfile(slant=0){
 101   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 102   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 103 }
 104
 105 module EdgeProfile(){
 106   difference(){
 107     hull(){
 108       translate(epp3) square(case_th_bottom*2, center=true);
 109       circleat(epp2o, r=case_th_bottom);
 110       circleat(epp1, r=case_th_side);
 111       rectfromto(epp0, epp4);
 112     }
 113     polygon([ epp5 + [0,10],
 114               epp1,
 115               epp2i,
 116               epp3 + [10,0] ]);
 117   }
 118 }
 119
 120 module LidEdgeProfile(){
 121   polygon([ lpp10,
 122             lpp11,
 123             lpp12,
 124             lpp13,
 125             lpp13 + [10, 0],
 126             lpp10 + [10, 0]
 127             ]);
 128   intersection(){
 129     circleat(lpp12, r=lid_lip);
 130     rectfromto( lpp12 + [-10,   0],
 131                 lpp12 + [+10, +10] );
 132   }
 133 }
 134
 135 module ButtonCoverProfile(){
 136   intersection(){
 137     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 138     hull(){
 139       EdgeProfile();
 140       LidEdgeProfile();
 141     }
 142   }
 143 }
 144
 145 module ButtonPlan(l, deep, cut){
 146   bigger =
 147     (deep ? lid_buttoncover_overlap : 0) +
 148     (cut  ? 0 : -lid_buttoncover_gap);
 149
 150   d_D1_y =
 151     (cut  ? 0 : lid_buttoncover_gap);
 152
 153   C = [0,0]; // by definition
 154   T = [ 0, epp4[1] ];
 155   G = T + [0,10];
 156   B0 = C + [0,-1] * button_cutout_depth;
 157   r0 = 0.5 * (T[1] - B0[1]);
 158   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 159   r1 = r0 + bigger;
 160   // | D1 - A | = r1 * 2
 161   // D1_y = T_y - r1 + d_D1_y
 162   // =>    4 * r1^2   =  (r1-r0 + d_D1_y)^2 + (D1_x - A_x)^2
 163   // =>    D1_x =  A_x + v/~ [  4 * r1^2   -   (r1-r0 + d_D1_y)^2 ]
 164   D1  = [ A[0] - sqrt( 4*r1*r1 - pow(bigger + d_D1_y, 2) ),
 165           T[1] - r1 + d_D1_y ];
 166   E1  = 0.5 * (D1 + A);
 167   F1  = D1 + [0,10];
 168
 169   hull(){
 170     for (m=[0,1]) mirror([m,0])
 171       circleat(A, r1);
 172   }
 173   for (m=[0,1]) mirror([m,0]) {
 174     difference(){
 175       polygon([ E1,
 176                 A,
 177                 B0,
 178                 G,
 179                 F1,
 180                 D1
 181                 ]);
 182       circleat(D1, r1);
 183     }
 184   }
 185 }
 186
 187 module CaseBase_rhsflip(yn=[0,1]) {
 188   for (rhs=yn) {
 189     translate([phone_width/2, 0, 0])
 190       mirror([rhs,0,0])
 191       translate([-phone_width/2, 0, 0])
 192       children();
 193   }
 194 }
 195
 196 module CaseBase_botflip() {
 197   for (bot=[0,1]) {
 198     translate([0, -phone_height/2, 0])
 199       mirror([0, bot, 0])
 200       translate([0, phone_height/2, 0])
 201       children();
 202   }
 203 }
 204
 205 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 206   // sides
 207   CaseBase_rhsflip(){
 208     translate([0, -phone_cnr_rad, 0])
 209       rotate([90,0,0])
 210       linear_extrude(height = phone_height - phone_cnr_rad*2)
 211       children(0);
 212   }
 213   // corners
 214   CaseBase_rhsflip() CaseBase_botflip() {
 215     translate([+1,-1] * phone_cnr_rad)
 216       intersection(){
 217         rotate_extrude()
 218           intersection(){
 219             mirror([1,0,0])
 220               translate([-1,0] * phone_cnr_rad)
 221               children(0);
 222             rectfromto([0,-20],[10,20]);
 223           }
 224         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 225           cube([10,10,40]);
 226       }
 227   }
 228   // top and bottom
 229   CaseBase_botflip(){
 230     translate([ phone_width - phone_cnr_rad, 0,0 ])
 231       rotate([90,0,-90])
 232       linear_extrude(height = phone_width - phone_cnr_rad*2)
 233       children(0);
 234   }
 235   // fill
 236   translate([0,0, fill_zstart])
 237     mirror([0,0, fill_downwards])
 238     linear_extrude(height = fill_th)
 239     rectfromto([+1,-1] * phone_cnr_rad,
 240                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 241 }
 242
 243 module CaseBase(){
 244   AroundEdges(epp3[1], case_th_bottom, 1)
 245     EdgeProfile();
 246 }
 247
 248 module Case(){ ////toplevel
 249   difference(){
 250     union(){
 251       CaseBase();
 252
 253       // ledge (fixed keeper)
 254       intersection(){
 255         rotate([90, 0, 0])
 256           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 257           KeeperProfile(1);
 258
 259         // outline of the whole case, to stop it protruding
 260         translate([0,0, -25])
 261           linear_extrude(height = 50)
 262           hull()
 263           // CaseBase_rhsflip() // actually, we only care about the LH
 264           CaseBase_botflip()
 265           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 266       }
 267     }
 268
 269     // slot for keeper
 270     CaseBase_rhsflip(1)
 271       translate([0, -phone_cnr_rad, 0])
 272       rotate([90, 0, 0])
 273       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 274       minkowski(){
 275         KeeperProfile();
 276         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 277                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 278       }
 279
 280     // front camera
 281     CaseBase_rhsflip([1])
 282       mirror([0, 0, 1])
 283       linear_extrude(height = 20)
 284       mirror([0, 1, 0])
 285       rectfromto(camera_pos_tl, camera_pos_br);
 286
 287     // struts (invisible, because they're buried in the case)
 288     for (i= [1 : 1 : case_struts_count]) {
 289       translate([0,
 290                  -phone_height * i / (case_struts_count+1),
 291                  epp2i[1] - case_th_bottom + case_struts_solid_below])
 292         linear_extrude(height= case_th_bottom
 293                        -(case_struts_solid_below+case_struts_solid_above))
 294         rectfromto([               epp2i[0], -0.5 * case_struts_width ],
 295                    [ phone_width - epp2i[0], +0.5 * case_struts_width ]);
 296     }
 297   }
 298 }
 299
 300 module Lid(){ ////toplevel
 301   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 302     LidEdgeProfile();
 303 }
 304
 305 module TestLength(){ ////toplevel
 306   intersection(){
 307     Case();
 308     translate([-30, -200, -20])
 309     cube([30 + 15, 250, 40]);
 310   }
 311 }
 312
 313 module TestWidth(){ ////toplevel
 314   intersection(){
 315     Case();
 316     translate([-30, -(phone_height - 25), -20])
 317       mirror([0, 1, 0])
 318       cube([200, 50, 40]);
 319   }
 320 }
 321
 322 module TestLidWidthPrint(){ ////toplevel
 323   rotate([0,180.0])
 324     intersection(){
 325       Lid();
 326       translate([-30, -(phone_height - 25), -20])
 327         mirror([0, 1, 0])
 328         cube([200, 50, 40]);
 329     }
 330 }
 331
 332 module TestCamera(){ ////toplevel
 333   intersection(){
 334     Case();
 335     CaseBase_rhsflip(1)
 336       translate([0,0,-25])
 337       linear_extrude(height = 50)
 338       mirror([0, 1, 0])
 339       rectfromto([-20, -20],
 340                  camera_pos_br + [ 5, 5 ]);
 341   }
 342 }
 343
 344 module OneKeeper(){ ////toplevel
 345   translate([0, -phone_cnr_rad, 0])
 346     rotate([90, 0, 0])
 347     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 348     KeeperProfile();
 349 }
 350
 351 module OneKeeperPrint(){ ////toplevel
 352   rotate([0,180,0])
 353     OneKeeper();
 354 }
 355
 356 module Keeper(){ ////toplevel
 357   CaseBase_rhsflip()
 358     OneKeeper();
 359 }
 360
 361 module ButtonPlanForDemo(colour, z, deep, cut){
 362   color(colour)
 363     translate([0,0,z])
 364     ButtonPlan(8, deep, cut);
 365 }
 366
 367 module DemoProfiles(){ ////toplevel
 368   LidEdgeProfile();
 369   %EdgeProfile();
 370   KeeperProfile();
 371   translate([0,0,-1]) color("black") KeeperProfile(1);
 372
 373   translate([20,0]) {
 374     LidEdgeProfile();
 375     %EdgeProfile();
 376
 377     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 378
 379     color("blue") ButtonCoverProfile();
 380     color("red") {
 381       rectfromto(bppQ, demopoint_QR);
 382       rectfromto(bppR, demopoint_QR);
 383     }
 384   }
 385
 386   translate([-20,0]) {
 387     ButtonPlanForDemo("grey", -1, 0,1);
 388     ButtonPlanForDemo("blue", -2, 1,0);
 389     ButtonPlanForDemo("red",  -3, 1,1);
 390   }
 391 }
 392
 393 //EdgeProfile();
 394 //KeeperProfile();
 395 //CaseBase();
 396 //%Case();
 397 //Keeper();
 398 //LidEdgeProfile();
 399 //KeeperProfile();
 400 //DemoProfiles();