fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.0, 145.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 3;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 6.0;
 146 phone_rim_depth = 0.80; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 9.0;
 151 phone_total_thick = 12.0;
 152 phone_backside_slope_inner = 1.5; // larger means shallower
 153 phone_backside_slope_outer = 1.0; // larger means shallower
 154
 155 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 156 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 157
 158 jack_pos = [ 13.83, 8.485 ];
 159 jack_dia = 10.64 + .5; // some jack I had lying around
 160
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 //fingerpushhole_dias = [ 15, 18 ];
 169 fingerpushhole_dias = [];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 3.27 - 0.25;
 178 microusb_below = 0.0;
 179 microusb_width = 16.12 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // properties of the hinge fasteners
 219 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 220 hingescrew_shaft_len = 12;
 221 hingescrew_fasteners_extra_thick = 0.40;
 222 // ^ amount of thread protruding if everything was completely nominal
 223 //   and we are using two nuts
 224 hingescrew_nut_access_dia = 4.72 + 0.50;
 225 // ^ washer is 4.72 dia
 226 //   also, want to get pliers or tiny spanner in to do up locknut
 227 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 228 hingescrew_nut_thick = 1.93;
 229 hingescrew_head_th = 1.38 + 0.75;
 230 hingescrew_head_dia = 3.92;
 231
 232 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 233
 234 lever_cover_th = 0.75;
 235 hingemount_th = 2.5;
 236 hingemount_wd = 4.8725;
 237
 238 $fa = 5;
 239 $fs = 0.1;
 240
 241 button_l_fudge = 4.4;
 242 buttonishleg_default_l_is_fudge = 10;
 243
 244 hinge_base_slope = 1.5; // bigger is steeper
 245
 246 strut_min_at_end = 1.5;
 247
 248 hinge_x_gap = 0.125;
 249 hinge_x_postscrew_gap = 0.75;
 250 hinge_x_arms_gap = 0.35;
 251 hinge_r_arms_gap = 0.55;
 252
 253 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 254
 255 thumbrecess_depth = 1.3;
 256 thumbrecess_width = 16.5;
 257 thumbrecess_topcurve_r = 5.0;
 258
 259 prop_recess_under = 0.50;
 260 prop_recess_slop = 0.200; // each side
 261 prop_end_dia = 0.5;
 262 prop_main_th = 3;
 263 prop_taper_len = 6;
 264 prop_main_width = 4;
 265 prop_side_gap = 0.75; // each side
 266 prop_lidrecess_behind = 0.75;
 267 prop_caserecess_behind = 0.75;
 268 prop_caserecess_taper = 0.45; // one side only
 269 prop_prop_gap = 0.5;
 270 prop_prong_heel_slope = 0.5;
 271
 272 lid_fold_clearance_antislop = 0.5;
 273
 274 // ---------- calculated ----------
 275
 276 phone_width =  (phone + bumper*2)[0];
 277 phone_height = (phone + bumper*2)[1];
 278
 279 inside_br = [phone_width, -phone_height];
 280
 281 prop_prong_h = prop_main_th;
 282
 283 //echo(camera_pos_tl + bumper,
 284 //     camera_pos_br + bumper);
 285
 286 // ----- could be changed -----
 287 lid_buttoncover_gap = lid_gap_x;
 288 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 289
 290 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 291
 292 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 293
 294 //prop_nose_len = case_th_lid - prop_recess_under;
 295 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 296 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 297
 298
 299 //lid_lip_overlap_width xxx bad name = ;
 300 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 301
 302 epp0 = [0,0];
 303 epp1 = [0, -phone_edge_thick];
 304 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 305 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 306 epp3 = epp2i + [10, 0];
 307 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 308 epp4 = epp5 + [-1,0] * case_th_side;
 309
 310 kppe = [0,0];
 311 kppd = kppe + [1,0] * keeper_inner_width;
 312 kppc = kppd + [0,1] * keeper_th_z;
 313 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 314 kppf = kppe - [0,1] * keeper_inner_height;
 315 kppa = [ kppb[0], kppf[1] ];
 316
 317 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 318 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 319
 320 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 321 // exact x posn not very important; must extend past end of keeper
 322
 323 lpp15 = [ lpp14[0],
 324           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 325           + lid_screen_gap_extra ];
 326 // ^ beam theory says to maximise force before contact,
 327 //   the gap below the `beam' (the lid) must be 1/3
 328 //   the thickness (ie the lid thickness) if the beam
 329 //   is solid, or 1/2 if it has a top and bottom only.
 330 //   ours is mostly solid.
 331
 332 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 333              case_th_lip);
 334
 335 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 336 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 337
 338 case_bottom_z = epp2o[1] - case_th_bottom;
 339
 340 // button profile
 341 bppM = epp4 + [0,5];
 342 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 343 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 344 bppS = [ epp1[0], bppR[1] ];
 345 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 346 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 347 bppO = [ bppN[0], bppP[1] ];
 348 bppL = lpp10 + [5,0];
 349 bppK = [ bppL[0], bppN[1] ];
 350 bppJ = [ bppN[0], bppL[1] ];
 351 bppU = [ bppJ[0], lpp12[1] ];
 352 bppV = lpp11;
 353 bppW = lpp10;
 354
 355 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 356
 357 // notification led aperture
 358
 359 nla_r0 = led_aperture/2;
 360 nla_r1 = nla_r0 + led_window_ledge;
 361 nla_r2 = nla_r1 + multicolour_gap;
 362 nla_t =
 363   led_window_style >= 3 ? initial_layer_thick :
 364   led_window_style >= 2 ? led_window_ledge : 0;
 365
 366
 367 // hinge plan
 368 hp_rn = hingescrew_nut_access_dia/2;
 369 hp_r2_min = hp_rn + lever_cover_th;
 370 hp_rs = hingescrew_shaft_dia/2;
 371 hp_r1_min = hp_rs + hingemount_th;
 372
 373 hp_r1 = max(hp_r1_min, hp_r2_min);
 374 hp_r2 = hp_r1;
 375
 376 hppU = lpp13;
 377 hppS = epp2o + [0,-1] * case_th_bottom;
 378 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 379
 380 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 381          0.5 * (hppU + hppS)[1] ];
 382 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 383 hppB = hppT + [0,-1] * hp_k;
 384
 385 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 386 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 387 hppE = [ hppE_x, hppE_y ];
 388
 389 // hinge elevation x coords
 390
 391 hex20 = max(epp2o[0],
 392             phone_cnr_rad,
 393             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 394 hex21 = hex20 + hingemount_wd;
 395 hex22 = hex21 + hinge_x_gap;
 396 hex27 = hex20 + hingescrew_shaft_len;
 397 hex24 = hex27 + hinge_x_postscrew_gap;
 398 hex23 = hex27 - (hingescrew_nut_thick*2
 399                  + hingescrew_fasteners_extra_thick);
 400 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 401
 402 echo(hex20, hex21, hex22, hex23, hex24);
 403 //  6, 10.8725, 10.9975, 13.74, 18.75
 404 module chk(act,exp) {
 405   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 406   else echo("ok", act);
 407 }
 408 chk(hex20, 6);
 409 chk(hex21, 10.8725);
 410 chk(hex22, 10.9975);
 411 chk(hex23, 13.74);
 412 chk(hex24, 18.75);
 413
 414 lid_fold_clearance_skew =
 415   (lpp10[1] - hppB[1]) /
 416   (lpp10[0] - hppB[0]);
 417
 418 echo("SK",lid_fold_clearance_skew);
 419
 420 // thumb recess (used to be "catch" hence cpp*
 421
 422 cppA = epp4 + [thumbrecess_depth, 0];
 423 cppB = [ cppA[0], epp1[1] ];
 424
 425 // lanyard
 426
 427 ly_r = lanyard_half_dia / 2;
 428 ly_rc = ly_r * 2;
 429
 430 ly_theta = -atan2vector(epp2i - epp1);
 431 ly_o = epp2i + 3 * ly_r * unitvector2d(epp1 - epp2i);
 432
 433 max_case_bottom_edge_thickness =
 434   case_th_bottom
 435   + sin(ly_theta) * (epp2i-epp2o)[0];
 436
 437 ly_q_z = -(ly_rc + ly_r);
 438 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 439
 440 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 441
 442 // prop recess in case
 443
 444 prop_x_pos = phone_width/2;
 445
 446 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 447
 448 prc_r1 = prop_end_dia/2;
 449 prc_r3 = prc_r1 + prop_recess_slop;
 450
 451 prcp2 = [ epp4[0] + prop_buildout_less,
 452           case_bottom_z ];
 453
 454 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 455
 456 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 457           epp2i[1] - prc_r3 - prop_recess_under];
 458
 459 // prop recess in lid
 460
 461 prl_r10 = prop_end_dia/2;
 462 prl_r10o = prl_r10 + prop_recess_slop;
 463
 464 prlp10 = lpp10 + [1,1] * prl_r10o
 465   + [1,0] * prop_lidrecess_behind
 466   + [0,1] * prop_recess_under;
 467
 468 // prop
 469
 470 $prpp10 = [0,0];
 471 $prpp11 = [0, prop_taper_len];
 472
 473 $prp_r10 = prl_r10;
 474
 475 // ---------- modules ----------
 476
 477 module AdhocMultiprintFrame(phase, z0, zs) {
 478   // from z0 to z0 + zs*layer
 479   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 480   xextra = extra + -epp4[0];
 481   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 482   yextra = extra + -epp4[0];
 483   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 484   p0 = [ xrange[0], yrange[0] ];
 485   p1 = [ xrange[1], yrange[1] ];
 486   echo(p0, p1);
 487   translate([0,0, z0])
 488     mirror([0,0, zs<0 ? 1 : 0])
 489     linear_extrude(height= initial_layer_thick)
 490     difference(){
 491       rectfromto(p0 - [1,1] * initial_layer_width,
 492                  p1 + [1,1] * initial_layer_width);
 493       rectfromto(p0, p1);
 494     }
 495 }
 496
 497 module KeeperProfile(slant=0){
 498   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 499   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 500 }
 501
 502 module EdgeProfile(){
 503   difference(){
 504     hull(){
 505       translate(epp3) square(case_th_bottom*2, center=true);
 506       circleat(epp2o, r=case_th_bottom);
 507       circleat(epp1, r=case_th_side);
 508       rectfromto(epp0, epp4);
 509     }
 510     polygon([ epp5 + [0,10],
 511               epp1,
 512               epp2i,
 513               epp3 + [10,0] ]);
 514   }
 515 }
 516
 517 module LanyardLanyardProfile(entry=false){
 518   hull(){
 519     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 520       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 521         circle(r= lanyard_half_dia/2);
 522   }
 523 }
 524
 525 module LanyardCurveChannelProfile(){
 526   translate([0, -ly_r])
 527     LanyardLanyardProfile();
 528 }
 529
 530 module LanyardEntryChannelProfile(){
 531   LanyardLanyardProfile(true);
 532 }
 533
 534 module LanyardMainChannelProfile(){
 535   LanyardCurveChannelProfile();
 536   difference(){
 537     square(center=true, ly_r * [6, 2]);
 538     for (xs=[-1,+1])
 539       translate(ly_r * [3 * xs, -1])
 540         circle(r = ly_r);
 541   }
 542 }
 543
 544 module LanyardEntryOuterProfile(){
 545   circleat([ly_re + ly_r, 0], ly_re);
 546 }
 547
 548 module LanyardEntry(){
 549   q_z = ly_q_z;
 550   oec_y = ly_oec_y;
 551
 552   d_x = -ly_rc;
 553
 554   translate([d_x, 0, q_z]) {
 555     intersection(){
 556       rotate([90,0,0])
 557         rotate_extrude(convexity=10)
 558         rotate(90)
 559         translate([0, -q_z])
 560         LanyardCurveChannelProfile();
 561       translate([0,-10,0])
 562         cube([20,20,20]);
 563     }
 564   }
 565
 566   mirror([0,0,1])
 567     translate([0,0,-1])
 568     linear_extrude(height=20)
 569     rotate(-90)
 570     LanyardEntryChannelProfile();
 571
 572   translate([0, ly_r*2, 0])
 573     rotate([90,0,0])
 574     linear_extrude(height = ly_r*4){
 575     difference(){
 576       rectfromto([d_x, q_z], [ly_r, 0]);
 577       circleat([d_x, q_z], ly_rc);
 578     }
 579   }
 580
 581   translate([0,0,q_z]){
 582     for (my=[0,1])
 583       mirror([0,my,0]){
 584         translate([0, oec_y, 0]){
 585           difference(){
 586             translate(ly_re * [-1,0,-2])
 587               cube(ly_re * [2,1,2]);
 588             rotate_extrude(convexity=10)
 589               LanyardEntryOuterProfile();
 590           }
 591         }
 592       }
 593     difference(){
 594       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 595         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 596       for (mx=[0,1])
 597         mirror([mx,0,0])
 598           rotate([90,0,0])
 599           translate([0,0,-10])
 600           linear_extrude(height=20)
 601           LanyardEntryOuterProfile();
 602     }
 603   }
 604 }
 605
 606 module LanyardCutout(l){
 607   rotate([0,-90,0])
 608     linear_extrude(height=l)
 609     rotate(-90)
 610     LanyardMainChannelProfile();
 611
 612   for (ee=[0,1]){
 613     translate(ee * l * [-1,0])
 614       mirror([ee,0,0])
 615       LanyardEntry();
 616   }
 617 }
 618
 619 module LidEdgeProfile(){
 620   polygon([ lpp10,
 621             lpp11,
 622             lpp12,
 623             lpp13,
 624             lpp13 + [10, 0],
 625             lpp15 + [10, 0],
 626             lpp15,
 627             lpp14,
 628             ]);
 629   intersection(){
 630     circleat(lpp12, r=lp_r12);
 631     rectfromto( lpp12 + [-10,   0],
 632                 lpp12 + [+10, +10] );
 633   }
 634 }
 635
 636 module LidEdgeFoldClearanceProfile(){
 637   translate([-lid_fold_clearance_antislop, 0])
 638     polygon([ lpp10,
 639               lpp11,
 640               lpp11 + [-20,  0],
 641               lpp11 + [-20, 20],
 642               lpp11 + [+20, 20],
 643               lpp10 + [+20,  0] ]);
 644 }
 645
 646 module ButtonCoverProfile(){
 647   intersection(){
 648     polygon(concat([ bppM, bppP, bppO, bppJ ],
 649                    (enable_support && !$button_suppress_over_keeper
 650                     ? [ bppU, bppV, bppW ] : []),
 651                    [ bppL, bppK ]));
 652     hull(){
 653       EdgeProfile();
 654       LidEdgeProfile();
 655     }
 656   }
 657 }
 658
 659 module ButtonPlan(l, deep, cut){
 660   epsilon =
 661     (cut  ? 0 : lid_buttoncover_gap);
 662
 663   delta =
 664     (deep ? lid_buttoncover_overlap : 0);
 665
 666   C = [0,0]; // by definition
 667   T = [ 0, epp4[1] ];
 668   G = T + [0,10];
 669
 670   B0 = C + [0,-1] * button_cutout_depth;
 671   B1 = B0 + [0,1] * epsilon;
 672
 673   r0 = 0.5 * (T[1] - B0[1]);
 674   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 675   H = A + [0,-1] * delta;
 676
 677   D = A + [-2,0] * r0;
 678   F = D + [0,10];
 679
 680   E0 = 0.5 * (D + A);
 681   E1 = E0 + [1,0] * epsilon;
 682
 683   I0 = [ E0[0], H[1] ];
 684   I1 = [ E1[0], H[1] ];
 685
 686   hull(){
 687     for (m=[0,1]) mirror([m,0])
 688       circleat(H, r0 - epsilon);
 689   }
 690   for (m=[0,1]) mirror([m,0]) {
 691     difference(){
 692       polygon([ E1,
 693                 I1,
 694                 H,
 695                 B1,
 696                 G,
 697                 F,
 698                 D
 699                 ]);
 700       circleat(D, r0 + epsilon);
 701     }
 702   }
 703 }
 704
 705 module ButtonCoverReinf(){ ////toplevel
 706   minkowski(){
 707     rotate([90,0,0])
 708       linear_extrude(height=0.01)
 709       intersection(){
 710         ButtonCoverProfile();
 711         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 712           square([100,100]);
 713     }
 714     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 715       circle(r= lid_buttoncover_reinf);
 716       translate([-20,0]) square(40, center=true);
 717     }
 718   }
 719 }
 720
 721 module ThumbRecessCutProfile(){
 722   difference(){
 723     polygon([ cppA + [-10,0],
 724               cppB + [-10,0],
 725               cppB,
 726               cppA ]);
 727     circleat(epp1, r=case_th_side);
 728   }
 729 }
 730
 731 module Flip_rhs(yn=[0,1]) {
 732   for ($rhsflip=yn) {
 733     translate([phone_width/2, 0, 0])
 734       mirror([$rhsflip,0,0])
 735       translate([-phone_width/2, 0, 0])
 736       children();
 737   }
 738 }
 739
 740 module Flip_bot(yn=[0,1]) {
 741   for ($botflip=yn) {
 742     translate([0, -phone_height/2, 0])
 743       mirror([0, $botflip, 0])
 744       translate([0, phone_height/2, 0])
 745       children();
 746   }
 747 }
 748
 749 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 750   // sides
 751   Flip_rhs(){
 752     translate([0, -phone_cnr_rad, 0])
 753       rotate([90,0,0])
 754       linear_extrude(height = phone_height - phone_cnr_rad*2)
 755       children(0);
 756   }
 757   // corners
 758   Flip_rhs() Flip_bot() {
 759     translate([+1,-1] * phone_cnr_rad)
 760       intersection(){
 761         rotate_extrude()
 762           intersection(){
 763             mirror([1,0,0])
 764               translate([-1,0] * phone_cnr_rad)
 765               children(0);
 766             rectfromto([0,-20],[10,20]);
 767           }
 768         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 769           cube([10,10,40]);
 770       }
 771   }
 772   // top and bottom
 773   Flip_bot(){
 774     translate([ phone_width - phone_cnr_rad, 0,0 ])
 775       rotate([90,0,-90])
 776       linear_extrude(height = phone_width - phone_cnr_rad*2)
 777       children(0);
 778   }
 779   // fill
 780   translate([0,0, fill_zstart])
 781     mirror([0,0, fill_downwards])
 782     linear_extrude(height = fill_th)
 783     rectfromto([+1,-1] * phone_cnr_rad,
 784                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 785 }
 786
 787 module CaseAperture(pos, dia, $fn) {
 788   theta = 180/$fn;
 789   translate([ pos[0] + bumper[0],
 790               -epp2i[0],
 791               -pos[1] ])
 792     rotate([-90, theta, 0])
 793     cylinder(r = dia/2 / cos(theta),
 794              h = 60);
 795 }
 796
 797 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 798   // y_ref_sign:
 799   //   +1  measured from top    of actual phone to top    of button
 800   //   -1  measured from bottom of actual phone to bottom of button
 801   //    0  y is centre of button in coordinate system
 802   $button_l= l;
 803   $button_suppress_over_keeper= suppress_over_keeper;
 804   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 805           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 806           y;
 807   //echo(eff_y);
 808   translate([0, eff_y, 0])
 809     children();
 810 }
 811
 812 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 813   $button_leg_only = true;
 814   SideButton(y, y_ref_sign, l) children();
 815 }
 816
 817 module Buttons(){
 818   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 819   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 820   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 821   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 822 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 823 }
 824
 825 module Struts(x_start, z_min, th){
 826   // if th is negative, starts at z_min and works towards -ve z
 827   // and object should then be printed other way up
 828   for (i= [1 : 1 : case_struts_count]) {
 829     translate([0,
 830                0,
 831                z_min])
 832       mirror([0,0, th<0 ? 1 : 0])
 833       translate([0,
 834                  -phone_height * i / (case_struts_count+1),
 835                  case_struts_solid_below])
 836       linear_extrude(height= abs(th)
 837                      -(case_struts_solid_below+case_struts_solid_above))
 838       rectfromto([               x_start, -0.5 * case_struts_width ],
 839                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 840   }
 841 }
 842
 843 module OrdinaryRearAperture(rhs,bot, pos){
 844   Flip_rhs(rhs) Flip_bot(bot)
 845     linextr(-20, 20)
 846     mirror([0,1])
 847     translate(pos + bumper)
 848     children();
 849 }
 850
 851 module MicroUSB(){
 852   Flip_bot(1){
 853     rotate([90,0,0])
 854       mirror([0,0,1])
 855       linextr(-epp2i[0], 60)
 856       translate([0.5 * phone_width, 0, 0])
 857       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 858                  [+microusb_width/2, epp0[1] + -microusb_above]);
 859   }
 860 }
 861
 862 module OrdinaryRearApertures(){
 863   // rear speaker
 864   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 865     rectfromto(-rearspeaker_gap,
 866                rearspeaker_size + rearspeaker_gap);
 867
 868   // finger hole to remove phone
 869   if (len(fingerpushhole_dias))
 870     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 871                                 phone[1]/2 ])
 872     scale(fingerpushhole_dias)
 873     circle(r= 0.5 );
 874 }
 875
 876 module RearCameraAperture(){
 877   Flip_rhs(1)
 878     mirror([0, 0, 1])
 879     linear_extrude(height = 20)
 880     mirror([0, 1, 0])
 881     translate(bumper)
 882     rectfromto(camera_pos_tl, camera_pos_br);
 883 }
 884
 885 module HingeLidProfile(){
 886   hull(){
 887     circleat(hppT, hp_r1);
 888     circleat(lpp12, lp_r12);
 889     polygon([lpp10,
 890              lpp13 + [2,0],
 891              lpp12,
 892              hppT]);
 893   }
 894 }
 895
 896 module HingeBaseProfile(){
 897   difference(){
 898     hull(){
 899       circleat(hppB, hp_r1);
 900       circleat(hppE, hp_r1);
 901       circleat(epp2o, case_th_bottom);
 902       circleat(hppB + [10,0], hp_r1);
 903     }
 904     polygon([epp5, epp1, epp2i, epp3, bppL]);
 905   }
 906 }
 907
 908 module HingeLeverOuterProfile(){
 909   hull(){
 910     circleat(hppT, hp_r2);
 911     circleat(hppB, hp_r2);
 912   }
 913 }
 914
 915 module HingeLeverInnerProfile(){
 916   for (s = [-1,+1]) {
 917     c = s > 0 ? hppT : hppB;
 918     translate(c)
 919       mirror([0,0,s>0])
 920       rotate(s<0 ? -40 : 0)
 921       hull()
 922       for (x=[-20,20])
 923         for (y=[0, s * 10])
 924           translate([x,y])
 925             circle(hp_rn);
 926   }
 927 }
 928
 929 module HingeLeverNutProfile(){
 930   for (c= [hppB, hppT]) {
 931     translate(c)
 932       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 933   }
 934 }
 935
 936 module Flip_hinge(doflip=1){
 937   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 938   translate(hinge_origin)
 939     rotate([doflip*180,0,0])
 940     translate(-hinge_origin)
 941     children();
 942 }
 943
 944 module HingePortion(x0,x1){
 945   Flip_rhs() Flip_bot(1)
 946     translate([x0,0,0])
 947     mirror([1,0,0])
 948     rotate([90,0,-90])
 949     linear_extrude(height=x1-x0)
 950     children();
 951 }
 952
 953 module ThumbRecessApply(ztop){
 954   width = thumbrecess_width;
 955   w = width + thumbrecess_topcurve_r*2 + 1;
 956   translate([phone_width/2, 0,0]){
 957     difference(){
 958       rotate([90,0,-90])
 959         linextr(-w/2, w/2)
 960         children(0);
 961       translate([0, 50, 0])
 962         rotate([90,0,0])
 963         linear_extrude(height=100){
 964         for (m=[0,1]) mirror([m,0,0]) {
 965           hull(){
 966             translate([w/2, ztop - thumbrecess_topcurve_r])
 967               circle(thumbrecess_topcurve_r);
 968             translate([w/2, -50])
 969               square(thumbrecess_topcurve_r*2, center=true);
 970           }
 971         }
 972       }
 973     }
 974   }
 975 }
 976
 977 module CaseBase(){
 978   AroundEdges(epp3[1], case_th_bottom, 1)
 979     EdgeProfile();
 980 }
 981
 982 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 983
 984 module PropProfileAssignments(gamma){
 985   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 986   x = prop_x(gamma);
 987   p = phone_height + prlp10[0] - hppB[0];
 988   b = p + x;
 989
 990   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 991   a = q + x;
 992   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 993   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 994
 995   $prp_theta = 90 - $prp_alpha;
 996   beta = 180 - $prp_alpha - gamma;
 997   psi = 90 - beta;
 998
 999   //echo("abc", a,b,c);
1000
1001   v1 = [ [ cos(psi), -sin(psi) ],    // x
1002          [ sin(psi),  cos(psi) ] ];  // y
1003
1004   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1005
1006   $prp_r1 = prc_r1;
1007   $prp_r11 = prop_main_th/2;
1008
1009   $prpp1 = $prpp7 + [1,0] *
1010     // this is approximate, but will do
1011     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1012   $prpp3 = $prpp1 +
1013     v1[0] * -$prp_r1 +
1014     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1015   $prpp12 = $prpp3 + v1[0] *
1016     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1017   $prp_r8 = prop_main_th;
1018   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1019   $prp_r5 = $prp_r8;
1020   $prpp5 = [ $prpp12[0] - $prp_r5,
1021             $prpp3[1] - prop_prong_h + $prp_r5 ];
1022   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1023          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1024   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1025   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1026
1027   children();
1028 }
1029
1030 module PropProfile(gamma, cut=0, rot=0){
1031   PropProfileAssignments(gamma){
1032
1033     //#circleat($prpp3,1);
1034     //#circleat($prpp12,1);
1035
1036     if (!cut) {
1037       hull(){
1038         translate($prpp8)
1039           intersection(){
1040             circle($prp_r8);
1041             polygon([[-20,-0], [20,20], [0,0]]);
1042           }
1043         rectfromto($prpp6, $prpp9);
1044         translate($prpp5) intersection(){
1045           circle($prp_r5);
1046           polygon([[-10,-10], [0,0], [10,0]]);
1047         }
1048         rectfromto($prpp12 + [0,-0.1], $prpp3);
1049       }
1050       hull(){
1051         circleat($prpp1, $prp_r1);
1052         rectfromto($prpp12 + [0,-0.1], $prpp3);
1053       }
1054     }
1055     // main shaft
1056     rotate([0,0, rot*-$prp_theta]){
1057       hull(){
1058         extra = cut ? prop_recess_slop : 0;
1059         rectfromto($prpp6, $prpp9);
1060         circleat($prpp11, $prp_r11 + extra);
1061         circleat($prpp10, $prp_r10 + extra);
1062       }
1063     }
1064   }
1065 }
1066
1067 module PropAggregateProfile(){
1068   for (angle = prop_angles)
1069     PropProfile(angle, 0,0);
1070 }
1071
1072 module Prop(){ ////toplevel
1073   hw = prop_main_width/2;
1074   linextr(-hw, +hw)
1075     PropAggregateProfile();
1076 }
1077
1078 module Case(){ ////toplevel
1079   difference(){
1080     union(){
1081       CaseBase();
1082
1083       // ledge (fixed keeper)
1084       Flip_rhs(1-keeper_side) intersection(){
1085         rotate([90, 0, 0])
1086           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1087           KeeperProfile(1);
1088
1089         // outline of the whole case, to stop it protruding
1090         translate([0,0, -25])
1091           linear_extrude(height = 50)
1092           hull()
1093           Flip_bot()
1094           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1095       }
1096
1097       // hinge
1098       HingePortion(hex20, hex21) HingeBaseProfile();
1099
1100       // buildout for prop recess
1101       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1102         linextr(case_bottom_z, epp2i[1])
1103         hull() {
1104           for (dxs = [-1,+1])
1105             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1106                        -epp2o[0] ],
1107                      r = epp2o[0] - prcp2[0]);
1108         }
1109     }
1110
1111     // slot for keeper
1112     Flip_rhs(keeper_side)
1113       translate([0, -phone_cnr_rad, 0])
1114       rotate([90, 0, 0])
1115       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1116       minkowski(){
1117         KeeperProfile();
1118         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1119                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1120       }
1121
1122     // front camera
1123     RearCameraAperture();
1124
1125     // struts (invisible, because they're buried in the case)
1126     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1127
1128     Buttons(){
1129       mirror([1,0,0])
1130         rotate([90,0,90]) {
1131           if (!($button_leg_only && enable_support))
1132           intersection(){
1133             translate([0,0,-10])
1134               linear_extrude(height= 20)
1135               ButtonPlan($button_l, 0,1);
1136             if ($button_leg_only)
1137               rotate([-90,90,0])
1138                 translate([phone_width/2, -400, kppe[1]])
1139                 mirror([1-abs($rhsflip - keeper_side),0,0])
1140                 cube([400, 800, 50]);
1141             if (enable_support && !$button_suppress_over_keeper)
1142               rotate([-90,90,0])
1143               translate([-400, -400, kppd[1]])
1144                 mirror([0,0,1])
1145                 cube([800,800,100]);
1146           }
1147           translate([0,0, -bppR[0]])
1148             linear_extrude(height= 20)
1149             ButtonPlan($button_l, 1,1);
1150         }
1151
1152     }
1153
1154     // apertures along top edge
1155     CaseAperture(jack_pos, jack_dia, 8);
1156     Flip_rhs(1)
1157       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1158
1159     OrdinaryRearApertures();
1160
1161     MicroUSB();
1162
1163     // gaps for the lid's hinge arms
1164     HingePortion(hex20 - hinge_x_arms_gap,
1165                  hex21 + hinge_x_arms_gap)
1166       minkowski(){
1167         HingeLidProfile();
1168         circle(r= hinge_r_arms_gap, $fn= 8);
1169       }
1170
1171     // screw holes in the hinge arms
1172     HingeScrews();
1173
1174     // thumb recess
1175     ThumbRecessApply(epp4[1])
1176       ThumbRecessCutProfile();
1177
1178     // lanyard
1179     Flip_bot(1)
1180       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1181       rotate([0, ly_theta, 0])
1182       rotate([0,0,90])
1183       LanyardCutout(lanyard_channel_len);
1184
1185     // prop recess
1186     Flip_rhs(1)
1187       translate([prop_x_pos,0,0])
1188       mirror([0,1,0])
1189       rotate([90,0,90])
1190       linextr(-prop_recess_hw, +prop_recess_hw)
1191       hull(){
1192         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1193           circleat(prcp1 + 20*d,
1194                    prc_r3);
1195       }
1196   }
1197 }
1198
1199 module LidAdhocMultiprintFrame(phase){
1200   if (led_window_style >= 3) {
1201     AdhocMultiprintFrame(phase, lpp13[1], -1);
1202   }
1203 }
1204
1205 module LidAroundEdges(){
1206   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1207     children();
1208 }
1209
1210 module Lid(){ ////toplevel
1211   skew_centre = [0, lpp11[0], lpp11[1]];
1212   difference(){
1213     union(){
1214       intersection(){
1215         LidAroundEdges()
1216           LidEdgeProfile();
1217
1218         translate(skew_centre)
1219           multmatrix([[ 1, 0, 0, 0 ],
1220                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1221                       [ 0, 0, 1, 0 ],
1222                       [ 0, 0, 0, 1 ]])
1223           translate(-skew_centre)
1224           LidAroundEdges()
1225           LidEdgeFoldClearanceProfile();
1226       }
1227
1228       // button covers
1229       Buttons(){
1230         intersection(){
1231           rotate([90,0,90])
1232             translate([0,0,-10])
1233             linear_extrude(height= 20)
1234             ButtonPlan($button_l, 1,0);
1235           union(){
1236             rotate([90,0,0])
1237               translate([0,0,-100])
1238               linear_extrude(height= 200)
1239               ButtonCoverProfile();
1240             hull()
1241               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1242                                  - lid_buttoncover_reinf))
1243                 translate([0,y,0])
1244                   ButtonCoverReinf();
1245           }
1246         }
1247       }
1248
1249       // hinge arms
1250       HingePortion(hex20, hex21) {
1251         LidEdgeProfile();
1252         HingeLidProfile();
1253       }
1254     }
1255     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1256
1257     // screw holes in the hinge arms
1258     HingeScrews();
1259
1260     // prop recess
1261     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1262       mirror([0,1,0])
1263       rotate([90,0,90])
1264       linextr(-prop_recess_hw, +prop_recess_hw)
1265       hull()
1266       for (pa = prop_angles)
1267         PropProfile(pa, 1,1);
1268
1269     // notification led aperture
1270     if (led_window_style)
1271       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1272         translate([0,0,-10])
1273           cylinder(r=nla_r0, h=20);
1274         if (led_window_style >= 2)
1275           translate([0,0, -nla_t])
1276             cylinder(r=nla_r2, height=20);
1277       }
1278
1279     }
1280
1281   LidAdhocMultiprintFrame(1);
1282 }
1283
1284 module HingeLever(){ ////toplevel
1285   difference() {
1286     // outer body, positive
1287     HingePortion(hex22, hex22 + phone_width/2)
1288       HingeLeverOuterProfile();
1289
1290     // space for the screws
1291     HingePortion(hex26, hex24)
1292       HingeLeverInnerProfile();
1293
1294     // recesses for the nuts
1295     HingePortion(hex23, hex26+1)
1296       HingeLeverNutProfile();
1297
1298     // bores for the screws
1299     HingeScrews();
1300
1301     // space for the charging cable
1302     MicroUSB();
1303     Flip_hinge() MicroUSB();
1304   }
1305 }
1306
1307 module LidWindow(){ ////toplevel
1308   translate([led_pos[0], -led_pos[1], lpp13[1]])
1309     mirror([0,0,1])
1310     cylinder(r= nla_r1, h=nla_t);
1311   LidAdhocMultiprintFrame(0);
1312 }
1313
1314 module LidWindowPrint(){ ////toplevel
1315   rotate([0,180,0])
1316     LidWindow();
1317 }
1318
1319 module DemoLidWindowSelect(){
1320   translate([led_pos[0], led_pos[1], -100]) {
1321     translate([0, -30, 0]) cube([400, 400, 200]);
1322   }
1323 }
1324
1325 module DemoLidWindow(){ ////toplevel
1326   %Lid();
1327   LidWindow();
1328   translate([0,40,0]){
1329     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1330     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1331   }
1332 }
1333
1334 module HingeLeverPrint(){ ////toplevel
1335   rotate([-90,0,0])
1336     translate([-phone_width/2, phone_height, 0])
1337     HingeLever();
1338 }
1339
1340 module TestSelectLength(){
1341   translate([-30, -200, -20])
1342     cube([30 + 15, 250, 40]);
1343 }
1344
1345 module TestLength(){ ////toplevel
1346   intersection(){
1347     Case();
1348     TestSelectLength();
1349   }
1350 }
1351
1352 module TestLengthRight(){ ////toplevel
1353   intersection(){
1354     Case();
1355     Flip_rhs(1)
1356       TestSelectLength();
1357   }
1358 }
1359
1360 module TestSelectWidth(){
1361   translate([-30, -(phone_height - 25), -20])
1362     mirror([0, 1, 0])
1363     cube([200, 50, 40]);
1364 }
1365
1366 module TestWidth(){ ////toplevel
1367   intersection(){
1368     Case();
1369     TestSelectWidth();
1370   }
1371 }
1372
1373 module TestLidWidthPrint(){ ////toplevel
1374   rotate([0,180.0]) intersection(){
1375     Lid();
1376     TestSelectWidth();
1377   }
1378 }
1379
1380 module TestSelectRearAperture(){
1381   minkowski(){
1382     union() children();
1383     translate([20, 0,0])
1384       cube([42, 2, 1], center=true);
1385   }
1386 }
1387
1388 module TestSelectCamera(){
1389   minkowski(){
1390     TestSelectRearAperture()
1391       RearCameraAperture();
1392     cube([0.1, 50, 0.1]);
1393   }
1394 }
1395
1396 module TestSelectOrdinaryRearApertures(){
1397   TestSelectRearAperture()
1398     OrdinaryRearApertures();
1399 }
1400
1401 module TestCamera(){ ////toplevel
1402   intersection(){
1403     Case();
1404     TestSelectCamera();
1405   }
1406 }
1407
1408 module TestLidByCamera(){ ////toplevel
1409   intersection(){
1410     Lid();
1411     TestSelectCamera();
1412   }
1413 }
1414
1415 module TestLidByCameraPrint(){ ////toplevel
1416   rotate([180,0,0]) TestLidByCamera();
1417 }
1418
1419 module DemoByCamera(){ ////toplevel
1420   color("blue") TestLidByCamera();
1421   color("red")  TestCamera();
1422 }
1423
1424 module OneKeeper(){ ////toplevel
1425   translate([0, -phone_cnr_rad, 0])
1426     rotate([90, 0, 0])
1427     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1428     KeeperProfile();
1429 }
1430
1431 module OneKeeperPrint(){ ////toplevel
1432   rotate([0,180,0])
1433     OneKeeper();
1434 }
1435
1436 module LidPrint(){ ////toplevel
1437   rotate([0,180,0])
1438     Lid();
1439 }
1440
1441 module TestSelectFrame(){
1442   include = [1,-1] * (epp2i[0] + 4);
1443
1444   difference(){
1445     cube(1000, center=true);
1446     translate([0,0, -100])
1447       linear_extrude(height=200)
1448       rectfromto(include,  inside_br - include);
1449   }
1450 }
1451
1452 module TestSelectLidFrame(){
1453   TestSelectFrame();
1454   translate([led_pos[0], -led_pos[1], -50])
1455     cylinder(r= nla_r2+3, h=100);
1456 }
1457
1458 module TestFrameCase(){ ////toplevel
1459   intersection(){
1460     Case();
1461     union(){
1462       TestSelectFrame();
1463       TestSelectCamera();
1464       TestSelectOrdinaryRearApertures();
1465     }
1466   }
1467 }
1468
1469 module TestSelectTopApertures(){
1470   translate([-100, -35, -100])
1471     cube([400, 100, 200]);
1472   LidAdhocMultiprintFrame(0);
1473   LidAdhocMultiprintFrame(1);
1474 }
1475
1476 module TestTopApertures(){ ////toplevel
1477   intersection(){
1478     Case();
1479     TestSelectFrame();
1480     TestSelectTopApertures();
1481   }
1482 }
1483
1484 module TestLidTopAperturesPrint(){ ////toplevel
1485   rotate([0,180,0]) intersection(){
1486     Lid();
1487     TestSelectLidFrame();
1488     TestSelectTopApertures();
1489   }
1490 }
1491
1492 module TestLidWindowTopAperturesPrint(){ ////toplevel
1493   rotate([0,180,0]) intersection(){
1494     LidWindow();
1495     TestSelectTopApertures();
1496   }
1497 }
1498
1499 module TestFrameLidPrint(){ ////toplevel
1500   rotate([0,180,0]) intersection(){
1501     Lid();
1502     TestSelectLidFrame();
1503   }
1504 }
1505
1506 module ButtonPlanForDemo(z, deep, cut){
1507   translate([0,0,z])
1508     ButtonPlan(8, deep, cut);
1509 }
1510
1511 module HingeScrews(){
1512   Flip_rhs() Flip_bot(1){
1513     for (c= [ hppT, hppB ])
1514       translate([ hex20,
1515                   -c[0],
1516                   c[1] ]){
1517         rotate([0,90,0])
1518           translate([0,0,-.2])
1519           cylinder( r= hingescrew_shaft_dia/2,
1520                     h = hingescrew_shaft_len+0.2 );
1521         rotate([0,-90,0])
1522           translate([0,0,+.1])
1523           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1524       }
1525   }
1526 }
1527
1528 module DemoPropAngleSelect(c){
1529   color(c) difference(){
1530     union(){ children(); }
1531     translate([ prop_x_pos, -400, -200 ])
1532       cube([ 400,800,400 ]);
1533   }
1534 }
1535
1536 module DemoPropAngle(ang){
1537   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1538   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1539
1540   translate(hL)
1541     rotate([ang/2,0,0])
1542     translate(-hL)
1543     translate(hC)
1544     rotate([ang/2,0,0])
1545     translate(-hC) {
1546       DemoPropAngleSelect("red") Case();
1547
1548       color("orange")
1549         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1550         PropProfileAssignments(ang) {
1551           echo($prpp1);
1552           rotate([-$prp_theta, 0, 0])
1553           translate([0, $prpp1[0], -$prpp1[1]])
1554           rotate([90,0,-90])
1555           Prop();
1556         }
1557     }
1558
1559   translate([0,0, -hp_k*2])
1560     DemoPropAngleSelect("blue")
1561     Lid();
1562 }
1563
1564 module DemoPropAngles(){ ////toplevel
1565   for (i=[0 : len(prop_angles)-1])
1566     translate(i * [0, -100, 100])
1567     DemoPropAngle(prop_angles[i]);
1568 }
1569
1570 module DemoHingeAngle(ang1,ang2){
1571   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1572   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1573
1574   translate(hL)
1575     rotate([ang2,0,0])
1576     translate(-hL)
1577     translate(hC)
1578     rotate([ang1,0,0])
1579     translate(-hC) {
1580       color("red") Lid();
1581     }
1582
1583   color("blue") intersection(){
1584     Case();
1585     union(){
1586       translate([bppJ[0], -400, -200])
1587         mirror([1,0,0])
1588         cube([400, 800, 400]);
1589       translate([10, -400, -200])
1590         cube([10, 800, 400]);
1591     }
1592   }
1593 }
1594
1595 module DemoHingeAngles(){ ////toplevel
1596   angles = [ 0, 4, 8, 12 ];
1597   echo("angles",angles);
1598   for (i=[0 : len(angles)-1]) {
1599     translate(i * [0, 0, 30]) {
1600       DemoHingeAngle(0,angles[i]);
1601       translate([0, 200, 0])
1602         DemoHingeAngle(angles[i],0);
1603     }
1604   }
1605 }
1606
1607 module DemoSelectAdhocLeftRight(right=0) {
1608   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1609     mirror([1-right, 0,0])
1610     cube([400, 800, 200]);
1611 }
1612
1613 module DemoLeft(){ ////toplevel
1614   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1615   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1616 }
1617
1618 module DemoFrame(){ ////toplevel
1619   color("red") TestFrameCase();
1620   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1621   color("black") HingeScrews();
1622   %HingeLever();
1623 }
1624
1625 module DemoLanyardCutout(){ ////toplevel
1626   LanyardCutout(25);
1627 }
1628
1629 module DemoHingedFrame(){ ///toplevel
1630   color("red") TestFrameCase();
1631   translate([0,0, -2*hp_k])
1632   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1633
1634   Flip_hinge(){
1635     color("orange") HingeLever();
1636     color("black") HingeScrews();
1637   }
1638 }
1639
1640 module DemoHinge(){ ////toplevel
1641   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1642     DemoFrame();
1643     translate([0,0, -hp_k*3])
1644       DemoHingedFrame();
1645   }
1646 }
1647
1648 module DemoProfiles(){ ////toplevel
1649   LidEdgeProfile();
1650   %EdgeProfile();
1651   KeeperProfile();
1652   translate([0,0,-1]) color("black") KeeperProfile(1);
1653   translate(ly_o){
1654     rotate(-ly_theta){
1655       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1656       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1657       translate([0, ly_q_z]){
1658         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1659         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1660       }
1661     }
1662   }
1663   translate([0,0,-5]) color("white") translate(epp2i)
1664     rotate(-ly_theta)
1665     rectfromto([-15, 0],
1666                [+15, -max_case_bottom_edge_thickness]);
1667
1668   translate([0,20]) {
1669     LanyardMainChannelProfile();
1670     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1671     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1672   }
1673
1674   translate([20,0]) {
1675     LidEdgeProfile();
1676     %EdgeProfile();
1677
1678     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1679
1680     color("blue") ButtonCoverProfile();
1681     color("red") {
1682       rectfromto(bppQ, demopoint_QR);
1683       rectfromto(bppR, demopoint_QR);
1684     }
1685   }
1686
1687   translate([-20,0]) {
1688     color("black") ButtonPlanForDemo(-2, 0,1);
1689     color("red" )  ButtonPlanForDemo(-4, 1,1);
1690     color("blue")  ButtonPlanForDemo(-6, 1,0);
1691   }
1692
1693   translate([0, -30]) {
1694     %LidEdgeProfile();
1695     %EdgeProfile();
1696     color("blue") HingeLidProfile();
1697     color("red")  HingeBaseProfile();
1698     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1699   }
1700
1701   for (f=[0,1]) {
1702     translate([-30, -60 + 30*f]) {
1703       translate([0,0,-4]) EdgeProfile();
1704       %translate([0,0,-10]) HingeBaseProfile();
1705       translate([0,-2] * f * hp_k) {
1706         translate([0,0,-4]) LidEdgeProfile();
1707         %translate([0,0,-10]) %HingeLidProfile();
1708       }
1709       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1710         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1711         translate([0,0,0]) color("red") difference(){
1712           HingeLeverOuterProfile();
1713           HingeLeverInnerProfile();
1714         }
1715         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1716       }
1717     }
1718   }
1719
1720   translate([20,-30]) {
1721     %EdgeProfile();
1722     %LidEdgeProfile();
1723     //translate([0,0,1]) ThumbRecessCutProfile();
1724     translate([0,0,+1]) color("red")
1725       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1726   }
1727
1728   translate([40,-30]) {
1729     difference(){
1730       LidEdgeProfile();
1731       translate(prlp10)
1732         PropProfile(10, 1, 0);
1733     }
1734     translate(prlp10)
1735       PropProfile(15, 0);
1736   }
1737   translate([60,-30]) {
1738     PropAggregateProfile();
1739   }
1740 }
1741
1742 //EdgeProfile();
1743 //KeeperProfile();
1744 //CaseBase();
1745 //%Case();
1746 //Keeper();
1747 //LidEdgeProfile();
1748 //KeeperProfile();
1749 //DemoProfiles();
1750 //PropRecess();