fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone_height = 146.5 - .80;
   4 phone_width = 76.75 - .50;
   5
   6 phone_cnr_rad = 6.0;
   7
   8 button_cutout_depth = 9;
   9
  10 phone_edge_thick = 9.0;
  11 phone_total_thick = 12.0;
  12 phone_backside_slope_inner = 1.5; // larger means shallower
  13 phone_backside_slope_outer = 1.0; // larger means shallower
  14
  15 camera_pos_tl = [  7.0, 13.0 ]; // measured from tl corner
  16 camera_pos_br = [ 22.85,37.85]; // tl/br as seen from back
  17
  18 case_th_bottom = 2.5;
  19 case_th_lid = 2.5;
  20 case_th_side = 2;
  21 case_th_lip = 1.2;
  22
  23 case_struts_count = 6;
  24 case_struts_solid_below = 1.00;
  25 case_struts_solid_above = 0.75;
  26 case_struts_width = 0.10;
  27
  28 keeper_th_z = 0.75;
  29 keeper_th_x = 0.75;
  30 keeper_inner_width = 2.75;
  31 keeper_inner_height = 2.75;
  32 keeper_slant_slope = 2; // larger means steeper
  33
  34 keeper_gap_z_top = 0.25;
  35 keeper_gap_z_bot = 0.75;
  36 keeper_gap_x     = 0.25;
  37 keeper_gap_x_holes = 0.75;
  38
  39 case_lip = 1.25;
  40
  41 lid_gap_x = 0.25;
  42 lid_gap_z = 0.25;
  43 lid_lip = 1.75;
  44
  45 $fa = 5;
  46 $fs = 0.1;
  47
  48 button_l_fudge = 4.5;
  49
  50 // ---------- calculated ----------
  51
  52 // ----- could be changed -----
  53 lid_buttoncover_gap = lid_gap_x;
  54 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  55
  56 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  57
  58 //lid_lip_overlap_width xxx bad name = ;
  59 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  60
  61 epp0 = [0,0];
  62 epp1 = [0, -phone_edge_thick];
  63 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  64 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  65 epp3 = epp2i + [10, 0];
  66 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  67 epp4 = epp5 + [-1,0] * case_th_side;
  68
  69 kppe = [0,0];
  70 kppd = kppe + [1,0] * keeper_inner_width;
  71 kppc = kppd + [0,1] * keeper_th_z;
  72 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  73 kppf = kppe - [0,1] * keeper_inner_height;
  74 kppa = [ kppb[0], kppf[1] ];
  75
  76 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  77 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  78
  79 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  80
  81 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
  82 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
  83
  84 echo(lpp13 - lpp10);
  85
  86 // button profile
  87 bppM = epp4 + [0,5];
  88 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  89 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
  90 bppS = [ epp1[0], bppR[1] ];
  91 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
  92 bppP = bppQ + [0,1] * lid_buttoncover_gap;
  93 bppO = [ bppN[0], bppP[1] ];
  94 bppL = lpp10 + [5,0];
  95 bppK = [ bppL[0], bppN[1] ];
  96 bppJ = [ bppN[0], bppL[1] ];
  97
  98 module rectfromto(a,b) {
  99   ab = b - a;
 100   translate([min(a[0], b[0]), min(a[1], b[1])])
 101     square([abs(ab[0]), abs(ab[1])]);
 102 }
 103 module circleat(c,r) { translate(c) circle(r); }
 104
 105 module KeeperProfile(slant=0){
 106   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 107   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 108 }
 109
 110 module EdgeProfile(){
 111   difference(){
 112     hull(){
 113       translate(epp3) square(case_th_bottom*2, center=true);
 114       circleat(epp2o, r=case_th_bottom);
 115       circleat(epp1, r=case_th_side);
 116       rectfromto(epp0, epp4);
 117     }
 118     polygon([ epp5 + [0,10],
 119               epp1,
 120               epp2i,
 121               epp3 + [10,0] ]);
 122   }
 123 }
 124
 125 module LidEdgeProfile(){
 126   polygon([ lpp10,
 127             lpp11,
 128             lpp12,
 129             lpp13,
 130             lpp13 + [10, 0],
 131             lpp10 + [10, 0]
 132             ]);
 133   intersection(){
 134     circleat(lpp12, r=lp_r12);
 135     rectfromto( lpp12 + [-10,   0],
 136                 lpp12 + [+10, +10] );
 137   }
 138 }
 139
 140 module ButtonCoverProfile(){
 141   intersection(){
 142     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 143     hull(){
 144       EdgeProfile();
 145       LidEdgeProfile();
 146     }
 147   }
 148 }
 149
 150 module ButtonPlan(l, deep, cut){
 151   bigger =
 152     (deep ? lid_buttoncover_overlap : 0) +
 153     (cut  ? 0 : -lid_buttoncover_gap);
 154
 155   d_D1_y =
 156     (cut  ? 0 : lid_buttoncover_gap);
 157
 158   C = [0,0]; // by definition
 159   T = [ 0, epp4[1] ];
 160   G = T + [0,10];
 161   B0 = C + [0,-1] * button_cutout_depth;
 162   r0 = 0.5 * (T[1] - B0[1]);
 163   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 164   r1 = r0 + bigger;
 165   // | D1 - A | = r1 * 2
 166   // D1_y = T_y - r1 + d_D1_y
 167   // =>    4 * r1^2   =  (r1-r0 + d_D1_y)^2 + (D1_x - A_x)^2
 168   // =>    D1_x =  A_x + v/~ [  4 * r1^2   -   (r1-r0 + d_D1_y)^2 ]
 169   D1  = [ A[0] - sqrt( 4*r1*r1 - pow(bigger + d_D1_y, 2) ),
 170           T[1] - r1 + d_D1_y ];
 171   E1  = 0.5 * (D1 + A);
 172   F1  = D1 + [0,10];
 173
 174   hull(){
 175     for (m=[0,1]) mirror([m,0])
 176       circleat(A, r1);
 177   }
 178   for (m=[0,1]) mirror([m,0]) {
 179     difference(){
 180       polygon([ E1,
 181                 A,
 182                 B0,
 183                 G,
 184                 F1,
 185                 D1
 186                 ]);
 187       circleat(D1, r1);
 188     }
 189   }
 190 }
 191
 192 module CaseBase_rhsflip(yn=[0,1]) {
 193   for (rhs=yn) {
 194     translate([phone_width/2, 0, 0])
 195       mirror([rhs,0,0])
 196       translate([-phone_width/2, 0, 0])
 197       children();
 198   }
 199 }
 200
 201 module CaseBase_botflip() {
 202   for (bot=[0,1]) {
 203     translate([0, -phone_height/2, 0])
 204       mirror([0, bot, 0])
 205       translate([0, phone_height/2, 0])
 206       children();
 207   }
 208 }
 209
 210 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 211   // sides
 212   CaseBase_rhsflip(){
 213     translate([0, -phone_cnr_rad, 0])
 214       rotate([90,0,0])
 215       linear_extrude(height = phone_height - phone_cnr_rad*2)
 216       children(0);
 217   }
 218   // corners
 219   CaseBase_rhsflip() CaseBase_botflip() {
 220     translate([+1,-1] * phone_cnr_rad)
 221       intersection(){
 222         rotate_extrude()
 223           intersection(){
 224             mirror([1,0,0])
 225               translate([-1,0] * phone_cnr_rad)
 226               children(0);
 227             rectfromto([0,-20],[10,20]);
 228           }
 229         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 230           cube([10,10,40]);
 231       }
 232   }
 233   // top and bottom
 234   CaseBase_botflip(){
 235     translate([ phone_width - phone_cnr_rad, 0,0 ])
 236       rotate([90,0,-90])
 237       linear_extrude(height = phone_width - phone_cnr_rad*2)
 238       children(0);
 239   }
 240   // fill
 241   translate([0,0, fill_zstart])
 242     mirror([0,0, fill_downwards])
 243     linear_extrude(height = fill_th)
 244     rectfromto([+1,-1] * phone_cnr_rad,
 245                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 246 }
 247
 248 module Struts(z_min, th){
 249   for (i= [1 : 1 : case_struts_count]) {
 250     translate([0,
 251                0,
 252                z_min])
 253       translate([0,
 254                -phone_height * i / (case_struts_count+1),
 255                case_struts_solid_below])
 256       linear_extrude(height= th
 257                      -(case_struts_solid_below+case_struts_solid_above))
 258       rectfromto([               epp2i[0], -0.5 * case_struts_width ],
 259                  [ phone_width - epp2i[0], +0.5 * case_struts_width ]);
 260   }
 261 }
 262
 263 module CaseBase(){
 264   AroundEdges(epp3[1], case_th_bottom, 1)
 265     EdgeProfile();
 266 }
 267
 268 module Case(){ ////toplevel
 269   difference(){
 270     union(){
 271       CaseBase();
 272
 273       // ledge (fixed keeper)
 274       intersection(){
 275         rotate([90, 0, 0])
 276           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 277           KeeperProfile(1);
 278
 279         // outline of the whole case, to stop it protruding
 280         translate([0,0, -25])
 281           linear_extrude(height = 50)
 282           hull()
 283           // CaseBase_rhsflip() // actually, we only care about the LH
 284           CaseBase_botflip()
 285           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 286       }
 287     }
 288
 289     // slot for keeper
 290     CaseBase_rhsflip(1)
 291       translate([0, -phone_cnr_rad, 0])
 292       rotate([90, 0, 0])
 293       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 294       minkowski(){
 295         KeeperProfile();
 296         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 297                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 298       }
 299
 300     // front camera
 301     CaseBase_rhsflip([1])
 302       mirror([0, 0, 1])
 303       linear_extrude(height = 20)
 304       mirror([0, 1, 0])
 305       rectfromto(camera_pos_tl, camera_pos_br);
 306
 307     // struts (invisible, because they're buried in the case)
 308     Struts(epp2i[1] - case_th_bottom, case_th_bottom);
 309   }
 310 }
 311
 312 module Lid(){ ////toplevel
 313   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 314     LidEdgeProfile();
 315 }
 316
 317 module TestLength(){ ////toplevel
 318   intersection(){
 319     Case();
 320     translate([-30, -200, -20])
 321     cube([30 + 15, 250, 40]);
 322   }
 323 }
 324
 325 module TestWidth(){ ////toplevel
 326   intersection(){
 327     Case();
 328     translate([-30, -(phone_height - 25), -20])
 329       mirror([0, 1, 0])
 330       cube([200, 50, 40]);
 331   }
 332 }
 333
 334 module TestLidWidthPrint(){ ////toplevel
 335   rotate([0,180.0])
 336     intersection(){
 337       Lid();
 338       translate([-30, -(phone_height - 25), -20])
 339         mirror([0, 1, 0])
 340         cube([200, 50, 40]);
 341     }
 342 }
 343
 344 module TestCamera(){ ////toplevel
 345   intersection(){
 346     Case();
 347     CaseBase_rhsflip(1)
 348       translate([0,0,-25])
 349       linear_extrude(height = 50)
 350       mirror([0, 1, 0])
 351       rectfromto([-20, -20],
 352                  camera_pos_br + [ 5, 5 ]);
 353   }
 354 }
 355
 356 module OneKeeper(){ ////toplevel
 357   translate([0, -phone_cnr_rad, 0])
 358     rotate([90, 0, 0])
 359     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 360     KeeperProfile();
 361 }
 362
 363 module OneKeeperPrint(){ ////toplevel
 364   rotate([0,180,0])
 365     OneKeeper();
 366 }
 367
 368 module Keeper(){ ////toplevel
 369   CaseBase_rhsflip()
 370     OneKeeper();
 371 }
 372
 373 module ButtonPlanForDemo(colour, z, deep, cut){
 374   color(colour)
 375     translate([0,0,z])
 376     ButtonPlan(8, deep, cut);
 377 }
 378
 379 module DemoProfiles(){ ////toplevel
 380   LidEdgeProfile();
 381   %EdgeProfile();
 382   KeeperProfile();
 383   translate([0,0,-1]) color("black") KeeperProfile(1);
 384
 385   translate([20,0]) {
 386     LidEdgeProfile();
 387     %EdgeProfile();
 388
 389     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 390
 391     color("blue") ButtonCoverProfile();
 392     color("red") {
 393       rectfromto(bppQ, demopoint_QR);
 394       rectfromto(bppR, demopoint_QR);
 395     }
 396   }
 397
 398   translate([-20,0]) {
 399     ButtonPlanForDemo("grey", -1, 0,1);
 400     ButtonPlanForDemo("blue", -2, 1,0);
 401     ButtonPlanForDemo("red",  -3, 1,1);
 402   }
 403 }
 404
 405 //EdgeProfile();
 406 //KeeperProfile();
 407 //CaseBase();
 408 //%Case();
 409 //Keeper();
 410 //LidEdgeProfile();
 411 //KeeperProfile();
 412 //DemoProfiles();