fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207
 208 catch_slop = 0.50;
 209
 210 foldover_gap = 0.50;
 211 foldover_lever_gap = 0.50;
 212
 213 // properties of the hinge fasteners
 214 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 215 hingescrew_shaft_len = 12;
 216 hingescrew_fasteners_extra_thick = 0.40;
 217 // ^ amount of thread protruding if everything was completely nominal
 218 //   and we are using two nuts
 219 hingescrew_nut_access_dia = 4.72 + 0.50;
 220 // ^ washer is 4.72 dia
 221 //   also, want to get pliers or tiny spanner in to do up locknut
 222 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 223 hingescrew_nut_thick = 1.93;
 224 hingescrew_head_th = 1.38 + 0.75;
 225 hingescrew_head_dia = 3.92;
 226
 227 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 228
 229 lever_cover_th = 0.75;
 230 hingemount_th = 2.5;
 231 hingemount_wd = 4.8725;
 232
 233 $fa = 5;
 234 $fs = 0.1;
 235
 236 button_l_fudge = 4.4;
 237 buttonishleg_default_l_is_fudge = 10;
 238
 239 hinge_base_slope = 1.5; // bigger is steeper
 240
 241 strut_min_at_end = 1.5;
 242
 243 hinge_x_gap = 0.125;
 244 hinge_x_postscrew_gap = 0.75;
 245 hinge_x_arms_gap = 0.35;
 246 hinge_r_arms_gap = 0.55;
 247
 248 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 249
 250 catch_len = 7.5;
 251 catch_width = 15;
 252 catch_thickness = 1.0;
 253 catch_side_gap = 0.75; // each side
 254
 255 catch_depth = 0.75;
 256 catch_height = 0.35;
 257 catch_finger_height = 1.5;
 258 catch_finger_depth = 2.5;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 // ---------- calculated ----------
 274
 275 phone_width =  (phone + bumper*2)[0];
 276 phone_height = (phone + bumper*2)[1];
 277
 278 inside_br = [phone_width, -phone_height];
 279
 280 prop_prong_h = prop_main_th;
 281
 282 //echo(camera_pos_tl + bumper,
 283 //     camera_pos_br + bumper);
 284
 285 // ----- could be changed -----
 286 lid_buttoncover_gap = lid_gap_x;
 287 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 288
 289 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 290
 291 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 292
 293 //prop_nose_len = case_th_lid - prop_recess_under;
 294 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 295 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 296
 297
 298 //lid_lip_overlap_width xxx bad name = ;
 299 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 300
 301 epp0 = [0,0];
 302 epp1 = [0, -phone_edge_thick];
 303 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 304 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 305 epp3 = epp2i + [10, 0];
 306 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 307 epp4 = epp5 + [-1,0] * case_th_side;
 308
 309 kppe = [0,0];
 310 kppd = kppe + [1,0] * keeper_inner_width;
 311 kppc = kppd + [0,1] * keeper_th_z;
 312 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 313 kppf = kppe - [0,1] * keeper_inner_height;
 314 kppa = [ kppb[0], kppf[1] ];
 315
 316 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 317 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 318
 319 lpp14 = lpp10 + [1,0] * keeper_inner_width;
 320 // exact x posn not very important; must extend past end of keeper
 321
 322 lpp15 = [ lpp14[0],
 323           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 324           + lid_screen_gap_extra ];
 325 // ^ beam theory says to maximise force before contact,
 326 //   the gap below the `beam' (the lid) must be 1/3
 327 //   the thickness (ie the lid thickness) if the beam
 328 //   is solid, or 1/2 if it has a top and bottom only.
 329 //   ours is mostly solid.
 330
 331 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 332              case_th_lip);
 333
 334 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 335 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 336
 337 case_bottom_z = epp2o[1] - case_th_bottom;
 338
 339 // button profile
 340 bppM = epp4 + [0,5];
 341 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 342 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 343 bppS = [ epp1[0], bppR[1] ];
 344 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 345 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 346 bppO = [ bppN[0], bppP[1] ];
 347 bppL = lpp10 + [5,0];
 348 bppK = [ bppL[0], bppN[1] ];
 349 bppJ = [ bppN[0], bppL[1] ];
 350 bppU = [ bppJ[0], lpp12[1] ];
 351 bppV = lpp11;
 352 bppW = lpp10;
 353
 354 // notification led aperture
 355
 356 nla_r0 = led_aperture/2;
 357 nla_r1 = nla_r0 + led_window_ledge;
 358 nla_r2 = nla_r1 + multicolour_gap;
 359 nla_t =
 360   led_window_style >= 3 ? initial_layer_thick :
 361   led_window_style >= 2 ? led_window_ledge : 0;
 362
 363
 364 // hinge plan
 365 hp_rn = hingescrew_nut_access_dia/2;
 366 hp_r2_min = hp_rn + lever_cover_th;
 367 hp_rs = hingescrew_shaft_dia/2;
 368 hp_r1_min = hp_rs + hingemount_th;
 369
 370 hp_r1 = max(hp_r1_min, hp_r2_min);
 371 hp_r2 = hp_r1;
 372
 373 hppU = lpp13;
 374 hppS = epp2o + [0,-1] * case_th_bottom;
 375 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 376
 377 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 378          0.5 * (hppU + hppS)[1] ];
 379 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 380 hppB = hppT + [0,-1] * hp_k;
 381
 382 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 383 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 384 hppE = [ hppE_x, hppE_y ];
 385
 386 // hinge elevation x coords
 387
 388 hex20 = max(epp2o[0],
 389             phone_cnr_rad,
 390             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 391 hex21 = hex20 + hingemount_wd;
 392 hex22 = hex21 + hinge_x_gap;
 393 hex27 = hex20 + hingescrew_shaft_len;
 394 hex24 = hex27 + hinge_x_postscrew_gap;
 395 hex23 = hex27 - (hingescrew_nut_thick*2
 396                  + hingescrew_fasteners_extra_thick);
 397 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 398
 399 echo(hex20, hex21, hex22, hex23, hex24);
 400 //  6, 10.8725, 10.9975, 13.74, 18.75
 401 module chk(act,exp) {
 402   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 403   else echo("ok", act);
 404 }
 405 chk(hex20, 6);
 406 chk(hex21, 10.8725);
 407 chk(hex22, 10.9975);
 408 chk(hex23, 13.74);
 409 chk(hex24, 18.75);
 410
 411 lid_close_clearance_skew =
 412   (lpp10[1] - hppB[1]) /
 413   (lpp10[0] - hppB[0]);
 414
 415 echo("SK",lid_close_clearance_skew);
 416
 417 // catch
 418
 419 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 420 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 421 cppB = [ epp0[0], cppA[1] ];
 422 cppP = [ epp4[0], cppJ[1] ];
 423
 424 cppS = cppJ + [0,-1] * catch_len;
 425 cppD = [ cppA[0], cppS[1] + catch_slop ];
 426 cppC = [ cppB[0], cppD[1] ];
 427 cppT = cppS + [1,0] * catch_depth;
 428 cppU = cppT + [0,-1] * catch_height;
 429 cppV = [ cppS[0], cppU[1] - catch_depth ];
 430
 431 cppR = 0.5*(cppP + cppJ);
 432
 433 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 434 cppQ = [ cppR[0],
 435          cppV[1] - (catch_finger_height - cp_rQ) ];
 436 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 437
 438 // prop recess in case
 439
 440 prop_x_pos = phone_width/2;
 441
 442 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 443
 444 prc_r1 = prop_end_dia/2;
 445 prc_r3 = prc_r1 + prop_recess_slop;
 446
 447 prcp2 = [ epp4[0] + prop_buildout_less,
 448           case_bottom_z ];
 449
 450 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 451
 452 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 453           epp2i[1] - prc_r3 - prop_recess_under];
 454
 455 // prop recess in lid
 456
 457 prl_r10 = prop_end_dia/2;
 458 prl_r10o = prl_r10 + prop_recess_slop;
 459
 460 prlp10 = lpp10 + [1,1] * prl_r10o
 461   + [1,0] * prop_lidrecess_behind
 462   + [0,1] * prop_recess_under;
 463
 464 // prop
 465
 466 $prpp10 = [0,0];
 467 $prpp11 = [0, prop_taper_len];
 468
 469 $prp_r10 = prl_r10;
 470
 471 // ---------- modules ----------
 472
 473 module AdhocMultiprintFrame(phase, z0, zs) {
 474   // from z0 to z0 + zs*layer
 475   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 476   xextra = extra + -epp4[0];
 477   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 478   yextra = extra + -epp4[0];
 479   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 480   p0 = [ xrange[0], yrange[0] ];
 481   p1 = [ xrange[1], yrange[1] ];
 482   echo(p0, p1);
 483   translate([0,0, z0])
 484     mirror([0,0, zs<0 ? 1 : 0])
 485     linear_extrude(height= initial_layer_thick)
 486     difference(){
 487       rectfromto(p0 - [1,1] * initial_layer_width,
 488                  p1 + [1,1] * initial_layer_width);
 489       rectfromto(p0, p1);
 490     }
 491 }
 492
 493 module KeeperProfile(slant=0){
 494   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 495   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 496 }
 497
 498 module EdgeProfile(){
 499   difference(){
 500     hull(){
 501       translate(epp3) square(case_th_bottom*2, center=true);
 502       circleat(epp2o, r=case_th_bottom);
 503       circleat(epp1, r=case_th_side);
 504       rectfromto(epp0, epp4);
 505     }
 506     polygon([ epp5 + [0,10],
 507               epp1,
 508               epp2i,
 509               epp3 + [10,0] ]);
 510   }
 511 }
 512
 513 module LidEdgeProfile(){
 514   polygon([ lpp10,
 515             lpp11,
 516             lpp12,
 517             lpp13,
 518             lpp13 + [10, 0],
 519             lpp15 + [10, 0],
 520             lpp15,
 521             lpp14,
 522             ]);
 523   intersection(){
 524     circleat(lpp12, r=lp_r12);
 525     rectfromto( lpp12 + [-10,   0],
 526                 lpp12 + [+10, +10] );
 527   }
 528 }
 529
 530 module LidEdgeFoldClearanceProfile(){
 531   polygon([ lpp10,
 532             lpp11,
 533             lpp11 + [-20,  0],
 534             lpp11 + [-20, 20],
 535             lpp11 + [+20, 20],
 536             lpp10 + [+20,  0] ]);
 537 }
 538
 539 module ButtonCoverProfile(){
 540   intersection(){
 541     polygon(concat([ bppM, bppP, bppO, bppJ ],
 542                    (enable_support && !$button_suppress_over_keeper
 543                     ? [ bppU, bppV, bppW ] : []),
 544                    [ bppL, bppK ]));
 545     hull(){
 546       EdgeProfile();
 547       LidEdgeProfile();
 548     }
 549   }
 550 }
 551
 552 module ButtonPlan(l, deep, cut){
 553   epsilon =
 554     (cut  ? 0 : lid_buttoncover_gap);
 555
 556   delta =
 557     (deep ? lid_buttoncover_overlap : 0);
 558
 559   C = [0,0]; // by definition
 560   T = [ 0, epp4[1] ];
 561   G = T + [0,10];
 562
 563   B0 = C + [0,-1] * button_cutout_depth;
 564   B1 = B0 + [0,1] * epsilon;
 565
 566   r0 = 0.5 * (T[1] - B0[1]);
 567   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 568   H = A + [0,-1] * delta;
 569
 570   D = A + [-2,0] * r0;
 571   F = D + [0,10];
 572
 573   E0 = 0.5 * (D + A);
 574   E1 = E0 + [1,0] * epsilon;
 575
 576   I0 = [ E0[0], H[1] ];
 577   I1 = [ E1[0], H[1] ];
 578
 579   hull(){
 580     for (m=[0,1]) mirror([m,0])
 581       circleat(H, r0 - epsilon);
 582   }
 583   for (m=[0,1]) mirror([m,0]) {
 584     difference(){
 585       polygon([ E1,
 586                 I1,
 587                 H,
 588                 B1,
 589                 G,
 590                 F,
 591                 D
 592                 ]);
 593       circleat(D, r0 + epsilon);
 594     }
 595   }
 596 }
 597
 598 module CatchCatchProfile(){
 599   hull(){
 600     for (c=[ cppR, cppQ ])
 601       circleat(c, cp_rQ);
 602   }
 603   hull(){
 604     circleat(lpp12, lp_r12);
 605     circleat(lpp12 + [5,0], lp_r12);
 606     rectfromto(cppP, cppP + [5,0.1]);
 607   }
 608   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 609 }
 610
 611 module CatchCutProfile(){
 612   polygon([ cppB,
 613             cppA,
 614             cppD,
 615             cppF,
 616             cppF + [0,-10],
 617             cppF + [-10,-10],
 618             lpp12 + [-10,0],
 619             lpp12 + [10,0]
 620             ]);
 621 }
 622
 623 module Flip_rhs(yn=[0,1]) {
 624   for ($rhsflip=yn) {
 625     translate([phone_width/2, 0, 0])
 626       mirror([$rhsflip,0,0])
 627       translate([-phone_width/2, 0, 0])
 628       children();
 629   }
 630 }
 631
 632 module Flip_bot(yn=[0,1]) {
 633   for ($botflip=yn) {
 634     translate([0, -phone_height/2, 0])
 635       mirror([0, $botflip, 0])
 636       translate([0, phone_height/2, 0])
 637       children();
 638   }
 639 }
 640
 641 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 642   // sides
 643   Flip_rhs(){
 644     translate([0, -phone_cnr_rad, 0])
 645       rotate([90,0,0])
 646       linear_extrude(height = phone_height - phone_cnr_rad*2)
 647       children(0);
 648   }
 649   // corners
 650   Flip_rhs() Flip_bot() {
 651     translate([+1,-1] * phone_cnr_rad)
 652       intersection(){
 653         rotate_extrude()
 654           intersection(){
 655             mirror([1,0,0])
 656               translate([-1,0] * phone_cnr_rad)
 657               children(0);
 658             rectfromto([0,-20],[10,20]);
 659           }
 660         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 661           cube([10,10,40]);
 662       }
 663   }
 664   // top and bottom
 665   Flip_bot(){
 666     translate([ phone_width - phone_cnr_rad, 0,0 ])
 667       rotate([90,0,-90])
 668       linear_extrude(height = phone_width - phone_cnr_rad*2)
 669       children(0);
 670   }
 671   // fill
 672   translate([0,0, fill_zstart])
 673     mirror([0,0, fill_downwards])
 674     linear_extrude(height = fill_th)
 675     rectfromto([+1,-1] * phone_cnr_rad,
 676                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 677 }
 678
 679 module CaseAperture(pos, dia, $fn) {
 680   theta = 180/$fn;
 681   translate([ pos[0] + bumper[0],
 682               -epp2i[0],
 683               -pos[1] ])
 684     rotate([-90, theta, 0])
 685     cylinder(r = dia/2 / cos(theta),
 686              h = 60);
 687 }
 688
 689 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 690   // y_ref_sign:
 691   //   +1  measured from top    of actual phone to top    of button
 692   //   -1  measured from bottom of actual phone to bottom of button
 693   //    0  y is centre of button in coordinate system
 694   $button_l= l;
 695   $button_suppress_over_keeper= suppress_over_keeper;
 696   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 697           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 698           y;
 699   //echo(eff_y);
 700   translate([0, eff_y, 0])
 701     children();
 702 }
 703
 704 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 705   $button_leg_only = true;
 706   SideButton(y, y_ref_sign, l) children();
 707 }
 708
 709 module Buttons(){
 710   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 711   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 712   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 713   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 714 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 715 }
 716
 717 module Struts(x_start, z_min, th){
 718   // if th is negative, starts at z_min and works towards -ve z
 719   // and object should then be printed other way up
 720   for (i= [1 : 1 : case_struts_count]) {
 721     translate([0,
 722                0,
 723                z_min])
 724       mirror([0,0, th<0 ? 1 : 0])
 725       translate([0,
 726                  -phone_height * i / (case_struts_count+1),
 727                  case_struts_solid_below])
 728       linear_extrude(height= abs(th)
 729                      -(case_struts_solid_below+case_struts_solid_above))
 730       rectfromto([               x_start, -0.5 * case_struts_width ],
 731                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 732   }
 733 }
 734
 735 module OrdinaryRearAperture(rhs,bot, pos){
 736   Flip_rhs(rhs) Flip_bot(bot)
 737     linextr(-20, 20)
 738     mirror([0,1])
 739     translate(pos + bumper)
 740     children();
 741 }
 742
 743 module MicroUSB(){
 744   Flip_bot(1){
 745     rotate([90,0,0])
 746       mirror([0,0,1])
 747       linextr(-epp2i[0], 60)
 748       translate([0.5 * phone_width, 0, 0])
 749       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 750                  [+microusb_width/2, epp0[1] + -microusb_above]);
 751   }
 752 }
 753
 754 module OrdinaryRearApertures(){
 755   // rear speaker
 756   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 757     rectfromto(-rearspeaker_gap,
 758                rearspeaker_size + rearspeaker_gap);
 759
 760   // finger hole to remove phone
 761   if (len(fingerpushhole_dias))
 762     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 763                                 phone[1]/2 ])
 764     scale(fingerpushhole_dias)
 765     circle(r= 0.5 );
 766 }
 767
 768 module RearCameraAperture(){
 769   Flip_rhs(1)
 770     mirror([0, 0, 1])
 771     linear_extrude(height = 20)
 772     mirror([0, 1, 0])
 773     translate(bumper)
 774     rectfromto(camera_pos_tl, camera_pos_br);
 775 }
 776
 777 module HingeLidProfile(){
 778   hull(){
 779     circleat(hppT, hp_r1);
 780     circleat(lpp12, lp_r12);
 781     polygon([lpp10,
 782              lpp13 + [2,0],
 783              lpp12,
 784              hppT]);
 785   }
 786 }
 787
 788 module HingeBaseProfile(){
 789   difference(){
 790     hull(){
 791       circleat(hppB, hp_r1);
 792       circleat(hppE, hp_r1);
 793       circleat(epp2o, case_th_bottom);
 794       circleat(hppB + [10,0], hp_r1);
 795     }
 796     polygon([epp5, epp1, epp2i, epp3, bppL]);
 797   }
 798 }
 799
 800 module HingeLeverOuterProfile(){
 801   hull(){
 802     circleat(hppT, hp_r2);
 803     circleat(hppB, hp_r2);
 804   }
 805 }
 806
 807 module HingeLeverInnerProfile(){
 808   for (s = [-1,+1]) {
 809     c = s > 0 ? hppT : hppB;
 810     translate(c)
 811       mirror([0,0,s>0])
 812       rotate(s<0 ? -40 : 0)
 813       hull()
 814       for (x=[-20,20])
 815         for (y=[0, s * 10])
 816           translate([x,y])
 817             circle(hp_rn);
 818   }
 819 }
 820
 821 module HingeLeverNutProfile(){
 822   for (c= [hppB, hppT]) {
 823     translate(c)
 824       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 825   }
 826 }
 827
 828 module Flip_hinge(doflip=1){
 829   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 830   translate(hinge_origin)
 831     rotate([doflip*180,0,0])
 832     translate(-hinge_origin)
 833     children();
 834 }
 835
 836 module HingePortion(x0,x1){
 837   Flip_rhs() Flip_bot(1)
 838     translate([x0,0,0])
 839     mirror([1,0,0])
 840     rotate([90,0,-90])
 841     linear_extrude(height=x1-x0)
 842     children();
 843 }
 844
 845 module CatchPortion(width){
 846   translate([phone_width/2, 0,0])
 847     rotate([90,0,-90])
 848     linextr(-width/2, width/2)
 849     children(0);
 850 }
 851
 852 module CaseBase(){
 853   AroundEdges(epp3[1], case_th_bottom, 1)
 854     EdgeProfile();
 855 }
 856
 857 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 858
 859 module PropProfileAssignments(gamma){
 860   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 861   x = prop_x(gamma);
 862   p = phone_height + prlp10[0] - hppB[0];
 863   b = p + x;
 864
 865   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 866   a = q + x;
 867   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 868   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 869
 870   $prp_theta = 90 - $prp_alpha;
 871   beta = 180 - $prp_alpha - gamma;
 872   psi = 90 - beta;
 873
 874   //echo("abc", a,b,c);
 875
 876   v1 = [ [ cos(psi), -sin(psi) ],    // x
 877          [ sin(psi),  cos(psi) ] ];  // y
 878
 879   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 880
 881   $prp_r1 = prc_r1;
 882   $prp_r11 = prop_main_th/2;
 883
 884   $prpp1 = $prpp7 + [1,0] *
 885     // this is approximate, but will do
 886     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 887   $prpp3 = $prpp1 +
 888     v1[0] * -$prp_r1 +
 889     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 890   $prpp12 = $prpp3 + v1[0] *
 891     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 892   $prp_r8 = prop_main_th;
 893   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 894   $prp_r5 = $prp_r8;
 895   $prpp5 = [ $prpp12[0] - $prp_r5,
 896             $prpp3[1] - prop_prong_h + $prp_r5 ];
 897   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 898          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 899   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 900   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 901
 902   children();
 903 }
 904
 905 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 906   PropProfileAssignments(gamma){
 907
 908     //#circleat($prpp3,1);
 909     //#circleat($prpp12,1);
 910
 911     if (!cut) {
 912       hull(){
 913         translate($prpp8)
 914           intersection(){
 915             circle($prp_r8);
 916             polygon([[-20,-0], [20,20], [0,0]]);
 917           }
 918         rectfromto($prpp6, $prpp9);
 919         translate($prpp5) intersection(){
 920           circle($prp_r5);
 921           polygon([[-10,-10], [0,0], [10,0]]);
 922         }
 923         rectfromto($prpp12 + [0,-0.1], $prpp3);
 924       }
 925       hull(){
 926         circleat($prpp1, $prp_r1);
 927         rectfromto($prpp12 + [0,-0.1], $prpp3);
 928       }
 929     }
 930     // main shaft
 931     rotate([0,0, rot*-$prp_theta]){
 932       hull(){
 933         extra = cut ? prop_recess_slop : 0;
 934         rectfromto($prpp6, $prpp9);
 935         circleat($prpp11, $prp_r11 + extra);
 936         circleat($prpp10, $prp_r10 + extra);
 937       }
 938     }
 939   }
 940 }
 941
 942 module PropAggregateProfile(){
 943   for (angle = prop_angles)
 944     PropProfile(angle, 0,0);
 945 }
 946
 947 module Prop(){ ////toplevel
 948   hw = prop_main_width/2;
 949   linextr(-hw, +hw)
 950     PropAggregateProfile();
 951 }
 952
 953 module Case(){ ////toplevel
 954   difference(){
 955     union(){
 956       CaseBase();
 957
 958       // ledge (fixed keeper)
 959       Flip_rhs(1-keeper_side) intersection(){
 960         rotate([90, 0, 0])
 961           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 962           KeeperProfile(1);
 963
 964         // outline of the whole case, to stop it protruding
 965         translate([0,0, -25])
 966           linear_extrude(height = 50)
 967           hull()
 968           Flip_bot()
 969           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 970       }
 971
 972       // hinge
 973       HingePortion(hex20, hex21) HingeBaseProfile();
 974
 975       // buildout for prop recess
 976       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 977         linextr(case_bottom_z, epp2i[1])
 978         hull() {
 979           for (dxs = [-1,+1])
 980             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 981                        -epp2o[0] ],
 982                      r = epp2o[0] - prcp2[0]);
 983         }
 984     }
 985
 986     // slot for keeper
 987     Flip_rhs(keeper_side)
 988       translate([0, -phone_cnr_rad, 0])
 989       rotate([90, 0, 0])
 990       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 991       minkowski(){
 992         KeeperProfile();
 993         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 994                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 995       }
 996
 997     // front camera
 998     RearCameraAperture();
 999
1000     // struts (invisible, because they're buried in the case)
1001     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1002
1003     Buttons(){
1004       mirror([1,0,0])
1005         rotate([90,0,90]) {
1006           if (!($button_leg_only && enable_support))
1007           intersection(){
1008             translate([0,0,-10])
1009               linear_extrude(height= 20)
1010               ButtonPlan($button_l, 0,1);
1011             if ($button_leg_only)
1012               rotate([-90,90,0])
1013                 translate([phone_width/2, -400, kppe[1]])
1014                 mirror([1-abs($rhsflip - keeper_side),0,0])
1015                 cube([400, 800, 50]);
1016             if (enable_support && !$button_suppress_over_keeper)
1017               rotate([-90,90,0])
1018               translate([-400, -400, kppd[1]])
1019                 mirror([0,0,1])
1020                 cube([800,800,100]);
1021           }
1022           translate([0,0, -bppR[0]])
1023             linear_extrude(height= 20)
1024             ButtonPlan($button_l, 1,1);
1025         }
1026
1027     }
1028
1029     // apertures along top edge
1030     CaseAperture(jack_pos, jack_dia, 8);
1031     Flip_rhs(1)
1032       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1033
1034     OrdinaryRearApertures();
1035
1036     MicroUSB();
1037
1038     // gaps for the lid's hinge arms
1039     HingePortion(hex20 - hinge_x_arms_gap,
1040                  hex21 + hinge_x_arms_gap)
1041       minkowski(){
1042         HingeLidProfile();
1043         circle(r= hinge_r_arms_gap, $fn= 8);
1044       }
1045
1046     // screw holes in the hinge arms
1047     HingeScrews();
1048
1049     // catch striker
1050     CatchPortion(catch_width + catch_side_gap*2)
1051       CatchCutProfile();
1052
1053     // prop recess
1054     Flip_rhs(1)
1055       translate([prop_x_pos,0,0])
1056       mirror([0,1,0])
1057       rotate([90,0,90])
1058       linextr(-prop_recess_hw, +prop_recess_hw)
1059       hull(){
1060         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1061           circleat(prcp1 + 20*d,
1062                    prc_r3);
1063       }
1064   }
1065 }
1066
1067 module LidAdhocMultiprintFrame(phase){
1068   if (led_window_style >= 3) {
1069     AdhocMultiprintFrame(phase, lpp13[1], -1);
1070   }
1071 }
1072
1073 module LidAroundEdges(){
1074   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
1075     children();
1076 }
1077
1078 module Lid(){ ////toplevel
1079   skew_centre = [0, lpp11[0], lpp11[1]];
1080   difference(){
1081     union(){
1082       intersection(){
1083         LidAroundEdges()
1084           LidEdgeProfile();
1085
1086         translate(skew_centre)
1087           multmatrix([[ 1, 0, 0, 0 ],
1088                       [ 0, 1, -lid_close_clearance_skew, 0 ],
1089                       [ 0, 0, 1, 0 ],
1090                       [ 0, 0, 0, 1 ]])
1091           translate(-skew_centre)
1092           LidAroundEdges()
1093           LidEdgeFoldClearanceProfile();
1094       }
1095
1096       // button covers
1097       Buttons(){
1098         intersection(){
1099           rotate([90,0,90])
1100             translate([0,0,-10])
1101             linear_extrude(height= 20)
1102             ButtonPlan($button_l, 1,0);
1103           rotate([90,0,0])
1104              translate([0,0,-100])
1105             linear_extrude(height= 200)
1106             ButtonCoverProfile();
1107         }
1108       }
1109
1110       // hinge arms
1111       HingePortion(hex20, hex21) {
1112         LidEdgeProfile();
1113         HingeLidProfile();
1114       }
1115
1116       // catch
1117       CatchPortion(catch_width)
1118         CatchCatchProfile();
1119     }
1120     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1121
1122     // screw holes in the hinge arms
1123     HingeScrews();
1124
1125     // prop recess
1126     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1127       mirror([0,1,0])
1128       rotate([90,0,90])
1129       linextr(-prop_recess_hw, +prop_recess_hw)
1130       hull()
1131       for (pa = prop_angles)
1132         PropProfile(pa, 1,1);
1133
1134     // notification led aperture
1135     if (led_window_style)
1136       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1137         translate([0,0,-10])
1138           cylinder(r=nla_r0, h=20);
1139         if (led_window_style >= 2)
1140           translate([0,0, -nla_t])
1141             cylinder(r=nla_r2, height=20);
1142       }
1143
1144     }
1145
1146   LidAdhocMultiprintFrame(1);
1147 }
1148
1149 module HingeLever(){ ////toplevel
1150   difference() {
1151     // outer body, positive
1152     HingePortion(hex22, hex22 + phone_width/2)
1153       HingeLeverOuterProfile();
1154
1155     // space for the screws
1156     HingePortion(hex26, hex24)
1157       HingeLeverInnerProfile();
1158
1159     // recesses for the nuts
1160     HingePortion(hex23, hex26+1)
1161       HingeLeverNutProfile();
1162
1163     // bores for the screws
1164     HingeScrews();
1165
1166     // space for the charging cable
1167     MicroUSB();
1168     Flip_hinge() MicroUSB();
1169   }
1170 }
1171
1172 module LidWindow(){ ////toplevel
1173   translate([led_pos[0], -led_pos[1], lpp13[1]])
1174     mirror([0,0,1])
1175     cylinder(r= nla_r1, h=nla_t);
1176   LidAdhocMultiprintFrame(0);
1177 }
1178
1179 module LidWindowPrint(){ ////toplevel
1180   rotate([0,180,0])
1181     LidWindow();
1182 }
1183
1184 module DemoLidWindowSelect(){
1185   translate([led_pos[0], led_pos[1], -100]) {
1186     translate([0, -30, 0]) cube([400, 400, 200]);
1187   }
1188 }
1189
1190 module DemoLidWindow(){ ////toplevel
1191   %Lid();
1192   LidWindow();
1193   translate([0,40,0]){
1194     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1195     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1196   }
1197 }
1198
1199 module HingeLeverPrint(){ ////toplevel
1200   rotate([-90,0,0])
1201     translate([-phone_width/2, phone_height, 0])
1202     HingeLever();
1203 }
1204
1205 module TestSelectLength(){
1206   translate([-30, -200, -20])
1207     cube([30 + 15, 250, 40]);
1208 }
1209
1210 module TestLength(){ ////toplevel
1211   intersection(){
1212     Case();
1213     TestSelectLength();
1214   }
1215 }
1216
1217 module TestLengthRight(){ ////toplevel
1218   intersection(){
1219     Case();
1220     Flip_rhs(1)
1221       TestSelectLength();
1222   }
1223 }
1224
1225 module TestSelectWidth(){
1226   translate([-30, -(phone_height - 25), -20])
1227     mirror([0, 1, 0])
1228     cube([200, 50, 40]);
1229 }
1230
1231 module TestWidth(){ ////toplevel
1232   intersection(){
1233     Case();
1234     TestSelectWidth();
1235   }
1236 }
1237
1238 module TestLidWidthPrint(){ ////toplevel
1239   rotate([0,180.0]) intersection(){
1240     Lid();
1241     TestSelectWidth();
1242   }
1243 }
1244
1245 module TestSelectRearAperture(){
1246   minkowski(){
1247     union() children();
1248     translate([20, 0,0])
1249       cube([42, 2, 1], center=true);
1250   }
1251 }
1252
1253 module TestSelectCamera(){
1254   minkowski(){
1255     TestSelectRearAperture()
1256       RearCameraAperture();
1257     cube([0.1, 50, 0.1]);
1258   }
1259 }
1260
1261 module TestSelectOrdinaryRearApertures(){
1262   TestSelectRearAperture()
1263     OrdinaryRearApertures();
1264 }
1265
1266 module TestCamera(){ ////toplevel
1267   intersection(){
1268     Case();
1269     TestSelectCamera();
1270   }
1271 }
1272
1273 module TestLidByCamera(){ ////toplevel
1274   intersection(){
1275     Lid();
1276     TestSelectCamera();
1277   }
1278 }
1279
1280 module TestLidByCameraPrint(){ ////toplevel
1281   rotate([180,0,0]) TestLidByCamera();
1282 }
1283
1284 module DemoByCamera(){ ////toplevel
1285   color("blue") TestLidByCamera();
1286   color("red")  TestCamera();
1287 }
1288
1289 module OneKeeper(){ ////toplevel
1290   translate([0, -phone_cnr_rad, 0])
1291     rotate([90, 0, 0])
1292     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1293     KeeperProfile();
1294 }
1295
1296 module OneKeeperPrint(){ ////toplevel
1297   rotate([0,180,0])
1298     OneKeeper();
1299 }
1300
1301 module LidPrint(){ ////toplevel
1302   rotate([0,180,0])
1303     Lid();
1304 }
1305
1306 module TestSelectFrame(){
1307   include = [1,-1] * (epp2i[0] + 4);
1308
1309   difference(){
1310     cube(1000, center=true);
1311     translate([0,0, -100])
1312       linear_extrude(height=200)
1313       rectfromto(include,  inside_br - include);
1314   }
1315 }
1316
1317 module TestSelectLidFrame(){
1318   TestSelectFrame();
1319   translate([led_pos[0], -led_pos[1], -50])
1320     cylinder(r= nla_r2+3, h=100);
1321 }
1322
1323 module TestFrameCase(){ ////toplevel
1324   intersection(){
1325     Case();
1326     union(){
1327       TestSelectFrame();
1328       TestSelectCamera();
1329       TestSelectOrdinaryRearApertures();
1330     }
1331   }
1332 }
1333
1334 module TestSelectTopApertures(){
1335   translate([-100, -35, -100])
1336     cube([400, 100, 200]);
1337   LidAdhocMultiprintFrame(0);
1338   LidAdhocMultiprintFrame(1);
1339 }
1340
1341 module TestTopApertures(){ ////toplevel
1342   intersection(){
1343     Case();
1344     TestSelectFrame();
1345     TestSelectTopApertures();
1346   }
1347 }
1348
1349 module TestLidTopAperturesPrint(){ ////toplevel
1350   rotate([0,180,0]) intersection(){
1351     Lid();
1352     TestSelectLidFrame();
1353     TestSelectTopApertures();
1354   }
1355 }
1356
1357 module TestLidWindowTopAperturesPrint(){ ////toplevel
1358   rotate([0,180,0]) intersection(){
1359     LidWindow();
1360     TestSelectTopApertures();
1361   }
1362 }
1363
1364 module TestFrameLidPrint(){ ////toplevel
1365   rotate([0,180,0]) intersection(){
1366     Lid();
1367     TestSelectLidFrame();
1368   }
1369 }
1370
1371 module ButtonPlanForDemo(z, deep, cut){
1372   translate([0,0,z])
1373     ButtonPlan(8, deep, cut);
1374 }
1375
1376 module HingeScrews(){
1377   Flip_rhs() Flip_bot(1){
1378     for (c= [ hppT, hppB ])
1379       translate([ hex20,
1380                   -c[0],
1381                   c[1] ]){
1382         rotate([0,90,0])
1383           translate([0,0,-.2])
1384           cylinder( r= hingescrew_shaft_dia/2,
1385                     h = hingescrew_shaft_len+0.2 );
1386         rotate([0,-90,0])
1387           translate([0,0,+.1])
1388           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1389       }
1390   }
1391 }
1392
1393 module DemoPropAngleSelect(c){
1394   color(c) difference(){
1395     union(){ children(); }
1396     translate([ prop_x_pos, -400, -200 ])
1397       cube([ 400,800,400 ]);
1398   }
1399 }
1400
1401 module DemoPropAngle(ang){
1402   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1403   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1404
1405   translate(hL)
1406     rotate([ang/2,0,0])
1407     translate(-hL)
1408     translate(hC)
1409     rotate([ang/2,0,0])
1410     translate(-hC) {
1411       DemoPropAngleSelect("red") Case();
1412
1413       color("orange")
1414         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1415         PropProfileAssignments(ang) {
1416           echo($prpp1);
1417           rotate([-$prp_theta, 0, 0])
1418           translate([0, $prpp1[0], -$prpp1[1]])
1419           rotate([90,0,-90])
1420           Prop();
1421         }
1422     }
1423
1424   translate([0,0, -hp_k*2])
1425     DemoPropAngleSelect("blue")
1426     Lid();
1427 }
1428
1429 module DemoPropAngles(){ ////toplevel
1430   for (i=[0 : len(prop_angles)-1])
1431     translate(i * [0, -100, 100])
1432     DemoPropAngle(prop_angles[i]);
1433 }
1434
1435 module DemoHingeAngle(ang1,ang2){
1436   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1437   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1438
1439   translate(hL)
1440     rotate([ang2,0,0])
1441     translate(-hL)
1442     translate(hC)
1443     rotate([ang1,0,0])
1444     translate(-hC) {
1445       color("red") Lid();
1446     }
1447
1448   color("blue") intersection(){
1449     Case();
1450     union(){
1451       translate([bppJ[0], -400, -200])
1452         mirror([1,0,0])
1453         cube([400, 800, 400]);
1454       translate([10, -400, -200])
1455         cube([10, 800, 400]);
1456     }
1457   }
1458 }
1459
1460 module DemoHingeAngles(){ ////toplevel
1461   angles = [ 0, 4, 8, 12 ];
1462   echo("angles",angles);
1463   for (i=[0 : len(angles)-1]) {
1464     translate(i * [0, 0, 30]) {
1465       DemoHingeAngle(0,angles[i]);
1466       translate([0, 200, 0])
1467         DemoHingeAngle(angles[i],0);
1468     }
1469   }
1470 }
1471
1472 module DemoSelectAdhocLeftRight(right=0) {
1473   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1474     mirror([1-right, 0,0])
1475     cube([400, 800, 200]);
1476 }
1477
1478 module DemoLeft(){ ////toplevel
1479   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1480   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1481 }
1482
1483 module DemoFrame(){ ////toplevel
1484   color("red") TestFrameCase();
1485   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1486   color("black") HingeScrews();
1487   %HingeLever();
1488 }
1489
1490 module DemoHingedFrame(){ ///toplevel
1491   color("red") TestFrameCase();
1492   translate([0,0, -2*hp_k])
1493   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1494
1495   Flip_hinge(){
1496     color("orange") HingeLever();
1497     color("black") HingeScrews();
1498   }
1499 }
1500
1501 module DemoHinge(){ ////toplevel
1502   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1503     DemoFrame();
1504     translate([0,0, -hp_k*3])
1505       DemoHingedFrame();
1506   }
1507 }
1508
1509 module DemoProfiles(){ ////toplevel
1510   LidEdgeProfile();
1511   %EdgeProfile();
1512   KeeperProfile();
1513   translate([0,0,-1]) color("black") KeeperProfile(1);
1514
1515   translate([20,0]) {
1516     LidEdgeProfile();
1517     %EdgeProfile();
1518
1519     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1520
1521     color("blue") ButtonCoverProfile();
1522     color("red") {
1523       rectfromto(bppQ, demopoint_QR);
1524       rectfromto(bppR, demopoint_QR);
1525     }
1526   }
1527
1528   translate([-20,0]) {
1529     color("black") ButtonPlanForDemo(-2, 0,1);
1530     color("red" )  ButtonPlanForDemo(-4, 1,1);
1531     color("blue")  ButtonPlanForDemo(-6, 1,0);
1532   }
1533
1534   translate([0, -30]) {
1535     %LidEdgeProfile();
1536     %EdgeProfile();
1537     color("blue") HingeLidProfile();
1538     color("red")  HingeBaseProfile();
1539     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1540   }
1541
1542   for (f=[0,1]) {
1543     translate([-30, -60 + 30*f]) {
1544       translate([0,0,-4]) EdgeProfile();
1545       %translate([0,0,-10]) HingeBaseProfile();
1546       translate([0,-2] * f * hp_k) {
1547         translate([0,0,-4]) LidEdgeProfile();
1548         %translate([0,0,-10]) %HingeLidProfile();
1549       }
1550       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1551         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1552         translate([0,0,0]) color("red") difference(){
1553           HingeLeverOuterProfile();
1554           HingeLeverInnerProfile();
1555         }
1556         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1557       }
1558     }
1559   }
1560
1561   translate([20,-30]) {
1562     %EdgeProfile();
1563     %LidEdgeProfile();
1564     //translate([0,0,1]) CatchCutProfile();
1565     color("blue") CatchCatchProfile();
1566     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1567   }
1568
1569   translate([40,-30]) {
1570     difference(){
1571       LidEdgeProfile();
1572       translate(prlp10)
1573         PropProfile(10, 1, 0);
1574     }
1575     translate(prlp10)
1576       PropProfile(15, 0);
1577   }
1578   translate([60,-30]) {
1579     PropAggregateProfile();
1580   }
1581 }
1582
1583 //EdgeProfile();
1584 //KeeperProfile();
1585 //CaseBase();
1586 //%Case();
1587 //Keeper();
1588 //LidEdgeProfile();
1589 //KeeperProfile();
1590 //DemoProfiles();
1591 //PropRecess();