chiark / gitweb /
59dd894fcbad25d60300a7c8a5513d56b0192cb0
[reprap-play.git] / fairphone-case.scad
1 // -*- C -*-
2
3 phone = [ 75.0, 145.0 ];
4
5 bumper = [ 0.250, 0.250 ];
6 // ^ One side.  Overall size is increased by twice this.
7 // If no bumpers, is the gap around the phone.
8
9 phone_cnr_rad = 6.0;
10
11 button_cutout_depth = 9;
12
13 phone_edge_thick = 9.0;
14 phone_total_thick = 12.0;
15 phone_backside_slope_inner = 1.5; // larger means shallower
16 phone_backside_slope_outer = 1.0; // larger means shallower
17
18 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
19 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
20
21 jack_pos = [ 13.92, 7.96 ];
22 jack_dia = 9.1 + .5; // some jack I had lying around
23
24 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
25 noisecancelmic_dia = 1.75;
26
27 rearspeaker_pos_bl = [ 14.92, 18.72 ];
28 rearspeaker_size   = [  3.76,  7.36 ];
29
30 case_th_bottom = 2.5;
31 case_th_lid = 2.5;
32 case_th_side = 2;
33 case_th_lip = 1.2;
34
35 case_struts_count = 6;
36 case_struts_solid_below = 1.00;
37 case_struts_solid_above = 0.75;
38 case_struts_width = 0.10;
39
40 keeper_th_z = 0.75;
41 keeper_th_x = 0.75;
42 keeper_inner_width = 2.75;
43 keeper_inner_height = 2.75;
44 keeper_slant_slope = 2; // larger means steeper
45
46 keeper_gap_z_top = 0.25;
47 keeper_gap_z_bot = 0.75;
48 keeper_gap_x     = 0.25;
49 keeper_gap_x_holes = 0.75;
50
51 case_lip = 1.25;
52
53 lid_gap_x = 0.25;
54 lid_gap_z = 0.25;
55 lid_lip = 1.75;
56
57 $fa = 5;
58 $fs = 0.1;
59
60 button_l_fudge = 4.4;
61 buttonishleg_default_l_is_fudge = 10;
62
63 strut_min_at_end = 1.5;
64
65 rearspeaker_gap    = [ 1.0, 1.0 ]; // each side
66
67 // ---------- calculated ----------
68
69 phone_width =  (phone + bumper*2)[0];
70 phone_height = (phone + bumper*2)[1];
71
72 inside_br = [phone_width, -phone_height];
73
74 //echo(camera_pos_tl + bumper,
75 //     camera_pos_br + bumper);
76
77 // ----- could be changed -----
78 lid_buttoncover_gap = lid_gap_x;
79 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
80
81 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
82
83 //lid_lip_overlap_width xxx bad name = ;
84 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
85
86 epp0 = [0,0];
87 epp1 = [0, -phone_edge_thick];
88 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
89 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
90 epp3 = epp2i + [10, 0];
91 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
92 epp4 = epp5 + [-1,0] * case_th_side;
93
94 kppe = [0,0];
95 kppd = kppe + [1,0] * keeper_inner_width;
96 kppc = kppd + [0,1] * keeper_th_z;
97 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
98 kppf = kppe - [0,1] * keeper_inner_height;
99 kppa = [ kppb[0], kppf[1] ];
100
101 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
102 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
103
104 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
105
106 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
107 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
108
109 // button profile
110 bppM = epp4 + [0,5];
111 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
112 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
113 bppS = [ epp1[0], bppR[1] ];
114 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
115 bppP = bppQ + [0,1] * lid_buttoncover_gap;
116 bppO = [ bppN[0], bppP[1] ];
117 bppL = lpp10 + [5,0];
118 bppK = [ bppL[0], bppN[1] ];
119 bppJ = [ bppN[0], bppL[1] ];
120
121 module rectfromto(a,b) {
122   ab = b - a;
123   translate([min(a[0], b[0]), min(a[1], b[1])])
124     square([abs(ab[0]), abs(ab[1])]);
125 }
126 module circleat(c,r) { translate(c) circle(r); }
127 module linextr(z0,z1) {
128   translate([0,0,z0])
129     linear_extrude(height=z1-z0)
130     children();
131 }
132
133 module KeeperProfile(slant=0){
134   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
135   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
136 }
137
138 module EdgeProfile(){
139   difference(){
140     hull(){
141       translate(epp3) square(case_th_bottom*2, center=true);
142       circleat(epp2o, r=case_th_bottom);
143       circleat(epp1, r=case_th_side);
144       rectfromto(epp0, epp4);
145     }
146     polygon([ epp5 + [0,10],
147               epp1,
148               epp2i,
149               epp3 + [10,0] ]);
150   }
151 }
152
153 module LidEdgeProfile(){
154   polygon([ lpp10,
155             lpp11,
156             lpp12,
157             lpp13,
158             lpp13 + [10, 0],
159             lpp10 + [10, 0]
160             ]);
161   intersection(){
162     circleat(lpp12, r=lp_r12);
163     rectfromto( lpp12 + [-10,   0],
164                 lpp12 + [+10, +10] );
165   }
166 }
167
168 module ButtonCoverProfile(){
169   intersection(){
170     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
171     hull(){
172       EdgeProfile();
173       LidEdgeProfile();
174     }
175   }
176 }
177
178 module ButtonPlan(l, deep, cut){
179   epsilon =
180     (cut  ? 0 : lid_buttoncover_gap);
181
182   delta =
183     (deep ? lid_buttoncover_overlap : 0);
184
185   C = [0,0]; // by definition
186   T = [ 0, epp4[1] ];
187   G = T + [0,10];
188
189   B0 = C + [0,-1] * button_cutout_depth;
190   B1 = B0 + [0,1] * epsilon;
191
192   r0 = 0.5 * (T[1] - B0[1]);
193   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
194   H = A + [0,-1] * delta;
195
196   D = A + [-2,0] * r0;
197   F = D + [0,10];
198
199   E0 = 0.5 * (D + A);
200   E1 = E0 + [1,0] * epsilon;
201
202   I0 = [ E0[0], H[1] ];
203   I1 = [ E1[0], H[1] ];
204
205   hull(){
206     for (m=[0,1]) mirror([m,0])
207       circleat(H, r0 - epsilon);
208   }
209   for (m=[0,1]) mirror([m,0]) {
210     difference(){
211       polygon([ E1,
212                 I1,
213                 H,
214                 B1,
215                 G,
216                 F,
217                 D
218                 ]);
219       circleat(D, r0 + epsilon);
220     }
221   }
222 }
223
224 module CaseBase_rhsflip(yn=[0,1]) {
225   for ($rhsflip=yn) {
226     translate([phone_width/2, 0, 0])
227       mirror([$rhsflip,0,0])
228       translate([-phone_width/2, 0, 0])
229       children();
230   }
231 }
232
233 module CaseBase_botflip(yn=[0,1]) {
234   for ($botflip=yn) {
235     translate([0, -phone_height/2, 0])
236       mirror([0, $botflip, 0])
237       translate([0, phone_height/2, 0])
238       children();
239   }
240 }  
241
242 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
243   // sides
244   CaseBase_rhsflip(){
245     translate([0, -phone_cnr_rad, 0])
246       rotate([90,0,0])
247       linear_extrude(height = phone_height - phone_cnr_rad*2)
248       children(0);
249   }
250   // corners
251   CaseBase_rhsflip() CaseBase_botflip() {
252     translate([+1,-1] * phone_cnr_rad)
253       intersection(){
254         rotate_extrude()
255           intersection(){
256             mirror([1,0,0])
257               translate([-1,0] * phone_cnr_rad)
258               children(0);
259             rectfromto([0,-20],[10,20]);
260           }
261         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
262           cube([10,10,40]);
263       }
264   }
265   // top and bottom
266   CaseBase_botflip(){
267     translate([ phone_width - phone_cnr_rad, 0,0 ])
268       rotate([90,0,-90])
269       linear_extrude(height = phone_width - phone_cnr_rad*2)
270       children(0);
271   }
272   // fill
273   translate([0,0, fill_zstart])
274     mirror([0,0, fill_downwards])
275     linear_extrude(height = fill_th)
276     rectfromto([+1,-1] * phone_cnr_rad,
277                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
278 }
279
280 module CaseAperture(pos, dia, $fn) {
281   theta = 180/$fn;
282   translate([ pos[0] + bumper[0],
283               -epp2i[0],
284               -pos[1] ])
285     rotate([-90, theta, 0])
286     cylinder(r = dia/2 / cos(theta),
287              h = 60);
288 }
289
290 module SideButton(y, y_ref_sign, l){
291   // y_ref_sign:
292   //   +1  measured from top    of actual phone to top    of button
293   //   -1  measured from bottom of actual phone to bottom of button
294   //    0  y is centre of button in coordinate system
295   $button_l= l;
296   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
297           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
298           y;
299   echo(eff_y);
300   translate([0, eff_y, 0])
301     children();
302 }
303
304 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
305   $button_leg_only = true;
306   SideButton(y, y_ref_sign, l) children();
307 }
308
309 module Buttons(){
310   CaseBase_rhsflip([1]) SideButton(15.580, +1, 8.9) children(); // power
311   CaseBase_rhsflip([1]) SideButton(48.700, -1, 8.920) children(); // camera
312   CaseBase_rhsflip([0]) SideButton(30.800, +1, 21.96) children(); // volume
313   CaseBase_rhsflip(   ) LidButtonishLeg(20, -1) children();
314 //  CaseBase_rhsflip([0]) LidButtonishLeg(20, +1, 20) children();
315 }
316
317 module Struts(x_start, z_min, th){
318   // if th is negative, starts at z_min and works towards -ve z
319   // and object should then be printed other way up
320   for (i= [1 : 1 : case_struts_count]) {
321     translate([0,
322                0,
323                z_min])
324       mirror([0,0, th<0 ? 1 : 0])
325       translate([0,
326                  -phone_height * i / (case_struts_count+1),
327                  case_struts_solid_below])
328       linear_extrude(height= abs(th)
329                      -(case_struts_solid_below+case_struts_solid_above))
330       rectfromto([               x_start, -0.5 * case_struts_width ],
331                  [ phone_width - x_start, +0.5 * case_struts_width ]);
332   }
333 }
334
335 module CaseBase(){
336   AroundEdges(epp3[1], case_th_bottom, 1)
337     EdgeProfile();
338 }
339
340 module Case(){ ////toplevel
341   difference(){
342     union(){
343       CaseBase();
344
345       // ledge (fixed keeper)
346       intersection(){
347         rotate([90, 0, 0])
348           linear_extrude(height = phone_height + phone_cnr_rad * 2)
349           KeeperProfile(1);
350
351         // outline of the whole case, to stop it protruding
352         translate([0,0, -25])
353           linear_extrude(height = 50)
354           hull()
355           // CaseBase_rhsflip() // actually, we only care about the LH
356           CaseBase_botflip()
357           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
358       }
359     }
360
361     // slot for keeper
362     CaseBase_rhsflip(1)
363       translate([0, -phone_cnr_rad, 0])
364       rotate([90, 0, 0])
365       linear_extrude(height = phone_height + phone_cnr_rad * 2)
366       minkowski(){
367         KeeperProfile();
368         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
369                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
370       }
371
372     // front camera
373     CaseBase_rhsflip([1])
374       mirror([0, 0, 1])
375       linear_extrude(height = 20)
376       mirror([0, 1, 0])
377       translate(bumper)
378       rectfromto(camera_pos_tl, camera_pos_br);
379
380     // struts (invisible, because they're buried in the case)
381     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
382
383     Buttons(){
384       mirror([1,0,0])
385         rotate([90,0,90]) {
386           intersection(){
387             translate([0,0,-10])
388               linear_extrude(height= 20)
389               ButtonPlan($button_l, 0,1);
390             if ($button_leg_only)
391               rotate([-90,90,0])
392                 translate([phone_width/2, -400, kppe[1]])
393                 mirror([$rhsflip,0,0]) cube([400, 800, 50]);
394           }
395           translate([0,0, -bppR[0]])
396             linear_extrude(height= 20)
397             ButtonPlan($button_l, 1,1);
398         }
399     }
400
401     // apertures along top edge
402     CaseAperture(jack_pos, jack_dia, 8);
403     CaseBase_rhsflip([1])
404       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 20);
405
406     // rear speaker
407     CaseBase_rhsflip([1]) CaseBase_botflip([1])
408       linextr(-20, 20)
409       mirror([0,1])
410       translate(rearspeaker_pos_bl + bumper)
411       rectfromto(-rearspeaker_gap,
412                  rearspeaker_size + rearspeaker_gap);
413   }
414 }
415
416 module Lid(){ ////toplevel
417   difference(){
418     union(){
419       AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
420         LidEdgeProfile();
421
422       // button covers
423       Buttons(){
424         intersection(){
425           rotate([90,0,90])
426             translate([0,0,-10])
427             linear_extrude(height= 20)
428             ButtonPlan($button_l, 1,0);
429           rotate([90,0,0])
430              translate([0,0,-100])
431             linear_extrude(height= 200)
432             ButtonCoverProfile();
433         }
434       }
435     }
436     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
437   }
438 }
439
440 module TestLength(){ ////toplevel
441   intersection(){
442     Case();
443     translate([-30, -200, -20])
444     cube([30 + 15, 250, 40]);
445   }
446 }
447
448 module TestSelectWidth(){
449   translate([-30, -(phone_height - 25), -20])
450     mirror([0, 1, 0])
451     cube([200, 50, 40]);
452 }
453
454 module TestWidth(){ ////toplevel
455   intersection(){
456     Case();
457     TestSelectWidth();
458   }
459 }
460
461 module TestLidWidthPrint(){ ////toplevel
462   rotate([0,180.0]) intersection(){
463     Lid();
464     TestSelectWidth();
465   }
466 }
467
468 module TestSelectCamera(){
469   CaseBase_rhsflip(1)
470     translate([0,0,-25])
471     linear_extrude(height = 50)
472     mirror([0, 1, 0])
473     rectfromto([-20, -20],
474                camera_pos_br + bumper + [ 5, 5 ]);
475 }
476
477 module TestSelectRearSpeaker(){
478   CaseBase_rhsflip(1) CaseBase_botflip([1])
479     linextr(-20,20)
480     mirror([0,1,0])
481     translate(rearspeaker_pos_bl + bumper)
482     rectfromto(-(rearspeaker_gap + [40,2]),
483                rearspeaker_size + rearspeaker_gap + [2,2]);
484 }
485
486 module TestCamera(){ ////toplevel
487   intersection(){
488     Case();
489     TestSelectCamera();
490   }
491 }
492
493 module TestLidByCamera(){ ////toplevel
494   intersection(){
495     Lid();
496     TestSelectCamera();
497   }
498 }
499
500 module TestLidByCameraPrint(){ ////toplevel
501   rotate([180,0,0]) TestLidByCamera();
502 }
503
504 module DemoByCamera(){ ////toplevel
505   color("blue") TestLidByCamera();
506   color("red")  TestCamera();
507 }
508
509 module OneKeeper(){ ////toplevel
510   translate([0, -phone_cnr_rad, 0])
511     rotate([90, 0, 0])
512     linear_extrude(height = phone_height - phone_cnr_rad * 2)
513     KeeperProfile();
514 }
515
516 module OneKeeperPrint(){ ////toplevel
517   rotate([0,180,0])
518     OneKeeper();
519 }
520
521 module LidPrint(){ ////toplevel
522   rotate([0,180,0])
523     Lid();
524 }
525
526 module TestSelectFrame(){
527   include = [1,-1] * (epp2i[0] + 4);
528
529   difference(){
530     cube(1000, center=true);
531     translate([0,0, -100])
532       linear_extrude(height=200)
533       rectfromto(include,  inside_br - include);
534   }
535 }
536
537 module TestFrameCase(){ ////toplevel
538   intersection(){
539     Case();
540     union(){
541       TestSelectFrame();
542       TestSelectCamera();
543       TestSelectRearSpeaker();
544     }
545   }
546 }
547
548 module TestFrameLidPrint(){ ////toplevel
549   rotate([0,0,180]) intersection(){
550     Lid();
551     TestSelectFrame();
552   }
553 }
554
555 module Keeper(){ ////toplevel
556   CaseBase_rhsflip()
557     OneKeeper();
558 }
559
560 module ButtonPlanForDemo(z, deep, cut){
561   translate([0,0,z])
562     ButtonPlan(8, deep, cut);
563 }
564
565 module DemoProfiles(){ ////toplevel
566   LidEdgeProfile();
567   %EdgeProfile();
568   KeeperProfile();
569   translate([0,0,-1]) color("black") KeeperProfile(1);
570
571   translate([20,0]) {
572     LidEdgeProfile();
573     %EdgeProfile();
574
575     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
576   
577     color("blue") ButtonCoverProfile();
578     color("red") {
579       rectfromto(bppQ, demopoint_QR);
580       rectfromto(bppR, demopoint_QR);
581     }
582   }
583
584   translate([-20,0]) {
585     color("black") ButtonPlanForDemo(-2, 0,1);
586     color("red" )  ButtonPlanForDemo(-4, 1,1);
587     color("blue")  ButtonPlanForDemo(-6, 1,0);
588   }
589 }
590
591 //EdgeProfile();
592 //KeeperProfile();
593 //CaseBase();
594 //%Case();
595 //Keeper();
596 //LidEdgeProfile();
597 //KeeperProfile();
598 //DemoProfiles();