fairphone-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121
 122 phone = [ 75.0, 145.0 ];
 123
 124 prop_buildout_less = 3;
 125
 126 prop_angles = [ 15, 30, 45, 60 ];
 127
 128 bumper = [ 0.250, -0.025 ];
 129 // ^ One side.  Overall size is increased by twice this.
 130 // If no bumpers, is the gap around the phone.
 131
 132 enable_support = 1;
 133
 134 led_window_style = 3;
 135 // 0: no window
 136 // 1: simply an opening
 137 // 2: opening with separate cover model, for printing in clear (two colour)
 138 // 3: like 2 but one-layer window for ad-hoc multi-colour
 139
 140 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 141 initial_layer_width = 0.750; // ^ needed for mode 3 only
 142 multicolour_gap = 0.15; // each side
 143
 144 phone_cnr_rad = 6.0;
 145 phone_rim_depth = 0.80; // includes allowance for a screen protector
 146
 147 button_cutout_depth = 9;
 148
 149 phone_edge_thick = 9.0;
 150 phone_total_thick = 12.0;
 151 phone_backside_slope_inner = 1.5; // larger means shallower
 152 phone_backside_slope_outer = 1.0; // larger means shallower
 153
 154 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 155 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 156
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 led_pos = [ 13.98, 10.00 ];
 161 led_aperture = 9;
 162 led_window_ledge = 0.75; // each side
 163
 164 noisecancelmic_pos = [ 19.54, 7.37 ];   // from rhs
 165 noisecancelmic_dia = 4.00;
 166
 167 //fingerpushhole_dias = [ 15, 18 ];
 168 fingerpushhole_dias = [];
 169
 170 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 171 rearspeaker_size   = [  3.76,  7.36 ];
 172
 173 microusb_above = 3.27 - 0.25;
 174 microusb_below = 0.0;
 175 microusb_width = 16.12 + 1.25;
 176
 177 case_th_bottom = 2.5;
 178 case_th_lid = 3.0;
 179 case_th_side = 2;
 180 case_th_lip = 1.2;
 181
 182 lid_screen_gap_extra = .66;
 183
 184 case_struts_count = 6;
 185 case_struts_solid_below = 1.00;
 186 case_struts_solid_above = 0.75;
 187 case_struts_width = 0.10;
 188
 189 keeper_th_z = 0.75;
 190 keeper_th_x = 0.75;
 191 keeper_inner_width = 2.75;
 192 keeper_inner_height = 2.75;
 193 keeper_slant_slope = 2; // larger means steeper
 194
 195 keeper_gap_z_top = 0.25;
 196 keeper_gap_z_bot = 0.75;
 197 keeper_gap_x     = 0.25;
 198 keeper_gap_x_holes = 0.75;
 199
 200 keeper_side = 0; // 0 = lhs; 1 = rhs
 201
 202 case_lip = 1.25;
 203
 204 lid_gap_x = 0.25;
 205 lid_gap_z = 0.25;
 206 lid_lip = 1.75;
 207
 208 catch_slop = 0.50;
 209
 210 foldover_gap = 0.50;
 211 foldover_lever_gap = 0.50;
 212
 213 // properties of the hinge fasteners
 214 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 215 hingescrew_shaft_len = 12;
 216 hingescrew_fasteners_extra_thick = 0.40;
 217 // ^ amount of thread protruding if everything was completely nominal
 218 //   and we are using two nuts
 219 hingescrew_nut_access_dia = 4.72 + 0.50;
 220 // ^ washer is 4.72 dia
 221 //   also, want to get pliers or tiny spanner in to do up locknut
 222 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 223 hingescrew_nut_thick = 1.93;
 224 hingescrew_head_th = 1.38 + 0.75;
 225 hingescrew_head_dia = 3.92;
 226
 227 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 228
 229 lever_cover_th = 0.75;
 230 hingemount_th = 2.5;
 231 hingemount_wd = 4.8725;
 232
 233 $fa = 5;
 234 $fs = 0.1;
 235
 236 button_l_fudge = 4.4;
 237 buttonishleg_default_l_is_fudge = 10;
 238
 239 hinge_base_slope = 1.5; // bigger is steeper
 240
 241 strut_min_at_end = 1.5;
 242
 243 hinge_x_gap = 0.125;
 244 hinge_x_postscrew_gap = 0.75;
 245 hinge_x_arms_gap = 0.35;
 246 hinge_r_arms_gap = 0.55;
 247
 248 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 249
 250 catch_len = 7.5;
 251 catch_width = 15;
 252 catch_thickness = 1.0;
 253 catch_side_gap = 0.75; // each side
 254
 255 catch_depth = 0.75;
 256 catch_height = 0.35;
 257 catch_finger_height = 1.5;
 258 catch_finger_depth = 2.5;
 259
 260 prop_recess_under = 0.50;
 261 prop_recess_slop = 0.200; // each side
 262 prop_end_dia = 0.5;
 263 prop_main_th = 3;
 264 prop_taper_len = 6;
 265 prop_main_width = 4;
 266 prop_side_gap = 0.75; // each side
 267 prop_lidrecess_behind = 0.75;
 268 prop_caserecess_behind = 0.75;
 269 prop_caserecess_taper = 0.45; // one side only
 270 prop_prop_gap = 0.5;
 271 prop_prong_heel_slope = 0.5;
 272
 273 // ---------- calculated ----------
 274
 275 phone_width =  (phone + bumper*2)[0];
 276 phone_height = (phone + bumper*2)[1];
 277
 278 inside_br = [phone_width, -phone_height];
 279
 280 prop_prong_h = prop_main_th;
 281
 282 //echo(camera_pos_tl + bumper,
 283 //     camera_pos_br + bumper);
 284
 285 // ----- could be changed -----
 286 lid_buttoncover_gap = lid_gap_x;
 287 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 288
 289 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
 290
 291 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 292
 293 //prop_nose_len = case_th_lid - prop_recess_under;
 294 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 295 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 296
 297
 298 //lid_lip_overlap_width xxx bad name = ;
 299 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 300
 301 epp0 = [0,0];
 302 epp1 = [0, -phone_edge_thick];
 303 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
 304 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
 305 epp3 = epp2i + [10, 0];
 306 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 307 epp4 = epp5 + [-1,0] * case_th_side;
 308
 309 kppe = [0,0];
 310 kppd = kppe + [1,0] * keeper_inner_width;
 311 kppc = kppd + [0,1] * keeper_th_z;
 312 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 313 kppf = kppe - [0,1] * keeper_inner_height;
 314 kppa = [ kppb[0], kppf[1] ];
 315
 316 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 317 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 318
 319 lpp14 = lpp10 + [1,0] * keeper_inner_width;
 320 // exact x posn not very important; must extend past end of keeper
 321
 322 lpp15 = [ lpp14[0],
 323           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 324           + lid_screen_gap_extra ];
 325 // ^ beam theory says to maximise force before contact,
 326 //   the gap below the `beam' (the lid) must be 1/3
 327 //   the thickness (ie the lid thickness) if the beam
 328 //   is solid, or 1/2 if it has a top and bottom only.
 329 //   ours is mostly solid.
 330
 331 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 332              case_th_lip);
 333
 334 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 335 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 336
 337 case_bottom_z = epp2o[1] - case_th_bottom;
 338
 339 // button profile
 340 bppM = epp4 + [0,5];
 341 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
 342 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 343 bppS = [ epp1[0], bppR[1] ];
 344 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 345 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 346 bppO = [ bppN[0], bppP[1] ];
 347 bppL = lpp10 + [5,0];
 348 bppK = [ bppL[0], bppN[1] ];
 349 bppJ = [ bppN[0], bppL[1] ];
 350 bppU = [ bppJ[0], lpp12[1] ];
 351 bppV = lpp11;
 352 bppW = lpp10;
 353
 354 // notification led aperture
 355
 356 nla_r0 = led_aperture/2;
 357 nla_r1 = nla_r0 + led_window_ledge;
 358 nla_r2 = nla_r1 + multicolour_gap;
 359 nla_t =
 360   led_window_style >= 3 ? initial_layer_thick :
 361   led_window_style >= 2 ? led_window_ledge : 0;
 362
 363
 364 // hinge plan
 365 hp_rn = hingescrew_nut_access_dia/2;
 366 hp_r2_min = hp_rn + lever_cover_th;
 367 hp_rs = hingescrew_shaft_dia/2;
 368 hp_r1_min = hp_rs + hingemount_th;
 369
 370 hp_r1 = max(hp_r1_min, hp_r2_min);
 371 hp_r2 = hp_r1;
 372
 373 hppU = lpp13;
 374 hppS = epp2o + [0,-1] * case_th_bottom;
 375 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 376
 377 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 378          0.5 * (hppU + hppS)[1] ];
 379 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 380 hppB = hppT + [0,-1] * hp_k;
 381
 382 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 383 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 384 hppE = [ hppE_x, hppE_y ];
 385
 386 // hinge elevation x coords
 387
 388 hex20 = max(epp2o[0],
 389             phone_cnr_rad,
 390             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 391 hex21 = hex20 + hingemount_wd;
 392 hex22 = hex21 + hinge_x_gap;
 393 hex27 = hex20 + hingescrew_shaft_len;
 394 hex24 = hex27 + hinge_x_postscrew_gap;
 395 hex23 = hex27 - (hingescrew_nut_thick*2
 396                  + hingescrew_fasteners_extra_thick);
 397 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 398
 399 echo(hex20, hex21, hex22, hex23, hex24);
 400 //  6, 10.8725, 10.9975, 13.74, 18.75
 401 module chk(act,exp) {
 402   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 403   else echo("ok", act);
 404 }
 405 chk(hex20, 6);
 406 chk(hex21, 10.8725);
 407 chk(hex22, 10.9975);
 408 chk(hex23, 13.74);
 409 chk(hex24, 18.75);
 410
 411 // catch
 412
 413 cppJ = [ epp4[0] + catch_thickness, lpp10[1] ];
 414 cppA = cppJ + [lid_gap_x, -lid_gap_z];
 415 cppB = [ epp0[0], cppA[1] ];
 416 cppP = [ epp4[0], cppJ[1] ];
 417
 418 cppS = cppJ + [0,-1] * catch_len;
 419 cppD = [ cppA[0], cppS[1] + catch_slop ];
 420 cppC = [ cppB[0], cppD[1] ];
 421 cppT = cppS + [1,0] * catch_depth;
 422 cppU = cppT + [0,-1] * catch_height;
 423 cppV = [ cppS[0], cppU[1] - catch_depth ];
 424
 425 cppR = 0.5*(cppP + cppJ);
 426
 427 cp_rQ = 0.5 * (cppJ[0] - cppP[0]);
 428 cppQ = [ cppR[0],
 429          cppV[1] - (catch_finger_height - cp_rQ) ];
 430 cppF = [ cppV[0] + catch_finger_depth, cppC[1] ];
 431
 432 // prop recess in case
 433
 434 prop_x_pos = phone_width/2;
 435
 436 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 437
 438 prc_r1 = prop_end_dia/2;
 439 prc_r3 = prc_r1 + prop_recess_slop;
 440
 441 prcp2 = [ epp4[0] + prop_buildout_less,
 442           case_bottom_z ];
 443
 444 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 445
 446 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 447           epp2i[1] - prc_r3 - prop_recess_under];
 448
 449 // prop recess in lid
 450
 451 prl_r10 = prop_end_dia/2;
 452 prl_r10o = prl_r10 + prop_recess_slop;
 453
 454 prlp10 = lpp10 + [1,1] * prl_r10o
 455   + [1,0] * prop_lidrecess_behind
 456   + [0,1] * prop_recess_under;
 457
 458 // prop
 459
 460 $prpp10 = [0,0];
 461 $prpp11 = [0, prop_taper_len];
 462
 463 $prp_r10 = prl_r10;
 464
 465 // ---------- modules ----------
 466
 467 module AdhocMultiprintFrame(phase, z0, zs) {
 468   // from z0 to z0 + zs*layer
 469   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 470   xextra = extra + -epp4[0];
 471   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 472   yextra = extra + -epp4[0];
 473   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 474   p0 = [ xrange[0], yrange[0] ];
 475   p1 = [ xrange[1], yrange[1] ];
 476   echo(p0, p1);
 477   translate([0,0, z0])
 478     mirror([0,0, zs<0 ? 1 : 0])
 479     linear_extrude(height= initial_layer_thick)
 480     difference(){
 481       rectfromto(p0 - [1,1] * initial_layer_width,
 482                  p1 + [1,1] * initial_layer_width);
 483       rectfromto(p0, p1);
 484     }
 485 }
 486
 487 module KeeperProfile(slant=0){
 488   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 489   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 490 }
 491
 492 module EdgeProfile(){
 493   difference(){
 494     hull(){
 495       translate(epp3) square(case_th_bottom*2, center=true);
 496       circleat(epp2o, r=case_th_bottom);
 497       circleat(epp1, r=case_th_side);
 498       rectfromto(epp0, epp4);
 499     }
 500     polygon([ epp5 + [0,10],
 501               epp1,
 502               epp2i,
 503               epp3 + [10,0] ]);
 504   }
 505 }
 506
 507 module LidEdgeProfile(){
 508   polygon([ lpp10,
 509             lpp11,
 510             lpp12,
 511             lpp13,
 512             lpp13 + [10, 0],
 513             lpp15 + [10, 0],
 514             lpp15,
 515             lpp14,
 516             ]);
 517   intersection(){
 518     circleat(lpp12, r=lp_r12);
 519     rectfromto( lpp12 + [-10,   0],
 520                 lpp12 + [+10, +10] );
 521   }
 522 }
 523
 524 module LidEdgeFoldClearanceProfile(){
 525   polygon([ lpp10 + [0,  -10],
 526             lpp11,
 527             lpp11 + [20,   0],
 528             lpp10 + [20, -10]
 529             ]);
 530 }
 531
 532 module ButtonCoverProfile(){
 533   intersection(){
 534     polygon(concat([ bppM, bppP, bppO, bppJ ],
 535                    (enable_support && !$button_suppress_over_keeper
 536                     ? [ bppU, bppV, bppW ] : []),
 537                    [ bppL, bppK ]));
 538     hull(){
 539       EdgeProfile();
 540       LidEdgeProfile();
 541     }
 542   }
 543 }
 544
 545 module ButtonPlan(l, deep, cut){
 546   epsilon =
 547     (cut  ? 0 : lid_buttoncover_gap);
 548
 549   delta =
 550     (deep ? lid_buttoncover_overlap : 0);
 551
 552   C = [0,0]; // by definition
 553   T = [ 0, epp4[1] ];
 554   G = T + [0,10];
 555
 556   B0 = C + [0,-1] * button_cutout_depth;
 557   B1 = B0 + [0,1] * epsilon;
 558
 559   r0 = 0.5 * (T[1] - B0[1]);
 560   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 561   H = A + [0,-1] * delta;
 562
 563   D = A + [-2,0] * r0;
 564   F = D + [0,10];
 565
 566   E0 = 0.5 * (D + A);
 567   E1 = E0 + [1,0] * epsilon;
 568
 569   I0 = [ E0[0], H[1] ];
 570   I1 = [ E1[0], H[1] ];
 571
 572   hull(){
 573     for (m=[0,1]) mirror([m,0])
 574       circleat(H, r0 - epsilon);
 575   }
 576   for (m=[0,1]) mirror([m,0]) {
 577     difference(){
 578       polygon([ E1,
 579                 I1,
 580                 H,
 581                 B1,
 582                 G,
 583                 F,
 584                 D
 585                 ]);
 586       circleat(D, r0 + epsilon);
 587     }
 588   }
 589 }
 590
 591 module CatchCatchProfile(){
 592   hull(){
 593     for (c=[ cppR, cppQ ])
 594       circleat(c, cp_rQ);
 595   }
 596   hull(){
 597     circleat(lpp12, lp_r12);
 598     circleat(lpp12 + [5,0], lp_r12);
 599     rectfromto(cppP, cppP + [5,0.1]);
 600   }
 601   polygon([cppJ, cppS, cppT, cppU, cppV, cppQ, cppR]);
 602 }
 603
 604 module CatchCutProfile(){
 605   polygon([ cppB,
 606             cppA,
 607             cppD,
 608             cppF,
 609             cppF + [0,-10],
 610             cppF + [-10,-10],
 611             lpp12 + [-10,0],
 612             lpp12 + [10,0]
 613             ]);
 614 }
 615
 616 module Flip_rhs(yn=[0,1]) {
 617   for ($rhsflip=yn) {
 618     translate([phone_width/2, 0, 0])
 619       mirror([$rhsflip,0,0])
 620       translate([-phone_width/2, 0, 0])
 621       children();
 622   }
 623 }
 624
 625 module Flip_bot(yn=[0,1]) {
 626   for ($botflip=yn) {
 627     translate([0, -phone_height/2, 0])
 628       mirror([0, $botflip, 0])
 629       translate([0, phone_height/2, 0])
 630       children();
 631   }
 632 }
 633
 634 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 635   // sides
 636   Flip_rhs(){
 637     translate([0, -phone_cnr_rad, 0])
 638       rotate([90,0,0])
 639       linear_extrude(height = phone_height - phone_cnr_rad*2)
 640       children(0);
 641   }
 642   // corners
 643   Flip_rhs() Flip_bot() {
 644     translate([+1,-1] * phone_cnr_rad)
 645       intersection(){
 646         rotate_extrude()
 647           intersection(){
 648             mirror([1,0,0])
 649               translate([-1,0] * phone_cnr_rad)
 650               children(0);
 651             rectfromto([0,-20],[10,20]);
 652           }
 653         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 654           cube([10,10,40]);
 655       }
 656   }
 657   // top and bottom
 658   Flip_bot(){
 659     translate([ phone_width - phone_cnr_rad, 0,0 ])
 660       rotate([90,0,-90])
 661       linear_extrude(height = phone_width - phone_cnr_rad*2)
 662       children(0);
 663   }
 664   // fill
 665   translate([0,0, fill_zstart])
 666     mirror([0,0, fill_downwards])
 667     linear_extrude(height = fill_th)
 668     rectfromto([+1,-1] * phone_cnr_rad,
 669                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 670 }
 671
 672 module CaseAperture(pos, dia, $fn) {
 673   theta = 180/$fn;
 674   translate([ pos[0] + bumper[0],
 675               -epp2i[0],
 676               -pos[1] ])
 677     rotate([-90, theta, 0])
 678     cylinder(r = dia/2 / cos(theta),
 679              h = 60);
 680 }
 681
 682 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 683   // y_ref_sign:
 684   //   +1  measured from top    of actual phone to top    of button
 685   //   -1  measured from bottom of actual phone to bottom of button
 686   //    0  y is centre of button in coordinate system
 687   $button_l= l;
 688   $button_suppress_over_keeper= suppress_over_keeper;
 689   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 690           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 691           y;
 692   //echo(eff_y);
 693   translate([0, eff_y, 0])
 694     children();
 695 }
 696
 697 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 698   $button_leg_only = true;
 699   SideButton(y, y_ref_sign, l) children();
 700 }
 701
 702 module Buttons(){
 703   Flip_rhs(1) SideButton(15.580, +1, 8.9     ) children(); // power
 704   Flip_rhs(1) SideButton(48.700, -1, 8.920   ) children(); // camera
 705   Flip_rhs(0) SideButton(30.800, +1, 21.96, 1) children(); // volume
 706   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 707 //  Flip_rhs(0) LidButtonishLeg(20, +1, 20) children();
 708 }
 709
 710 module Struts(x_start, z_min, th){
 711   // if th is negative, starts at z_min and works towards -ve z
 712   // and object should then be printed other way up
 713   for (i= [1 : 1 : case_struts_count]) {
 714     translate([0,
 715                0,
 716                z_min])
 717       mirror([0,0, th<0 ? 1 : 0])
 718       translate([0,
 719                  -phone_height * i / (case_struts_count+1),
 720                  case_struts_solid_below])
 721       linear_extrude(height= abs(th)
 722                      -(case_struts_solid_below+case_struts_solid_above))
 723       rectfromto([               x_start, -0.5 * case_struts_width ],
 724                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 725   }
 726 }
 727
 728 module OrdinaryRearAperture(rhs,bot, pos){
 729   Flip_rhs(rhs) Flip_bot(bot)
 730     linextr(-20, 20)
 731     mirror([0,1])
 732     translate(pos + bumper)
 733     children();
 734 }
 735
 736 module MicroUSB(){
 737   Flip_bot(1){
 738     rotate([90,0,0])
 739       mirror([0,0,1])
 740       linextr(-epp2i[0], 60)
 741       translate([0.5 * phone_width, 0, 0])
 742       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 743                  [+microusb_width/2, epp0[1] + -microusb_above]);
 744   }
 745 }
 746
 747 module OrdinaryRearApertures(){
 748   // rear speaker
 749   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 750     rectfromto(-rearspeaker_gap,
 751                rearspeaker_size + rearspeaker_gap);
 752
 753   // finger hole to remove phone
 754   if (len(fingerpushhole_dias))
 755     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 756                                 phone[1]/2 ])
 757     scale(fingerpushhole_dias)
 758     circle(r= 0.5 );
 759 }
 760
 761 module RearCameraAperture(){
 762   Flip_rhs(1)
 763     mirror([0, 0, 1])
 764     linear_extrude(height = 20)
 765     mirror([0, 1, 0])
 766     translate(bumper)
 767     rectfromto(camera_pos_tl, camera_pos_br);
 768 }
 769
 770 module HingeLidProfile(){
 771   hull(){
 772     circleat(hppT, hp_r1);
 773     circleat(lpp12, lp_r12);
 774     polygon([lpp10,
 775              lpp13 + [2,0],
 776              lpp12,
 777              hppT]);
 778   }
 779 }
 780
 781 module HingeBaseProfile(){
 782   difference(){
 783     hull(){
 784       circleat(hppB, hp_r1);
 785       circleat(hppE, hp_r1);
 786       circleat(epp2o, case_th_bottom);
 787       circleat(hppB + [10,0], hp_r1);
 788     }
 789     polygon([epp5, epp1, epp2i, epp3, bppL]);
 790   }
 791 }
 792
 793 module HingeLeverOuterProfile(){
 794   hull(){
 795     circleat(hppT, hp_r2);
 796     circleat(hppB, hp_r2);
 797   }
 798 }
 799
 800 module HingeLeverInnerProfile(){
 801   for (s = [-1,+1]) {
 802     c = s > 0 ? hppT : hppB;
 803     translate(c)
 804       mirror([0,0,s>0])
 805       rotate(s<0 ? -40 : 0)
 806       hull()
 807       for (x=[-20,20])
 808         for (y=[0, s * 10])
 809           translate([x,y])
 810             circle(hp_rn);
 811   }
 812 }
 813
 814 module HingeLeverNutProfile(){
 815   for (c= [hppB, hppT]) {
 816     translate(c)
 817       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 818   }
 819 }
 820
 821 module Flip_hinge(doflip=1){
 822   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 823   translate(hinge_origin)
 824     rotate([doflip*180,0,0])
 825     translate(-hinge_origin)
 826     children();
 827 }
 828
 829 module HingePortion(x0,x1){
 830   Flip_rhs() Flip_bot(1)
 831     translate([x0,0,0])
 832     mirror([1,0,0])
 833     rotate([90,0,-90])
 834     linear_extrude(height=x1-x0)
 835     children(0);
 836 }
 837
 838 module CatchPortion(width){
 839   translate([phone_width/2, 0,0])
 840     rotate([90,0,-90])
 841     linextr(-width/2, width/2)
 842     children(0);
 843 }
 844
 845 module CaseBase(){
 846   AroundEdges(epp3[1], case_th_bottom, 1)
 847     EdgeProfile();
 848 }
 849
 850 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 851
 852 module PropProfileAssignments(gamma){
 853   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 854   x = prop_x(gamma);
 855   p = phone_height + prlp10[0] - hppB[0];
 856   b = p + x;
 857
 858   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 859   a = q + x;
 860   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 861   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 862
 863   $prp_theta = 90 - $prp_alpha;
 864   beta = 180 - $prp_alpha - gamma;
 865   psi = 90 - beta;
 866
 867   //echo("abc", a,b,c);
 868
 869   v1 = [ [ cos(psi), -sin(psi) ],    // x
 870          [ sin(psi),  cos(psi) ] ];  // y
 871
 872   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
 873
 874   $prp_r1 = prc_r1;
 875   $prp_r11 = prop_main_th/2;
 876
 877   $prpp1 = $prpp7 + [1,0] *
 878     // this is approximate, but will do
 879     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
 880   $prpp3 = $prpp1 +
 881     v1[0] * -$prp_r1 +
 882     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
 883   $prpp12 = $prpp3 + v1[0] *
 884     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
 885   $prp_r8 = prop_main_th;
 886   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
 887   $prp_r5 = $prp_r8;
 888   $prpp5 = [ $prpp12[0] - $prp_r5,
 889             $prpp3[1] - prop_prong_h + $prp_r5 ];
 890   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
 891          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
 892   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
 893   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
 894
 895   children();
 896 }
 897
 898 module PropProfile(gamma, cut=0, rot=0){ ////toplevel
 899   PropProfileAssignments(gamma){
 900
 901     //#circleat($prpp3,1);
 902     //#circleat($prpp12,1);
 903
 904     if (!cut) {
 905       hull(){
 906         translate($prpp8)
 907           intersection(){
 908             circle($prp_r8);
 909             polygon([[-20,-0], [20,20], [0,0]]);
 910           }
 911         rectfromto($prpp6, $prpp9);
 912         translate($prpp5) intersection(){
 913           circle($prp_r5);
 914           polygon([[-10,-10], [0,0], [10,0]]);
 915         }
 916         rectfromto($prpp12 + [0,-0.1], $prpp3);
 917       }
 918       hull(){
 919         circleat($prpp1, $prp_r1);
 920         rectfromto($prpp12 + [0,-0.1], $prpp3);
 921       }
 922     }
 923     // main shaft
 924     rotate([0,0, rot*-$prp_theta]){
 925       hull(){
 926         extra = cut ? prop_recess_slop : 0;
 927         rectfromto($prpp6, $prpp9);
 928         circleat($prpp11, $prp_r11 + extra);
 929         circleat($prpp10, $prp_r10 + extra);
 930       }
 931     }
 932   }
 933 }
 934
 935 module PropAggregateProfile(){
 936   for (angle = prop_angles)
 937     PropProfile(angle, 0,0);
 938 }
 939
 940 module Prop(){ ////toplevel
 941   hw = prop_main_width/2;
 942   linextr(-hw, +hw)
 943     PropAggregateProfile();
 944 }
 945
 946 module Case(){ ////toplevel
 947   difference(){
 948     union(){
 949       CaseBase();
 950
 951       // ledge (fixed keeper)
 952       Flip_rhs(1-keeper_side) intersection(){
 953         rotate([90, 0, 0])
 954           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 955           KeeperProfile(1);
 956
 957         // outline of the whole case, to stop it protruding
 958         translate([0,0, -25])
 959           linear_extrude(height = 50)
 960           hull()
 961           Flip_bot()
 962           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 963       }
 964
 965       // hinge
 966       HingePortion(hex20, hex21) HingeBaseProfile();
 967
 968       // buildout for prop recess
 969       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
 970         linextr(case_bottom_z, epp2i[1])
 971         hull() {
 972           for (dxs = [-1,+1])
 973             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
 974                        -epp2o[0] ],
 975                      r = epp2o[0] - prcp2[0]);
 976         }
 977     }
 978
 979     // slot for keeper
 980     Flip_rhs(keeper_side)
 981       translate([0, -phone_cnr_rad, 0])
 982       rotate([90, 0, 0])
 983       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 984       minkowski(){
 985         KeeperProfile();
 986         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 987                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 988       }
 989
 990     // front camera
 991     RearCameraAperture();
 992
 993     // struts (invisible, because they're buried in the case)
 994     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 995
 996     Buttons(){
 997       mirror([1,0,0])
 998         rotate([90,0,90]) {
 999           if (!($button_leg_only && enable_support))
1000           intersection(){
1001             translate([0,0,-10])
1002               linear_extrude(height= 20)
1003               ButtonPlan($button_l, 0,1);
1004             if ($button_leg_only)
1005               rotate([-90,90,0])
1006                 translate([phone_width/2, -400, kppe[1]])
1007                 mirror([1-abs($rhsflip - keeper_side),0,0])
1008                 cube([400, 800, 50]);
1009             if (enable_support && !$button_suppress_over_keeper)
1010               rotate([-90,90,0])
1011               translate([-400, -400, kppd[1]])
1012                 mirror([0,0,1])
1013                 cube([800,800,100]);
1014           }
1015           translate([0,0, -bppR[0]])
1016             linear_extrude(height= 20)
1017             ButtonPlan($button_l, 1,1);
1018         }
1019
1020     }
1021
1022     // apertures along top edge
1023     CaseAperture(jack_pos, jack_dia, 8);
1024     Flip_rhs(1)
1025       CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1026
1027     OrdinaryRearApertures();
1028
1029     MicroUSB();
1030
1031     // gaps for the lid's hinge arms
1032     HingePortion(hex20 - hinge_x_arms_gap,
1033                  hex21 + hinge_x_arms_gap)
1034       minkowski(){
1035         HingeLidProfile();
1036         circle(r= hinge_r_arms_gap, $fn= 8);
1037       }
1038
1039     // screw holes in the hinge arms
1040     HingeScrews();
1041
1042     // catch striker
1043     CatchPortion(catch_width + catch_side_gap*2)
1044       CatchCutProfile();
1045
1046     // prop recess
1047     Flip_rhs(1)
1048       translate([prop_x_pos,0,0])
1049       mirror([0,1,0])
1050       rotate([90,0,90])
1051       linextr(-prop_recess_hw, +prop_recess_hw)
1052       hull(){
1053         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1054           circleat(prcp1 + 20*d,
1055                    prc_r3);
1056       }
1057   }
1058 }
1059
1060 module LidAdhocMultiprintFrame(phase){
1061   if (led_window_style >= 3) {
1062     AdhocMultiprintFrame(phase, lpp13[1], -1);
1063   }
1064 }
1065
1066 module LidAroundEdges(){
1067   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
1068     children();
1069 }
1070
1071 module Lid(){ ////toplevel
1072   skew_centre = [0, lpp11[0], lpp11[1]];
1073   difference(){
1074     union(){
1075       LidAroundEdges()
1076         LidEdgeProfile();
1077
1078       // button covers
1079       Buttons(){
1080         intersection(){
1081           rotate([90,0,90])
1082             translate([0,0,-10])
1083             linear_extrude(height= 20)
1084             ButtonPlan($button_l, 1,0);
1085           rotate([90,0,0])
1086              translate([0,0,-100])
1087             linear_extrude(height= 200)
1088             ButtonCoverProfile();
1089         }
1090       }
1091
1092       // hinge arms
1093       HingePortion(hex20, hex21) HingeLidProfile();
1094
1095       // catch
1096       CatchPortion(catch_width)
1097         CatchCatchProfile();
1098     }
1099     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1100
1101     translate(skew_centre)
1102       multmatrix([[ 1, 0, 0, 0 ],
1103                   [ 0, 1, 2, 0 ],
1104                   [ 0, 0, 1, 0 ],
1105                   [ 0, 0, 0, 1 ]])
1106       translate(-skew_centre)
1107       LidAroundEdges()
1108       LidEdgeFoldClearanceProfile();
1109
1110     // screw holes in the hinge arms
1111     HingeScrews();
1112
1113     // prop recess
1114     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1115       mirror([0,1,0])
1116       rotate([90,0,90])
1117       linextr(-prop_recess_hw, +prop_recess_hw)
1118       hull()
1119       for (pa = prop_angles)
1120         PropProfile(pa, 1,1);
1121
1122     // notification led aperture
1123     if (led_window_style)
1124       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1125         translate([0,0,-10])
1126           cylinder(r=nla_r0, h=20);
1127         if (led_window_style >= 2)
1128           translate([0,0, -nla_t])
1129             cylinder(r=nla_r2, height=20);
1130       }
1131
1132     }
1133
1134   LidAdhocMultiprintFrame(1);
1135 }
1136
1137 module HingeLever(){ ////toplevel
1138   difference() {
1139     // outer body, positive
1140     HingePortion(hex22, hex22 + phone_width/2)
1141       HingeLeverOuterProfile();
1142
1143     // space for the screws
1144     HingePortion(hex26, hex24)
1145       HingeLeverInnerProfile();
1146
1147     // recesses for the nuts
1148     HingePortion(hex23, hex26+1)
1149       HingeLeverNutProfile();
1150
1151     // bores for the screws
1152     HingeScrews();
1153
1154     // space for the charging cable
1155     MicroUSB();
1156     Flip_hinge() MicroUSB();
1157   }
1158 }
1159
1160 module LidWindow(){ ////toplevel
1161   translate([led_pos[0], -led_pos[1], lpp13[1]])
1162     mirror([0,0,1])
1163     cylinder(r= nla_r1, h=nla_t);
1164   LidAdhocMultiprintFrame(0);
1165 }
1166
1167 module LidWindowPrint(){ ////toplevel
1168   rotate([0,180,0])
1169     LidWindow();
1170 }
1171
1172 module DemoLidWindowSelect(){
1173   translate([led_pos[0], led_pos[1], -100]) {
1174     translate([0, -30, 0]) cube([400, 400, 200]);
1175   }
1176 }
1177
1178 module DemoLidWindow(){ ////toplevel
1179   %Lid();
1180   LidWindow();
1181   translate([0,40,0]){
1182     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1183     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1184   }
1185 }
1186
1187 module HingeLeverPrint(){ ////toplevel
1188   rotate([-90,0,0])
1189     translate([-phone_width/2, phone_height, 0])
1190     HingeLever();
1191 }
1192
1193 module TestSelectLength(){
1194   translate([-30, -200, -20])
1195     cube([30 + 15, 250, 40]);
1196 }
1197
1198 module TestLength(){ ////toplevel
1199   intersection(){
1200     Case();
1201     TestSelectLength();
1202   }
1203 }
1204
1205 module TestLengthRight(){ ////toplevel
1206   intersection(){
1207     Case();
1208     Flip_rhs(1)
1209       TestSelectLength();
1210   }
1211 }
1212
1213 module TestSelectWidth(){
1214   translate([-30, -(phone_height - 25), -20])
1215     mirror([0, 1, 0])
1216     cube([200, 50, 40]);
1217 }
1218
1219 module TestWidth(){ ////toplevel
1220   intersection(){
1221     Case();
1222     TestSelectWidth();
1223   }
1224 }
1225
1226 module TestLidWidthPrint(){ ////toplevel
1227   rotate([0,180.0]) intersection(){
1228     Lid();
1229     TestSelectWidth();
1230   }
1231 }
1232
1233 module TestSelectRearAperture(){
1234   minkowski(){
1235     union() children();
1236     translate([20, 0,0])
1237       cube([42, 2, 1], center=true);
1238   }
1239 }
1240
1241 module TestSelectCamera(){
1242   minkowski(){
1243     TestSelectRearAperture()
1244       RearCameraAperture();
1245     cube([0.1, 50, 0.1]);
1246   }
1247 }
1248
1249 module TestSelectOrdinaryRearApertures(){
1250   TestSelectRearAperture()
1251     OrdinaryRearApertures();
1252 }
1253
1254 module TestCamera(){ ////toplevel
1255   intersection(){
1256     Case();
1257     TestSelectCamera();
1258   }
1259 }
1260
1261 module TestLidByCamera(){ ////toplevel
1262   intersection(){
1263     Lid();
1264     TestSelectCamera();
1265   }
1266 }
1267
1268 module TestLidByCameraPrint(){ ////toplevel
1269   rotate([180,0,0]) TestLidByCamera();
1270 }
1271
1272 module DemoByCamera(){ ////toplevel
1273   color("blue") TestLidByCamera();
1274   color("red")  TestCamera();
1275 }
1276
1277 module OneKeeper(){ ////toplevel
1278   translate([0, -phone_cnr_rad, 0])
1279     rotate([90, 0, 0])
1280     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1281     KeeperProfile();
1282 }
1283
1284 module OneKeeperPrint(){ ////toplevel
1285   rotate([0,180,0])
1286     OneKeeper();
1287 }
1288
1289 module LidPrint(){ ////toplevel
1290   rotate([0,180,0])
1291     Lid();
1292 }
1293
1294 module TestSelectFrame(){
1295   include = [1,-1] * (epp2i[0] + 4);
1296
1297   difference(){
1298     cube(1000, center=true);
1299     translate([0,0, -100])
1300       linear_extrude(height=200)
1301       rectfromto(include,  inside_br - include);
1302   }
1303 }
1304
1305 module TestSelectLidFrame(){
1306   TestSelectFrame();
1307   translate([led_pos[0], -led_pos[1], -50])
1308     cylinder(r= nla_r2+3, h=100);
1309 }
1310
1311 module TestFrameCase(){ ////toplevel
1312   intersection(){
1313     Case();
1314     union(){
1315       TestSelectFrame();
1316       TestSelectCamera();
1317       TestSelectOrdinaryRearApertures();
1318     }
1319   }
1320 }
1321
1322 module TestSelectTopApertures(){
1323   translate([-100, -35, -100])
1324     cube([400, 100, 200]);
1325   LidAdhocMultiprintFrame(0);
1326   LidAdhocMultiprintFrame(1);
1327 }
1328
1329 module TestTopApertures(){ ////toplevel
1330   intersection(){
1331     Case();
1332     TestSelectFrame();
1333     TestSelectTopApertures();
1334   }
1335 }
1336
1337 module TestLidTopAperturesPrint(){ ////toplevel
1338   rotate([0,180,0]) intersection(){
1339     Lid();
1340     TestSelectLidFrame();
1341     TestSelectTopApertures();
1342   }
1343 }
1344
1345 module TestLidWindowTopAperturesPrint(){ ////toplevel
1346   rotate([0,180,0]) intersection(){
1347     LidWindow();
1348     TestSelectTopApertures();
1349   }
1350 }
1351
1352 module TestFrameLidPrint(){ ////toplevel
1353   rotate([0,180,0]) intersection(){
1354     Lid();
1355     TestSelectLidFrame();
1356   }
1357 }
1358
1359 module ButtonPlanForDemo(z, deep, cut){
1360   translate([0,0,z])
1361     ButtonPlan(8, deep, cut);
1362 }
1363
1364 module HingeScrews(){
1365   Flip_rhs() Flip_bot(1){
1366     for (c= [ hppT, hppB ])
1367       translate([ hex20,
1368                   -c[0],
1369                   c[1] ]){
1370         rotate([0,90,0])
1371           translate([0,0,-.2])
1372           cylinder( r= hingescrew_shaft_dia/2,
1373                     h = hingescrew_shaft_len+0.2 );
1374         rotate([0,-90,0])
1375           translate([0,0,+.1])
1376           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1377       }
1378   }
1379 }
1380
1381 module DemoPropAngleSelect(c){
1382   color(c) difference(){
1383     union(){ children(); }
1384     translate([ prop_x_pos, -400, -200 ])
1385       cube([ 400,800,400 ]);
1386   }
1387 }
1388
1389 module DemoPropAngle(ang){
1390   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1391   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1392
1393   translate(hL)
1394     rotate([ang/2,0,0])
1395     translate(-hL)
1396     translate(hC)
1397     rotate([ang/2,0,0])
1398     translate(-hC) {
1399       DemoPropAngleSelect("red") Case();
1400
1401       color("orange")
1402         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1403         PropProfileAssignments(ang) {
1404           echo($prpp1);
1405           rotate([-$prp_theta, 0, 0])
1406           translate([0, $prpp1[0], -$prpp1[1]])
1407           rotate([90,0,-90])
1408           Prop();
1409         }
1410     }
1411
1412   translate([0,0, -hp_k*2])
1413     DemoPropAngleSelect("blue")
1414     Lid();
1415 }
1416
1417 module DemoPropAngles(){ ////toplevel
1418   for (i=[0 : len(prop_angles)-1])
1419     translate(i * [0, -100, 100])
1420     DemoPropAngle(prop_angles[i]);
1421 }
1422
1423 module DemoHingeAngle(ang1,ang2){
1424   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1425   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1426
1427   translate(hL)
1428     rotate([ang2,0,0])
1429     translate(-hL)
1430     translate(hC)
1431     rotate([ang1,0,0])
1432     translate(-hC) {
1433       color("red") Lid();
1434     }
1435
1436   color("blue") intersection(){
1437     Case();
1438     union(){
1439       translate([bppJ[0], -400, -200])
1440         mirror([1,0,0])
1441         cube([400, 800, 400]);
1442       translate([10, -400, -200])
1443         cube([10, 800, 400]);
1444     }
1445   }
1446 }
1447
1448 module DemoHingeAngles(){ ////toplevel
1449   angles = [ 0, 4, 8, 12 ];
1450   echo("angles",angles);
1451   for (i=[0 : len(angles)-1]) {
1452     translate(i * [0, 0, 30]) {
1453       DemoHingeAngle(0,angles[i]);
1454       translate([0, 200, 0])
1455         DemoHingeAngle(angles[i],0);
1456     }
1457   }
1458 }
1459
1460 module DemoSelectAdhocLeftRight(right=0) {
1461   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1462     mirror([1-right, 0,0])
1463     cube([400, 800, 200]);
1464 }
1465
1466 module DemoLeft(){ ////toplevel
1467   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1468   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1469 }
1470
1471 module DemoFrame(){ ////toplevel
1472   color("red") TestFrameCase();
1473   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1474   color("black") HingeScrews();
1475   %HingeLever();
1476 }
1477
1478 module DemoHingedFrame(){ ///toplevel
1479   color("red") TestFrameCase();
1480   translate([0,0, -2*hp_k])
1481   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1482
1483   Flip_hinge(){
1484     color("orange") HingeLever();
1485     color("black") HingeScrews();
1486   }
1487 }
1488
1489 module DemoHinge(){ ////toplevel
1490   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1491     DemoFrame();
1492     translate([0,0, -hp_k*3])
1493       DemoHingedFrame();
1494   }
1495 }
1496
1497 module DemoProfiles(){ ////toplevel
1498   LidEdgeProfile();
1499   %EdgeProfile();
1500   KeeperProfile();
1501   translate([0,0,-1]) color("black") KeeperProfile(1);
1502
1503   translate([20,0]) {
1504     LidEdgeProfile();
1505     %EdgeProfile();
1506
1507     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1508
1509     color("blue") ButtonCoverProfile();
1510     color("red") {
1511       rectfromto(bppQ, demopoint_QR);
1512       rectfromto(bppR, demopoint_QR);
1513     }
1514   }
1515
1516   translate([-20,0]) {
1517     color("black") ButtonPlanForDemo(-2, 0,1);
1518     color("red" )  ButtonPlanForDemo(-4, 1,1);
1519     color("blue")  ButtonPlanForDemo(-6, 1,0);
1520   }
1521
1522   translate([0, -30]) {
1523     %LidEdgeProfile();
1524     %EdgeProfile();
1525     color("blue") HingeLidProfile();
1526     color("red")  HingeBaseProfile();
1527     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1528   }
1529
1530   for (f=[0,1]) {
1531     translate([-30, -60 + 30*f]) {
1532       translate([0,0,-4]) EdgeProfile();
1533       %translate([0,0,-10]) HingeBaseProfile();
1534       translate([0,-2] * f * hp_k) {
1535         translate([0,0,-4]) LidEdgeProfile();
1536         %translate([0,0,-10]) %HingeLidProfile();
1537       }
1538       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1539         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1540         translate([0,0,0]) color("red") difference(){
1541           HingeLeverOuterProfile();
1542           HingeLeverInnerProfile();
1543         }
1544         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1545       }
1546     }
1547   }
1548
1549   translate([20,-30]) {
1550     %EdgeProfile();
1551     %LidEdgeProfile();
1552     //translate([0,0,1]) CatchCutProfile();
1553     color("blue") CatchCatchProfile();
1554     color("red") difference(){ EdgeProfile(); CatchCutProfile(); }
1555   }
1556
1557   translate([40,-30]) {
1558     difference(){
1559       LidEdgeProfile();
1560       translate(prlp10)
1561         PropProfile(10, 1, 0);
1562     }
1563     translate(prlp10)
1564       PropProfile(15, 0);
1565   }
1566   translate([60,-30]) {
1567     PropAggregateProfile();
1568   }
1569 }
1570
1571 //EdgeProfile();
1572 //KeeperProfile();
1573 //CaseBase();
1574 //%Case();
1575 //Keeper();
1576 //LidEdgeProfile();
1577 //KeeperProfile();
1578 //DemoProfiles();
1579 //PropRecess();