fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone_height = 146.5 - .80;
   4 phone_width = 76.75 - .50;
   5
   6 phone_cnr_rad = 6.0;
   7
   8 button_cutout_depth = 9;
   9
  10 phone_edge_thick = 9.0;
  11 phone_total_thick = 12.0;
  12 phone_backside_slope_inner = 1.5; // larger means shallower
  13 phone_backside_slope_outer = 1.0; // larger means shallower
  14
  15 camera_pos_tl = [  7.0, 13.0 ]; // measured from tl corner
  16 camera_pos_br = [ 22.85,37.85]; // tl/br as seen from back
  17
  18 case_th_bottom = 2.5;
  19 case_th_lid = 2.5;
  20 case_th_side = 2;
  21 case_th_lip = 1.2;
  22
  23 case_struts_count = 6;
  24 case_struts_solid_below = 1.00;
  25 case_struts_solid_above = 0.75;
  26 case_struts_width = 0.10;
  27
  28 keeper_th_z = 0.75;
  29 keeper_th_x = 0.75;
  30 keeper_inner_width = 2.75;
  31 keeper_inner_height = 2.75;
  32 keeper_slant_slope = 2; // larger means steeper
  33
  34 keeper_gap_z_top = 0.25;
  35 keeper_gap_z_bot = 0.75;
  36 keeper_gap_x     = 0.25;
  37 keeper_gap_x_holes = 0.75;
  38
  39 case_lip = 1.25;
  40
  41 lid_gap_x = 0.25;
  42 lid_gap_z = 0.25;
  43 lid_lip = 1.75;
  44
  45 $fa = 5;
  46 $fs = 0.1;
  47
  48 button_l_fudge = 4.5;
  49
  50 strut_min_at_end = 1.5;
  51
  52 // ---------- calculated ----------
  53
  54 // ----- could be changed -----
  55 lid_buttoncover_gap = lid_gap_x;
  56 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  57
  58 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  59
  60 //lid_lip_overlap_width xxx bad name = ;
  61 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  62
  63 epp0 = [0,0];
  64 epp1 = [0, -phone_edge_thick];
  65 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  66 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  67 epp3 = epp2i + [10, 0];
  68 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  69 epp4 = epp5 + [-1,0] * case_th_side;
  70
  71 kppe = [0,0];
  72 kppd = kppe + [1,0] * keeper_inner_width;
  73 kppc = kppd + [0,1] * keeper_th_z;
  74 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  75 kppf = kppe - [0,1] * keeper_inner_height;
  76 kppa = [ kppb[0], kppf[1] ];
  77
  78 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  79 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  80
  81 lp_r12 = case_th_lid - (lpp11[1] - lpp10[1]);
  82
  83 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
  84 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
  85
  86 echo(lpp13 - lpp10);
  87
  88 // button profile
  89 bppM = epp4 + [0,5];
  90 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  91 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
  92 bppS = [ epp1[0], bppR[1] ];
  93 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
  94 bppP = bppQ + [0,1] * lid_buttoncover_gap;
  95 bppO = [ bppN[0], bppP[1] ];
  96 bppL = lpp10 + [5,0];
  97 bppK = [ bppL[0], bppN[1] ];
  98 bppJ = [ bppN[0], bppL[1] ];
  99
 100 module rectfromto(a,b) {
 101   ab = b - a;
 102   translate([min(a[0], b[0]), min(a[1], b[1])])
 103     square([abs(ab[0]), abs(ab[1])]);
 104 }
 105 module circleat(c,r) { translate(c) circle(r); }
 106
 107 module KeeperProfile(slant=0){
 108   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 109   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 110 }
 111
 112 module EdgeProfile(){
 113   difference(){
 114     hull(){
 115       translate(epp3) square(case_th_bottom*2, center=true);
 116       circleat(epp2o, r=case_th_bottom);
 117       circleat(epp1, r=case_th_side);
 118       rectfromto(epp0, epp4);
 119     }
 120     polygon([ epp5 + [0,10],
 121               epp1,
 122               epp2i,
 123               epp3 + [10,0] ]);
 124   }
 125 }
 126
 127 module LidEdgeProfile(){
 128   polygon([ lpp10,
 129             lpp11,
 130             lpp12,
 131             lpp13,
 132             lpp13 + [10, 0],
 133             lpp10 + [10, 0]
 134             ]);
 135   intersection(){
 136     circleat(lpp12, r=lp_r12);
 137     rectfromto( lpp12 + [-10,   0],
 138                 lpp12 + [+10, +10] );
 139   }
 140 }
 141
 142 module ButtonCoverProfile(){
 143   intersection(){
 144     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 145     hull(){
 146       EdgeProfile();
 147       LidEdgeProfile();
 148     }
 149   }
 150 }
 151
 152 module ButtonPlan(l, deep, cut){
 153   bigger =
 154     (deep ? lid_buttoncover_overlap : 0) +
 155     (cut  ? 0 : -lid_buttoncover_gap);
 156
 157   d_D1_y =
 158     (cut  ? 0 : lid_buttoncover_gap);
 159
 160   C = [0,0]; // by definition
 161   T = [ 0, epp4[1] ];
 162   G = T + [0,10];
 163   B0 = C + [0,-1] * button_cutout_depth;
 164   r0 = 0.5 * (T[1] - B0[1]);
 165   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 166   r1 = r0 + bigger;
 167   // | D1 - A | = r1 * 2
 168   // D1_y = T_y - r1 + d_D1_y
 169   // =>    4 * r1^2   =  (r1-r0 + d_D1_y)^2 + (D1_x - A_x)^2
 170   // =>    D1_x =  A_x + v/~ [  4 * r1^2   -   (r1-r0 + d_D1_y)^2 ]
 171   D1  = [ A[0] - sqrt( 4*r1*r1 - pow(bigger + d_D1_y, 2) ),
 172           T[1] - r1 + d_D1_y ];
 173   E1  = 0.5 * (D1 + A);
 174   F1  = D1 + [0,10];
 175
 176   hull(){
 177     for (m=[0,1]) mirror([m,0])
 178       circleat(A, r1);
 179   }
 180   for (m=[0,1]) mirror([m,0]) {
 181     difference(){
 182       polygon([ E1,
 183                 A,
 184                 B0,
 185                 G,
 186                 F1,
 187                 D1
 188                 ]);
 189       circleat(D1, r1);
 190     }
 191   }
 192 }
 193
 194 module CaseBase_rhsflip(yn=[0,1]) {
 195   for (rhs=yn) {
 196     translate([phone_width/2, 0, 0])
 197       mirror([rhs,0,0])
 198       translate([-phone_width/2, 0, 0])
 199       children();
 200   }
 201 }
 202
 203 module CaseBase_botflip() {
 204   for (bot=[0,1]) {
 205     translate([0, -phone_height/2, 0])
 206       mirror([0, bot, 0])
 207       translate([0, phone_height/2, 0])
 208       children();
 209   }
 210 }
 211
 212 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 213   // sides
 214   CaseBase_rhsflip(){
 215     translate([0, -phone_cnr_rad, 0])
 216       rotate([90,0,0])
 217       linear_extrude(height = phone_height - phone_cnr_rad*2)
 218       children(0);
 219   }
 220   // corners
 221   CaseBase_rhsflip() CaseBase_botflip() {
 222     translate([+1,-1] * phone_cnr_rad)
 223       intersection(){
 224         rotate_extrude()
 225           intersection(){
 226             mirror([1,0,0])
 227               translate([-1,0] * phone_cnr_rad)
 228               children(0);
 229             rectfromto([0,-20],[10,20]);
 230           }
 231         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 232           cube([10,10,40]);
 233       }
 234   }
 235   // top and bottom
 236   CaseBase_botflip(){
 237     translate([ phone_width - phone_cnr_rad, 0,0 ])
 238       rotate([90,0,-90])
 239       linear_extrude(height = phone_width - phone_cnr_rad*2)
 240       children(0);
 241   }
 242   // fill
 243   translate([0,0, fill_zstart])
 244     mirror([0,0, fill_downwards])
 245     linear_extrude(height = fill_th)
 246     rectfromto([+1,-1] * phone_cnr_rad,
 247                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 248 }
 249
 250 module Struts(x_start, z_min, th){
 251   // if th is negative, starts at z_min and works towards -ve z
 252   // and object should then be printed other way up
 253   for (i= [1 : 1 : case_struts_count]) {
 254     translate([0,
 255                0,
 256                z_min])
 257       mirror([0,0, th<0 ? 1 : 0])
 258       translate([0,
 259                  -phone_height * i / (case_struts_count+1),
 260                  case_struts_solid_below])
 261       linear_extrude(height= abs(th)
 262                      -(case_struts_solid_below+case_struts_solid_above))
 263       rectfromto([               x_start, -0.5 * case_struts_width ],
 264                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 265   }
 266 }
 267
 268 module CaseBase(){
 269   AroundEdges(epp3[1], case_th_bottom, 1)
 270     EdgeProfile();
 271 }
 272
 273 module Case(){ ////toplevel
 274   difference(){
 275     union(){
 276       CaseBase();
 277
 278       // ledge (fixed keeper)
 279       intersection(){
 280         rotate([90, 0, 0])
 281           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 282           KeeperProfile(1);
 283
 284         // outline of the whole case, to stop it protruding
 285         translate([0,0, -25])
 286           linear_extrude(height = 50)
 287           hull()
 288           // CaseBase_rhsflip() // actually, we only care about the LH
 289           CaseBase_botflip()
 290           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 291       }
 292     }
 293
 294     // slot for keeper
 295     CaseBase_rhsflip(1)
 296       translate([0, -phone_cnr_rad, 0])
 297       rotate([90, 0, 0])
 298       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 299       minkowski(){
 300         KeeperProfile();
 301         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 302                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 303       }
 304
 305     // front camera
 306     CaseBase_rhsflip([1])
 307       mirror([0, 0, 1])
 308       linear_extrude(height = 20)
 309       mirror([0, 1, 0])
 310       rectfromto(camera_pos_tl, camera_pos_br);
 311
 312     // struts (invisible, because they're buried in the case)
 313     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
 314   }
 315 }
 316
 317 module Lid(){ ////toplevel
 318   difference(){
 319     union(){
 320       %AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 321         LidEdgeProfile();
 322     }
 323     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
 324   }
 325 }
 326
 327 module TestLength(){ ////toplevel
 328   intersection(){
 329     Case();
 330     translate([-30, -200, -20])
 331     cube([30 + 15, 250, 40]);
 332   }
 333 }
 334
 335 module TestWidth(){ ////toplevel
 336   intersection(){
 337     Case();
 338     translate([-30, -(phone_height - 25), -20])
 339       mirror([0, 1, 0])
 340       cube([200, 50, 40]);
 341   }
 342 }
 343
 344 module TestLidWidthPrint(){ ////toplevel
 345   rotate([0,180.0])
 346     intersection(){
 347       Lid();
 348       translate([-30, -(phone_height - 25), -20])
 349         mirror([0, 1, 0])
 350         cube([200, 50, 40]);
 351     }
 352 }
 353
 354 module TestCamera(){ ////toplevel
 355   intersection(){
 356     Case();
 357     CaseBase_rhsflip(1)
 358       translate([0,0,-25])
 359       linear_extrude(height = 50)
 360       mirror([0, 1, 0])
 361       rectfromto([-20, -20],
 362                  camera_pos_br + [ 5, 5 ]);
 363   }
 364 }
 365
 366 module OneKeeper(){ ////toplevel
 367   translate([0, -phone_cnr_rad, 0])
 368     rotate([90, 0, 0])
 369     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 370     KeeperProfile();
 371 }
 372
 373 module OneKeeperPrint(){ ////toplevel
 374   rotate([0,180,0])
 375     OneKeeper();
 376 }
 377
 378 module Keeper(){ ////toplevel
 379   CaseBase_rhsflip()
 380     OneKeeper();
 381 }
 382
 383 module ButtonPlanForDemo(colour, z, deep, cut){
 384   color(colour)
 385     translate([0,0,z])
 386     ButtonPlan(8, deep, cut);
 387 }
 388
 389 module DemoProfiles(){ ////toplevel
 390   LidEdgeProfile();
 391   %EdgeProfile();
 392   KeeperProfile();
 393   translate([0,0,-1]) color("black") KeeperProfile(1);
 394
 395   translate([20,0]) {
 396     LidEdgeProfile();
 397     %EdgeProfile();
 398
 399     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 400
 401     color("blue") ButtonCoverProfile();
 402     color("red") {
 403       rectfromto(bppQ, demopoint_QR);
 404       rectfromto(bppR, demopoint_QR);
 405     }
 406   }
 407
 408   translate([-20,0]) {
 409     ButtonPlanForDemo("grey", -1, 0,1);
 410     ButtonPlanForDemo("blue", -2, 1,0);
 411     ButtonPlanForDemo("red",  -3, 1,1);
 412   }
 413 }
 414
 415 //EdgeProfile();
 416 //KeeperProfile();
 417 //CaseBase();
 418 //%Case();
 419 //Keeper();
 420 //LidEdgeProfile();
 421 //KeeperProfile();
 422 //DemoProfiles();