fairphone-case.scad

   1 // -*- C -*-
   2
   3 phone_height = 146.5 - .80;
   4 phone_width = 76.75;
   5
   6 phone_cnr_rad = 6.0;
   7
   8 button_cutout_depth = 9;
   9
  10 phone_edge_thick = 9.0;
  11 phone_total_thick = 12.0;
  12 phone_backside_slope_inner = 1.5; // larger means shallower
  13 phone_backside_slope_outer = 1.0; // larger means shallower
  14
  15 camera_pos_tl = [  7.0, 13.0 ]; // measured from tl corner
  16 camera_pos_br = [ 24.0, 39.5 ]; // tl/br as seen from back
  17
  18 case_th_bottom = 2.5;
  19 case_th_lid = 2.5;
  20 case_th_side = 2;
  21 case_th_lip = 1.2;
  22
  23 case_struts_count = 6;
  24 case_struts_solid_below = 0.75;
  25 case_struts_solid_above = 1.00;
  26 case_struts_width = 0.10;
  27
  28 keeper_th_z = 0.75;
  29 keeper_th_x = 0.75;
  30 keeper_inner_width = 2.75;
  31 keeper_inner_height = 2.75;
  32
  33 keeper_gap_z_top = 0.25;
  34 keeper_gap_z_bot = 0.75;
  35 keeper_gap_x     = 0.25;
  36 keeper_gap_x_holes = 0.75;
  37
  38 case_lip = 1.25;
  39
  40 lid_gap_x = 0.25;
  41 lid_gap_z = 0.25;
  42 lid_lip = 1.75;
  43
  44 $fa = 5;
  45 $fs = 0.1;
  46
  47 button_l_fudge = 4.5;
  48
  49 // ---------- calculated ----------
  50
  51 // ----- could be changed -----
  52 lid_buttoncover_gap = lid_gap_x;
  53 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
  54
  55 phone_backside_slope_thick = phone_total_thick - phone_edge_thick;
  56
  57 //lid_lip_overlap_width xxx bad name = ;
  58 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
  59
  60 epp0 = [0,0];
  61 epp1 = [0, -phone_edge_thick];
  62 epp2i = epp1 + phone_backside_slope_thick * [ phone_backside_slope_inner, -1 ];
  63 epp2o = epp1 + phone_backside_slope_thick * [ phone_backside_slope_outer, -1 ];
  64 epp3 = epp2i + [10, 0];
  65 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
  66 epp4 = epp5 + [-1,0] * case_th_side;
  67
  68 kppe = [0,0];
  69 kppd = kppe + [1,0] * keeper_inner_width;
  70 kppc = kppd + [0,1] * keeper_th_z;
  71 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
  72 kppf = kppe - [0,1] * keeper_inner_height;
  73 kppa = [ kppb[0], kppf[1] ];
  74
  75 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
  76 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
  77 lpp12 = [ epp4[0] + lid_lip,   lpp11[1] ];
  78 lpp13 = [ lpp12[0],            lpp12[1] + lid_lip ];
  79
  80 // button profile
  81 bppM = epp4 + [0,5];
  82 bppN = [ 0.5 * (epp0[0] + epp4[0]), bppM[1] ];
  83 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
  84 bppS = [ epp1[0], bppR[1] ];
  85 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
  86 bppP = bppQ + [0,1] * lid_buttoncover_gap;
  87 bppO = [ bppN[0], bppP[1] ];
  88 bppL = lpp10 + [5,0];
  89 bppK = [ bppL[0], bppN[1] ];
  90 bppJ = [ bppN[0], bppL[1] ];
  91
  92 module rectfromto(a,b) {
  93   ab = b - a;
  94   translate([min(a[0], b[0]), min(a[1], b[1])])
  95     square([abs(ab[0]), abs(ab[1])]);
  96 }
  97 module circleat(c,r) { translate(c) circle(r); }
  98
  99 module KeeperProfile(){
 100   polygon([kppe, kppd, kppc, kppb, kppa, kppf]);
 101 }
 102
 103 module EdgeProfile(){
 104   difference(){
 105     hull(){
 106       translate(epp3) square(case_th_bottom*2, center=true);
 107       circleat(epp2o, r=case_th_bottom);
 108       circleat(epp1, r=case_th_side);
 109       rectfromto(epp0, epp4);
 110     }
 111     polygon([ epp5 + [0,10],
 112               epp1,
 113               epp2i,
 114               epp3 + [10,0] ]);
 115   }
 116 }
 117
 118 module LidEdgeProfile(){
 119   polygon([ lpp10,
 120             lpp11,
 121             lpp12,
 122             lpp13,
 123             lpp13 + [10, 0],
 124             lpp10 + [10, 0]
 125             ]);
 126   intersection(){
 127     circleat(lpp12, r=lid_lip);
 128     rectfromto( lpp12 + [-10,   0],
 129                 lpp12 + [+10, +10] );
 130   }
 131 }
 132
 133 module ButtonCoverProfile(){
 134   intersection(){
 135     polygon([ bppM, bppP, bppO, bppJ, bppL, bppK ]);
 136     hull(){
 137       EdgeProfile();
 138       LidEdgeProfile();
 139     }
 140   }
 141 }
 142
 143 module ButtonPlan(l, deep, cut){
 144   bigger =
 145     (deep ? lid_buttoncover_overlap : 0) +
 146     (cut  ? 0 : -lid_buttoncover_gap);
 147
 148   d_D1_y =
 149     (cut  ? 0 : lid_buttoncover_gap);
 150
 151   C = [0,0]; // by definition
 152   T = [ 0, epp4[1] ];
 153   G = T + [0,10];
 154   B0 = C + [0,-1] * button_cutout_depth;
 155   r0 = 0.5 * (T[1] - B0[1]);
 156   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 157   r1 = r0 + bigger;
 158   // | D1 - A | = r1 * 2
 159   // D1_y = T_y - r1 + d_D1_y
 160   // =>    4 * r1^2   =  (r1-r0 + d_D1_y)^2 + (D1_x - A_x)^2
 161   // =>    D1_x =  A_x + v/~ [  4 * r1^2   -   (r1-r0 + d_D1_y)^2 ]
 162   D1  = [ A[0] - sqrt( 4*r1*r1 - pow(bigger + d_D1_y, 2) ),
 163           T[1] - r1 + d_D1_y ];
 164   E1  = 0.5 * (D1 + A);
 165   F1  = D1 + [0,10];
 166
 167   hull(){
 168     for (m=[0,1]) mirror([m,0])
 169       circleat(A, r1);
 170   }
 171   for (m=[0,1]) mirror([m,0]) {
 172     difference(){
 173       polygon([ E1,
 174                 A,
 175                 B0,
 176                 G,
 177                 F1,
 178                 D1
 179                 ]);
 180       circleat(D1, r1);
 181     }
 182   }
 183 }
 184
 185 module CaseBase_rhsflip(yn=[0,1]) {
 186   for (rhs=yn) {
 187     translate([phone_width/2, 0, 0])
 188       mirror([rhs,0,0])
 189       translate([-phone_width/2, 0, 0])
 190       children();
 191   }
 192 }
 193
 194 module CaseBase_botflip() {
 195   for (bot=[0,1]) {
 196     translate([0, -phone_height/2, 0])
 197       mirror([0, bot, 0])
 198       translate([0, phone_height/2, 0])
 199       children();
 200   }
 201 }
 202
 203 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 204   // sides
 205   CaseBase_rhsflip(){
 206     translate([0, -phone_cnr_rad, 0])
 207       rotate([90,0,0])
 208       linear_extrude(height = phone_height - phone_cnr_rad*2)
 209       children(0);
 210   }
 211   // corners
 212   CaseBase_rhsflip() CaseBase_botflip() {
 213     translate([+1,-1] * phone_cnr_rad)
 214       intersection(){
 215         rotate_extrude()
 216           intersection(){
 217             mirror([1,0,0])
 218               translate([-1,0] * phone_cnr_rad)
 219               children(0);
 220             rectfromto([0,-20],[10,20]);
 221           }
 222         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 223           cube([10,10,40]);
 224       }
 225   }
 226   // top and bottom
 227   CaseBase_botflip(){
 228     translate([ phone_width - phone_cnr_rad, 0,0 ])
 229       rotate([90,0,-90])
 230       linear_extrude(height = phone_width - phone_cnr_rad*2)
 231       children(0);
 232   }
 233   // fill
 234   translate([0,0, fill_zstart])
 235     mirror([0,0, fill_downwards])
 236     linear_extrude(height = fill_th)
 237     rectfromto([+1,-1] * phone_cnr_rad,
 238                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 239 }
 240
 241 module CaseBase(){
 242   AroundEdges(epp3[1], case_th_bottom, 1)
 243     EdgeProfile();
 244 }
 245
 246 module Case(){ ////toplevel
 247   difference(){
 248     union(){
 249       CaseBase();
 250
 251       // ledge (fixed keeper)
 252       intersection(){
 253         rotate([90, 0, 0])
 254           linear_extrude(height = phone_height + phone_cnr_rad * 2)
 255           KeeperProfile();
 256
 257         // outline of the whole case, to stop it protruding
 258         translate([0,0, -25])
 259           linear_extrude(height = 50)
 260           hull()
 261           // CaseBase_rhsflip() // actually, we only care about the LH
 262           CaseBase_botflip()
 263           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
 264       }
 265     }
 266
 267     // slot for keeper
 268     CaseBase_rhsflip(1)
 269       translate([0, -phone_cnr_rad, 0])
 270       rotate([90, 0, 0])
 271       linear_extrude(height = phone_height + phone_cnr_rad * 2)
 272       minkowski(){
 273         KeeperProfile();
 274         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
 275                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
 276       }
 277
 278     // front camera
 279     CaseBase_rhsflip([1])
 280       mirror([0, 0, 1])
 281       linear_extrude(height = 20)
 282       mirror([0, 1, 0])
 283       rectfromto(camera_pos_tl, camera_pos_br);
 284
 285     // struts (invisible, because they're buried in the case)
 286     for (i= [1 : 1 : case_struts_count]) {
 287       translate([0,
 288                  -phone_height * i / (case_struts_count+1),
 289                  epp2i[1] - case_th_bottom + case_struts_solid_below])
 290         linear_extrude(height= case_th_bottom
 291                        -(case_struts_solid_below+case_struts_solid_above))
 292         rectfromto([               epp2i[0], -0.5 * case_struts_width ],
 293                    [ phone_width - epp2i[0], +0.5 * case_struts_width ]);
 294     }
 295   }
 296 }
 297
 298 module Lid(){ ////toplevel
 299   AroundEdges(lpp10[1], lpp13[1] - lpp10[1], 0)
 300     LidEdgeProfile();
 301 }
 302
 303 module TestLength(){ ////toplevel
 304   intersection(){
 305     Case();
 306     translate([-30, -200, -20])
 307     cube([30 + 15, 250, 40]);
 308   }
 309 }
 310
 311 module TestWidth(){ ////toplevel
 312   intersection(){
 313     Case();
 314     translate([-30, -(phone_height - 25), -20])
 315       mirror([0, 1, 0])
 316       cube([200, 50, 40]);
 317   }
 318 }
 319
 320 module TestLidWidthPrint(){ ////toplevel
 321   rotate([0,180.0])
 322     intersection(){
 323       Lid();
 324       translate([-30, -(phone_height - 25), -20])
 325         mirror([0, 1, 0])
 326         cube([200, 50, 40]);
 327     }
 328 }
 329
 330 module TestCamera(){ ////toplevel
 331   intersection(){
 332     Case();
 333     CaseBase_rhsflip(1)
 334       translate([0,0,-25])
 335       linear_extrude(height = 50)
 336       mirror([0, 1, 0])
 337       rectfromto([-20, -20],
 338                  camera_pos_br + [ 5, 5 ]);
 339   }
 340 }
 341
 342 module OneKeeper(){ ////toplevel
 343   translate([0, -phone_cnr_rad, 0])
 344     rotate([90, 0, 0])
 345     linear_extrude(height = phone_height - phone_cnr_rad * 2)
 346     KeeperProfile();
 347 }
 348
 349 module OneKeeperPrint(){ ////toplevel
 350   rotate([0,180,0])
 351     OneKeeper();
 352 }
 353
 354 module Keeper(){ ////toplevel
 355   CaseBase_rhsflip()
 356     OneKeeper();
 357 }
 358
 359 module ButtonPlanForDemo(colour, z, deep, cut){
 360   color(colour)
 361     translate([0,0,z])
 362     ButtonPlan(8, deep, cut);
 363 }
 364
 365 module DemoProfiles(){ ////toplevel
 366   LidEdgeProfile();
 367   %EdgeProfile();
 368   KeeperProfile();
 369
 370   translate([20,0]) {
 371     LidEdgeProfile();
 372     %EdgeProfile();
 373
 374     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
 375
 376     color("blue") ButtonCoverProfile();
 377     color("red") {
 378       rectfromto(bppQ, demopoint_QR);
 379       rectfromto(bppR, demopoint_QR);
 380     }
 381   }
 382
 383   translate([-20,0]) {
 384     ButtonPlanForDemo("grey", -1, 0,1);
 385     ButtonPlanForDemo("blue", -2, 1,0);
 386     ButtonPlanForDemo("red",  -3, 1,1);
 387   }
 388 }
 389
 390 //EdgeProfile();
 391 //KeeperProfile();
 392 //CaseBase();
 393 //%Case();
 394 //Keeper();
 395 //LidEdgeProfile();
 396 //KeeperProfile();
 397 //DemoProfiles();